lib/Mouse/Meta/Attribute.pm

   1 #!/usr/bin/env perl
   2 package Mouse::Meta::Attribute;
   3 use strict;
   4 use warnings;
   5
   6 use Carp 'confess';
   7 use Mouse::Util qw/blessed weaken/;
   8
   9 sub new {
  10     my $class = shift;
  11     my %args  = @_;
  12
  13     my $name = $args{name};
  14
  15     $args{init_arg} = $name
  16         unless exists $args{init_arg};
  17
  18     $args{is} ||= '';
  19
  20     bless \%args, $class;
  21 }
  22
  23 sub name              { $_[0]->{name}             }
  24 sub associated_class  { $_[0]->{associated_class} }
  25 sub _is_metadata      { $_[0]->{is}               }
  26 sub is_required       { $_[0]->{required}         }
  27 sub default           { $_[0]->{default}          }
  28 sub is_lazy           { $_[0]->{lazy}             }
  29 sub is_lazy_build     { $_[0]->{lazy_build}       }
  30 sub predicate         { $_[0]->{predicate}        }
  31 sub clearer           { $_[0]->{clearer}          }
  32 sub handles           { $_[0]->{handles}          }
  33 sub is_weak_ref       { $_[0]->{weak_ref}         }
  34 sub init_arg          { $_[0]->{init_arg}         }
  35 sub type_constraint   { $_[0]->{type_constraint}  }
  36 sub trigger           { $_[0]->{trigger}          }
  37 sub builder           { $_[0]->{builder}          }
  38 sub should_auto_deref { $_[0]->{auto_deref}       }
  39
  40 sub has_default         { exists $_[0]->{default}         }
  41 sub has_predicate       { exists $_[0]->{predicate}       }
  42 sub has_clearer         { exists $_[0]->{clearer}         }
  43 sub has_handles         { exists $_[0]->{handles}         }
  44 sub has_type_constraint { exists $_[0]->{type_constraint} }
  45 sub has_trigger         { exists $_[0]->{trigger}         }
  46 sub has_builder         { exists $_[0]->{builder}         }
  47
  48 sub _create_args {
  49     $_[0]->{_create_args} = $_[1] if @_ > 1;
  50     $_[0]->{_create_args}
  51 }
  52
  53 sub inlined_name {
  54     my $self = shift;
  55     my $name = $self->name;
  56     my $key   = "'" . $name . "'";
  57     return $key;
  58 }
  59
  60 sub generate_accessor {
  61     my $attribute = shift;
  62
  63     my $name         = $attribute->name;
  64     my $default      = $attribute->default;
  65     my $type         = $attribute->type_constraint;
  66     my $constraint   = $attribute->find_type_constraint;
  67     my $builder      = $attribute->builder;
  68     my $trigger      = $attribute->trigger;
  69     my $is_weak      = $attribute->is_weak_ref;
  70     my $should_deref = $attribute->should_auto_deref;
  71
  72     my $self  = '$_[0]';
  73     my $key   = $attribute->inlined_name;
  74
  75     my $accessor = "sub {\n";
  76     if ($attribute->_is_metadata eq 'rw') {
  77         $accessor .= 'if (scalar(@_) >= 2) {' . "\n";
  78
  79         my $value = '$_[1]';
  80
  81         if ($constraint) {
  82             $accessor .= 'local $_ = '.$value.';
  83                 unless ($constraint->()) {
  84                     my $display = defined($_) ? overload::StrVal($_) : "undef";
  85                     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
  86             }' . "\n"
  87         }
  88
  89         # if there's nothing left to do for the attribute we can return during
  90         # this setter
  91         $accessor .= 'return ' if !$is_weak && !$trigger && !$should_deref;
  92
  93         $accessor .= $self.'->{'.$key.'} = '.$value.';' . "\n";
  94
  95         if ($is_weak) {
  96             $accessor .= 'weaken('.$self.'->{'.$key.'}) if ref('.$self.'->{'.$key.'});' . "\n";
  97         }
  98
  99         if ($trigger) {
 100             $accessor .= '$trigger->('.$self.', '.$value.', $attribute);' . "\n";
 101         }
 102
 103         $accessor .= "}\n";
 104     }
 105     else {
 106         $accessor .= 'confess "Cannot assign a value to a read-only accessor" if scalar(@_) >= 2;' . "\n";
 107     }
 108
 109     if ($attribute->is_lazy) {
 110         $accessor .= $self.'->{'.$key.'} = ';
 111
 112         $accessor .= $attribute->has_builder
 113                 ? $self.'->$builder'
 114                     : ref($default) eq 'CODE'
 115                     ? '$default->('.$self.')'
 116                     : '$default';
 117         $accessor .= ' if !exists '.$self.'->{'.$key.'};' . "\n";
 118     }
 119
 120     if ($should_deref) {
 121         if ($attribute->type_constraint eq 'ArrayRef') {
 122             $accessor .= 'if (wantarray) {
 123                 return @{ '.$self.'->{'.$key.'} || [] };
 124             }';
 125         }
 126         else {
 127             $accessor .= 'if (wantarray) {
 128                 return %{ '.$self.'->{'.$key.'} || {} };
 129             }';
 130         }
 131     }
 132
 133     $accessor .= 'return '.$self.'->{'.$key.'};
 134     }';
 135
 136     my $sub = eval $accessor;
 137     confess $@ if $@;
 138     return $sub;
 139 }
 140
 141 sub generate_predicate {
 142     my $attribute = shift;
 143     my $key = $attribute->inlined_name;
 144
 145     my $predicate = 'sub { exists($_[0]->{'.$key.'}) }';
 146
 147     my $sub = eval $predicate;
 148     confess $@ if $@;
 149     return $sub;
 150 }
 151
 152 sub generate_clearer {
 153     my $attribute = shift;
 154     my $key = $attribute->inlined_name;
 155
 156     my $clearer = 'sub { delete($_[0]->{'.$key.'}) }';
 157
 158     my $sub = eval $clearer;
 159     confess $@ if $@;
 160     return $sub;
 161 }
 162
 163 sub generate_handles {
 164     my $attribute = shift;
 165     my $reader = $attribute->name;
 166     my %handles = $attribute->_canonicalize_handles($attribute->handles);
 167
 168     my %method_map;
 169
 170     for my $local_method (keys %handles) {
 171         my $remote_method = $handles{$local_method};
 172
 173         my $method = 'sub {
 174             my $self = shift;
 175             $self->$reader->$remote_method(@_)
 176         }';
 177
 178         $method_map{$local_method} = eval $method;
 179         confess $@ if $@;
 180     }
 181
 182     return \%method_map;
 183 }
 184
 185 sub create {
 186     my ($self, $class, $name, %args) = @_;
 187
 188     $args{name} = $name;
 189     $args{associated_class} = $class;
 190
 191     %args = $self->canonicalize_args($name, %args);
 192     $self->validate_args($name, \%args);
 193
 194     $args{type_constraint} = delete $args{isa}
 195         if exists $args{isa};
 196
 197     my $attribute = $self->new(%args);
 198
 199     $attribute->_create_args(\%args);
 200
 201     $class->add_attribute($attribute);
 202
 203     # install an accessor
 204     if ($attribute->_is_metadata eq 'rw' || $attribute->_is_metadata eq 'ro') {
 205         my $accessor = $attribute->generate_accessor;
 206         $class->add_method($name => $accessor);
 207     }
 208
 209     for my $method (qw/predicate clearer/) {
 210         my $predicate = "has_$method";
 211         if ($attribute->$predicate) {
 212             my $generator = "generate_$method";
 213             my $coderef = $attribute->$generator;
 214             $class->add_method($attribute->$method => $coderef);
 215         }
 216     }
 217
 218     if ($attribute->has_handles) {
 219         my $method_map = $attribute->generate_handles;
 220         for my $method_name (keys %$method_map) {
 221             $class->add_method($method_name => $method_map->{$method_name});
 222         }
 223     }
 224
 225     return $attribute;
 226 }
 227
 228 sub canonicalize_args {
 229     my $self = shift;
 230     my $name = shift;
 231     my %args = @_;
 232
 233     if ($args{lazy_build}) {
 234         $args{lazy}      = 1;
 235         $args{required}  = 1;
 236         $args{builder}   = "_build_${name}"
 237             if !exists($args{builder});
 238         if ($name =~ /^_/) {
 239             $args{clearer}   = "_clear${name}" if !exists($args{clearer});
 240             $args{predicate} = "_has${name}" if !exists($args{predicate});
 241         }
 242         else {
 243             $args{clearer}   = "clear_${name}" if !exists($args{clearer});
 244             $args{predicate} = "has_${name}" if !exists($args{predicate});
 245         }
 246     }
 247
 248     return %args;
 249 }
 250
 251 sub validate_args {
 252     my $self = shift;
 253     my $name = shift;
 254     my $args = shift;
 255
 256     confess "You can not use lazy_build and default for the same attribute ($name)"
 257         if $args->{lazy_build} && exists $args->{default};
 258
 259     confess "You cannot have lazy attribute ($name) without specifying a default value for it"
 260         if $args->{lazy}
 261         && !exists($args->{default})
 262         && !exists($args->{builder});
 263
 264     confess "References are not allowed as default values, you must wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])"
 265         if ref($args->{default})
 266         && ref($args->{default}) ne 'CODE';
 267
 268     confess "You cannot auto-dereference without specifying a type constraint on attribute ($name)"
 269         if $args->{auto_deref} && !exists($args->{isa});
 270
 271     confess "You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)"
 272         if $args->{auto_deref}
 273         && $args->{isa} ne 'ArrayRef'
 274         && $args->{isa} ne 'HashRef';
 275
 276     if ($args->{trigger}) {
 277         if (ref($args->{trigger}) eq 'HASH') {
 278             Carp::carp "HASH-based form of trigger has been removed. Only the coderef form of triggers are now supported.";
 279         }
 280
 281         confess "Trigger must be a CODE ref on attribute ($name)"
 282             if ref($args->{trigger}) ne 'CODE';
 283     }
 284
 285     return 1;
 286 }
 287
 288 sub find_type_constraint {
 289     my $self = shift;
 290     my $type = $self->type_constraint;
 291
 292     return unless $type;
 293
 294     my $checker = Mouse::TypeRegistry->optimized_constraints->{$type};
 295     return $checker if $checker;
 296
 297     return sub { blessed($_) && blessed($_) eq $type };
 298 }
 299
 300 sub verify_type_constraint {
 301     my $self = shift;
 302     local $_ = shift;
 303
 304     my $type = $self->type_constraint
 305         or return 1;
 306     my $constraint = $self->find_type_constraint;
 307
 308     return 1 if $constraint->($_);
 309
 310     my $name = $self->name;
 311     my $display = defined($_) ? overload::StrVal($_) : 'undef';
 312     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
 313 }
 314
 315 sub _canonicalize_handles {
 316     my $self    = shift;
 317     my $handles = shift;
 318
 319     if (ref($handles) eq 'HASH') {
 320         return %$handles;
 321     }
 322     elsif (ref($handles) eq 'ARRAY') {
 323         return map { $_ => $_ } @$handles;
 324     }
 325     else {
 326         confess "Unable to canonicalize the 'handles' option with $handles";
 327     }
 328 }
 329
 330 sub clone_parent {
 331     my $self  = shift;
 332     my $class = shift;
 333     my $name  = shift;
 334     my %args  = ($self->get_parent_args($class, $name), @_);
 335
 336     $self->create($class, $name, %args);
 337 }
 338
 339 sub get_parent_args {
 340     my $self  = shift;
 341     my $class = shift;
 342     my $name  = shift;
 343
 344     for my $super ($class->linearized_isa) {
 345         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 346             or next;
 347         return %{ $super_attr->_create_args };
 348     }
 349
 350     confess "Could not find an attribute by the name of '$name' to inherit from";
 351 }
 352
 353 1;
 354
 355 __END__
 356
 357 =head1 NAME
 358
 359 Mouse::Meta::Attribute - attribute metaclass
 360
 361 =head1 METHODS
 362
 363 =head2 new %args -> Mouse::Meta::Attribute
 364
 365 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 366
 367 =head2 create OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 368
 369 Creates a new attribute in OwnerClass. Accessors and helper methods are
 370 installed. Some error checking is done.
 371
 372 =head2 name -> AttributeName
 373
 374 =head2 associated_class -> OwnerClass
 375
 376 =head2 is_required -> Bool
 377
 378 =head2 default -> Item
 379
 380 =head2 has_default -> Bool
 381
 382 =head2 is_lazy -> Bool
 383
 384 =head2 predicate -> MethodName | Undef
 385
 386 =head2 has_predicate -> Bool
 387
 388 =head2 clearer -> MethodName | Undef
 389
 390 =head2 has_clearer -> Bool
 391
 392 =head2 handles -> { LocalName => RemoteName }
 393
 394 =head2 has_handles -> Bool
 395
 396 =head2 is_weak_ref -> Bool
 397
 398 =head2 init_arg -> Str
 399
 400 =head2 type_constraint -> Str
 401
 402 =head2 has_type_constraint -> Bool
 403
 404 =head2 trigger => CODE | Undef
 405
 406 =head2 has_trigger -> Bool
 407
 408 =head2 builder => MethodName | Undef
 409
 410 =head2 has_builder -> Bool
 411
 412 =head2 is_lazy_build => Bool
 413
 414 =head2 should_auto_deref -> Bool
 415
 416 Informational methods.
 417
 418 =head2 generate_accessor -> CODE
 419
 420 Creates a new code reference for the attribute's accessor.
 421
 422 =head2 generate_predicate -> CODE
 423
 424 Creates a new code reference for the attribute's predicate.
 425
 426 =head2 generate_clearer -> CODE
 427
 428 Creates a new code reference for the attribute's clearer.
 429
 430 =head2 generate_handles -> { MethodName => CODE }
 431
 432 Creates a new code reference for each of the attribute's handles methods.
 433
 434 =head2 find_type_constraint -> CODE
 435
 436 Returns a code reference which can be used to check that a given value passes
 437 this attribute's type constraint;
 438
 439 =head2 verify_type_constraint Item -> 1 | ERROR
 440
 441 Checks that the given value passes this attribute's type constraint. Returns 1
 442 on success, otherwise C<confess>es.
 443
 444 =head2 canonicalize_args Name, %args -> %args
 445
 446 Canonicalizes some arguments to create. In particular, C<lazy_build> is
 447 canonicalized into C<lazy>, C<builder>, etc.
 448
 449 =head2 validate_args Name, \%args -> 1 | ERROR
 450
 451 Checks that the arguments to create the attribute (ie those specified by
 452 C<has>) are valid.
 453
 454 =head2 clone_parent OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 455
 456 Creates a new attribute in OwnerClass, inheriting options from parent classes.
 457 Accessors and helper methods are installed. Some error checking is done.
 458
 459 =head2 get_parent_args OwnerClass, AttributeName -> Hash
 460
 461 Returns the options that the parent class of C<OwnerClass> used for attribute
 462 C<AttributeName>.
 463
 464 =cut
 465