lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use Mouse::Util qw/:meta get_linear_isa not_supported/; # enables strict and warnings
   3
   4 use Scalar::Util qw/blessed weaken/;
   5
   6 use Mouse::Meta::Module;
   7 our @ISA = qw(Mouse::Meta::Module);
   8
   9 sub attribute_metaclass;
  10 sub method_metaclass;
  11
  12 sub constructor_class;
  13 sub destructor_class;
  14
  15 my @MetaClassTypes = qw(
  16     attribute_metaclass
  17     method_metaclass
  18     constructor_class
  19     destructor_class
  20 );
  21
  22 sub _construct_meta {
  23     my($class, %args) = @_;
  24
  25     $args{attributes} = {};
  26     $args{methods}    = {};
  27     $args{roles}      = [];
  28
  29     $args{superclasses} = do {
  30         no strict 'refs';
  31         \@{ $args{package} . '::ISA' };
  32     };
  33
  34     my $self = bless \%args, ref($class) || $class;
  35     if(ref($self) ne __PACKAGE__){
  36         $self->meta->_initialize_object($self, \%args);
  37     }
  38     return $self;
  39 }
  40
  41 sub create_anon_class{
  42     my $self = shift;
  43     return $self->create(undef, @_);
  44 }
  45
  46 sub is_anon_class;
  47
  48 sub roles;
  49
  50 sub calculate_all_roles {
  51     my $self = shift;
  52     my %seen;
  53     return grep { !$seen{ $_->name }++ }
  54            map  { $_->calculate_all_roles } @{ $self->roles };
  55 }
  56
  57 sub superclasses {
  58     my $self = shift;
  59
  60     if (@_) {
  61         foreach my $super(@_){
  62             Mouse::Util::load_class($super);
  63             my $meta = Mouse::Util::get_metaclass_by_name($super);
  64
  65             next if not defined $meta;
  66
  67             if(Mouse::Util::is_a_metarole($meta)){
  68                 $self->throw_error("You cannot inherit from a Mouse Role ($super)");
  69             }
  70
  71             next if $self->isa(ref $meta); # _superclass_meta_is_compatible
  72
  73             $self->_reconcile_with_superclass_meta($meta);
  74         }
  75         @{ $self->{superclasses} } = @_;
  76     }
  77
  78     return @{ $self->{superclasses} };
  79 }
  80
  81 sub _reconcile_with_superclass_meta {
  82     my($self, $super_meta) = @_;
  83
  84     # find incompatible traits
  85     my @incompatibles;
  86     foreach my $metaclass_type(@MetaClassTypes){
  87         my $super_c = $super_meta->$metaclass_type();
  88         my $self_c  = $self->$metaclass_type();
  89
  90         if(!$super_c->isa($self_c)){
  91             push @incompatibles, ($metaclass_type => $super_c);
  92         }
  93     }
  94
  95     my @roles;
  96     foreach my $role($super_meta->meta->calculate_all_roles){
  97         if(!$self->meta->does_role($role->name)){
  98             push @roles, $role->name;
  99         }
 100     }
 101
 102     #print "reconcile($self vs. $super_meta; @roles; @incompatibles)\n";
 103
 104     require Mouse::Util::MetaRole;
 105     Mouse::Util::MetaRole::apply_metaclass_roles(
 106         for_class       => $self,
 107         metaclass       => ref $super_meta,
 108         metaclass_roles => \@roles,
 109         @incompatibles,
 110     );
 111     return;
 112 }
 113
 114 sub find_method_by_name{
 115     my($self, $method_name) = @_;
 116     defined($method_name)
 117         or $self->throw_error('You must define a method name to find');
 118
 119     foreach my $class( $self->linearized_isa ){
 120         my $method = $self->initialize($class)->get_method($method_name);
 121         return $method if defined $method;
 122     }
 123     return undef;
 124 }
 125
 126 sub get_all_methods {
 127     my($self) = @_;
 128     return map{ $self->find_method_by_name($_) } $self->get_all_method_names;
 129 }
 130
 131 sub get_all_method_names {
 132     my $self = shift;
 133     my %uniq;
 134     return grep { $uniq{$_}++ == 0 }
 135             map { Mouse::Meta::Class->initialize($_)->get_method_list() }
 136             $self->linearized_isa;
 137 }
 138
 139 sub find_attribute_by_name{
 140     my($self, $name) = @_;
 141     my $attr;
 142     foreach my $class($self->linearized_isa){
 143         my $meta = Mouse::Util::get_metaclass_by_name($class) or next;
 144         $attr = $meta->get_attribute($name) and last;
 145     }
 146     return $attr;
 147 }
 148
 149 sub add_attribute {
 150     my $self = shift;
 151
 152     my($attr, $name);
 153
 154     if(blessed $_[0]){
 155         $attr = $_[0];
 156
 157         $attr->isa('Mouse::Meta::Attribute')
 158             || $self->throw_error("Your attribute must be an instance of Mouse::Meta::Attribute (or a subclass)");
 159
 160         $name = $attr->name;
 161     }
 162     else{
 163         # _process_attribute
 164         $name = shift;
 165
 166         my %args = (@_ == 1) ? %{$_[0]} : @_;
 167
 168         defined($name)
 169             or $self->throw_error('You must provide a name for the attribute');
 170
 171         if ($name =~ s/^\+//) { # inherited attributes
 172             my $inherited_attr = $self->find_attribute_by_name($name)
 173                 or $self->throw_error("Could not find an attribute by the name of '$name' to inherit from in ".$self->name);
 174
 175             $attr = $inherited_attr->clone_and_inherit_options(%args);
 176         }
 177         else{
 178             my($attribute_class, @traits) = $self->attribute_metaclass->interpolate_class(\%args);
 179             $args{traits} = \@traits if @traits;
 180
 181             $attr = $attribute_class->new($name, %args);
 182         }
 183     }
 184
 185     weaken( $attr->{associated_class} = $self );
 186
 187     $self->{attributes}{$attr->name} = $attr;
 188     $attr->install_accessors();
 189
 190     if(Mouse::Util::_MOUSE_VERBOSE && !$attr->{associated_methods} && ($attr->{is} || '') ne 'bare'){
 191         Carp::cluck(qq{Attribute (}.$attr->name.qq{) of class }.$self->name.qq{ has no associated methods (did you mean to provide an "is" argument?)});
 192     }
 193     return $attr;
 194 }
 195
 196 sub compute_all_applicable_attributes { # DEPRECATED
 197     Carp::cluck('compute_all_applicable_attributes() has been deprecated. Use get_all_attributes() instead');
 198
 199     return shift->get_all_attributes(@_)
 200 }
 201
 202 sub linearized_isa;
 203
 204 sub new_object;
 205
 206 sub clone_object {
 207     my $class  = shift;
 208     my $object = shift;
 209     my $args   = $object->Mouse::Object::BUILDARGS(@_);
 210
 211     (blessed($object) && $object->isa($class->name))
 212         || $class->throw_error("You must pass an instance of the metaclass (" . $class->name . "), not ($object)");
 213
 214     my $cloned = bless { %$object }, ref $object;
 215     $class->_initialize_object($cloned, $args);
 216
 217     return $cloned;
 218 }
 219
 220 sub clone_instance { # DEPRECATED
 221     my ($class, $instance, %params) = @_;
 222
 223     Carp::cluck('clone_instance() has been deprecated. Use clone_object() instead');
 224
 225     return $class->clone_object($instance, %params);
 226 }
 227
 228
 229 sub immutable_options {
 230     my ( $self, @args ) = @_;
 231
 232     return (
 233         inline_constructor => 1,
 234         inline_destructor  => 1,
 235         constructor_name   => 'new',
 236         @args,
 237     );
 238 }
 239
 240
 241 sub make_immutable {
 242     my $self = shift;
 243     my %args = $self->immutable_options(@_);
 244
 245     $self->{is_immutable}++;
 246
 247     if ($args{inline_constructor}) {
 248         my $c = $self->constructor_class;
 249         Mouse::Util::load_class($c);
 250         $self->add_method($args{constructor_name} =>
 251             $c->_generate_constructor($self, \%args));
 252     }
 253
 254     if ($args{inline_destructor}) {
 255         my $c = $self->destructor_class;
 256         Mouse::Util::load_class($c);
 257         $self->add_method(DESTROY =>
 258             $c->_generate_destructor($self, \%args));
 259     }
 260
 261     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 262     # at the end of a source file.
 263     return 1;
 264 }
 265
 266 sub make_mutable {
 267     my($self) = @_;
 268     $self->{is_immutable} = 0;
 269     return;
 270 }
 271
 272 sub is_immutable;
 273 sub is_mutable   { !$_[0]->is_immutable }
 274
 275 sub _install_modifier_pp{
 276     my( $self, $type, $name, $code ) = @_;
 277     my $into = $self->name;
 278
 279     my $original = $into->can($name)
 280         or $self->throw_error("The method '$name' is not found in the inheritance hierarchy for class $into");
 281
 282     my $modifier_table = $self->{modifiers}{$name};
 283
 284     if(!$modifier_table){
 285         my(@before, @after, @around, $cache, $modified);
 286
 287         $cache = $original;
 288
 289         $modified = sub {
 290             for my $c (@before) { $c->(@_) }
 291
 292             if(wantarray){ # list context
 293                 my @rval = $cache->(@_);
 294
 295                 for my $c(@after){ $c->(@_) }
 296                 return @rval;
 297             }
 298             elsif(defined wantarray){ # scalar context
 299                 my $rval = $cache->(@_);
 300
 301                 for my $c(@after){ $c->(@_) }
 302                 return $rval;
 303             }
 304             else{ # void context
 305                 $cache->(@_);
 306
 307                 for my $c(@after){ $c->(@_) }
 308                 return;
 309             }
 310         };
 311
 312         $self->{modifiers}{$name} = $modifier_table = {
 313             original => $original,
 314
 315             before   => \@before,
 316             after    => \@after,
 317             around   => \@around,
 318
 319             cache    => \$cache, # cache for around modifiers
 320         };
 321
 322         $self->add_method($name => $modified);
 323     }
 324
 325     if($type eq 'before'){
 326         unshift @{$modifier_table->{before}}, $code;
 327     }
 328     elsif($type eq 'after'){
 329         push @{$modifier_table->{after}}, $code;
 330     }
 331     else{ # around
 332         push @{$modifier_table->{around}}, $code;
 333
 334         my $next = ${ $modifier_table->{cache} };
 335         ${ $modifier_table->{cache} } = sub{ $code->($next, @_) };
 336     }
 337
 338     return;
 339 }
 340
 341 sub _install_modifier {
 342     my ( $self, $type, $name, $code ) = @_;
 343
 344     # load Class::Method::Modifiers first
 345     my $no_cmm_fast = do{
 346         local $@;
 347         eval q{ use Class::Method::Modifiers::Fast 0.041 () };
 348         $@;
 349     };
 350
 351     my $impl;
 352     if($no_cmm_fast){
 353         $impl = \&_install_modifier_pp;
 354     }
 355     else{
 356         my $install_modifier = Class::Method::Modifiers::Fast->can('install_modifier');
 357         $impl = sub {
 358             my ( $self, $type, $name, $code ) = @_;
 359             my $into = $self->name;
 360             $install_modifier->($into, $type, $name, $code);
 361
 362             $self->add_method($name => do{
 363                 no strict 'refs';
 364                 \&{ $into . '::' . $name };
 365             });
 366             return;
 367         };
 368     }
 369
 370     # replace this method itself :)
 371     {
 372         no warnings 'redefine';
 373         *_install_modifier = $impl;
 374     }
 375
 376     $self->$impl( $type, $name, $code );
 377 }
 378
 379 sub add_before_method_modifier {
 380     my ( $self, $name, $code ) = @_;
 381     $self->_install_modifier( 'before', $name, $code );
 382 }
 383
 384 sub add_around_method_modifier {
 385     my ( $self, $name, $code ) = @_;
 386     $self->_install_modifier( 'around', $name, $code );
 387 }
 388
 389 sub add_after_method_modifier {
 390     my ( $self, $name, $code ) = @_;
 391     $self->_install_modifier( 'after', $name, $code );
 392 }
 393
 394 sub add_override_method_modifier {
 395     my ($self, $name, $code) = @_;
 396
 397     if($self->has_method($name)){
 398         $self->throw_error("Cannot add an override method if a local method is already present");
 399     }
 400
 401     my $package = $self->name;
 402
 403     my $super_body = $package->can($name)
 404         or $self->throw_error("You cannot override '$name' because it has no super method");
 405
 406     $self->add_method($name => sub {
 407         local $Mouse::SUPER_PACKAGE = $package;
 408         local $Mouse::SUPER_BODY    = $super_body;
 409         local @Mouse::SUPER_ARGS    = @_;
 410
 411         $code->(@_);
 412     });
 413     return;
 414 }
 415
 416 sub add_augment_method_modifier {
 417     my ($self, $name, $code) = @_;
 418     if($self->has_method($name)){
 419         $self->throw_error("Cannot add an augment method if a local method is already present");
 420     }
 421
 422     my $super = $self->find_method_by_name($name)
 423         or $self->throw_error("You cannot augment '$name' because it has no super method");
 424
 425     my $super_package = $super->package_name;
 426     my $super_body    = $super->body;
 427
 428     $self->add_method($name => sub{
 429         local $Mouse::INNER_BODY{$super_package} = $code;
 430         local $Mouse::INNER_ARGS{$super_package} = [@_];
 431         $super_body->(@_);
 432     });
 433     return;
 434 }
 435
 436 sub does_role {
 437     my ($self, $role_name) = @_;
 438
 439     (defined $role_name)
 440         || $self->throw_error("You must supply a role name to look for");
 441
 442     for my $class ($self->linearized_isa) {
 443         my $meta = Mouse::Util::get_metaclass_by_name($class)
 444             or next;
 445
 446         for my $role (@{ $meta->roles }) {
 447
 448             return 1 if $role->does_role($role_name);
 449         }
 450     }
 451
 452     return 0;
 453 }
 454
 455 1;
 456 __END__
 457
 458 =head1 NAME
 459
 460 Mouse::Meta::Class - The Mouse class metaclass
 461
 462 =head1 VERSION
 463
 464 This document describes Mouse version 0.49
 465
 466 =head1 METHODS
 467
 468 =head2 C<< initialize(ClassName) -> Mouse::Meta::Class >>
 469
 470 Finds or creates a C<Mouse::Meta::Class> instance for the given ClassName. Only
 471 one instance should exist for a given class.
 472
 473 =head2 C<< name -> ClassName >>
 474
 475 Returns the name of the owner class.
 476
 477 =head2 C<< superclasses -> ClassNames >> C<< superclass(ClassNames) >>
 478
 479 Gets (or sets) the list of superclasses of the owner class.
 480
 481 =head2 C<< add_method(name => CodeRef) >>
 482
 483 Adds a method to the owner class.
 484
 485 =head2 C<< has_method(name) -> Bool >>
 486
 487 Returns whether we have a method with the given name.
 488
 489 =head2 C<< get_method(name) -> Mouse::Meta::Method | undef >>
 490
 491 Returns a L<Mouse::Meta::Method> with the given name.
 492
 493 Note that you can also use C<< $metaclass->name->can($name) >> for a method body.
 494
 495 =head2 C<< get_method_list -> Names >>
 496
 497 Returns a list of method names which are defined in the local class.
 498 If you want a list of all applicable methods for a class, use the
 499 C<get_all_methods> method.
 500
 501 =head2 C<< get_all_methods -> (Mouse::Meta::Method) >>
 502
 503 Return the list of all L<Mouse::Meta::Method> instances associated with
 504 the class and its superclasses.
 505
 506 =head2 C<< add_attribute(name => spec | Mouse::Meta::Attribute) >>
 507
 508 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 509 class.
 510
 511 =head2 C<< has_attribute(Name) -> Bool >>
 512
 513 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 514
 515 =head2 C<< get_attribute Name -> Mouse::Meta::Attribute | undef >>
 516
 517 Returns the L<Mouse::Meta::Attribute> with the given name.
 518
 519 =head2 C<< get_attribute_list -> Names >>
 520
 521 Returns a list of attribute names which are defined in the local
 522 class. If you want a list of all applicable attributes for a class,
 523 use the C<get_all_attributes> method.
 524
 525 =head2 C<< get_all_attributes -> (Mouse::Meta::Attribute) >>
 526
 527 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 528 this class and its superclasses.
 529
 530 =head2 C<< linearized_isa -> [ClassNames] >>
 531
 532 Returns the list of classes in method dispatch order, with duplicates removed.
 533
 534 =head2 C<< new_object(Parameters) -> Instance >>
 535
 536 Creates a new instance.
 537
 538 =head2 C<< clone_object(Instance, Parameters) -> Instance >>
 539
 540 Clones the given instance which must be an instance governed by this
 541 metaclass.
 542
 543 =head2 C<< throw_error(Message, Parameters) >>
 544
 545 Throws an error with the given message.
 546
 547 =head1 SEE ALSO
 548
 549 L<Mouse::Meta::Module>
 550
 551 L<Moose::Meta::Class>
 552
 553 L<Class::MOP::Class>
 554
 555 =cut
 556