lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use strict;
   3 use warnings;
   4
   5 use Carp ();
   6
   7 use Mouse::Util qw(:meta);
   8
   9 use Mouse::Meta::TypeConstraint;
  10 use Mouse::Meta::Method::Accessor;
  11
  12 sub _process_options{
  13     my($class, $name, $args) = @_;
  14
  15
  16     # XXX: for backward compatibility (with method modifiers)
  17     if($class->can('canonicalize_args') != \&canonicalize_args){
  18         %{$args} = $class->canonicalize_args($name, %{$args});
  19     }
  20
  21     # taken from Class::MOP::Attribute::new
  22
  23     defined($name)
  24         or $class->throw_error('You must provide a name for the attribute');
  25
  26     if(!exists $args->{init_arg}){
  27         $args->{init_arg} = $name;
  28     }
  29
  30     # 'required' requires eigher 'init_arg', 'builder', or 'default'
  31     my $can_be_required = defined( $args->{init_arg} );
  32
  33     if(exists $args->{builder}){
  34         # XXX:
  35         # Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
  36         # This feature will be changed in a future. (gfx)
  37         $class->throw_error('builder must be a defined scalar value which is a method name')
  38             #if ref $args->{builder} || !defined $args->{builder};
  39             if !defined $args->{builder};
  40
  41         $can_be_required++;
  42     }
  43     elsif(exists $args->{default}){
  44         if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
  45             $class->throw_error("References are not allowed as default values, you must "
  46                               . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
  47         }
  48         $can_be_required++;
  49     }
  50
  51     if( $args->{required} && !$can_be_required ) {
  52         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
  53     }
  54
  55     # taken from Mouse::Meta::Attribute->new and _process_args->
  56
  57     if(exists $args->{is}){
  58         my $is = $args->{is};
  59
  60         if($is eq 'ro'){
  61             $args->{reader} ||= $name;
  62         }
  63         elsif($is eq 'rw'){
  64             if(exists $args->{writer}){
  65                 $args->{reader} ||= $name;
  66              }
  67              else{
  68                 $args->{accessor} ||= $name;
  69              }
  70         }
  71         elsif($is eq 'bare'){
  72             # do nothing, but don't complain (later) about missing methods
  73         }
  74         else{
  75             $is = 'undef' if !defined $is;
  76             $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
  77         }
  78     }
  79
  80     my $tc;
  81     if(exists $args->{isa}){
  82         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
  83     }
  84     elsif(exists $args->{does}){
  85         # TODO
  86         # $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
  87     }
  88     $tc = $args->{type_constraint};
  89
  90     if($args->{coerce}){
  91         defined($tc)
  92             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
  93
  94         $args->{weak_ref}
  95             && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
  96     }
  97
  98     if ($args->{lazy_build}) {
  99         exists($args->{default})
 100             && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
 101
 102         $args->{lazy}      = 1;
 103         $args->{builder} ||= "_build_${name}";
 104         if ($name =~ /^_/) {
 105             $args->{clearer}   ||= "_clear${name}";
 106             $args->{predicate} ||= "_has${name}";
 107         }
 108         else {
 109             $args->{clearer}   ||= "clear_${name}";
 110             $args->{predicate} ||= "has_${name}";
 111         }
 112     }
 113
 114     if ($args->{auto_deref}) {
 115         defined($tc)
 116             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
 117
 118         ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
 119             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
 120     }
 121
 122     if (exists $args->{trigger}) {
 123         ('CODE' eq ref $args->{trigger})
 124             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
 125     }
 126
 127     if ($args->{lazy}) {
 128         (exists $args->{default} || defined $args->{builder})
 129             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
 130     }
 131
 132     return;
 133 }
 134
 135 sub new {
 136     my $class = shift;
 137     my $name  = shift;
 138
 139     my %args  = (@_ == 1) ? %{ $_[0] } : @_;
 140
 141     $class->_process_options($name, \%args);
 142
 143     $args{name} = $name;
 144
 145     my $instance = bless \%args, $class;
 146
 147     # extra attributes
 148     if($class ne __PACKAGE__){
 149         $class->meta->_initialize_instance($instance,\%args);
 150     }
 151
 152 # XXX: there is no fast way to check attribute validity
 153 #    my @bad = ...;
 154 #    if(@bad){
 155 #        @bad = sort @bad;
 156 #        Carp::cluck("Found unknown argument(s) passed to '$name' attribute constructor in '$class': @bad");
 157 #    }
 158
 159     return $instance;
 160 }
 161
 162 # readers
 163
 164 sub name                 { $_[0]->{name}                   }
 165 sub associated_class     { $_[0]->{associated_class}       }
 166
 167 sub accessor             { $_[0]->{accessor}               }
 168 sub reader               { $_[0]->{reader}                 }
 169 sub writer               { $_[0]->{writer}                 }
 170 sub predicate            { $_[0]->{predicate}              }
 171 sub clearer              { $_[0]->{clearer}                }
 172 sub handles              { $_[0]->{handles}                }
 173
 174 sub _is_metadata         { $_[0]->{is}                     }
 175 sub is_required          { $_[0]->{required}               }
 176 sub default              { $_[0]->{default}                }
 177 sub is_lazy              { $_[0]->{lazy}                   }
 178 sub is_lazy_build        { $_[0]->{lazy_build}             }
 179 sub is_weak_ref          { $_[0]->{weak_ref}               }
 180 sub init_arg             { $_[0]->{init_arg}               }
 181 sub type_constraint      { $_[0]->{type_constraint}        }
 182
 183 sub trigger              { $_[0]->{trigger}                }
 184 sub builder              { $_[0]->{builder}                }
 185 sub should_auto_deref    { $_[0]->{auto_deref}             }
 186 sub should_coerce        { $_[0]->{coerce}                 }
 187
 188 sub get_read_method      { $_[0]->{reader} || $_[0]->{accessor} }
 189 sub get_write_method     { $_[0]->{writer} || $_[0]->{accessor} }
 190
 191 # predicates
 192
 193 sub has_accessor         { exists $_[0]->{accessor}        }
 194 sub has_reader           { exists $_[0]->{reader}          }
 195 sub has_writer           { exists $_[0]->{writer}          }
 196 sub has_predicate        { exists $_[0]->{predicate}       }
 197 sub has_clearer          { exists $_[0]->{clearer}         }
 198 sub has_handles          { exists $_[0]->{handles}         }
 199
 200 sub has_default          { exists $_[0]->{default}         }
 201 sub has_type_constraint  { exists $_[0]->{type_constraint} }
 202 sub has_trigger          { exists $_[0]->{trigger}         }
 203 sub has_builder          { exists $_[0]->{builder}         }
 204
 205 sub has_read_method      { exists $_[0]->{reader} || exists $_[0]->{accessor} }
 206 sub has_write_method     { exists $_[0]->{writer} || exists $_[0]->{accessor} }
 207
 208 sub _create_args {
 209     $_[0]->{_create_args} = $_[1] if @_ > 1;
 210     $_[0]->{_create_args}
 211 }
 212
 213 sub interpolate_class{
 214     my($class, $name, $args) = @_;
 215
 216     if(my $metaclass = delete $args->{metaclass}){
 217         $class = Mouse::Util::resolve_metaclass_alias( Attribute => $metaclass );
 218     }
 219
 220     my @traits;
 221     if(my $traits_ref = delete $args->{traits}){
 222
 223         for (my $i = 0; $i < @{$traits_ref}; $i++) {
 224             my $trait = Mouse::Util::resolve_metaclass_alias(Attribute => $traits_ref->[$i], trait => 1);
 225
 226             next if $class->does($trait);
 227
 228             push @traits, $trait;
 229
 230             # are there options?
 231             push @traits, $traits_ref->[++$i]
 232                 if ref($traits_ref->[$i+1]);
 233         }
 234
 235         if (@traits) {
 236             $class = Mouse::Meta::Class->create_anon_class(
 237                 superclasses => [ $class ],
 238                 roles        => \@traits,
 239                 cache        => 1,
 240             )->name;
 241         }
 242     }
 243
 244     return( $class, @traits );
 245 }
 246
 247 sub canonicalize_args{
 248     my ($self, $name, %args) = @_;
 249
 250     Carp::cluck("$self->canonicalize_args has been deprecated."
 251         . "Use \$self->_process_options instead.")
 252             if _MOUSE_VERBOSE;
 253
 254     return %args;
 255 }
 256
 257 sub create {
 258     my ($self, $class, $name, %args) = @_;
 259
 260     Carp::cluck("$self->create has been deprecated."
 261         . "Use \$meta->add_attribute and \$attr->install_accessors instead.")
 262             if _MOUSE_VERBOSE;
 263
 264     # noop
 265     return $self;
 266 }
 267
 268 sub _coerce_and_verify {
 269     my($self, $value, $instance) = @_;
 270
 271     my $type_constraint = $self->{type_constraint};
 272
 273     return $value if !$type_constraint;
 274
 275     if ($self->should_coerce && $type_constraint->has_coercion) {
 276         $value = $type_constraint->coerce($value);
 277     }
 278
 279     return $value if $type_constraint->check($value);
 280
 281     $self->verify_against_type_constraint($value);
 282
 283     return $value;
 284 }
 285
 286 sub verify_against_type_constraint {
 287     my ($self, $value) = @_;
 288
 289     my $type_constraint = $self->{type_constraint};
 290     return 1 if !$type_constraint;;
 291     return 1 if $type_constraint->check($value);
 292
 293     $self->verify_type_constraint_error($self->name, $value, $type_constraint);
 294 }
 295
 296 sub verify_type_constraint_error {
 297     my($self, $name, $value, $type) = @_;
 298     $self->throw_error("Attribute ($name) does not pass the type constraint because: " . $type->get_message($value));
 299 }
 300
 301 sub coerce_constraint { ## my($self, $value) = @_;
 302     my $type = $_[0]->{type_constraint}
 303         or return $_[1];
 304
 305     Carp::cluck("coerce_constraint() has been deprecated, which was an internal utility anyway");
 306
 307     return Mouse::Util::TypeConstraints->typecast_constraints($_[0]->associated_class->name, $type, $_[1]);
 308 }
 309
 310 sub _canonicalize_handles {
 311     my $self    = shift;
 312     my $handles = shift;
 313
 314     if (ref($handles) eq 'HASH') {
 315         return %$handles;
 316     }
 317     elsif (ref($handles) eq 'ARRAY') {
 318         return map { $_ => $_ } @$handles;
 319     }
 320     else {
 321         $self->throw_error("Unable to canonicalize the 'handles' option with $handles");
 322     }
 323 }
 324
 325 sub clone_and_inherit_options{
 326     my $self = shift;
 327     my $name = shift;
 328
 329     return ref($self)->new($name, %{$self}, (@_ == 1) ? %{$_[0]} : @_);
 330 }
 331
 332 sub clone_parent {
 333     my $self  = shift;
 334     my $class = shift;
 335     my $name  = shift;
 336     my %args  = ($self->get_parent_args($class, $name), @_);
 337
 338     Carp::cluck("$self->clone_parent has been deprecated."
 339         . "Use \$meta->add_attribute and \$attr->install_accessors instead.")
 340         if _MOUSE_VERBOSE;
 341
 342     $self->clone_and_inherited_args($class, $name, %args);
 343 }
 344
 345 sub get_parent_args {
 346     my $self  = shift;
 347     my $class = shift;
 348     my $name  = shift;
 349
 350     for my $super ($class->linearized_isa) {
 351         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 352             or next;
 353         return %{ $super_attr->_create_args };
 354     }
 355
 356     $self->throw_error("Could not find an attribute by the name of '$name' to inherit from");
 357 }
 358
 359 sub associate_method{
 360     my ($attribute, $method) = @_;
 361     $attribute->{associated_methods}++;
 362     return;
 363 }
 364
 365 sub install_accessors{
 366     my($attribute) = @_;
 367
 368     my $metaclass       = $attribute->{associated_class};
 369
 370     foreach my $type(qw(accessor reader writer predicate clearer handles)){
 371         if(exists $attribute->{$type}){
 372             my $installer    = '_install_' . $type;
 373
 374             Mouse::Meta::Method::Accessor->$installer($attribute, $attribute->{$type}, $metaclass);
 375
 376             $attribute->{associated_methods}++;
 377         }
 378     }
 379
 380     if($attribute->can('create') != \&create){
 381         # backword compatibility
 382         $attribute->create($metaclass, $attribute->name, %{$attribute});
 383     }
 384
 385     return;
 386 }
 387
 388 sub throw_error{
 389     my $self = shift;
 390
 391     my $metaclass = (ref $self && $self->associated_class) || 'Mouse::Meta::Class';
 392     $metaclass->throw_error(@_, depth => 1);
 393 }
 394
 395 1;
 396
 397 __END__
 398
 399 =head1 NAME
 400
 401 Mouse::Meta::Attribute - The Mouse attribute metaclass
 402
 403 =head1 METHODS
 404
 405 =head2 C<< new(%options) -> Mouse::Meta::Attribute >>
 406
 407 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 408
 409 It adds the following options to the constructor:
 410
 411 =over 4
 412
 413 =item C<< is => 'ro', 'rw', 'bare' >>
 414
 415 This provides a shorthand for specifying the C<reader>, C<writer>, or
 416 C<accessor> names. If the attribute is read-only ('ro') then it will
 417 have a C<reader> method with the same attribute as the name.
 418
 419 If it is read-write ('rw') then it will have an C<accessor> method
 420 with the same name. If you provide an explicit C<writer> for a
 421 read-write attribute, then you will have a C<reader> with the same
 422 name as the attribute, and a C<writer> with the name you provided.
 423
 424 Use 'bare' when you are deliberately not installing any methods
 425 (accessor, reader, etc.) associated with this attribute; otherwise,
 426 Moose will issue a deprecation warning when this attribute is added to a
 427 metaclass.
 428
 429 =item C<< isa => Type >>
 430
 431 This option accepts a type. The type can be a string, which should be
 432 a type name. If the type name is unknown, it is assumed to be a class
 433 name.
 434
 435 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 436
 437 If you I<also> provide a C<does> option, then your C<isa> option must
 438 be a class name, and that class must do the role specified with
 439 C<does>.
 440
 441 =item C<< does => Role >>
 442
 443 This is short-hand for saying that the attribute's type must be an
 444 object which does the named role.
 445
 446 B<This option is not yet supported.>
 447
 448 =item C<< coerce => Bool >>
 449
 450 This option is only valid for objects with a type constraint
 451 (C<isa>). If this is true, then coercions will be applied whenever
 452 this attribute is set.
 453
 454 You can make both this and the C<weak_ref> option true.
 455
 456 =item C<< trigger => CodeRef >>
 457
 458 This option accepts a subroutine reference, which will be called after
 459 the attribute is set.
 460
 461 =item C<< required => Bool >>
 462
 463 An attribute which is required must be provided to the constructor. An
 464 attribute which is required can also have a C<default> or C<builder>,
 465 which will satisfy its required-ness.
 466
 467 A required attribute must have a C<default>, C<builder> or a
 468 non-C<undef> C<init_arg>
 469
 470 =item C<< lazy => Bool >>
 471
 472 A lazy attribute must have a C<default> or C<builder>. When an
 473 attribute is lazy, the default value will not be calculated until the
 474 attribute is read.
 475
 476 =item C<< weak_ref => Bool >>
 477
 478 If this is true, the attribute's value will be stored as a weak
 479 reference.
 480
 481 =item C<< auto_deref => Bool >>
 482
 483 If this is true, then the reader will dereference the value when it is
 484 called. The attribute must have a type constraint which defines the
 485 attribute as an array or hash reference.
 486
 487 =item C<< lazy_build => Bool >>
 488
 489 Setting this to true makes the attribute lazy and provides a number of
 490 default methods.
 491
 492   has 'size' => (
 493       is         => 'ro',
 494       lazy_build => 1,
 495   );
 496
 497 is equivalent to this:
 498
 499   has 'size' => (
 500       is        => 'ro',
 501       lazy      => 1,
 502       builder   => '_build_size',
 503       clearer   => 'clear_size',
 504       predicate => 'has_size',
 505   );
 506
 507 =back
 508
 509 =head2 C<< associate_method(Method) >>
 510
 511 Associates a method with the attribute. Typically, this is called internally
 512 when an attribute generates its accessors.
 513
 514 Currently the argument I<Method> is ignored in Mouse.
 515
 516 =head2 C<< verify_against_type_constraint(Item) -> TRUE | ERROR >>
 517
 518 Checks that the given value passes this attribute's type constraint. Returns C<true>
 519 on success, otherwise C<confess>es.
 520
 521 =head2 C<< clone_and_inherit_options(options) -> Mouse::Meta::Attribute >>
 522
 523 Creates a new attribute in the owner class, inheriting options from parent classes.
 524 Accessors and helper methods are installed. Some error checking is done.
 525
 526 =head1 SEE ALSO
 527
 528 L<Moose::Meta::Attribute>
 529
 530 L<Class::MOP::Attribute>
 531
 532 =cut
 533