lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use Mouse::Util qw(:meta); # enables strict and warnings
   3
   4 use Carp ();
   5
   6 use Mouse::Meta::TypeConstraint;
   7
   8 my %valid_options = map { $_ => undef } (
   9   'accessor',
  10   'auto_deref',
  11   'builder',
  12   'clearer',
  13   'coerce',
  14   'default',
  15   'documentation',
  16   'does',
  17   'handles',
  18   'init_arg',
  19   'insertion_order',
  20   'is',
  21   'isa',
  22   'lazy',
  23   'lazy_build',
  24   'name',
  25   'predicate',
  26   'reader',
  27   'required',
  28   'traits',
  29   'trigger',
  30   'type_constraint',
  31   'weak_ref',
  32   'writer',
  33
  34   # internally used
  35   'associated_class',
  36   'associated_methods',
  37
  38   # Moose defines, but Mouse doesn't
  39   #'definition_context',
  40   #'initializer',
  41
  42   # special case for AttributeHelpers
  43   'provides',
  44   'curries',
  45 );
  46
  47 our @CARP_NOT = qw(Mouse::Meta::Class);
  48
  49 sub new {
  50     my $class = shift;
  51     my $name  = shift;
  52
  53     my $args  = $class->Mouse::Object::BUILDARGS(@_);
  54
  55     $class->_process_options($name, $args);
  56
  57     $args->{name} = $name;
  58
  59     # check options
  60     # (1) known by core
  61     my @bad = grep{ !exists $valid_options{$_} } keys %{$args};
  62
  63     # (2) known by subclasses
  64     if(@bad && $class ne __PACKAGE__){
  65         my %valid_attrs = (
  66             map { $_ => undef }
  67             grep { defined }
  68             map { $_->init_arg() }
  69             $class->meta->get_all_attributes()
  70         );
  71         @bad = grep{ !exists $valid_attrs{$_} } @bad;
  72     }
  73
  74     # (3) bad options found
  75     if(@bad){
  76         Carp::carp(
  77             "Found unknown argument(s) passed to '$name' attribute constructor in '$class': "
  78             . Mouse::Util::english_list(@bad));
  79     }
  80
  81     my $self = bless $args, $class;
  82     if($class ne __PACKAGE__){
  83         $class->meta->_initialize_object($self, $args);
  84     }
  85     return $self;
  86 }
  87
  88 sub has_read_method   { $_[0]->has_reader || $_[0]->has_accessor }
  89 sub has_write_method  { $_[0]->has_writer || $_[0]->has_accessor }
  90
  91 sub get_read_method   { $_[0]->reader || $_[0]->accessor }
  92 sub get_write_method  { $_[0]->writer || $_[0]->accessor }
  93
  94 sub get_read_method_ref{
  95     my($self) = @_;
  96     return $self->{_mouse_cache_read_method_ref}
  97         ||= $self->_get_accessor_method_ref('get_read_method', '_generate_reader');
  98 }
  99
 100 sub get_write_method_ref{
 101     my($self) = @_;
 102     return $self->{_mouse_cache_write_method_ref}
 103         ||= $self->_get_accessor_method_ref('get_write_method', '_generate_writer');
 104 }
 105
 106 sub interpolate_class{
 107     my($class, $args) = @_;
 108
 109     if(my $metaclass = delete $args->{metaclass}){
 110         $class = Mouse::Util::resolve_metaclass_alias( Attribute => $metaclass );
 111     }
 112
 113     my @traits;
 114     if(my $traits_ref = delete $args->{traits}){
 115
 116         for (my $i = 0; $i < @{$traits_ref}; $i++) {
 117             my $trait = Mouse::Util::resolve_metaclass_alias(Attribute => $traits_ref->[$i], trait => 1);
 118
 119             next if $class->does($trait);
 120
 121             push @traits, $trait;
 122
 123             # are there options?
 124             push @traits, $traits_ref->[++$i]
 125                 if ref($traits_ref->[$i+1]);
 126         }
 127
 128         if (@traits) {
 129             $class = Mouse::Meta::Class->create_anon_class(
 130                 superclasses => [ $class ],
 131                 roles        => \@traits,
 132                 cache        => 1,
 133             )->name;
 134         }
 135     }
 136
 137     return( $class, @traits );
 138 }
 139
 140 sub verify_against_type_constraint {
 141     my ($self, $value) = @_;
 142
 143     my $type_constraint = $self->{type_constraint};
 144     return 1 if !$type_constraint;
 145     return 1 if $type_constraint->check($value);
 146
 147     $self->_throw_type_constraint_error($value, $type_constraint);
 148 }
 149
 150 sub _throw_type_constraint_error {
 151     my($self, $value, $type) = @_;
 152
 153     $self->throw_error(
 154         sprintf q{Attribute (%s) does not pass the type constraint because: %s},
 155             $self->name,
 156             $type->get_message($value),
 157     );
 158 }
 159
 160 sub illegal_options_for_inheritance {
 161     return qw(reader writer accessor clearer predicate);
 162 }
 163
 164 sub clone_and_inherit_options{
 165     my $self = shift;
 166     my $args = $self->Mouse::Object::BUILDARGS(@_);
 167
 168     foreach my $illegal($self->illegal_options_for_inheritance) {
 169         if(exists $args->{$illegal} and exists $self->{$illegal}) {
 170             $self->throw_error("Illegal inherited option: $illegal");
 171         }
 172     }
 173
 174     foreach my $name(keys %{$self}){
 175         if(!exists $args->{$name}){
 176             $args->{$name} = $self->{$name}; # inherit from self
 177         }
 178     }
 179
 180     my($attribute_class, @traits) = ref($self)->interpolate_class($args);
 181     $args->{traits} = \@traits if @traits;
 182
 183     # remove temporary caches
 184     foreach my $attr(keys %{$args}){
 185         if($attr =~ /\A _mouse_cache_/xms){
 186             delete $args->{$attr};
 187         }
 188     }
 189
 190     # remove default if lazy_build => 1
 191     if($args->{lazy_build}) {
 192         delete $args->{default};
 193     }
 194
 195     return $attribute_class->new($self->name, $args);
 196 }
 197
 198
 199 sub _get_accessor_method_ref {
 200     my($self, $type, $generator) = @_;
 201
 202     my $metaclass = $self->associated_class
 203         || $self->throw_error('No asocciated class for ' . $self->name);
 204
 205     my $accessor = $self->$type();
 206     if($accessor){
 207         return $metaclass->get_method_body($accessor);
 208     }
 209     else{
 210         return $self->accessor_metaclass->$generator($self, $metaclass);
 211     }
 212 }
 213
 214 sub set_value {
 215     my($self, $object, $value) = @_;
 216     return $self->get_write_method_ref()->($object, $value);
 217 }
 218
 219 sub get_value {
 220     my($self, $object) = @_;
 221     return $self->get_read_method_ref()->($object);
 222 }
 223
 224 sub has_value {
 225     my($self, $object) = @_;
 226     my $accessor_ref = $self->{_mouse_cache_predicate_ref}
 227         ||= $self->_get_accessor_method_ref('predicate', '_generate_predicate');
 228
 229     return $accessor_ref->($object);
 230 }
 231
 232 sub clear_value {
 233     my($self, $object) = @_;
 234     my $accessor_ref = $self->{_mouse_cache_crealer_ref}
 235         ||= $self->_get_accessor_method_ref('clearer', '_generate_clearer');
 236
 237     return $accessor_ref->($object);
 238 }
 239
 240 sub associate_method{
 241     #my($attribute, $method_name) = @_;
 242     my($attribute) = @_;
 243     $attribute->{associated_methods}++;
 244     return;
 245 }
 246
 247 sub install_accessors{
 248     my($attribute) = @_;
 249
 250     my $metaclass      = $attribute->associated_class;
 251     my $accessor_class = $attribute->accessor_metaclass;
 252
 253     foreach my $type(qw(accessor reader writer predicate clearer)){
 254         if(exists $attribute->{$type}){
 255             my $generator = '_generate_' . $type;
 256             my $code      = $accessor_class->$generator($attribute, $metaclass);
 257             $metaclass->add_method($attribute->{$type} => $code);
 258             $attribute->associate_method($attribute->{$type});
 259         }
 260     }
 261
 262     # install delegation
 263     if(exists $attribute->{handles}){
 264         my %handles = $attribute->_canonicalize_handles();
 265
 266         while(my($handle, $method_to_call) = each %handles){
 267             if($metaclass->has_method($handle)) {
 268                 $attribute->throw_error("You cannot overwrite a locally defined method ($handle) with a delegation");
 269             }
 270
 271             $metaclass->add_method($handle =>
 272                 $attribute->_make_delegation_method(
 273                     $handle, $method_to_call));
 274
 275             $attribute->associate_method($handle);
 276         }
 277     }
 278
 279     return;
 280 }
 281
 282 sub delegation_metaclass() { ## no critic
 283     'Mouse::Meta::Method::Delegation'
 284 }
 285
 286 sub _canonicalize_handles {
 287     my($self) = @_;
 288     my $handles = $self->{handles};
 289
 290     my $handle_type = ref $handles;
 291     if ($handle_type eq 'HASH') {
 292         return %$handles;
 293     }
 294     elsif ($handle_type eq 'ARRAY') {
 295         return map { $_ => $_ } @$handles;
 296     }
 297     elsif ($handle_type eq 'Regexp') {
 298         my $meta = $self->_find_delegate_metaclass();
 299         return map  { $_ => $_ }
 300                grep { !Mouse::Object->can($_) && $_ =~ $handles }
 301                    Mouse::Util::is_a_metarole($meta)
 302                         ? $meta->get_method_list
 303                         : $meta->get_all_method_names;
 304     }
 305     elsif ($handle_type eq 'CODE') {
 306         return $handles->( $self, $self->_find_delegate_metaclass() );
 307     }
 308     else {
 309         $self->throw_error("Unable to canonicalize the 'handles' option with $handles");
 310     }
 311 }
 312
 313 sub _find_delegate_metaclass {
 314     my($self) = @_;
 315     my $meta;
 316     if($self->{isa}) {
 317         $meta = Mouse::Meta::Class->initialize("$self->{isa}");
 318     }
 319     elsif($self->{does}) {
 320         $meta = Mouse::Util::get_metaclass_by_name("$self->{does}");
 321     }
 322     defined($meta) or $self->throw_error(
 323         "Cannot find delegate metaclass for attribute " . $self->name);
 324     return $meta;
 325 }
 326
 327
 328 sub _make_delegation_method {
 329     my($self, $handle, $method_to_call) = @_;
 330     return Mouse::Util::load_class($self->delegation_metaclass)
 331         ->_generate_delegation($self, $handle, $method_to_call);
 332 }
 333
 334 1;
 335 __END__
 336
 337 =head1 NAME
 338
 339 Mouse::Meta::Attribute - The Mouse attribute metaclass
 340
 341 =head1 VERSION
 342
 343 This document describes Mouse version 0.73
 344
 345 =head1 DESCRIPTION
 346
 347 This is a meta object protocol for Mouse attributes,
 348 which is a subset of Moose::Meta::Attribute.
 349
 350 =head1 METHODS
 351
 352 =head2 C<< new(%options) -> Mouse::Meta::Attribute >>
 353
 354 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 355
 356 It adds the following options to the constructor:
 357
 358 =over 4
 359
 360 =item C<< is => 'ro', 'rw', 'bare' >>
 361
 362 This provides a shorthand for specifying the C<reader>, C<writer>, or
 363 C<accessor> names. If the attribute is read-only ('ro') then it will
 364 have a C<reader> method with the same attribute as the name.
 365
 366 If it is read-write ('rw') then it will have an C<accessor> method
 367 with the same name. If you provide an explicit C<writer> for a
 368 read-write attribute, then you will have a C<reader> with the same
 369 name as the attribute, and a C<writer> with the name you provided.
 370
 371 Use 'bare' when you are deliberately not installing any methods
 372 (accessor, reader, etc.) associated with this attribute; otherwise,
 373 Moose will issue a deprecation warning when this attribute is added to a
 374 metaclass.
 375
 376 =item C<< isa => Type >>
 377
 378 This option accepts a type. The type can be a string, which should be
 379 a type name. If the type name is unknown, it is assumed to be a class
 380 name.
 381
 382 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 383
 384 If you I<also> provide a C<does> option, then your C<isa> option must
 385 be a class name, and that class must do the role specified with
 386 C<does>.
 387
 388 =item C<< does => Role >>
 389
 390 This is short-hand for saying that the attribute's type must be an
 391 object which does the named role.
 392
 393 B<This option is not yet supported.>
 394
 395 =item C<< coerce => Bool >>
 396
 397 This option is only valid for objects with a type constraint
 398 (C<isa>). If this is true, then coercions will be applied whenever
 399 this attribute is set.
 400
 401 You can make both this and the C<weak_ref> option true.
 402
 403 =item C<< trigger => CodeRef >>
 404
 405 This option accepts a subroutine reference, which will be called after
 406 the attribute is set.
 407
 408 =item C<< required => Bool >>
 409
 410 An attribute which is required must be provided to the constructor. An
 411 attribute which is required can also have a C<default> or C<builder>,
 412 which will satisfy its required-ness.
 413
 414 A required attribute must have a C<default>, C<builder> or a
 415 non-C<undef> C<init_arg>
 416
 417 =item C<< lazy => Bool >>
 418
 419 A lazy attribute must have a C<default> or C<builder>. When an
 420 attribute is lazy, the default value will not be calculated until the
 421 attribute is read.
 422
 423 =item C<< weak_ref => Bool >>
 424
 425 If this is true, the attribute's value will be stored as a weak
 426 reference.
 427
 428 =item C<< auto_deref => Bool >>
 429
 430 If this is true, then the reader will dereference the value when it is
 431 called. The attribute must have a type constraint which defines the
 432 attribute as an array or hash reference.
 433
 434 =item C<< lazy_build => Bool >>
 435
 436 Setting this to true makes the attribute lazy and provides a number of
 437 default methods.
 438
 439   has 'size' => (
 440       is         => 'ro',
 441       lazy_build => 1,
 442   );
 443
 444 is equivalent to this:
 445
 446   has 'size' => (
 447       is        => 'ro',
 448       lazy      => 1,
 449       builder   => '_build_size',
 450       clearer   => 'clear_size',
 451       predicate => 'has_size',
 452   );
 453
 454 =back
 455
 456 =head2 C<< associate_method(MethodName) >>
 457
 458 Associates a method with the attribute. Typically, this is called internally
 459 when an attribute generates its accessors.
 460
 461 Currently the argument I<MethodName> is ignored in Mouse.
 462
 463 =head2 C<< verify_against_type_constraint(Item) -> TRUE | ERROR >>
 464
 465 Checks that the given value passes this attribute's type constraint. Returns C<true>
 466 on success, otherwise C<confess>es.
 467
 468 =head2 C<< clone_and_inherit_options(options) -> Mouse::Meta::Attribute >>
 469
 470 Creates a new attribute in the owner class, inheriting options from parent classes.
 471 Accessors and helper methods are installed. Some error checking is done.
 472
 473 =head2 C<< get_read_method_ref >>
 474
 475 =head2 C<< get_write_method_ref >>
 476
 477 Returns the subroutine reference of a method suitable for reading or
 478 writing the attribute's value in the associated class. These methods
 479 always return a subroutine reference, regardless of whether or not the
 480 attribute is read- or write-only.
 481
 482 =head1 SEE ALSO
 483
 484 L<Moose::Meta::Attribute>
 485
 486 L<Class::MOP::Attribute>
 487
 488 =cut
 489