lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use Mouse::Util qw(:meta); # enables strict and warnings
   3
   4 use Carp ();
   5
   6 use Mouse::Meta::TypeConstraint;
   7
   8 my %valid_options = map { $_ => undef } (
   9   'accessor',
  10   'auto_deref',
  11   'builder',
  12   'clearer',
  13   'coerce',
  14   'default',
  15   'documentation',
  16   'does',
  17   'handles',
  18   'init_arg',
  19   'insertion_order',
  20   'is',
  21   'isa',
  22   'lazy',
  23   'lazy_build',
  24   'name',
  25   'predicate',
  26   'reader',
  27   'required',
  28   'traits',
  29   'trigger',
  30   'type_constraint',
  31   'weak_ref',
  32   'writer',
  33
  34   # internally used
  35   'associated_class',
  36   'associated_methods',
  37
  38   # Moose defines, but Mouse doesn't
  39   #'definition_context',
  40   #'initializer',
  41
  42   # special case for AttributeHelpers
  43   'provides',
  44   'curries',
  45 );
  46
  47 our @CARP_NOT = qw(Mouse::Meta::Class);
  48
  49 sub new {
  50     my $class = shift;
  51     my $name  = shift;
  52
  53     my $args  = $class->Mouse::Object::BUILDARGS(@_);
  54
  55     $class->_process_options($name, $args);
  56
  57     $args->{name} = $name;
  58
  59     # check options
  60     # (1) known by core
  61     my @bad = grep{ !exists $valid_options{$_} } keys %{$args};
  62
  63     # (2) known by subclasses
  64     if(@bad && $class ne __PACKAGE__){
  65         my %valid_attrs = (
  66             map { $_ => undef }
  67             grep { defined }
  68             map { $_->init_arg() }
  69             $class->meta->get_all_attributes()
  70         );
  71         @bad = grep{ !exists $valid_attrs{$_} } @bad;
  72     }
  73
  74     # (3) bad options found
  75     if(@bad){
  76         Carp::carp(
  77             "Found unknown argument(s) passed to '$name' attribute constructor in '$class': "
  78             . Mouse::Util::english_list(@bad));
  79     }
  80
  81     my $self = bless $args, $class;
  82     if($class ne __PACKAGE__){
  83         $class->meta->_initialize_object($self, $args);
  84     }
  85     return $self;
  86 }
  87
  88 sub has_read_method   { $_[0]->has_reader || $_[0]->has_accessor }
  89 sub has_write_method  { $_[0]->has_writer || $_[0]->has_accessor }
  90
  91 sub get_read_method   { $_[0]->reader || $_[0]->accessor }
  92 sub get_write_method  { $_[0]->writer || $_[0]->accessor }
  93
  94 sub get_read_method_ref{
  95     my($self) = @_;
  96     return $self->{_read_method_ref}
  97         ||= $self->_get_accessor_method_ref('get_read_method', '_generate_reader');
  98 }
  99
 100 sub get_write_method_ref{
 101     my($self) = @_;
 102     return $self->{_write_method_ref}
 103         ||= $self->_get_accessor_method_ref('get_write_method', '_generate_writer');
 104 }
 105
 106 sub interpolate_class{
 107     my($class, $args) = @_;
 108
 109     if(my $metaclass = delete $args->{metaclass}){
 110         $class = Mouse::Util::resolve_metaclass_alias( Attribute => $metaclass );
 111     }
 112
 113     my @traits;
 114     if(my $traits_ref = delete $args->{traits}){
 115
 116         for (my $i = 0; $i < @{$traits_ref}; $i++) {
 117             my $trait = Mouse::Util::resolve_metaclass_alias(Attribute => $traits_ref->[$i], trait => 1);
 118
 119             next if $class->does($trait);
 120
 121             push @traits, $trait;
 122
 123             # are there options?
 124             push @traits, $traits_ref->[++$i]
 125                 if ref($traits_ref->[$i+1]);
 126         }
 127
 128         if (@traits) {
 129             $class = Mouse::Meta::Class->create_anon_class(
 130                 superclasses => [ $class ],
 131                 roles        => \@traits,
 132                 cache        => 1,
 133             )->name;
 134         }
 135     }
 136
 137     return( $class, @traits );
 138 }
 139
 140 sub _coerce_and_verify {
 141     #my($self, $value, $instance) = @_;
 142     my($self, $value) = @_;
 143
 144     my $type_constraint = $self->{type_constraint};
 145     return $value if !defined $type_constraint;
 146
 147     if ($self->should_coerce && $type_constraint->has_coercion) {
 148         $value = $type_constraint->coerce($value);
 149     }
 150
 151     $self->verify_against_type_constraint($value);
 152
 153     return $value;
 154 }
 155
 156 sub verify_against_type_constraint {
 157     my ($self, $value) = @_;
 158
 159     my $type_constraint = $self->{type_constraint};
 160     return 1 if !$type_constraint;
 161     return 1 if $type_constraint->check($value);
 162
 163     $self->_throw_type_constraint_error($value, $type_constraint);
 164 }
 165
 166 sub _throw_type_constraint_error {
 167     my($self, $value, $type) = @_;
 168
 169     $self->throw_error(
 170         sprintf q{Attribute (%s) does not pass the type constraint because: %s},
 171             $self->name,
 172             $type->get_message($value),
 173     );
 174 }
 175
 176 sub illegal_options_for_inheritance {
 177     return qw(reader writer accessor clearer predicate);
 178 }
 179
 180 sub clone_and_inherit_options{
 181     my $self = shift;
 182     my $args = $self->Mouse::Object::BUILDARGS(@_);
 183
 184     foreach my $illegal($self->illegal_options_for_inheritance) {
 185         if(exists $args->{$illegal} and exists $self->{$illegal}) {
 186             $self->throw_error("Illegal inherited option: $illegal");
 187         }
 188     }
 189
 190     foreach my $name(keys %{$self}){
 191         if(!exists $args->{$name}){
 192             $args->{$name} = $self->{$name}; # inherit from self
 193         }
 194     }
 195
 196     my($attribute_class, @traits) = ref($self)->interpolate_class($args);
 197     $args->{traits} = \@traits if @traits;
 198
 199     # remove temporary caches
 200     foreach my $attr(keys %{$args}){
 201         if($attr =~ /\A _/xms){
 202             delete $args->{$attr};
 203         }
 204     }
 205
 206     # remove default if lazy_build => 1
 207     if($args->{lazy_build}) {
 208         delete $args->{default};
 209     }
 210
 211     return $attribute_class->new($self->name, $args);
 212 }
 213
 214
 215 sub _get_accessor_method_ref {
 216     my($self, $type, $generator) = @_;
 217
 218     my $metaclass = $self->associated_class
 219         || $self->throw_error('No asocciated class for ' . $self->name);
 220
 221     my $accessor = $self->$type();
 222     if($accessor){
 223         return $metaclass->get_method_body($accessor);
 224     }
 225     else{
 226         return $self->accessor_metaclass->$generator($self, $metaclass);
 227     }
 228 }
 229
 230 sub set_value {
 231     my($self, $object, $value) = @_;
 232     return $self->get_write_method_ref()->($object, $value);
 233 }
 234
 235 sub get_value {
 236     my($self, $object) = @_;
 237     return $self->get_read_method_ref()->($object);
 238 }
 239
 240 sub has_value {
 241     my($self, $object) = @_;
 242     my $accessor_ref = $self->{_predicate_ref}
 243         ||= $self->_get_accessor_method_ref('predicate', '_generate_predicate');
 244
 245     return $accessor_ref->($object);
 246 }
 247
 248 sub clear_value {
 249     my($self, $object) = @_;
 250     my $accessor_ref = $self->{_crealer_ref}
 251         ||= $self->_get_accessor_method_ref('clearer', '_generate_clearer');
 252
 253     return $accessor_ref->($object);
 254 }
 255
 256 sub associate_method{
 257     #my($attribute, $method_name) = @_;
 258     my($attribute) = @_;
 259     $attribute->{associated_methods}++;
 260     return;
 261 }
 262
 263 sub install_accessors{
 264     my($attribute) = @_;
 265
 266     my $metaclass      = $attribute->associated_class;
 267     my $accessor_class = $attribute->accessor_metaclass;
 268
 269     foreach my $type(qw(accessor reader writer predicate clearer)){
 270         if(exists $attribute->{$type}){
 271             my $generator = '_generate_' . $type;
 272             my $code      = $accessor_class->$generator($attribute, $metaclass);
 273             $metaclass->add_method($attribute->{$type} => $code);
 274             $attribute->associate_method($attribute->{$type});
 275         }
 276     }
 277
 278     # install delegation
 279     if(exists $attribute->{handles}){
 280         my %handles = $attribute->_canonicalize_handles($attribute->{handles});
 281
 282         while(my($handle, $method_to_call) = each %handles){
 283             if($metaclass->has_method($handle)) {
 284                 $attribute->throw_error("You cannot overwrite a locally defined method ($handle) with a delegation");
 285             }
 286
 287             $metaclass->add_method($handle =>
 288                 $attribute->_make_delegation_method(
 289                     $handle, $method_to_call));
 290
 291             $attribute->associate_method($handle);
 292         }
 293     }
 294
 295     return;
 296 }
 297
 298 sub delegation_metaclass() { ## no critic
 299     'Mouse::Meta::Method::Delegation'
 300 }
 301
 302 sub _canonicalize_handles {
 303     my($self, $handles) = @_;
 304
 305     if (ref($handles) eq 'HASH') {
 306         return %$handles;
 307     }
 308     elsif (ref($handles) eq 'ARRAY') {
 309         return map { $_ => $_ } @$handles;
 310     }
 311     elsif ( ref($handles) eq 'CODE' ) {
 312         my $class_or_role = ( $self->{isa} || $self->{does} )
 313             || $self->throw_error( "Cannot find delegate metaclass for attribute " . $self->name );
 314         return $handles->( $self, Mouse::Meta::Class->initialize("$class_or_role"));
 315     }
 316     elsif (ref($handles) eq 'Regexp') {
 317         my $class_or_role = ($self->{isa} || $self->{does})
 318             || $self->throw_error("Cannot delegate methods based on a Regexp without a type constraint (isa)");
 319
 320         my $meta = Mouse::Meta::Class->initialize("$class_or_role"); # "" for stringify
 321         return map  { $_ => $_ }
 322                grep { !Mouse::Object->can($_) && $_ =~ $handles }
 323                    Mouse::Util::is_a_metarole($meta)
 324                         ? $meta->get_method_list
 325                         : $meta->get_all_method_names;
 326     }
 327     else {
 328         $self->throw_error("Unable to canonicalize the 'handles' option with $handles");
 329     }
 330 }
 331
 332 sub _make_delegation_method {
 333     my($self, $handle, $method_to_call) = @_;
 334     return Mouse::Util::load_class($self->delegation_metaclass)
 335         ->_generate_delegation($self, $handle, $method_to_call);
 336 }
 337
 338 1;
 339 __END__
 340
 341 =head1 NAME
 342
 343 Mouse::Meta::Attribute - The Mouse attribute metaclass
 344
 345 =head1 VERSION
 346
 347 This document describes Mouse version 0.70
 348
 349 =head1 DESCRIPTION
 350
 351 This is a meta object protocol for Mouse attributes,
 352 which is a subset of Moose::Meta::Attribute.
 353
 354 =head1 METHODS
 355
 356 =head2 C<< new(%options) -> Mouse::Meta::Attribute >>
 357
 358 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 359
 360 It adds the following options to the constructor:
 361
 362 =over 4
 363
 364 =item C<< is => 'ro', 'rw', 'bare' >>
 365
 366 This provides a shorthand for specifying the C<reader>, C<writer>, or
 367 C<accessor> names. If the attribute is read-only ('ro') then it will
 368 have a C<reader> method with the same attribute as the name.
 369
 370 If it is read-write ('rw') then it will have an C<accessor> method
 371 with the same name. If you provide an explicit C<writer> for a
 372 read-write attribute, then you will have a C<reader> with the same
 373 name as the attribute, and a C<writer> with the name you provided.
 374
 375 Use 'bare' when you are deliberately not installing any methods
 376 (accessor, reader, etc.) associated with this attribute; otherwise,
 377 Moose will issue a deprecation warning when this attribute is added to a
 378 metaclass.
 379
 380 =item C<< isa => Type >>
 381
 382 This option accepts a type. The type can be a string, which should be
 383 a type name. If the type name is unknown, it is assumed to be a class
 384 name.
 385
 386 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 387
 388 If you I<also> provide a C<does> option, then your C<isa> option must
 389 be a class name, and that class must do the role specified with
 390 C<does>.
 391
 392 =item C<< does => Role >>
 393
 394 This is short-hand for saying that the attribute's type must be an
 395 object which does the named role.
 396
 397 B<This option is not yet supported.>
 398
 399 =item C<< coerce => Bool >>
 400
 401 This option is only valid for objects with a type constraint
 402 (C<isa>). If this is true, then coercions will be applied whenever
 403 this attribute is set.
 404
 405 You can make both this and the C<weak_ref> option true.
 406
 407 =item C<< trigger => CodeRef >>
 408
 409 This option accepts a subroutine reference, which will be called after
 410 the attribute is set.
 411
 412 =item C<< required => Bool >>
 413
 414 An attribute which is required must be provided to the constructor. An
 415 attribute which is required can also have a C<default> or C<builder>,
 416 which will satisfy its required-ness.
 417
 418 A required attribute must have a C<default>, C<builder> or a
 419 non-C<undef> C<init_arg>
 420
 421 =item C<< lazy => Bool >>
 422
 423 A lazy attribute must have a C<default> or C<builder>. When an
 424 attribute is lazy, the default value will not be calculated until the
 425 attribute is read.
 426
 427 =item C<< weak_ref => Bool >>
 428
 429 If this is true, the attribute's value will be stored as a weak
 430 reference.
 431
 432 =item C<< auto_deref => Bool >>
 433
 434 If this is true, then the reader will dereference the value when it is
 435 called. The attribute must have a type constraint which defines the
 436 attribute as an array or hash reference.
 437
 438 =item C<< lazy_build => Bool >>
 439
 440 Setting this to true makes the attribute lazy and provides a number of
 441 default methods.
 442
 443   has 'size' => (
 444       is         => 'ro',
 445       lazy_build => 1,
 446   );
 447
 448 is equivalent to this:
 449
 450   has 'size' => (
 451       is        => 'ro',
 452       lazy      => 1,
 453       builder   => '_build_size',
 454       clearer   => 'clear_size',
 455       predicate => 'has_size',
 456   );
 457
 458 =back
 459
 460 =head2 C<< associate_method(MethodName) >>
 461
 462 Associates a method with the attribute. Typically, this is called internally
 463 when an attribute generates its accessors.
 464
 465 Currently the argument I<MethodName> is ignored in Mouse.
 466
 467 =head2 C<< verify_against_type_constraint(Item) -> TRUE | ERROR >>
 468
 469 Checks that the given value passes this attribute's type constraint. Returns C<true>
 470 on success, otherwise C<confess>es.
 471
 472 =head2 C<< clone_and_inherit_options(options) -> Mouse::Meta::Attribute >>
 473
 474 Creates a new attribute in the owner class, inheriting options from parent classes.
 475 Accessors and helper methods are installed. Some error checking is done.
 476
 477 =head2 C<< get_read_method_ref >>
 478
 479 =head2 C<< get_write_method_ref >>
 480
 481 Returns the subroutine reference of a method suitable for reading or
 482 writing the attribute's value in the associated class. These methods
 483 always return a subroutine reference, regardless of whether or not the
 484 attribute is read- or write-only.
 485
 486 =head1 SEE ALSO
 487
 488 L<Moose::Meta::Attribute>
 489
 490 L<Class::MOP::Attribute>
 491
 492 =cut
 493