lib/Mouse/Meta/Attribute.pm

   1 #!/usr/bin/env perl
   2 package Mouse::Meta::Attribute;
   3 use strict;
   4 use warnings;
   5
   6 use Carp 'confess';
   7 use Mouse::Util qw/blessed weaken/;
   8
   9 sub new {
  10     my $class = shift;
  11     my %args  = @_;
  12
  13     my $name = $args{name};
  14
  15     $args{init_arg} = $name
  16         unless exists $args{init_arg};
  17
  18     $args{is} ||= '';
  19
  20     bless \%args, $class;
  21 }
  22
  23 sub name              { $_[0]->{name}             }
  24 sub associated_class  { $_[0]->{associated_class} }
  25 sub _is_metadata      { $_[0]->{is}               }
  26 sub is_required       { $_[0]->{required}         }
  27 sub default           { $_[0]->{default}          }
  28 sub is_lazy           { $_[0]->{lazy}             }
  29 sub is_lazy_build     { $_[0]->{lazy_build}       }
  30 sub predicate         { $_[0]->{predicate}        }
  31 sub clearer           { $_[0]->{clearer}          }
  32 sub handles           { $_[0]->{handles}          }
  33 sub is_weak_ref       { $_[0]->{weak_ref}         }
  34 sub init_arg          { $_[0]->{init_arg}         }
  35 sub type_constraint   { $_[0]->{type_constraint}  }
  36 sub trigger           { $_[0]->{trigger}          }
  37 sub builder           { $_[0]->{builder}          }
  38 sub should_auto_deref { $_[0]->{auto_deref}       }
  39
  40 sub has_default         { exists $_[0]->{default}         }
  41 sub has_predicate       { exists $_[0]->{predicate}       }
  42 sub has_clearer         { exists $_[0]->{clearer}         }
  43 sub has_handles         { exists $_[0]->{handles}         }
  44 sub has_type_constraint { exists $_[0]->{type_constraint} }
  45 sub has_trigger         { exists $_[0]->{trigger}         }
  46 sub has_builder         { exists $_[0]->{builder}         }
  47
  48 sub _create_args {
  49     $_[0]->{_create_args} = $_[1] if @_ > 1;
  50     $_[0]->{_create_args}
  51 }
  52
  53 sub generate_accessor {
  54     my $attribute = shift;
  55
  56     my $name       = $attribute->name;
  57     my $key        = $name;
  58     my $default    = $attribute->default;
  59     my $type       = $attribute->type_constraint;
  60     my $constraint = $attribute->find_type_constraint;
  61     my $builder    = $attribute->builder;
  62     my $trigger    = $attribute->trigger;
  63
  64     my $accessor = 'sub {
  65         my $self = shift;';
  66
  67     if ($attribute->_is_metadata eq 'rw') {
  68         $accessor .= 'if (@_) {
  69         ';
  70
  71         if ($constraint) {
  72             $accessor .= 'local $_ = $_[0];
  73                 unless ($constraint->()) {
  74                     my $display = defined($_) ? overload::StrVal($_) : "undef";
  75                     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
  76             }'
  77         }
  78
  79         $accessor .= '$self->{$key} = $_[0];';
  80
  81         if ($attribute->is_weak_ref) {
  82             $accessor .= 'weaken($self->{$key}) if ref($self->{$key});';
  83         }
  84
  85         if ($trigger) {
  86             $accessor .= '$trigger->($self, $_[0], $attribute);';
  87         }
  88
  89         $accessor .= '}';
  90     }
  91     else {
  92         $accessor .= 'confess "Cannot assign a value to a read-only accessor" if @_;';
  93     }
  94
  95     if ($attribute->is_lazy) {
  96         $accessor .= '$self->{$key} = ';
  97
  98         $accessor .= $attribute->has_builder
  99                    ? '$self->$builder'
 100                      : ref($default) eq 'CODE'
 101                      ? '$default->($self)'
 102                      : '$default';
 103
 104         $accessor .= ' if !exists($self->{$key});';
 105     }
 106
 107     if ($attribute->should_auto_deref) {
 108         if ($attribute->type_constraint eq 'ArrayRef') {
 109             $accessor .= 'if (wantarray) {
 110                 return @{ $self->{$key} || [] };
 111             }';
 112         }
 113         else {
 114             $accessor .= 'if (wantarray) {
 115                 return %{ $self->{$key} || {} };
 116             }';
 117         }
 118     }
 119
 120     $accessor .= 'return $self->{$key};
 121     }';
 122
 123     return eval $accessor;
 124 }
 125
 126 sub generate_predicate {
 127     my $attribute = shift;
 128     my $key = $attribute->name;
 129
 130     my $predicate = 'sub { exists($_[0]->{$key}) }';
 131
 132     return eval $predicate;
 133 }
 134
 135 sub generate_clearer {
 136     my $attribute = shift;
 137     my $key = $attribute->name;
 138
 139     my $predicate = 'sub { delete($_[0]->{$key}) }';
 140
 141     return eval $predicate;
 142 }
 143
 144 sub generate_handles {
 145     my $attribute = shift;
 146     my $reader = $attribute->name;
 147     my %handles = $attribute->_canonicalize_handles($attribute->handles);
 148
 149     my %method_map;
 150
 151     for my $local_method (keys %handles) {
 152         my $remote_method = $handles{$local_method};
 153
 154         my $method = 'sub {
 155             my $self = shift;
 156             $self->$reader->$remote_method(@_)
 157         }';
 158
 159         $method_map{$local_method} = eval $method;
 160     }
 161
 162     return \%method_map;
 163 }
 164
 165 sub create {
 166     my ($self, $class, $name, %args) = @_;
 167
 168     $args{name} = $name;
 169     $args{associated_class} = $class;
 170
 171     %args = $self->canonicalize_args($name, %args);
 172     $self->validate_args($name, \%args);
 173
 174     $args{type_constraint} = delete $args{isa}
 175         if exists $args{isa};
 176
 177     my $attribute = $self->new(%args);
 178
 179     $attribute->_create_args(\%args);
 180
 181     $class->add_attribute($attribute);
 182
 183     # install an accessor
 184     if ($attribute->_is_metadata eq 'rw' || $attribute->_is_metadata eq 'ro') {
 185         my $accessor = $attribute->generate_accessor;
 186         $class->add_method($name => $accessor);
 187     }
 188
 189     for my $method (qw/predicate clearer/) {
 190         my $predicate = "has_$method";
 191         if ($attribute->$predicate) {
 192             my $generator = "generate_$method";
 193             my $coderef = $attribute->$generator;
 194             $class->add_method($attribute->$method => $coderef);
 195         }
 196     }
 197
 198     if ($attribute->has_handles) {
 199         my $method_map = $attribute->generate_handles;
 200         for my $method_name (keys %$method_map) {
 201             $class->add_method($method_name => $method_map->{$method_name});
 202         }
 203     }
 204
 205     return $attribute;
 206 }
 207
 208 sub canonicalize_args {
 209     my $self = shift;
 210     my $name = shift;
 211     my %args = @_;
 212
 213     if ($args{lazy_build}) {
 214         $args{lazy}      = 1;
 215         $args{required}  = 1;
 216         $args{builder}   = "_build_${name}"
 217             if !exists($args{builder});
 218         if ($name =~ /^_/) {
 219             $args{clearer}   = "_clear${name}" if !exists($args{clearer});
 220             $args{predicate} = "_has${name}" if !exists($args{predicate});
 221         }
 222         else {
 223             $args{clearer}   = "clear_${name}" if !exists($args{clearer});
 224             $args{predicate} = "has_${name}" if !exists($args{predicate});
 225         }
 226     }
 227
 228     return %args;
 229 }
 230
 231 sub validate_args {
 232     my $self = shift;
 233     my $name = shift;
 234     my $args = shift;
 235
 236     confess "You can not use lazy_build and default for the same attribute ($name)"
 237         if $args->{lazy_build} && exists $args->{default};
 238
 239     confess "You cannot have lazy attribute ($name) without specifying a default value for it"
 240         if $args->{lazy}
 241         && !exists($args->{default})
 242         && !exists($args->{builder});
 243
 244     confess "References are not allowed as default values, you must wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])"
 245         if ref($args->{default})
 246         && ref($args->{default}) ne 'CODE';
 247
 248     confess "You cannot auto-dereference without specifying a type constraint on attribute ($name)"
 249         if $args->{auto_deref} && !exists($args->{isa});
 250
 251     confess "You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)"
 252         if $args->{auto_deref}
 253         && $args->{isa} ne 'ArrayRef'
 254         && $args->{isa} ne 'HashRef';
 255
 256     if ($args->{trigger}) {
 257         if (ref($args->{trigger}) eq 'HASH') {
 258             Carp::carp "HASH-based form of trigger has been removed. Only the coderef form of triggers are now supported.";
 259         }
 260
 261         confess "Trigger must be a CODE ref on attribute ($name)"
 262             if ref($args->{trigger}) ne 'CODE';
 263     }
 264
 265     return 1;
 266 }
 267
 268 sub find_type_constraint {
 269     my $self = shift;
 270     my $type = $self->type_constraint;
 271
 272     return unless $type;
 273
 274     my $checker = Mouse::TypeRegistry->optimized_constraints->{$type};
 275     return $checker if $checker;
 276
 277     return sub { blessed($_) && blessed($_) eq $type };
 278 }
 279
 280 sub verify_type_constraint {
 281     my $self = shift;
 282     local $_ = shift;
 283
 284     my $type = $self->type_constraint
 285         or return 1;
 286     my $constraint = $self->find_type_constraint;
 287
 288     return 1 if $constraint->($_);
 289
 290     my $name = $self->name;
 291     my $display = defined($_) ? overload::StrVal($_) : 'undef';
 292     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
 293 }
 294
 295 sub _canonicalize_handles {
 296     my $self    = shift;
 297     my $handles = shift;
 298
 299     if (ref($handles) eq 'HASH') {
 300         return %$handles;
 301     }
 302     elsif (ref($handles) eq 'ARRAY') {
 303         return map { $_ => $_ } @$handles;
 304     }
 305     else {
 306         confess "Unable to canonicalize the 'handles' option with $handles";
 307     }
 308 }
 309
 310 sub clone_parent {
 311     my $self  = shift;
 312     my $class = shift;
 313     my $name  = shift;
 314     my %args  = ($self->get_parent_args($class, $name), @_);
 315
 316     $self->create($class, $name, %args);
 317 }
 318
 319 sub get_parent_args {
 320     my $self  = shift;
 321     my $class = shift;
 322     my $name  = shift;
 323
 324     for my $super ($class->linearized_isa) {
 325         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 326             or next;
 327         return %{ $super_attr->_create_args };
 328     }
 329
 330     confess "Could not find an attribute by the name of '$name' to inherit from";
 331 }
 332
 333 1;
 334
 335 __END__
 336
 337 =head1 NAME
 338
 339 Mouse::Meta::Attribute - attribute metaclass
 340
 341 =head1 METHODS
 342
 343 =head2 new %args -> Mouse::Meta::Attribute
 344
 345 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 346
 347 =head2 create OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 348
 349 Creates a new attribute in OwnerClass. Accessors and helper methods are
 350 installed. Some error checking is done.
 351
 352 =head2 name -> AttributeName
 353
 354 =head2 associated_class -> OwnerClass
 355
 356 =head2 is_required -> Bool
 357
 358 =head2 default -> Item
 359
 360 =head2 has_default -> Bool
 361
 362 =head2 is_lazy -> Bool
 363
 364 =head2 predicate -> MethodName | Undef
 365
 366 =head2 has_predicate -> Bool
 367
 368 =head2 clearer -> MethodName | Undef
 369
 370 =head2 has_clearer -> Bool
 371
 372 =head2 handles -> { LocalName => RemoteName }
 373
 374 =head2 has_handles -> Bool
 375
 376 =head2 is_weak_ref -> Bool
 377
 378 =head2 init_arg -> Str
 379
 380 =head2 type_constraint -> Str
 381
 382 =head2 has_type_constraint -> Bool
 383
 384 =head2 trigger => CODE | Undef
 385
 386 =head2 has_trigger -> Bool
 387
 388 =head2 builder => MethodName | Undef
 389
 390 =head2 has_builder -> Bool
 391
 392 =head2 is_lazy_build => Bool
 393
 394 =head2 should_auto_deref -> Bool
 395
 396 Informational methods.
 397
 398 =head2 generate_accessor -> CODE
 399
 400 Creates a new code reference for the attribute's accessor.
 401
 402 =head2 generate_predicate -> CODE
 403
 404 Creates a new code reference for the attribute's predicate.
 405
 406 =head2 generate_clearer -> CODE
 407
 408 Creates a new code reference for the attribute's clearer.
 409
 410 =head2 generate_handles -> { MethodName => CODE }
 411
 412 Creates a new code reference for each of the attribute's handles methods.
 413
 414 =head2 find_type_constraint -> CODE
 415
 416 Returns a code reference which can be used to check that a given value passes
 417 this attribute's type constraint;
 418
 419 =head2 verify_type_constraint Item -> 1 | ERROR
 420
 421 Checks that the given value passes this attribute's type constraint. Returns 1
 422 on success, otherwise C<confess>es.
 423
 424 =head2 canonicalize_args Name, %args -> %args
 425
 426 Canonicalizes some arguments to create. In particular, C<lazy_build> is
 427 canonicalized into C<lazy>, C<builder>, etc.
 428
 429 =head2 validate_args Name, \%args -> 1 | ERROR
 430
 431 Checks that the arguments to create the attribute (ie those specified by
 432 C<has>) are valid.
 433
 434 =head2 clone_parent OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 435
 436 Creates a new attribute in OwnerClass, inheriting options from parent classes.
 437 Accessors and helper methods are installed. Some error checking is done.
 438
 439 =head2 get_parent_args OwnerClass, AttributeName -> Hash
 440
 441 Returns the options that the parent class of C<OwnerClass> used for attribute
 442 C<AttributeName>.
 443
 444 =cut
 445