lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use strict;
   3 use warnings;
   4 require overload;
   5
   6 use Carp 'confess';
   7 use Scalar::Util ();
   8
   9 sub new {
  10     my $class = shift;
  11     my %args  = @_;
  12
  13     my $name = $args{name};
  14
  15     $args{init_arg} = $name
  16         unless exists $args{init_arg};
  17
  18     $args{is} ||= '';
  19
  20     bless \%args, $class;
  21 }
  22
  23 sub name                 { $_[0]->{name}                   }
  24 sub associated_class     { $_[0]->{associated_class}       }
  25 sub _is_metadata         { $_[0]->{is}                     }
  26 sub is_required          { $_[0]->{required}               }
  27 sub default              { $_[0]->{default}                }
  28 sub is_lazy              { $_[0]->{lazy}                   }
  29 sub is_lazy_build        { $_[0]->{lazy_build}             }
  30 sub predicate            { $_[0]->{predicate}              }
  31 sub clearer              { $_[0]->{clearer}                }
  32 sub handles              { $_[0]->{handles}                }
  33 sub is_weak_ref          { $_[0]->{weak_ref}               }
  34 sub init_arg             { $_[0]->{init_arg}               }
  35 sub type_constraint      { $_[0]->{type_constraint}        }
  36 sub trigger              { $_[0]->{trigger}                }
  37 sub builder              { $_[0]->{builder}                }
  38 sub should_auto_deref    { $_[0]->{auto_deref}             }
  39 sub should_coerce        { $_[0]->{should_coerce}          }
  40 sub find_type_constraint { $_[0]->{find_type_constraint}   }
  41
  42 sub has_default          { exists $_[0]->{default}         }
  43 sub has_predicate        { exists $_[0]->{predicate}       }
  44 sub has_clearer          { exists $_[0]->{clearer}         }
  45 sub has_handles          { exists $_[0]->{handles}         }
  46 sub has_type_constraint  { exists $_[0]->{type_constraint} }
  47 sub has_trigger          { exists $_[0]->{trigger}         }
  48 sub has_builder          { exists $_[0]->{builder}         }
  49
  50 sub _create_args {
  51     $_[0]->{_create_args} = $_[1] if @_ > 1;
  52     $_[0]->{_create_args}
  53 }
  54
  55 sub inlined_name {
  56     my $self = shift;
  57     my $name = $self->name;
  58     my $key   = "'" . $name . "'";
  59     return $key;
  60 }
  61
  62 sub generate_accessor {
  63     my $attribute = shift;
  64
  65     my $name          = $attribute->name;
  66     my $default       = $attribute->default;
  67     my $constraint    = $attribute->find_type_constraint;
  68     my $builder       = $attribute->builder;
  69     my $trigger       = $attribute->trigger;
  70     my $is_weak       = $attribute->is_weak_ref;
  71     my $should_deref  = $attribute->should_auto_deref;
  72     my $should_coerce = $attribute->should_coerce;
  73
  74     my $self  = '$_[0]';
  75     my $key   = $attribute->inlined_name;
  76
  77     my $accessor = "sub {\n";
  78     if ($attribute->_is_metadata eq 'rw') {
  79         $accessor .= 'if (scalar(@_) >= 2) {' . "\n";
  80
  81         my $value = '$_[1]';
  82
  83         if ($constraint) {
  84             $accessor .= 'my $val = ';
  85             if ($should_coerce) {
  86                 $accessor  .= 'Mouse::TypeRegistry->typecast_constraints("'.$attribute->associated_class->name.'", $attribute->{find_type_constraint}, $attribute->{type_constraint}, '.$value.');';
  87             } else {
  88                 $accessor .= $value.';';
  89             }
  90             $accessor .= 'local $_ = $val;';
  91             $accessor .= '
  92                 unless ($constraint->()) {
  93                     $attribute->verify_type_constraint_error($name, $_, $attribute->type_constraint);
  94                 }' . "\n";
  95             $value = '$val';
  96         }
  97
  98         # if there's nothing left to do for the attribute we can return during
  99         # this setter
 100         $accessor .= 'return ' if !$is_weak && !$trigger && !$should_deref;
 101
 102         $accessor .= $self.'->{'.$key.'} = '.$value.';' . "\n";
 103
 104         if ($is_weak) {
 105             $accessor .= 'Scalar::Util::weaken('.$self.'->{'.$key.'}) if ref('.$self.'->{'.$key.'});' . "\n";
 106         }
 107
 108         if ($trigger) {
 109             $accessor .= '$trigger->('.$self.', '.$value.', $attribute);' . "\n";
 110         }
 111
 112         $accessor .= "}\n";
 113     }
 114     else {
 115         $accessor .= 'confess "Cannot assign a value to a read-only accessor" if scalar(@_) >= 2;' . "\n";
 116     }
 117
 118     if ($attribute->is_lazy) {
 119         $accessor .= $self.'->{'.$key.'} = ';
 120
 121         $accessor .= $attribute->has_builder
 122                 ? $self.'->$builder'
 123                     : ref($default) eq 'CODE'
 124                     ? '$default->('.$self.')'
 125                     : '$default';
 126         $accessor .= ' if !exists '.$self.'->{'.$key.'};' . "\n";
 127     }
 128
 129     if ($should_deref) {
 130         my $type_constraint = $attribute->type_constraint;
 131         if (!ref($type_constraint) && $type_constraint eq 'ArrayRef') {
 132             $accessor .= 'if (wantarray) {
 133                 return @{ '.$self.'->{'.$key.'} || [] };
 134             }';
 135         }
 136         else {
 137             $accessor .= 'if (wantarray) {
 138                 return %{ '.$self.'->{'.$key.'} || {} };
 139             }';
 140         }
 141     }
 142
 143     $accessor .= 'return '.$self.'->{'.$key.'};
 144     }';
 145
 146     my $sub = eval $accessor;
 147     confess $@ if $@;
 148     return $sub;
 149 }
 150
 151 sub generate_predicate {
 152     my $attribute = shift;
 153     my $key = $attribute->inlined_name;
 154
 155     my $predicate = 'sub { exists($_[0]->{'.$key.'}) }';
 156
 157     my $sub = eval $predicate;
 158     confess $@ if $@;
 159     return $sub;
 160 }
 161
 162 sub generate_clearer {
 163     my $attribute = shift;
 164     my $key = $attribute->inlined_name;
 165
 166     my $clearer = 'sub { delete($_[0]->{'.$key.'}) }';
 167
 168     my $sub = eval $clearer;
 169     confess $@ if $@;
 170     return $sub;
 171 }
 172
 173 sub generate_handles {
 174     my $attribute = shift;
 175     my $reader = $attribute->name;
 176     my %handles = $attribute->_canonicalize_handles($attribute->handles);
 177
 178     my %method_map;
 179
 180     for my $local_method (keys %handles) {
 181         my $remote_method = $handles{$local_method};
 182
 183         my $method = 'sub {
 184             my $self = shift;
 185             $self->'.$reader.'->'.$remote_method.'(@_)
 186         }';
 187
 188         $method_map{$local_method} = eval $method;
 189         confess $@ if $@;
 190     }
 191
 192     return \%method_map;
 193 }
 194
 195 sub create {
 196     my ($self, $class, $name, %args) = @_;
 197
 198     $args{name} = $name;
 199     $args{associated_class} = $class;
 200
 201     %args = $self->canonicalize_args($name, %args);
 202     $self->validate_args($name, \%args);
 203
 204     $args{should_coerce} = delete $args{coerce}
 205         if exists $args{coerce};
 206
 207     if (exists $args{isa}) {
 208         my $type_constraint = delete $args{isa};
 209         $type_constraint =~ s/\s//g;
 210         my @type_constraints = split /\|/, $type_constraint;
 211
 212         my $code;
 213         my $optimized_constraints = Mouse::TypeRegistry->optimized_constraints;
 214         if (@type_constraints == 1) {
 215             $code = $optimized_constraints->{$type_constraints[0]} ||
 216                 sub { Scalar::Util::blessed($_) && Scalar::Util::blessed($_) eq $type_constraints[0] };
 217             $args{type_constraint} = $type_constraints[0];
 218         } else {
 219             my @code_list = map {
 220                 my $type = $_;
 221                 $optimized_constraints->{$type} ||
 222                     sub { Scalar::Util::blessed($_) && Scalar::Util::blessed($_) eq $type }
 223             } @type_constraints;
 224             $code = sub {
 225                 for my $code (@code_list) {
 226                     return 1 if $code->();
 227                 }
 228                 return 0;
 229             };
 230             $args{type_constraint} = \@type_constraints;
 231         }
 232         $args{find_type_constraint} = $code;
 233     }
 234
 235     my $attribute = $self->new(%args);
 236
 237     $attribute->_create_args(\%args);
 238
 239     $class->add_attribute($attribute);
 240
 241     # install an accessor
 242     if ($attribute->_is_metadata eq 'rw' || $attribute->_is_metadata eq 'ro') {
 243         my $accessor = $attribute->generate_accessor;
 244         $class->add_method($name => $accessor);
 245     }
 246
 247     for my $method (qw/predicate clearer/) {
 248         my $predicate = "has_$method";
 249         if ($attribute->$predicate) {
 250             my $generator = "generate_$method";
 251             my $coderef = $attribute->$generator;
 252             $class->add_method($attribute->$method => $coderef);
 253         }
 254     }
 255
 256     if ($attribute->has_handles) {
 257         my $method_map = $attribute->generate_handles;
 258         for my $method_name (keys %$method_map) {
 259             $class->add_method($method_name => $method_map->{$method_name});
 260         }
 261     }
 262
 263     return $attribute;
 264 }
 265
 266 sub canonicalize_args {
 267     my $self = shift;
 268     my $name = shift;
 269     my %args = @_;
 270
 271     if ($args{lazy_build}) {
 272         $args{lazy}      = 1;
 273         $args{required}  = 1;
 274         $args{builder}   = "_build_${name}"
 275             if !exists($args{builder});
 276         if ($name =~ /^_/) {
 277             $args{clearer}   = "_clear${name}" if !exists($args{clearer});
 278             $args{predicate} = "_has${name}" if !exists($args{predicate});
 279         }
 280         else {
 281             $args{clearer}   = "clear_${name}" if !exists($args{clearer});
 282             $args{predicate} = "has_${name}" if !exists($args{predicate});
 283         }
 284     }
 285
 286     return %args;
 287 }
 288
 289 sub validate_args {
 290     my $self = shift;
 291     my $name = shift;
 292     my $args = shift;
 293
 294     confess "You can not use lazy_build and default for the same attribute ($name)"
 295         if $args->{lazy_build} && exists $args->{default};
 296
 297     confess "You cannot have lazy attribute ($name) without specifying a default value for it"
 298         if $args->{lazy}
 299         && !exists($args->{default})
 300         && !exists($args->{builder});
 301
 302     confess "References are not allowed as default values, you must wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])"
 303         if ref($args->{default})
 304         && ref($args->{default}) ne 'CODE';
 305
 306     confess "You cannot auto-dereference without specifying a type constraint on attribute ($name)"
 307         if $args->{auto_deref} && !exists($args->{isa});
 308
 309     confess "You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)"
 310         if $args->{auto_deref}
 311         && $args->{isa} ne 'ArrayRef'
 312         && $args->{isa} ne 'HashRef';
 313
 314     if ($args->{trigger}) {
 315         if (ref($args->{trigger}) eq 'HASH') {
 316             Carp::carp "HASH-based form of trigger has been removed. Only the coderef form of triggers are now supported.";
 317         }
 318
 319         confess "Trigger must be a CODE ref on attribute ($name)"
 320             if ref($args->{trigger}) ne 'CODE';
 321     }
 322
 323     return 1;
 324 }
 325
 326 sub verify_type_constraint {
 327     return 1 unless $_[0]->{type_constraint};
 328
 329     local $_ = $_[1];
 330     return 1 if $_[0]->{find_type_constraint}->($_);
 331
 332     my $self = shift;
 333     $self->verify_type_constraint_error($self->name, $_, $self->type_constraint);
 334 }
 335
 336 sub verify_type_constraint_error {
 337     my($self, $name, $value, $type) = @_;
 338     $type = ref($type) eq 'ARRAY' ? join '|', @{ $type } : $type;
 339     my $display = defined($_) ? overload::StrVal($_) : 'undef';
 340     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
 341 }
 342
 343 sub coerce_constraint { ## my($self, $value) = @_;
 344     my $type = $_[0]->{type_constraint}
 345         or return $_[1];
 346     return Mouse::TypeRegistry->typecast_constraints($_[0]->associated_class->name, $_[0]->find_type_constraint, $type, $_[1]);
 347 }
 348
 349 sub _canonicalize_handles {
 350     my $self    = shift;
 351     my $handles = shift;
 352
 353     if (ref($handles) eq 'HASH') {
 354         return %$handles;
 355     }
 356     elsif (ref($handles) eq 'ARRAY') {
 357         return map { $_ => $_ } @$handles;
 358     }
 359     else {
 360         confess "Unable to canonicalize the 'handles' option with $handles";
 361     }
 362 }
 363
 364 sub clone_parent {
 365     my $self  = shift;
 366     my $class = shift;
 367     my $name  = shift;
 368     my %args  = ($self->get_parent_args($class, $name), @_);
 369
 370     $self->create($class, $name, %args);
 371 }
 372
 373 sub get_parent_args {
 374     my $self  = shift;
 375     my $class = shift;
 376     my $name  = shift;
 377
 378     for my $super ($class->linearized_isa) {
 379         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 380             or next;
 381         return %{ $super_attr->_create_args };
 382     }
 383
 384     confess "Could not find an attribute by the name of '$name' to inherit from";
 385 }
 386
 387 1;
 388
 389 __END__
 390
 391 =head1 NAME
 392
 393 Mouse::Meta::Attribute - attribute metaclass
 394
 395 =head1 METHODS
 396
 397 =head2 new %args -> Mouse::Meta::Attribute
 398
 399 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 400
 401 =head2 create OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 402
 403 Creates a new attribute in OwnerClass. Accessors and helper methods are
 404 installed. Some error checking is done.
 405
 406 =head2 name -> AttributeName
 407
 408 =head2 associated_class -> OwnerClass
 409
 410 =head2 is_required -> Bool
 411
 412 =head2 default -> Item
 413
 414 =head2 has_default -> Bool
 415
 416 =head2 is_lazy -> Bool
 417
 418 =head2 predicate -> MethodName | Undef
 419
 420 =head2 has_predicate -> Bool
 421
 422 =head2 clearer -> MethodName | Undef
 423
 424 =head2 has_clearer -> Bool
 425
 426 =head2 handles -> { LocalName => RemoteName }
 427
 428 =head2 has_handles -> Bool
 429
 430 =head2 is_weak_ref -> Bool
 431
 432 =head2 init_arg -> Str
 433
 434 =head2 type_constraint -> Str
 435
 436 =head2 has_type_constraint -> Bool
 437
 438 =head2 trigger => CODE | Undef
 439
 440 =head2 has_trigger -> Bool
 441
 442 =head2 builder => MethodName | Undef
 443
 444 =head2 has_builder -> Bool
 445
 446 =head2 is_lazy_build => Bool
 447
 448 =head2 should_auto_deref -> Bool
 449
 450 Informational methods.
 451
 452 =head2 generate_accessor -> CODE
 453
 454 Creates a new code reference for the attribute's accessor.
 455
 456 =head2 generate_predicate -> CODE
 457
 458 Creates a new code reference for the attribute's predicate.
 459
 460 =head2 generate_clearer -> CODE
 461
 462 Creates a new code reference for the attribute's clearer.
 463
 464 =head2 generate_handles -> { MethodName => CODE }
 465
 466 Creates a new code reference for each of the attribute's handles methods.
 467
 468 =head2 find_type_constraint -> CODE
 469
 470 Returns a code reference which can be used to check that a given value passes
 471 this attribute's type constraint;
 472
 473 =head2 verify_type_constraint Item -> 1 | ERROR
 474
 475 Checks that the given value passes this attribute's type constraint. Returns 1
 476 on success, otherwise C<confess>es.
 477
 478 =head2 canonicalize_args Name, %args -> %args
 479
 480 Canonicalizes some arguments to create. In particular, C<lazy_build> is
 481 canonicalized into C<lazy>, C<builder>, etc.
 482
 483 =head2 validate_args Name, \%args -> 1 | ERROR
 484
 485 Checks that the arguments to create the attribute (ie those specified by
 486 C<has>) are valid.
 487
 488 =head2 clone_parent OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 489
 490 Creates a new attribute in OwnerClass, inheriting options from parent classes.
 491 Accessors and helper methods are installed. Some error checking is done.
 492
 493 =head2 get_parent_args OwnerClass, AttributeName -> Hash
 494
 495 Returns the options that the parent class of C<OwnerClass> used for attribute
 496 C<AttributeName>.
 497
 498 =cut
 499