lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use strict;
   3 use warnings;
   4
   5 use Scalar::Util qw/blessed weaken/;
   6
   7 use Mouse::Util qw/:meta get_linear_isa not_supported/;
   8
   9 use Mouse::Meta::Method::Constructor;
  10 use Mouse::Meta::Method::Destructor;
  11 use Mouse::Meta::Module;
  12 our @ISA = qw(Mouse::Meta::Module);
  13
  14 sub method_metaclass()    { 'Mouse::Meta::Method'    }
  15 sub attribute_metaclass() { 'Mouse::Meta::Attribute' }
  16
  17 sub _construct_meta {
  18     my($class, %args) = @_;
  19
  20     $args{attributes} ||= {};
  21     $args{methods}    ||= {};
  22     $args{roles}      ||= [];
  23
  24     $args{superclasses} = do {
  25         no strict 'refs';
  26         \@{ $args{package} . '::ISA' };
  27     };
  28
  29     my $self = bless \%args, ref($class) || $class;
  30     if(ref($self) ne __PACKAGE__){
  31         $self->meta->_initialize_object($self, \%args);
  32     }
  33     return $self;
  34 }
  35
  36 sub create_anon_class{
  37     my $self = shift;
  38     return $self->create(undef, @_);
  39 }
  40
  41 sub is_anon_class{
  42     return exists $_[0]->{anon_serial_id};
  43 }
  44
  45 sub roles { $_[0]->{roles} }
  46
  47 sub superclasses {
  48     my $self = shift;
  49
  50     if (@_) {
  51         Mouse::load_class($_) for @_;
  52         @{ $self->{superclasses} } = @_;
  53     }
  54
  55     return @{ $self->{superclasses} };
  56 }
  57
  58 sub find_method_by_name{
  59     my($self, $method_name) = @_;
  60     defined($method_name)
  61         or $self->throw_error('You must define a method name to find');
  62     foreach my $class( $self->linearized_isa ){
  63         my $method = $self->initialize($class)->get_method($method_name);
  64         return $method if defined $method;
  65     }
  66     return undef;
  67 }
  68
  69 sub get_all_methods {
  70     my($self) = @_;
  71     return map{ $self->find_method_by_name($_) } $self->get_all_method_names;
  72 }
  73
  74 sub get_all_method_names {
  75     my $self = shift;
  76     my %uniq;
  77     return grep { $uniq{$_}++ == 0 }
  78             map { Mouse::Meta::Class->initialize($_)->get_method_list() }
  79             $self->linearized_isa;
  80 }
  81
  82 sub add_attribute {
  83     my $self = shift;
  84
  85     my($attr, $name);
  86
  87     if(blessed $_[0]){
  88         $attr = $_[0];
  89
  90         $attr->isa('Mouse::Meta::Attribute')
  91             || $self->throw_error("Your attribute must be an instance of Mouse::Meta::Attribute (or a subclass)");
  92
  93         $name = $attr->name;
  94     }
  95     else{
  96         # _process_attribute
  97         $name = shift;
  98
  99         my %args = (@_ == 1) ? %{$_[0]} : @_;
 100
 101         defined($name)
 102             or $self->throw_error('You must provide a name for the attribute');
 103
 104         if ($name =~ s/^\+//) { # inherited attributes
 105             my $inherited_attr;
 106
 107             # find_attribute_by_name
 108             foreach my $class($self->linearized_isa){
 109                 my $meta = Mouse::Util::get_metaclass_by_name($class) or next;
 110                 $inherited_attr = $meta->get_attribute($name) and last;
 111             }
 112
 113             defined($inherited_attr)
 114                 or $self->throw_error("Could not find an attribute by the name of '$name' to inherit from in ".$self->name);
 115
 116             $attr = $inherited_attr->clone_and_inherit_options(%args);
 117         }
 118         else{
 119             my($attribute_class, @traits) = $self->attribute_metaclass->interpolate_class(\%args);
 120             $args{traits} = \@traits if @traits;
 121
 122             $attr = $attribute_class->new($name, %args);
 123         }
 124     }
 125
 126     weaken( $attr->{associated_class} = $self );
 127
 128     $self->{attributes}{$attr->name} = $attr;
 129     $attr->install_accessors();
 130
 131     if(_MOUSE_VERBOSE && !$attr->{associated_methods} && ($attr->{is} || '') ne 'bare'){
 132         Carp::cluck(qq{Attribute (}.$attr->name.qq{) of class }.$self->name.qq{ has no associated methods (did you mean to provide an "is" argument?)});
 133     }
 134     return $attr;
 135 }
 136
 137 sub compute_all_applicable_attributes {
 138     Carp::cluck('compute_all_applicable_attributes() has been deprecated');
 139     return shift->get_all_attributes(@_)
 140 }
 141
 142 sub get_all_attributes {
 143     my $self = shift;
 144     my (@attr, %seen);
 145
 146     for my $class ($self->linearized_isa) {
 147         my $meta = Mouse::Util::get_metaclass_by_name($class)
 148             or next;
 149
 150         for my $name ($meta->get_attribute_list) {
 151             next if $seen{$name}++;
 152             push @attr, $meta->get_attribute($name);
 153         }
 154     }
 155
 156     return @attr;
 157 }
 158
 159 sub linearized_isa { @{ get_linear_isa($_[0]->name) } }
 160
 161 sub new_object {
 162     my $self = shift;
 163     my %args = (@_ == 1 ? %{$_[0]} : @_);
 164
 165     my $object = bless {}, $self->name;
 166
 167     $self->_initialize_object($object, \%args);
 168     return $object;
 169 }
 170
 171 sub _initialize_object{
 172     my($self, $object, $args) = @_;
 173
 174     my @triggers_queue;
 175
 176     foreach my $attribute ($self->get_all_attributes) {
 177         my $from = $attribute->init_arg;
 178         my $key  = $attribute->name;
 179
 180         if (defined($from) && exists($args->{$from})) {
 181             $object->{$key} = $attribute->_coerce_and_verify($args->{$from});
 182
 183             weaken($object->{$key})
 184                 if ref($object->{$key}) && $attribute->is_weak_ref;
 185
 186             if ($attribute->has_trigger) {
 187                 push @triggers_queue, [ $attribute->trigger, $object->{$key} ];
 188             }
 189         }
 190         else {
 191             if ($attribute->has_default || $attribute->has_builder) {
 192                 unless ($attribute->is_lazy) {
 193                     my $default = $attribute->default;
 194                     my $builder = $attribute->builder;
 195                     my $value =   $builder                ? $object->$builder()
 196                                 : ref($default) eq 'CODE' ? $object->$default()
 197                                 :                           $default;
 198
 199                     # XXX: we cannot use $attribute->set_value() because it invokes triggers.
 200                     $object->{$key} = $attribute->_coerce_and_verify($value, $object);;
 201
 202                     weaken($object->{$key})
 203                         if ref($object->{$key}) && $attribute->is_weak_ref;
 204                 }
 205             }
 206             else {
 207                 if ($attribute->is_required) {
 208                     $self->throw_error("Attribute (".$attribute->name.") is required");
 209                 }
 210             }
 211         }
 212     }
 213
 214     foreach my $trigger_and_value(@triggers_queue){
 215         my($trigger, $value) = @{$trigger_and_value};
 216         $trigger->($object, $value);
 217     }
 218
 219     if($self->is_anon_class){
 220         $object->{__METACLASS__} = $self;
 221     }
 222
 223     return $object;
 224 }
 225
 226 sub clone_object {
 227     my $class  = shift;
 228     my $object = shift;
 229     my %params = (@_ == 1) ? %{$_[0]} : @_;
 230
 231     (blessed($object) && $object->isa($class->name))
 232         || $class->throw_error("You must pass an instance of the metaclass (" . $class->name . "), not ($object)");
 233
 234     my $cloned = bless { %$object }, ref $object;
 235     $class->_initialize_object($cloned, \%params);
 236
 237     return $cloned;
 238 }
 239
 240 sub clone_instance {
 241     my ($class, $instance, %params) = @_;
 242
 243     Carp::cluck('clone_instance has been deprecated. Use clone_object instead')
 244         if _MOUSE_VERBOSE;
 245     return $class->clone_object($instance, %params);
 246 }
 247
 248 sub make_immutable {
 249     my $self = shift;
 250     my %args = (
 251         inline_constructor => 1,
 252         inline_destructor  => 1,
 253         constructor_name   => 'new',
 254         @_,
 255     );
 256
 257     $self->{is_immutable}++;
 258
 259     if ($args{inline_constructor}) {
 260         # generate and install
 261         Mouse::Meta::Method::Constructor->_generate_constructor_method($self, \%args);
 262     }
 263
 264     if ($args{inline_destructor}) {
 265         # generate and install
 266         Mouse::Meta::Method::Destructor->_generate_destructor_method($self, \%args);
 267     }
 268
 269     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 270     # at the end of a source file.
 271     return 1;
 272 }
 273
 274 sub make_mutable { not_supported }
 275
 276 sub is_immutable {  $_[0]->{is_immutable} }
 277 sub is_mutable   { !$_[0]->{is_immutable} }
 278
 279 sub _install_modifier_pp{
 280     my( $self, $into, $type, $name, $code ) = @_;
 281
 282     my $original = $into->can($name)
 283         or $self->throw_error("The method '$name' is not found in the inheritance hierarchy for class $into");
 284
 285     my $modifier_table = $self->{modifiers}{$name};
 286
 287     if(!$modifier_table){
 288         my(@before, @after, @around, $cache, $modified);
 289
 290         $cache = $original;
 291
 292         $modified = sub {
 293             for my $c (@before) { $c->(@_) }
 294
 295             if(wantarray){ # list context
 296                 my @rval = $cache->(@_);
 297
 298                 for my $c(@after){ $c->(@_) }
 299                 return @rval;
 300             }
 301             elsif(defined wantarray){ # scalar context
 302                 my $rval = $cache->(@_);
 303
 304                 for my $c(@after){ $c->(@_) }
 305                 return $rval;
 306             }
 307             else{ # void context
 308                 $cache->(@_);
 309
 310                 for my $c(@after){ $c->(@_) }
 311                 return;
 312             }
 313         };
 314
 315         $self->{modifiers}{$name} = $modifier_table = {
 316             original => $original,
 317
 318             before   => \@before,
 319             after    => \@after,
 320             around   => \@around,
 321
 322             cache    => \$cache, # cache for around modifiers
 323         };
 324
 325         $self->add_method($name => $modified);
 326     }
 327
 328     if($type eq 'before'){
 329         unshift @{$modifier_table->{before}}, $code;
 330     }
 331     elsif($type eq 'after'){
 332         push @{$modifier_table->{after}}, $code;
 333     }
 334     else{ # around
 335         push @{$modifier_table->{around}}, $code;
 336
 337         my $next = ${ $modifier_table->{cache} };
 338         ${ $modifier_table->{cache} } = sub{ $code->($next, @_) };
 339     }
 340
 341     return;
 342 }
 343
 344 sub _install_modifier {
 345     my ( $self, $into, $type, $name, $code ) = @_;
 346
 347     # load Class::Method::Modifiers first
 348     my $no_cmm_fast = do{
 349         local $@;
 350         eval q{ require Class::Method::Modifiers::Fast };
 351         $@;
 352     };
 353
 354     my $impl;
 355     if($no_cmm_fast){
 356         $impl = \&_install_modifier_pp;
 357     }
 358     else{
 359         my $install_modifier = Class::Method::Modifiers::Fast->can('_install_modifier');
 360         $impl = sub {
 361             my ( $self, $into, $type, $name, $code ) = @_;
 362             $install_modifier->(
 363                 $into,
 364                 $type,
 365                 $name,
 366                 $code
 367             );
 368             $self->{methods}{$name}++; # register it to the method map
 369             return;
 370         };
 371     }
 372
 373     # replace this method itself :)
 374     {
 375         no warnings 'redefine';
 376         *_install_modifier = $impl;
 377     }
 378
 379     $self->$impl( $into, $type, $name, $code );
 380 }
 381
 382 sub add_before_method_modifier {
 383     my ( $self, $name, $code ) = @_;
 384     $self->_install_modifier( $self->name, 'before', $name, $code );
 385 }
 386
 387 sub add_around_method_modifier {
 388     my ( $self, $name, $code ) = @_;
 389     $self->_install_modifier( $self->name, 'around', $name, $code );
 390 }
 391
 392 sub add_after_method_modifier {
 393     my ( $self, $name, $code ) = @_;
 394     $self->_install_modifier( $self->name, 'after', $name, $code );
 395 }
 396
 397 sub add_override_method_modifier {
 398     my ($self, $name, $code) = @_;
 399
 400     my $package = $self->name;
 401
 402     my $body = $package->can($name)
 403         or $self->throw_error("You cannot override '$name' because it has no super method");
 404
 405     $self->add_method($name => sub { $code->($package, $body, @_) });
 406 }
 407
 408 sub does_role {
 409     my ($self, $role_name) = @_;
 410
 411     (defined $role_name)
 412         || $self->throw_error("You must supply a role name to look for");
 413
 414     for my $class ($self->linearized_isa) {
 415         my $meta = Mouse::Util::get_metaclass_by_name($class);
 416         next unless $meta && $meta->can('roles');
 417
 418         for my $role (@{ $meta->roles }) {
 419
 420             return 1 if $role->does_role($role_name);
 421         }
 422     }
 423
 424     return 0;
 425 }
 426
 427 1;
 428
 429 __END__
 430
 431 =head1 NAME
 432
 433 Mouse::Meta::Class - The Mouse class metaclass
 434
 435 =head1 METHODS
 436
 437 =head2 C<< initialize(ClassName) -> Mouse::Meta::Class >>
 438
 439 Finds or creates a C<Mouse::Meta::Class> instance for the given ClassName. Only
 440 one instance should exist for a given class.
 441
 442 =head2 C<< name -> ClassName >>
 443
 444 Returns the name of the owner class.
 445
 446 =head2 C<< superclasses -> ClassNames >> C<< superclass(ClassNames) >>
 447
 448 Gets (or sets) the list of superclasses of the owner class.
 449
 450 =head2 C<< add_method(name => CodeRef) >>
 451
 452 Adds a method to the owner class.
 453
 454 =head2 C<< has_method(name) -> Bool >>
 455
 456 Returns whether we have a method with the given name.
 457
 458 =head2 C<< get_method(name) -> Mouse::Meta::Method | undef >>
 459
 460 Returns a L<Mouse::Meta::Method> with the given name.
 461
 462 Note that you can also use C<< $metaclass->name->can($name) >> for a method body.
 463
 464 =head2 C<< get_method_list -> Names >>
 465
 466 Returns a list of method names which are defined in the local class.
 467 If you want a list of all applicable methods for a class, use the
 468 C<get_all_methods> method.
 469
 470 =head2 C<< get_all_methods -> (Mouse::Meta::Method) >>
 471
 472 Return the list of all L<Mouse::Meta::Method> instances associated with
 473 the class and its superclasses.
 474
 475 =head2 C<< add_attribute(name => spec | Mouse::Meta::Attribute) >>
 476
 477 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 478 class.
 479
 480 =head2 C<< has_attribute(Name) -> Bool >>
 481
 482 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 483
 484 =head2 C<< get_attribute Name -> Mouse::Meta::Attribute | undef >>
 485
 486 Returns the L<Mouse::Meta::Attribute> with the given name.
 487
 488 =head2 C<< get_attribute_list -> Names >>
 489
 490 Returns a list of attribute names which are defined in the local
 491 class. If you want a list of all applicable attributes for a class,
 492 use the C<get_all_attributes> method.
 493
 494 =head2 C<< get_all_attributes -> (Mouse::Meta::Attribute) >>
 495
 496 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 497 this class and its superclasses.
 498
 499 =head2 C<< linearized_isa -> [ClassNames] >>
 500
 501 Returns the list of classes in method dispatch order, with duplicates removed.
 502
 503 =head2 C<< new_object(Parameters) -> Instance >>
 504
 505 Creates a new instance.
 506
 507 =head2 C<< clone_object(Instance, Parameters) -> Instance >>
 508
 509 Clones the given instance which must be an instance governed by this
 510 metaclass.
 511
 512 =head2 C<< throw_error(Message, Parameters) >>
 513
 514 Throws an error with the given message.
 515
 516 =head1 SEE ALSO
 517
 518 L<Moose::Meta::Class>
 519
 520 L<Class::MOP::Class>
 521
 522 =cut
 523