lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use Mouse::Util qw(:meta); # enables strict and warnings
   3
   4 use Carp ();
   5
   6 use Mouse::Meta::TypeConstraint;
   7
   8 #use Mouse::Meta::Method::Accessor;
   9 use Mouse::Meta::Method::Delegation;
  10
  11
  12 sub _process_options{
  13     my($class, $name, $args) = @_;
  14
  15
  16     # XXX: for backward compatibility (with method modifiers)
  17     if($class->can('canonicalize_args') != \&canonicalize_args){
  18         %{$args} = $class->canonicalize_args($name, %{$args});
  19     }
  20
  21     # taken from Class::MOP::Attribute::new
  22
  23     defined($name)
  24         or $class->throw_error('You must provide a name for the attribute');
  25
  26     if(!exists $args->{init_arg}){
  27         $args->{init_arg} = $name;
  28     }
  29
  30     # 'required' requires eigher 'init_arg', 'builder', or 'default'
  31     my $can_be_required = defined( $args->{init_arg} );
  32
  33     if(exists $args->{builder}){
  34         # XXX:
  35         # Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
  36         # This feature will be changed in a future. (gfx)
  37         $class->throw_error('builder must be a defined scalar value which is a method name')
  38             #if ref $args->{builder} || !defined $args->{builder};
  39             if !defined $args->{builder};
  40
  41         $can_be_required++;
  42     }
  43     elsif(exists $args->{default}){
  44         if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
  45             $class->throw_error("References are not allowed as default values, you must "
  46                               . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
  47         }
  48         $can_be_required++;
  49     }
  50
  51     if( $args->{required} && !$can_be_required ) {
  52         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
  53     }
  54
  55     # taken from Mouse::Meta::Attribute->new and _process_args->
  56
  57     if(exists $args->{is}){
  58         my $is = $args->{is};
  59
  60         if($is eq 'ro'){
  61             $args->{reader} ||= $name;
  62         }
  63         elsif($is eq 'rw'){
  64             if(exists $args->{writer}){
  65                 $args->{reader} ||= $name;
  66              }
  67              else{
  68                 $args->{accessor} ||= $name;
  69              }
  70         }
  71         elsif($is eq 'bare'){
  72             # do nothing, but don't complain (later) about missing methods
  73         }
  74         else{
  75             $is = 'undef' if !defined $is;
  76             $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
  77         }
  78     }
  79
  80     my $tc;
  81     if(exists $args->{isa}){
  82         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
  83     }
  84     elsif(exists $args->{does}){
  85         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
  86     }
  87     $tc = $args->{type_constraint};
  88
  89     if($args->{coerce}){
  90         defined($tc)
  91             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
  92
  93         $args->{weak_ref}
  94             && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
  95     }
  96
  97     if ($args->{lazy_build}) {
  98         exists($args->{default})
  99             && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
 100
 101         $args->{lazy}      = 1;
 102         $args->{builder} ||= "_build_${name}";
 103         if ($name =~ /^_/) {
 104             $args->{clearer}   ||= "_clear${name}";
 105             $args->{predicate} ||= "_has${name}";
 106         }
 107         else {
 108             $args->{clearer}   ||= "clear_${name}";
 109             $args->{predicate} ||= "has_${name}";
 110         }
 111     }
 112
 113     if ($args->{auto_deref}) {
 114         defined($tc)
 115             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
 116
 117         ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
 118             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
 119     }
 120
 121     if (exists $args->{trigger}) {
 122         ('CODE' eq ref $args->{trigger})
 123             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
 124     }
 125
 126     if ($args->{lazy}) {
 127         (exists $args->{default} || defined $args->{builder})
 128             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
 129     }
 130
 131     return;
 132 }
 133
 134 sub new {
 135     my $class = shift;
 136     my $name  = shift;
 137
 138     my %args  = (@_ == 1) ? %{ $_[0] } : @_;
 139
 140     $class->_process_options($name, \%args);
 141
 142     $args{name} = $name;
 143
 144     my $self = bless \%args, $class;
 145
 146     # extra attributes
 147     if($class ne __PACKAGE__){
 148         $class->meta->_initialize_object($self, \%args);
 149     }
 150
 151 # XXX: there is no fast way to check attribute validity
 152 #    my @bad = ...;
 153 #    if(@bad){
 154 #        @bad = sort @bad;
 155 #        Carp::cluck("Found unknown argument(s) passed to '$name' attribute constructor in '$class': @bad");
 156 #    }
 157
 158     return $self;
 159 }
 160
 161 sub has_read_method      { $_[0]->has_reader || $_[0]->has_accessor }
 162 sub has_write_method     { $_[0]->has_writer || $_[0]->has_accessor }
 163
 164 sub _create_args { # DEPRECATED
 165     $_[0]->{_create_args} = $_[1] if @_ > 1;
 166     $_[0]->{_create_args}
 167 }
 168
 169 sub interpolate_class{
 170     my($class, $args) = @_;
 171
 172     if(my $metaclass = delete $args->{metaclass}){
 173         $class = Mouse::Util::resolve_metaclass_alias( Attribute => $metaclass );
 174     }
 175
 176     my @traits;
 177     if(my $traits_ref = delete $args->{traits}){
 178
 179         for (my $i = 0; $i < @{$traits_ref}; $i++) {
 180             my $trait = Mouse::Util::resolve_metaclass_alias(Attribute => $traits_ref->[$i], trait => 1);
 181
 182             next if $class->does($trait);
 183
 184             push @traits, $trait;
 185
 186             # are there options?
 187             push @traits, $traits_ref->[++$i]
 188                 if ref($traits_ref->[$i+1]);
 189         }
 190
 191         if (@traits) {
 192             $class = Mouse::Meta::Class->create_anon_class(
 193                 superclasses => [ $class ],
 194                 roles        => \@traits,
 195                 cache        => 1,
 196             )->name;
 197         }
 198     }
 199
 200     return( $class, @traits );
 201 }
 202
 203 sub canonicalize_args{ # DEPRECATED
 204     my ($self, $name, %args) = @_;
 205
 206     Carp::cluck("$self->canonicalize_args has been deprecated."
 207         . "Use \$self->_process_options instead.")
 208             if _MOUSE_VERBOSE;
 209
 210     return %args;
 211 }
 212
 213 sub create { # DEPRECATED
 214     my ($self, $class, $name, %args) = @_;
 215
 216     Carp::cluck("$self->create has been deprecated."
 217         . "Use \$meta->add_attribute and \$attr->install_accessors instead.")
 218             if _MOUSE_VERBOSE;
 219
 220     # noop
 221     return $self;
 222 }
 223
 224 sub _coerce_and_verify {
 225     my($self, $value, $instance) = @_;
 226
 227     my $type_constraint = $self->{type_constraint};
 228     return $value if !defined $type_constraint;
 229
 230     if ($self->should_coerce && $type_constraint->has_coercion) {
 231         $value = $type_constraint->coerce($value);
 232     }
 233
 234     $self->verify_against_type_constraint($value);
 235
 236     return $value;
 237 }
 238
 239 sub verify_against_type_constraint {
 240     my ($self, $value) = @_;
 241
 242     my $type_constraint = $self->{type_constraint};
 243     return 1 if !$type_constraint;
 244     return 1 if $type_constraint->check($value);
 245
 246     $self->verify_type_constraint_error($self->name, $value, $type_constraint);
 247 }
 248
 249 sub verify_type_constraint_error {
 250     my($self, $name, $value, $type) = @_;
 251     $self->throw_error("Attribute ($name) does not pass the type constraint because: "
 252         . $type->get_message($value));
 253 }
 254
 255 sub coerce_constraint { # DEPRECATED
 256     my $type = $_[0]->{type_constraint}
 257         or return $_[1];
 258
 259     Carp::cluck("coerce_constraint() has been deprecated, which was an internal utility anyway");
 260
 261     return Mouse::Util::TypeConstraints->typecast_constraints($_[0]->associated_class->name, $type, $_[1]);
 262 }
 263
 264 sub clone_and_inherit_options{
 265     my($self, %args) = @_;
 266
 267     my($attribute_class, @traits) = ref($self)->interpolate_class(\%args);
 268
 269     $args{traits} = \@traits if @traits;
 270     return $attribute_class->new($self->name, %{$self}, %args);
 271 }
 272
 273 sub clone_parent { # DEPRECATED
 274     my $self  = shift;
 275     my $class = shift;
 276     my $name  = shift;
 277     my %args  = ($self->get_parent_args($class, $name), @_);
 278
 279     Carp::cluck("$self->clone_parent has been deprecated."
 280         . "Use \$meta->add_attribute and \$attr->install_accessors instead.")
 281         if _MOUSE_VERBOSE;
 282
 283     $self->clone_and_inherited_args($class, $name, %args);
 284 }
 285
 286 sub get_parent_args { # DEPRECATED
 287     my $self  = shift;
 288     my $class = shift;
 289     my $name  = shift;
 290
 291     for my $super ($class->linearized_isa) {
 292         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 293             or next;
 294         return %{ $super_attr->_create_args };
 295     }
 296
 297     $self->throw_error("Could not find an attribute by the name of '$name' to inherit from");
 298 }
 299
 300
 301 sub get_read_method {
 302     $_[0]->reader || $_[0]->accessor
 303 }
 304 sub get_write_method {
 305     $_[0]->writer || $_[0]->accessor
 306 }
 307
 308 sub get_read_method_ref{
 309     my($self) = @_;
 310
 311     $self->{_read_method_ref} ||= do{
 312         my $metaclass = $self->associated_class
 313             or $self->throw_error('No asocciated class for ' . $self->name);
 314
 315         my $reader = $self->{reader} || $self->{accessor};
 316         if($reader){
 317             $metaclass->name->can($reader);
 318         }
 319         else{
 320             $self->accessor_metaclass->_generate_reader($self, $metaclass);
 321         }
 322     };
 323 }
 324
 325 sub get_write_method_ref{
 326     my($self) = @_;
 327
 328     $self->{_write_method_ref} ||= do{
 329         my $metaclass = $self->associated_class
 330             or $self->throw_error('No asocciated class for ' . $self->name);
 331
 332         my $reader = $self->{writer} || $self->{accessor};
 333         if($reader){
 334             $metaclass->name->can($reader);
 335         }
 336         else{
 337             $self->accessor_metaclass->_generate_writer($self, $metaclass);
 338         }
 339     };
 340 }
 341
 342 sub _canonicalize_handles {
 343     my($self, $handles) = @_;
 344
 345     if (ref($handles) eq 'HASH') {
 346         return %$handles;
 347     }
 348     elsif (ref($handles) eq 'ARRAY') {
 349         return map { $_ => $_ } @$handles;
 350     }
 351     elsif (ref($handles) eq 'Regexp') {
 352         my $class_or_role = ($self->{isa} || $self->{does})
 353             || $self->throw_error("Cannot delegate methods based on a Regexp without a type constraint (isa)");
 354
 355         my $meta = Mouse::Meta::Class->initialize("$class_or_role"); # "" for stringify
 356         return map  { $_ => $_ }
 357                grep { $_ ne 'meta' && !Mouse::Object->can($_) && $_ =~ $handles }
 358                    Mouse::Util::TypeConstraints::_is_a_metarole($meta)
 359                         ? $meta->get_method_list
 360                         : $meta->get_all_method_names;
 361     }
 362     else {
 363         $self->throw_error("Unable to canonicalize the 'handles' option with $handles");
 364     }
 365 }
 366
 367 sub associate_method{
 368     my ($attribute, $method) = @_;
 369     $attribute->{associated_methods}++;
 370     return;
 371 }
 372
 373
 374 sub delegation_metaclass() { 'Mouse::Meta::Method::Delegation' }
 375
 376 sub install_accessors{
 377     my($attribute) = @_;
 378
 379     my $metaclass      = $attribute->associated_class;
 380     my $accessor_class = $attribute->accessor_metaclass;
 381
 382     foreach my $type(qw(accessor reader writer predicate clearer)){
 383         if(exists $attribute->{$type}){
 384             my $generator = '_generate_' . $type;
 385             my $code      = $accessor_class->$generator($attribute, $metaclass);
 386             $metaclass->add_method($attribute->{$type} => $code);
 387             $attribute->associate_method($code);
 388         }
 389     }
 390
 391     # install delegation
 392     if(exists $attribute->{handles}){
 393         my $delegation_class = $attribute->delegation_metaclass;
 394         my %handles = $attribute->_canonicalize_handles($attribute->{handles});
 395         my $reader  = $attribute->get_read_method_ref;
 396
 397         while(my($handle_name, $method_to_call) = each %handles){
 398             my $code = $delegation_class->_generate_delegation($attribute, $metaclass,
 399                 $reader, $handle_name, $method_to_call);
 400
 401             $metaclass->add_method($handle_name => $code);
 402             $attribute->associate_method($code);
 403         }
 404     }
 405
 406
 407     if($attribute->can('create') != \&create){
 408         # backword compatibility
 409         $attribute->create($metaclass, $attribute->name, %{$attribute});
 410     }
 411
 412     return;
 413 }
 414
 415 sub throw_error{
 416     my $self = shift;
 417
 418     my $metaclass = (ref $self && $self->associated_class) || 'Mouse::Meta::Class';
 419     $metaclass->throw_error(@_, depth => 1);
 420 }
 421
 422 1;
 423
 424 __END__
 425
 426 =head1 NAME
 427
 428 Mouse::Meta::Attribute - The Mouse attribute metaclass
 429
 430 =head1 VERSION
 431
 432 This document describes Mouse version 0.40_01
 433
 434 =head1 METHODS
 435
 436 =head2 C<< new(%options) -> Mouse::Meta::Attribute >>
 437
 438 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 439
 440 It adds the following options to the constructor:
 441
 442 =over 4
 443
 444 =item C<< is => 'ro', 'rw', 'bare' >>
 445
 446 This provides a shorthand for specifying the C<reader>, C<writer>, or
 447 C<accessor> names. If the attribute is read-only ('ro') then it will
 448 have a C<reader> method with the same attribute as the name.
 449
 450 If it is read-write ('rw') then it will have an C<accessor> method
 451 with the same name. If you provide an explicit C<writer> for a
 452 read-write attribute, then you will have a C<reader> with the same
 453 name as the attribute, and a C<writer> with the name you provided.
 454
 455 Use 'bare' when you are deliberately not installing any methods
 456 (accessor, reader, etc.) associated with this attribute; otherwise,
 457 Moose will issue a deprecation warning when this attribute is added to a
 458 metaclass.
 459
 460 =item C<< isa => Type >>
 461
 462 This option accepts a type. The type can be a string, which should be
 463 a type name. If the type name is unknown, it is assumed to be a class
 464 name.
 465
 466 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 467
 468 If you I<also> provide a C<does> option, then your C<isa> option must
 469 be a class name, and that class must do the role specified with
 470 C<does>.
 471
 472 =item C<< does => Role >>
 473
 474 This is short-hand for saying that the attribute's type must be an
 475 object which does the named role.
 476
 477 B<This option is not yet supported.>
 478
 479 =item C<< coerce => Bool >>
 480
 481 This option is only valid for objects with a type constraint
 482 (C<isa>). If this is true, then coercions will be applied whenever
 483 this attribute is set.
 484
 485 You can make both this and the C<weak_ref> option true.
 486
 487 =item C<< trigger => CodeRef >>
 488
 489 This option accepts a subroutine reference, which will be called after
 490 the attribute is set.
 491
 492 =item C<< required => Bool >>
 493
 494 An attribute which is required must be provided to the constructor. An
 495 attribute which is required can also have a C<default> or C<builder>,
 496 which will satisfy its required-ness.
 497
 498 A required attribute must have a C<default>, C<builder> or a
 499 non-C<undef> C<init_arg>
 500
 501 =item C<< lazy => Bool >>
 502
 503 A lazy attribute must have a C<default> or C<builder>. When an
 504 attribute is lazy, the default value will not be calculated until the
 505 attribute is read.
 506
 507 =item C<< weak_ref => Bool >>
 508
 509 If this is true, the attribute's value will be stored as a weak
 510 reference.
 511
 512 =item C<< auto_deref => Bool >>
 513
 514 If this is true, then the reader will dereference the value when it is
 515 called. The attribute must have a type constraint which defines the
 516 attribute as an array or hash reference.
 517
 518 =item C<< lazy_build => Bool >>
 519
 520 Setting this to true makes the attribute lazy and provides a number of
 521 default methods.
 522
 523   has 'size' => (
 524       is         => 'ro',
 525       lazy_build => 1,
 526   );
 527
 528 is equivalent to this:
 529
 530   has 'size' => (
 531       is        => 'ro',
 532       lazy      => 1,
 533       builder   => '_build_size',
 534       clearer   => 'clear_size',
 535       predicate => 'has_size',
 536   );
 537
 538 =back
 539
 540 =head2 C<< associate_method(Method) >>
 541
 542 Associates a method with the attribute. Typically, this is called internally
 543 when an attribute generates its accessors.
 544
 545 Currently the argument I<Method> is ignored in Mouse.
 546
 547 =head2 C<< verify_against_type_constraint(Item) -> TRUE | ERROR >>
 548
 549 Checks that the given value passes this attribute's type constraint. Returns C<true>
 550 on success, otherwise C<confess>es.
 551
 552 =head2 C<< clone_and_inherit_options(options) -> Mouse::Meta::Attribute >>
 553
 554 Creates a new attribute in the owner class, inheriting options from parent classes.
 555 Accessors and helper methods are installed. Some error checking is done.
 556
 557 =head2 C<< get_read_method_ref >>
 558
 559 =head2 C<< get_write_method_ref >>
 560
 561 Returns the subroutine reference of a method suitable for reading or
 562 writing the attribute's value in the associated class. These methods
 563 always return a subroutine reference, regardless of whether or not the
 564 attribute is read- or write-only.
 565
 566 =head1 SEE ALSO
 567
 568 L<Moose::Meta::Attribute>
 569
 570 L<Class::MOP::Attribute>
 571
 572 =cut
 573