lib/Mouse/Meta/Class.pm

   1 package Mouse::Meta::Class;
   2 use Mouse::Util qw/:meta get_linear_isa not_supported/; # enables strict and warnings
   3
   4 use Scalar::Util qw/blessed weaken/;
   5
   6 use Mouse::Meta::Module;
   7 our @ISA = qw(Mouse::Meta::Module);
   8
   9 sub attribute_metaclass;
  10 sub method_metaclass;
  11
  12 sub constructor_class;
  13 sub destructor_class;
  14
  15 my @MetaClassTypes = qw(
  16     attribute_metaclass
  17     method_metaclass
  18     constructor_class
  19     destructor_class
  20 );
  21
  22 sub _construct_meta {
  23     my($class, %args) = @_;
  24
  25     $args{attributes} = {};
  26     $args{methods}    = {};
  27     $args{roles}      = [];
  28
  29     $args{superclasses} = do {
  30         no strict 'refs';
  31         \@{ $args{package} . '::ISA' };
  32     };
  33
  34     my $self = bless \%args, ref($class) || $class;
  35     if(ref($self) ne __PACKAGE__){
  36         $self->meta->_initialize_object($self, \%args);
  37     }
  38     return $self;
  39 }
  40
  41 sub create_anon_class{
  42     my $self = shift;
  43     return $self->create(undef, @_);
  44 }
  45
  46 sub is_anon_class;
  47
  48 sub roles;
  49
  50 sub calculate_all_roles {
  51     my $self = shift;
  52     my %seen;
  53     return grep { !$seen{ $_->name }++ }
  54            map  { $_->calculate_all_roles } @{ $self->roles };
  55 }
  56
  57 sub superclasses {
  58     my $self = shift;
  59
  60     if (@_) {
  61         foreach my $super(@_){
  62             Mouse::Util::load_class($super);
  63             my $meta = Mouse::Util::get_metaclass_by_name($super);
  64
  65             next if not defined $meta;
  66
  67             if(Mouse::Util::is_a_metarole($meta)){
  68                 $self->throw_error("You cannot inherit from a Mouse Role ($super)");
  69             }
  70
  71             next if $self->isa(ref $meta); # _superclass_meta_is_compatible
  72
  73             $self->_reconcile_with_superclass_meta($meta);
  74         }
  75         @{ $self->{superclasses} } = @_;
  76     }
  77
  78     return @{ $self->{superclasses} };
  79 }
  80
  81 sub _reconcile_with_superclass_meta {
  82     my($self, $super_meta) = @_;
  83
  84     my @incompatibles;
  85
  86     foreach my $metaclass_type(@MetaClassTypes){
  87         my $super_c = $super_meta->$metaclass_type();
  88         my $self_c  = $self->$metaclass_type();
  89
  90         if(!$super_c->isa($self_c)){
  91             push @incompatibles, ($metaclass_type => $super_c);
  92         }
  93     }
  94
  95     my @roles;
  96
  97     foreach my $role($self->meta->calculate_all_roles){
  98         if(!$super_meta->meta->does_role($role->name)){
  99             push @roles, $role->name;
 100         }
 101     }
 102
 103     #print "reconcile($self vs. $super_meta; @roles; @incompatibles)\n";
 104
 105     require Mouse::Util::MetaRole;
 106     Mouse::Util::MetaRole::apply_metaclass_roles(
 107         for_class       => $self,
 108         metaclass       => ref $super_meta,
 109         metaclass_roles => \@roles,
 110         @incompatibles,
 111     );
 112     return;
 113 }
 114
 115 sub find_method_by_name{
 116     my($self, $method_name) = @_;
 117     defined($method_name)
 118         or $self->throw_error('You must define a method name to find');
 119
 120     foreach my $class( $self->linearized_isa ){
 121         my $method = $self->initialize($class)->get_method($method_name);
 122         return $method if defined $method;
 123     }
 124     return undef;
 125 }
 126
 127 sub get_all_methods {
 128     my($self) = @_;
 129     return map{ $self->find_method_by_name($_) } $self->get_all_method_names;
 130 }
 131
 132 sub get_all_method_names {
 133     my $self = shift;
 134     my %uniq;
 135     return grep { $uniq{$_}++ == 0 }
 136             map { Mouse::Meta::Class->initialize($_)->get_method_list() }
 137             $self->linearized_isa;
 138 }
 139
 140 sub find_attribute_by_name{
 141     my($self, $name) = @_;
 142     my $attr;
 143     foreach my $class($self->linearized_isa){
 144         my $meta = Mouse::Util::get_metaclass_by_name($class) or next;
 145         $attr = $meta->get_attribute($name) and last;
 146     }
 147     return $attr;
 148 }
 149
 150 sub add_attribute {
 151     my $self = shift;
 152
 153     my($attr, $name);
 154
 155     if(blessed $_[0]){
 156         $attr = $_[0];
 157
 158         $attr->isa('Mouse::Meta::Attribute')
 159             || $self->throw_error("Your attribute must be an instance of Mouse::Meta::Attribute (or a subclass)");
 160
 161         $name = $attr->name;
 162     }
 163     else{
 164         # _process_attribute
 165         $name = shift;
 166
 167         my %args = (@_ == 1) ? %{$_[0]} : @_;
 168
 169         defined($name)
 170             or $self->throw_error('You must provide a name for the attribute');
 171
 172         if ($name =~ s/^\+//) { # inherited attributes
 173             my $inherited_attr = $self->find_attribute_by_name($name)
 174                 or $self->throw_error("Could not find an attribute by the name of '$name' to inherit from in ".$self->name);
 175
 176             $attr = $inherited_attr->clone_and_inherit_options(%args);
 177         }
 178         else{
 179             my($attribute_class, @traits) = $self->attribute_metaclass->interpolate_class(\%args);
 180             $args{traits} = \@traits if @traits;
 181
 182             $attr = $attribute_class->new($name, %args);
 183         }
 184     }
 185
 186     weaken( $attr->{associated_class} = $self );
 187
 188     $self->{attributes}{$attr->name} = $attr;
 189     $attr->install_accessors();
 190
 191     if(Mouse::Util::_MOUSE_VERBOSE && !$attr->{associated_methods} && ($attr->{is} || '') ne 'bare'){
 192         Carp::cluck(qq{Attribute (}.$attr->name.qq{) of class }.$self->name.qq{ has no associated methods (did you mean to provide an "is" argument?)});
 193     }
 194     return $attr;
 195 }
 196
 197 sub compute_all_applicable_attributes {
 198     Carp::cluck('compute_all_applicable_attributes() has been deprecated')
 199         if Mouse::Util::_MOUSE_VERBOSE;
 200     return shift->get_all_attributes(@_)
 201 }
 202
 203 sub linearized_isa;
 204
 205 sub new_object;
 206
 207 sub clone_object {
 208     my $class  = shift;
 209     my $object = shift;
 210     my %params = (@_ == 1) ? %{$_[0]} : @_;
 211
 212     (blessed($object) && $object->isa($class->name))
 213         || $class->throw_error("You must pass an instance of the metaclass (" . $class->name . "), not ($object)");
 214
 215     my $cloned = bless { %$object }, ref $object;
 216     $class->_initialize_object($cloned, \%params);
 217
 218     return $cloned;
 219 }
 220
 221 sub clone_instance {
 222     my ($class, $instance, %params) = @_;
 223
 224     Carp::cluck('clone_instance has been deprecated. Use clone_object instead')
 225         if Mouse::Util::_MOUSE_VERBOSE;
 226     return $class->clone_object($instance, %params);
 227 }
 228
 229 sub make_immutable {
 230     my $self = shift;
 231     my %args = (
 232         inline_constructor => 1,
 233         inline_destructor  => 1,
 234         constructor_name   => 'new',
 235         @_,
 236     );
 237
 238     $self->{is_immutable}++;
 239
 240     if ($args{inline_constructor}) {
 241         my $c = $self->constructor_class;
 242         Mouse::Util::load_class($c);
 243         $self->add_method($args{constructor_name} =>
 244             $c->_generate_constructor($self, \%args));
 245     }
 246
 247     if ($args{inline_destructor}) {
 248         my $c = $self->destructor_class;
 249         Mouse::Util::load_class($c);
 250         $self->add_method(DESTROY =>
 251             $c->_generate_destructor($self, \%args));
 252     }
 253
 254     # Moose's make_immutable returns true allowing calling code to skip setting an explicit true value
 255     # at the end of a source file.
 256     return 1;
 257 }
 258
 259 sub make_mutable { not_supported }
 260
 261 sub is_immutable {  $_[0]->{is_immutable} }
 262 sub is_mutable   { !$_[0]->{is_immutable} }
 263
 264 sub _install_modifier_pp{
 265     my( $self, $type, $name, $code ) = @_;
 266     my $into = $self->name;
 267
 268     my $original = $into->can($name)
 269         or $self->throw_error("The method '$name' is not found in the inheritance hierarchy for class $into");
 270
 271     my $modifier_table = $self->{modifiers}{$name};
 272
 273     if(!$modifier_table){
 274         my(@before, @after, @around, $cache, $modified);
 275
 276         $cache = $original;
 277
 278         $modified = sub {
 279             for my $c (@before) { $c->(@_) }
 280
 281             if(wantarray){ # list context
 282                 my @rval = $cache->(@_);
 283
 284                 for my $c(@after){ $c->(@_) }
 285                 return @rval;
 286             }
 287             elsif(defined wantarray){ # scalar context
 288                 my $rval = $cache->(@_);
 289
 290                 for my $c(@after){ $c->(@_) }
 291                 return $rval;
 292             }
 293             else{ # void context
 294                 $cache->(@_);
 295
 296                 for my $c(@after){ $c->(@_) }
 297                 return;
 298             }
 299         };
 300
 301         $self->{modifiers}{$name} = $modifier_table = {
 302             original => $original,
 303
 304             before   => \@before,
 305             after    => \@after,
 306             around   => \@around,
 307
 308             cache    => \$cache, # cache for around modifiers
 309         };
 310
 311         $self->add_method($name => $modified);
 312     }
 313
 314     if($type eq 'before'){
 315         unshift @{$modifier_table->{before}}, $code;
 316     }
 317     elsif($type eq 'after'){
 318         push @{$modifier_table->{after}}, $code;
 319     }
 320     else{ # around
 321         push @{$modifier_table->{around}}, $code;
 322
 323         my $next = ${ $modifier_table->{cache} };
 324         ${ $modifier_table->{cache} } = sub{ $code->($next, @_) };
 325     }
 326
 327     return;
 328 }
 329
 330 sub _install_modifier {
 331     my ( $self, $type, $name, $code ) = @_;
 332
 333     # load Class::Method::Modifiers first
 334     my $no_cmm_fast = do{
 335         local $@;
 336         eval q{ require Class::Method::Modifiers::Fast };
 337         $@;
 338     };
 339
 340     my $impl;
 341     if($no_cmm_fast){
 342         $impl = \&_install_modifier_pp;
 343     }
 344     else{
 345         my $install_modifier = Class::Method::Modifiers::Fast->can('_install_modifier');
 346         $impl = sub {
 347             my ( $self, $type, $name, $code ) = @_;
 348             my $into = $self->name;
 349             $install_modifier->($into, $type, $name, $code);
 350
 351             $self->add_method($name => do{
 352                 no strict 'refs';
 353                 \&{ $into . '::' . $name };
 354             });
 355             return;
 356         };
 357     }
 358
 359     # replace this method itself :)
 360     {
 361         no warnings 'redefine';
 362         *_install_modifier = $impl;
 363     }
 364
 365     $self->$impl( $type, $name, $code );
 366 }
 367
 368 sub add_before_method_modifier {
 369     my ( $self, $name, $code ) = @_;
 370     $self->_install_modifier( 'before', $name, $code );
 371 }
 372
 373 sub add_around_method_modifier {
 374     my ( $self, $name, $code ) = @_;
 375     $self->_install_modifier( 'around', $name, $code );
 376 }
 377
 378 sub add_after_method_modifier {
 379     my ( $self, $name, $code ) = @_;
 380     $self->_install_modifier( 'after', $name, $code );
 381 }
 382
 383 sub add_override_method_modifier {
 384     my ($self, $name, $code) = @_;
 385
 386     if($self->has_method($name)){
 387         $self->throw_error("Cannot add an override method if a local method is already present");
 388     }
 389
 390     my $package = $self->name;
 391
 392     my $super_body = $package->can($name)
 393         or $self->throw_error("You cannot override '$name' because it has no super method");
 394
 395     $self->add_method($name => sub {
 396         local $Mouse::SUPER_PACKAGE = $package;
 397         local $Mouse::SUPER_BODY    = $super_body;
 398         local @Mouse::SUPER_ARGS    = @_;
 399
 400         $code->(@_);
 401     });
 402     return;
 403 }
 404
 405 sub add_augment_method_modifier {
 406     my ($self, $name, $code) = @_;
 407     if($self->has_method($name)){
 408         $self->throw_error("Cannot add an augment method if a local method is already present");
 409     }
 410
 411     my $super = $self->find_method_by_name($name)
 412         or $self->throw_error("You cannot augment '$name' because it has no super method");
 413
 414     my $super_package = $super->package_name;
 415     my $super_body    = $super->body;
 416
 417     $self->add_method($name => sub{
 418         local $Mouse::INNER_BODY{$super_package} = $code;
 419         local $Mouse::INNER_ARGS{$super_package} = [@_];
 420         $super_body->(@_);
 421     });
 422     return;
 423 }
 424
 425 sub does_role {
 426     my ($self, $role_name) = @_;
 427
 428     (defined $role_name)
 429         || $self->throw_error("You must supply a role name to look for");
 430
 431     for my $class ($self->linearized_isa) {
 432         my $meta = Mouse::Util::get_metaclass_by_name($class)
 433             or next;
 434
 435         for my $role (@{ $meta->roles }) {
 436
 437             return 1 if $role->does_role($role_name);
 438         }
 439     }
 440
 441     return 0;
 442 }
 443
 444 1;
 445 __END__
 446
 447 =head1 NAME
 448
 449 Mouse::Meta::Class - The Mouse class metaclass
 450
 451 =head1 VERSION
 452
 453 This document describes Mouse version 0.40_08
 454
 455 =head1 METHODS
 456
 457 =head2 C<< initialize(ClassName) -> Mouse::Meta::Class >>
 458
 459 Finds or creates a C<Mouse::Meta::Class> instance for the given ClassName. Only
 460 one instance should exist for a given class.
 461
 462 =head2 C<< name -> ClassName >>
 463
 464 Returns the name of the owner class.
 465
 466 =head2 C<< superclasses -> ClassNames >> C<< superclass(ClassNames) >>
 467
 468 Gets (or sets) the list of superclasses of the owner class.
 469
 470 =head2 C<< add_method(name => CodeRef) >>
 471
 472 Adds a method to the owner class.
 473
 474 =head2 C<< has_method(name) -> Bool >>
 475
 476 Returns whether we have a method with the given name.
 477
 478 =head2 C<< get_method(name) -> Mouse::Meta::Method | undef >>
 479
 480 Returns a L<Mouse::Meta::Method> with the given name.
 481
 482 Note that you can also use C<< $metaclass->name->can($name) >> for a method body.
 483
 484 =head2 C<< get_method_list -> Names >>
 485
 486 Returns a list of method names which are defined in the local class.
 487 If you want a list of all applicable methods for a class, use the
 488 C<get_all_methods> method.
 489
 490 =head2 C<< get_all_methods -> (Mouse::Meta::Method) >>
 491
 492 Return the list of all L<Mouse::Meta::Method> instances associated with
 493 the class and its superclasses.
 494
 495 =head2 C<< add_attribute(name => spec | Mouse::Meta::Attribute) >>
 496
 497 Begins keeping track of the existing L<Mouse::Meta::Attribute> for the owner
 498 class.
 499
 500 =head2 C<< has_attribute(Name) -> Bool >>
 501
 502 Returns whether we have a L<Mouse::Meta::Attribute> with the given name.
 503
 504 =head2 C<< get_attribute Name -> Mouse::Meta::Attribute | undef >>
 505
 506 Returns the L<Mouse::Meta::Attribute> with the given name.
 507
 508 =head2 C<< get_attribute_list -> Names >>
 509
 510 Returns a list of attribute names which are defined in the local
 511 class. If you want a list of all applicable attributes for a class,
 512 use the C<get_all_attributes> method.
 513
 514 =head2 C<< get_all_attributes -> (Mouse::Meta::Attribute) >>
 515
 516 Returns the list of all L<Mouse::Meta::Attribute> instances associated with
 517 this class and its superclasses.
 518
 519 =head2 C<< linearized_isa -> [ClassNames] >>
 520
 521 Returns the list of classes in method dispatch order, with duplicates removed.
 522
 523 =head2 C<< new_object(Parameters) -> Instance >>
 524
 525 Creates a new instance.
 526
 527 =head2 C<< clone_object(Instance, Parameters) -> Instance >>
 528
 529 Clones the given instance which must be an instance governed by this
 530 metaclass.
 531
 532 =head2 C<< throw_error(Message, Parameters) >>
 533
 534 Throws an error with the given message.
 535
 536 =head1 SEE ALSO
 537
 538 L<Mouse::Meta::Module>
 539
 540 L<Moose::Meta::Class>
 541
 542 L<Class::MOP::Class>
 543
 544 =cut
 545