lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use strict;
   3 use warnings;
   4 require overload;
   5
   6 use Carp 'confess';
   7 use Scalar::Util ();
   8
   9 sub new {
  10     my ($class, $name, %options) = @_;
  11
  12     $options{name} = $name;
  13
  14     $options{init_arg} = $name
  15         unless exists $options{init_arg};
  16
  17     $options{is} ||= '';
  18
  19     bless \%options, $class;
  20 }
  21
  22 sub name                 { $_[0]->{name}                   }
  23 sub associated_class     { $_[0]->{associated_class}       }
  24 sub _is_metadata         { $_[0]->{is}                     }
  25 sub is_required          { $_[0]->{required}               }
  26 sub default              { $_[0]->{default}                }
  27 sub is_lazy              { $_[0]->{lazy}                   }
  28 sub is_lazy_build        { $_[0]->{lazy_build}             }
  29 sub predicate            { $_[0]->{predicate}              }
  30 sub clearer              { $_[0]->{clearer}                }
  31 sub handles              { $_[0]->{handles}                }
  32 sub is_weak_ref          { $_[0]->{weak_ref}               }
  33 sub init_arg             { $_[0]->{init_arg}               }
  34 sub type_constraint      { $_[0]->{type_constraint}        }
  35 sub trigger              { $_[0]->{trigger}                }
  36 sub builder              { $_[0]->{builder}                }
  37 sub should_auto_deref    { $_[0]->{auto_deref}             }
  38 sub should_coerce        { $_[0]->{should_coerce}          }
  39 sub find_type_constraint { $_[0]->{find_type_constraint}   }
  40
  41 sub has_default          { exists $_[0]->{default}         }
  42 sub has_predicate        { exists $_[0]->{predicate}       }
  43 sub has_clearer          { exists $_[0]->{clearer}         }
  44 sub has_handles          { exists $_[0]->{handles}         }
  45 sub has_type_constraint  { exists $_[0]->{type_constraint} }
  46 sub has_trigger          { exists $_[0]->{trigger}         }
  47 sub has_builder          { exists $_[0]->{builder}         }
  48
  49 sub _create_args {
  50     $_[0]->{_create_args} = $_[1] if @_ > 1;
  51     $_[0]->{_create_args}
  52 }
  53
  54 sub inlined_name {
  55     my $self = shift;
  56     my $name = $self->name;
  57     my $key   = "'" . $name . "'";
  58     return $key;
  59 }
  60
  61 sub generate_accessor {
  62     my $attribute = shift;
  63
  64     my $name          = $attribute->name;
  65     my $default       = $attribute->default;
  66     my $constraint    = $attribute->find_type_constraint;
  67     my $builder       = $attribute->builder;
  68     my $trigger       = $attribute->trigger;
  69     my $is_weak       = $attribute->is_weak_ref;
  70     my $should_deref  = $attribute->should_auto_deref;
  71     my $should_coerce = $attribute->should_coerce;
  72
  73     my $self  = '$_[0]';
  74     my $key   = $attribute->inlined_name;
  75
  76     my $accessor = "sub {\n";
  77     if ($attribute->_is_metadata eq 'rw') {
  78         $accessor .= 'if (@_ >= 2) {' . "\n";
  79
  80         my $value = '$_[1]';
  81
  82         if ($constraint) {
  83             $accessor .= 'my $val = ';
  84             if ($should_coerce) {
  85                 $accessor  .= 'Mouse::Util::TypeConstraints->typecast_constraints("'.$attribute->associated_class->name.'", $attribute->{find_type_constraint}, $attribute->{type_constraint}, '.$value.');';
  86             } else {
  87                 $accessor .= $value.';';
  88             }
  89             $accessor .= 'local $_ = $val;';
  90             $accessor .= '
  91                 unless ($constraint->()) {
  92                     $attribute->verify_type_constraint_error($name, $_, $attribute->type_constraint);
  93                 }' . "\n";
  94             $value = '$val';
  95         }
  96
  97         # if there's nothing left to do for the attribute we can return during
  98         # this setter
  99         $accessor .= 'return ' if !$is_weak && !$trigger && !$should_deref;
 100
 101         $accessor .= $self.'->{'.$key.'} = '.$value.';' . "\n";
 102
 103         if ($is_weak) {
 104             $accessor .= 'Scalar::Util::weaken('.$self.'->{'.$key.'}) if ref('.$self.'->{'.$key.'});' . "\n";
 105         }
 106
 107         if ($trigger) {
 108             $accessor .= '$trigger->('.$self.', '.$value.', $attribute);' . "\n";
 109         }
 110
 111         $accessor .= "}\n";
 112     }
 113     else {
 114         $accessor .= 'confess "Cannot assign a value to a read-only accessor" if scalar(@_) >= 2;' . "\n";
 115     }
 116
 117     if ($attribute->is_lazy) {
 118         $accessor .= $self.'->{'.$key.'} = ';
 119
 120         $accessor .= $attribute->has_builder
 121                 ? $self.'->$builder'
 122                     : ref($default) eq 'CODE'
 123                     ? '$default->('.$self.')'
 124                     : '$default';
 125         $accessor .= ' if !exists '.$self.'->{'.$key.'};' . "\n";
 126     }
 127
 128     if ($should_deref) {
 129         my $type_constraint = $attribute->type_constraint;
 130         if (!ref($type_constraint) && $type_constraint eq 'ArrayRef') {
 131             $accessor .= 'if (wantarray) {
 132                 return @{ '.$self.'->{'.$key.'} || [] };
 133             }';
 134         }
 135         else {
 136             $accessor .= 'if (wantarray) {
 137                 return %{ '.$self.'->{'.$key.'} || {} };
 138             }';
 139         }
 140     }
 141
 142     $accessor .= 'return '.$self.'->{'.$key.'};
 143     }';
 144
 145     my $sub = eval $accessor;
 146     confess $@ if $@;
 147     return $sub;
 148 }
 149
 150 sub generate_predicate {
 151     my $attribute = shift;
 152     my $key = $attribute->inlined_name;
 153
 154     my $predicate = 'sub { exists($_[0]->{'.$key.'}) }';
 155
 156     my $sub = eval $predicate;
 157     confess $@ if $@;
 158     return $sub;
 159 }
 160
 161 sub generate_clearer {
 162     my $attribute = shift;
 163     my $key = $attribute->inlined_name;
 164
 165     my $clearer = 'sub { delete($_[0]->{'.$key.'}) }';
 166
 167     my $sub = eval $clearer;
 168     confess $@ if $@;
 169     return $sub;
 170 }
 171
 172 sub generate_handles {
 173     my $attribute = shift;
 174     my $reader = $attribute->name;
 175     my %handles = $attribute->_canonicalize_handles($attribute->handles);
 176
 177     my %method_map;
 178
 179     for my $local_method (keys %handles) {
 180         my $remote_method = $handles{$local_method};
 181
 182         my $method = 'sub {
 183             my $self = shift;
 184             $self->'.$reader.'->'.$remote_method.'(@_)
 185         }';
 186
 187         $method_map{$local_method} = eval $method;
 188         confess $@ if $@;
 189     }
 190
 191     return \%method_map;
 192 }
 193
 194 sub create {
 195     my ($self, $class, $name, %args) = @_;
 196
 197     $args{name} = $name;
 198     $args{associated_class} = $class;
 199
 200     %args = $self->canonicalize_args($name, %args);
 201     $self->validate_args($name, \%args);
 202
 203     $args{should_coerce} = delete $args{coerce}
 204         if exists $args{coerce};
 205
 206     if (exists $args{isa}) {
 207         my $type_constraint = delete $args{isa};
 208         $type_constraint =~ s/\s//g;
 209         my @type_constraints = split /\|/, $type_constraint;
 210
 211         my $code;
 212         my $optimized_constraints = Mouse::Util::TypeConstraints->optimized_constraints;
 213         if (@type_constraints == 1) {
 214             $code = $optimized_constraints->{$type_constraints[0]} ||
 215                 sub { Scalar::Util::blessed($_) && $_->isa($type_constraints[0]) };
 216             $args{type_constraint} = $type_constraints[0];
 217         } else {
 218             my @code_list = map {
 219                 my $type = $_;
 220                 $optimized_constraints->{$type} ||
 221                     sub { Scalar::Util::blessed($_) && $_->isa($type) }
 222             } @type_constraints;
 223             $code = sub {
 224                 for my $code (@code_list) {
 225                     return 1 if $code->();
 226                 }
 227                 return 0;
 228             };
 229             $args{type_constraint} = \@type_constraints;
 230         }
 231         $args{find_type_constraint} = $code;
 232     }
 233
 234     my $attribute = $self->new($name, %args);
 235
 236     $attribute->_create_args(\%args);
 237
 238     $class->add_attribute($attribute);
 239
 240     # install an accessor
 241     if ($attribute->_is_metadata eq 'rw' || $attribute->_is_metadata eq 'ro') {
 242         my $accessor = $attribute->generate_accessor;
 243         $class->add_method($name => $accessor);
 244     }
 245
 246     for my $method (qw/predicate clearer/) {
 247         my $predicate = "has_$method";
 248         if ($attribute->$predicate) {
 249             my $generator = "generate_$method";
 250             my $coderef = $attribute->$generator;
 251             $class->add_method($attribute->$method => $coderef);
 252         }
 253     }
 254
 255     if ($attribute->has_handles) {
 256         my $method_map = $attribute->generate_handles;
 257         for my $method_name (keys %$method_map) {
 258             $class->add_method($method_name => $method_map->{$method_name});
 259         }
 260     }
 261
 262     return $attribute;
 263 }
 264
 265 sub canonicalize_args {
 266     my $self = shift;
 267     my $name = shift;
 268     my %args = @_;
 269
 270     if ($args{lazy_build}) {
 271         $args{lazy}      = 1;
 272         $args{required}  = 1;
 273         $args{builder}   = "_build_${name}"
 274             if !exists($args{builder});
 275         if ($name =~ /^_/) {
 276             $args{clearer}   = "_clear${name}" if !exists($args{clearer});
 277             $args{predicate} = "_has${name}" if !exists($args{predicate});
 278         }
 279         else {
 280             $args{clearer}   = "clear_${name}" if !exists($args{clearer});
 281             $args{predicate} = "has_${name}" if !exists($args{predicate});
 282         }
 283     }
 284
 285     return %args;
 286 }
 287
 288 sub validate_args {
 289     my $self = shift;
 290     my $name = shift;
 291     my $args = shift;
 292
 293     confess "You can not use lazy_build and default for the same attribute ($name)"
 294         if $args->{lazy_build} && exists $args->{default};
 295
 296     confess "You cannot have lazy attribute ($name) without specifying a default value for it"
 297         if $args->{lazy}
 298         && !exists($args->{default})
 299         && !exists($args->{builder});
 300
 301     confess "References are not allowed as default values, you must wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])"
 302         if ref($args->{default})
 303         && ref($args->{default}) ne 'CODE';
 304
 305     confess "You cannot auto-dereference without specifying a type constraint on attribute ($name)"
 306         if $args->{auto_deref} && !exists($args->{isa});
 307
 308     confess "You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)"
 309         if $args->{auto_deref}
 310         && $args->{isa} ne 'ArrayRef'
 311         && $args->{isa} ne 'HashRef';
 312
 313     if ($args->{trigger}) {
 314         if (ref($args->{trigger}) eq 'HASH') {
 315             Carp::carp "HASH-based form of trigger has been removed. Only the coderef form of triggers are now supported.";
 316         }
 317
 318         confess "Trigger must be a CODE ref on attribute ($name)"
 319             if ref($args->{trigger}) ne 'CODE';
 320     }
 321
 322     return 1;
 323 }
 324
 325 sub verify_against_type_constraint {
 326     return 1 unless $_[0]->{type_constraint};
 327
 328     local $_ = $_[1];
 329     return 1 if $_[0]->{find_type_constraint}->($_);
 330
 331     my $self = shift;
 332     $self->verify_type_constraint_error($self->name, $_, $self->type_constraint);
 333 }
 334
 335 sub verify_type_constraint_error {
 336     my($self, $name, $value, $type) = @_;
 337     $type = ref($type) eq 'ARRAY' ? join '|', @{ $type } : $type;
 338     my $display = defined($_) ? overload::StrVal($_) : 'undef';
 339     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
 340 }
 341
 342 sub coerce_constraint { ## my($self, $value) = @_;
 343     my $type = $_[0]->{type_constraint}
 344         or return $_[1];
 345     return Mouse::Util::TypeConstraints->typecast_constraints($_[0]->associated_class->name, $_[0]->find_type_constraint, $type, $_[1]);
 346 }
 347
 348 sub _canonicalize_handles {
 349     my $self    = shift;
 350     my $handles = shift;
 351
 352     if (ref($handles) eq 'HASH') {
 353         return %$handles;
 354     }
 355     elsif (ref($handles) eq 'ARRAY') {
 356         return map { $_ => $_ } @$handles;
 357     }
 358     else {
 359         confess "Unable to canonicalize the 'handles' option with $handles";
 360     }
 361 }
 362
 363 sub clone_parent {
 364     my $self  = shift;
 365     my $class = shift;
 366     my $name  = shift;
 367     my %args  = ($self->get_parent_args($class, $name), @_);
 368
 369     $self->create($class, $name, %args);
 370 }
 371
 372 sub get_parent_args {
 373     my $self  = shift;
 374     my $class = shift;
 375     my $name  = shift;
 376
 377     for my $super ($class->linearized_isa) {
 378         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 379             or next;
 380         return %{ $super_attr->_create_args };
 381     }
 382
 383     confess "Could not find an attribute by the name of '$name' to inherit from";
 384 }
 385
 386 1;
 387
 388 __END__
 389
 390 =head1 NAME
 391
 392 Mouse::Meta::Attribute - attribute metaclass
 393
 394 =head1 METHODS
 395
 396 =head2 new %args -> Mouse::Meta::Attribute
 397
 398 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 399
 400 =head2 create OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 401
 402 Creates a new attribute in OwnerClass. Accessors and helper methods are
 403 installed. Some error checking is done.
 404
 405 =head2 name -> AttributeName
 406
 407 =head2 associated_class -> OwnerClass
 408
 409 =head2 is_required -> Bool
 410
 411 =head2 default -> Item
 412
 413 =head2 has_default -> Bool
 414
 415 =head2 is_lazy -> Bool
 416
 417 =head2 predicate -> MethodName | Undef
 418
 419 =head2 has_predicate -> Bool
 420
 421 =head2 clearer -> MethodName | Undef
 422
 423 =head2 has_clearer -> Bool
 424
 425 =head2 handles -> { LocalName => RemoteName }
 426
 427 =head2 has_handles -> Bool
 428
 429 =head2 is_weak_ref -> Bool
 430
 431 =head2 init_arg -> Str
 432
 433 =head2 type_constraint -> Str
 434
 435 =head2 has_type_constraint -> Bool
 436
 437 =head2 trigger => CODE | Undef
 438
 439 =head2 has_trigger -> Bool
 440
 441 =head2 builder => MethodName | Undef
 442
 443 =head2 has_builder -> Bool
 444
 445 =head2 is_lazy_build => Bool
 446
 447 =head2 should_auto_deref -> Bool
 448
 449 Informational methods.
 450
 451 =head2 generate_accessor -> CODE
 452
 453 Creates a new code reference for the attribute's accessor.
 454
 455 =head2 generate_predicate -> CODE
 456
 457 Creates a new code reference for the attribute's predicate.
 458
 459 =head2 generate_clearer -> CODE
 460
 461 Creates a new code reference for the attribute's clearer.
 462
 463 =head2 generate_handles -> { MethodName => CODE }
 464
 465 Creates a new code reference for each of the attribute's handles methods.
 466
 467 =head2 find_type_constraint -> CODE
 468
 469 Returns a code reference which can be used to check that a given value passes
 470 this attribute's type constraint;
 471
 472 =head2 verify_against_type_constraint Item -> 1 | ERROR
 473
 474 Checks that the given value passes this attribute's type constraint. Returns 1
 475 on success, otherwise C<confess>es.
 476
 477 =head2 canonicalize_args Name, %args -> %args
 478
 479 Canonicalizes some arguments to create. In particular, C<lazy_build> is
 480 canonicalized into C<lazy>, C<builder>, etc.
 481
 482 =head2 validate_args Name, \%args -> 1 | ERROR
 483
 484 Checks that the arguments to create the attribute (ie those specified by
 485 C<has>) are valid.
 486
 487 =head2 clone_parent OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 488
 489 Creates a new attribute in OwnerClass, inheriting options from parent classes.
 490 Accessors and helper methods are installed. Some error checking is done.
 491
 492 =head2 get_parent_args OwnerClass, AttributeName -> Hash
 493
 494 Returns the options that the parent class of C<OwnerClass> used for attribute
 495 C<AttributeName>.
 496
 497 =cut
 498