lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use Mouse::Util qw(:meta); # enables strict and warnings
   3
   4 use Carp ();
   5
   6 use Mouse::Meta::TypeConstraint;
   7
   8 sub _process_options{
   9     my($class, $name, $args) = @_;
  10
  11     # XXX: for backward compatibility (with method modifiers)
  12     if($class->can('canonicalize_args') != \&canonicalize_args){
  13         %{$args} = $class->canonicalize_args($name, %{$args});
  14     }
  15
  16     # taken from Class::MOP::Attribute::new
  17
  18     defined($name)
  19         or $class->throw_error('You must provide a name for the attribute');
  20
  21     if(!exists $args->{init_arg}){
  22         $args->{init_arg} = $name;
  23     }
  24
  25     # 'required' requires eigher 'init_arg', 'builder', or 'default'
  26     my $can_be_required = defined( $args->{init_arg} );
  27
  28     if(exists $args->{builder}){
  29         # XXX:
  30         # Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
  31         # This feature will be changed in a future. (gfx)
  32         $class->throw_error('builder must be a defined scalar value which is a method name')
  33             #if ref $args->{builder} || !defined $args->{builder};
  34             if !defined $args->{builder};
  35
  36         $can_be_required++;
  37     }
  38     elsif(exists $args->{default}){
  39         if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
  40             $class->throw_error("References are not allowed as default values, you must "
  41                               . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
  42         }
  43         $can_be_required++;
  44     }
  45
  46     if( $args->{required} && !$can_be_required ) {
  47         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
  48     }
  49
  50     # taken from Mouse::Meta::Attribute->new and _process_args->
  51
  52     if(exists $args->{is}){
  53         my $is = $args->{is};
  54
  55         if($is eq 'ro'){
  56             $args->{reader} ||= $name;
  57         }
  58         elsif($is eq 'rw'){
  59             if(exists $args->{writer}){
  60                 $args->{reader} ||= $name;
  61              }
  62              else{
  63                 $args->{accessor} ||= $name;
  64              }
  65         }
  66         elsif($is eq 'bare'){
  67             # do nothing, but don't complain (later) about missing methods
  68         }
  69         else{
  70             $is = 'undef' if !defined $is;
  71             $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
  72         }
  73     }
  74
  75     my $tc;
  76     if(exists $args->{isa}){
  77         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
  78     }
  79     elsif(exists $args->{does}){
  80         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
  81     }
  82     $tc = $args->{type_constraint};
  83
  84     if($args->{coerce}){
  85         defined($tc)
  86             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
  87
  88         $args->{weak_ref}
  89             && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
  90     }
  91
  92     if ($args->{lazy_build}) {
  93         exists($args->{default})
  94             && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
  95
  96         $args->{lazy}      = 1;
  97         $args->{builder} ||= "_build_${name}";
  98         if ($name =~ /^_/) {
  99             $args->{clearer}   ||= "_clear${name}";
 100             $args->{predicate} ||= "_has${name}";
 101         }
 102         else {
 103             $args->{clearer}   ||= "clear_${name}";
 104             $args->{predicate} ||= "has_${name}";
 105         }
 106     }
 107
 108     if ($args->{auto_deref}) {
 109         defined($tc)
 110             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
 111
 112         ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
 113             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
 114     }
 115
 116     if (exists $args->{trigger}) {
 117         ('CODE' eq ref $args->{trigger})
 118             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
 119     }
 120
 121     if ($args->{lazy}) {
 122         (exists $args->{default} || defined $args->{builder})
 123             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
 124     }
 125
 126     return;
 127 }
 128
 129 sub new {
 130     my $class = shift;
 131     my $name  = shift;
 132
 133     my %args  = (@_ == 1) ? %{ $_[0] } : @_;
 134
 135     $class->_process_options($name, \%args);
 136
 137     $args{name} = $name;
 138
 139     my $self = bless \%args, $class;
 140
 141     # extra attributes
 142     if($class ne __PACKAGE__){
 143         $class->meta->_initialize_object($self, \%args);
 144     }
 145
 146 # XXX: there is no fast way to check attribute validity
 147 #    my @bad = ...;
 148 #    if(@bad){
 149 #        @bad = sort @bad;
 150 #        Carp::cluck("Found unknown argument(s) passed to '$name' attribute constructor in '$class': @bad");
 151 #    }
 152
 153     return $self;
 154 }
 155
 156 sub has_read_method      { $_[0]->has_reader || $_[0]->has_accessor }
 157 sub has_write_method     { $_[0]->has_writer || $_[0]->has_accessor }
 158
 159 sub _create_args { # DEPRECATED
 160     $_[0]->{_create_args} = $_[1] if @_ > 1;
 161     $_[0]->{_create_args}
 162 }
 163
 164 sub interpolate_class{
 165     my($class, $args) = @_;
 166
 167     if(my $metaclass = delete $args->{metaclass}){
 168         $class = Mouse::Util::resolve_metaclass_alias( Attribute => $metaclass );
 169     }
 170
 171     my @traits;
 172     if(my $traits_ref = delete $args->{traits}){
 173
 174         for (my $i = 0; $i < @{$traits_ref}; $i++) {
 175             my $trait = Mouse::Util::resolve_metaclass_alias(Attribute => $traits_ref->[$i], trait => 1);
 176
 177             next if $class->does($trait);
 178
 179             push @traits, $trait;
 180
 181             # are there options?
 182             push @traits, $traits_ref->[++$i]
 183                 if ref($traits_ref->[$i+1]);
 184         }
 185
 186         if (@traits) {
 187             $class = Mouse::Meta::Class->create_anon_class(
 188                 superclasses => [ $class ],
 189                 roles        => \@traits,
 190                 cache        => 1,
 191             )->name;
 192         }
 193     }
 194
 195     return( $class, @traits );
 196 }
 197
 198 sub canonicalize_args{ # DEPRECATED
 199     my ($self, $name, %args) = @_;
 200
 201     Carp::cluck("$self->canonicalize_args has been deprecated."
 202         . "Use \$self->_process_options instead.")
 203             if Mouse::Util::_MOUSE_VERBOSE;
 204
 205     return %args;
 206 }
 207
 208 sub create { # DEPRECATED
 209     my ($self, $class, $name, %args) = @_;
 210
 211     Carp::cluck("$self->create has been deprecated."
 212         . "Use \$meta->add_attribute and \$attr->install_accessors instead.")
 213             if Mouse::Util::_MOUSE_VERBOSE;
 214
 215     # noop
 216     return $self;
 217 }
 218
 219 sub _coerce_and_verify {
 220     my($self, $value, $instance) = @_;
 221
 222     my $type_constraint = $self->{type_constraint};
 223     return $value if !defined $type_constraint;
 224
 225     if ($self->should_coerce && $type_constraint->has_coercion) {
 226         $value = $type_constraint->coerce($value);
 227     }
 228
 229     $self->verify_against_type_constraint($value);
 230
 231     return $value;
 232 }
 233
 234 sub verify_against_type_constraint {
 235     my ($self, $value) = @_;
 236
 237     my $type_constraint = $self->{type_constraint};
 238     return 1 if !$type_constraint;
 239     return 1 if $type_constraint->check($value);
 240
 241     $self->verify_type_constraint_error($self->name, $value, $type_constraint);
 242 }
 243
 244 sub verify_type_constraint_error {
 245     my($self, $name, $value, $type) = @_;
 246     $self->throw_error("Attribute ($name) does not pass the type constraint because: "
 247         . $type->get_message($value));
 248 }
 249
 250 sub coerce_constraint { # DEPRECATED
 251     my $type = $_[0]->{type_constraint}
 252         or return $_[1];
 253
 254     Carp::cluck("coerce_constraint() has been deprecated, which was an internal utility anyway");
 255
 256     return Mouse::Util::TypeConstraints->typecast_constraints($_[0]->associated_class->name, $type, $_[1]);
 257 }
 258
 259 sub clone_and_inherit_options{
 260     my($self, %args) = @_;
 261
 262     my($attribute_class, @traits) = ref($self)->interpolate_class(\%args);
 263
 264     $args{traits} = \@traits if @traits;
 265     # do not inherit the 'handles' attribute
 266     foreach my $name(keys %{$self}){
 267         if(!exists $args{$name} && $name ne 'handles'){
 268             $args{$name} = $self->{$name};
 269         }
 270     }
 271     return $attribute_class->new($self->name, %args);
 272 }
 273
 274 sub clone_parent { # DEPRECATED
 275     my $self  = shift;
 276     my $class = shift;
 277     my $name  = shift;
 278     my %args  = ($self->get_parent_args($class, $name), @_);
 279
 280     Carp::cluck("$self->clone_parent has been deprecated."
 281         . "Use \$meta->add_attribute and \$attr->install_accessors instead.")
 282         if Mouse::Util::_MOUSE_VERBOSE;
 283
 284     $self->clone_and_inherited_args($class, $name, %args);
 285 }
 286
 287 sub get_parent_args { # DEPRECATED
 288     my $self  = shift;
 289     my $class = shift;
 290     my $name  = shift;
 291
 292     for my $super ($class->linearized_isa) {
 293         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 294             or next;
 295         return %{ $super_attr->_create_args };
 296     }
 297
 298     $self->throw_error("Could not find an attribute by the name of '$name' to inherit from");
 299 }
 300
 301
 302 sub get_read_method {
 303     return $_[0]->reader || $_[0]->accessor
 304 }
 305 sub get_write_method {
 306     return $_[0]->writer || $_[0]->accessor
 307 }
 308
 309 sub _get_accessor_method_ref {
 310     my($self, $type, $generator) = @_;
 311
 312     my $metaclass = $self->associated_class
 313         || $self->throw_error('No asocciated class for ' . $self->name);
 314
 315     my $accessor = $self->$type();
 316     if($accessor){
 317         return $metaclass->get_method_body($accessor);
 318     }
 319     else{
 320         return $self->accessor_metaclass->$generator($self, $metaclass);
 321     }
 322 }
 323
 324 sub get_read_method_ref{
 325     my($self) = @_;
 326     return $self->{_read_method_ref} ||= $self->_get_accessor_method_ref('get_read_method', '_generate_reader');
 327 }
 328
 329 sub get_write_method_ref{
 330     my($self) = @_;
 331     return $self->{_write_method_ref} ||= $self->_get_accessor_method_ref('get_write_method', '_generate_writer');
 332 }
 333
 334 sub set_value {
 335     my($self, $object, $value) = @_;
 336     return $self->get_write_method_ref()->($object, $value);
 337 }
 338
 339 sub get_value {
 340     my($self, $object) = @_;
 341     return $self->get_read_method_ref()->($object);
 342 }
 343
 344 sub has_value {
 345     my($self, $object) = @_;
 346     my $accessor_ref = $self->{_predicate_ref}
 347         ||= $self->_get_accessor_method_ref('predicate', '_generate_predicate');
 348
 349     return $accessor_ref->($object);
 350 }
 351
 352 sub clear_value {
 353     my($self, $object) = @_;
 354     my $accessor_ref = $self->{_crealer_ref}
 355         ||= $self->_get_accessor_method_ref('clearer', '_generate_clearer');
 356
 357     return $accessor_ref->($object);
 358 }
 359
 360
 361 sub associate_method{
 362     my ($attribute, $method_name) = @_;
 363     $attribute->{associated_methods}++;
 364     return;
 365 }
 366
 367 sub install_accessors{
 368     my($attribute) = @_;
 369
 370     my $metaclass      = $attribute->associated_class;
 371     my $accessor_class = $attribute->accessor_metaclass;
 372
 373     foreach my $type(qw(accessor reader writer predicate clearer)){
 374         if(exists $attribute->{$type}){
 375             my $generator = '_generate_' . $type;
 376             my $code      = $accessor_class->$generator($attribute, $metaclass);
 377             $metaclass->add_method($attribute->{$type} => $code);
 378             $attribute->associate_method($attribute->{$type});
 379         }
 380     }
 381
 382     # install delegation
 383     if(exists $attribute->{handles}){
 384         my %handles = $attribute->_canonicalize_handles($attribute->{handles});
 385
 386         while(my($handle, $method_to_call) = each %handles){
 387             $metaclass->add_method($handle =>
 388                 $attribute->_make_delegation_method(
 389                     $handle, $method_to_call));
 390
 391             $attribute->associate_method($handle);
 392         }
 393     }
 394
 395     if($attribute->can('create') != \&create){
 396         # backword compatibility
 397         $attribute->create($metaclass, $attribute->name, %{$attribute});
 398     }
 399
 400     return;
 401 }
 402
 403 sub delegation_metaclass() { 'Mouse::Meta::Method::Delegation' }
 404
 405 sub _canonicalize_handles {
 406     my($self, $handles) = @_;
 407
 408     if (ref($handles) eq 'HASH') {
 409         return %$handles;
 410     }
 411     elsif (ref($handles) eq 'ARRAY') {
 412         return map { $_ => $_ } @$handles;
 413     }
 414     elsif (ref($handles) eq 'Regexp') {
 415         my $class_or_role = ($self->{isa} || $self->{does})
 416             || $self->throw_error("Cannot delegate methods based on a Regexp without a type constraint (isa)");
 417
 418         my $meta = Mouse::Meta::Class->initialize("$class_or_role"); # "" for stringify
 419         return map  { $_ => $_ }
 420                grep { !Mouse::Object->can($_) && $_ =~ $handles }
 421                    Mouse::Util::is_a_metarole($meta)
 422                         ? $meta->get_method_list
 423                         : $meta->get_all_method_names;
 424     }
 425     else {
 426         $self->throw_error("Unable to canonicalize the 'handles' option with $handles");
 427     }
 428 }
 429
 430 sub _make_delegation_method {
 431     my($self, $handle, $method_to_call) = @_;
 432     my $delegator = $self->delegation_metaclass;
 433     Mouse::Util::load_class($delegator);
 434
 435     return $delegator->_generate_delegation($self, $handle, $method_to_call);
 436 }
 437
 438 sub throw_error{
 439     my $self = shift;
 440
 441     my $metaclass = (ref $self && $self->associated_class) || 'Mouse::Meta::Class';
 442     $metaclass->throw_error(@_, depth => 1);
 443 }
 444
 445 1;
 446 __END__
 447
 448 =head1 NAME
 449
 450 Mouse::Meta::Attribute - The Mouse attribute metaclass
 451
 452 =head1 VERSION
 453
 454 This document describes Mouse version 0.44
 455
 456 =head1 METHODS
 457
 458 =head2 C<< new(%options) -> Mouse::Meta::Attribute >>
 459
 460 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 461
 462 It adds the following options to the constructor:
 463
 464 =over 4
 465
 466 =item C<< is => 'ro', 'rw', 'bare' >>
 467
 468 This provides a shorthand for specifying the C<reader>, C<writer>, or
 469 C<accessor> names. If the attribute is read-only ('ro') then it will
 470 have a C<reader> method with the same attribute as the name.
 471
 472 If it is read-write ('rw') then it will have an C<accessor> method
 473 with the same name. If you provide an explicit C<writer> for a
 474 read-write attribute, then you will have a C<reader> with the same
 475 name as the attribute, and a C<writer> with the name you provided.
 476
 477 Use 'bare' when you are deliberately not installing any methods
 478 (accessor, reader, etc.) associated with this attribute; otherwise,
 479 Moose will issue a deprecation warning when this attribute is added to a
 480 metaclass.
 481
 482 =item C<< isa => Type >>
 483
 484 This option accepts a type. The type can be a string, which should be
 485 a type name. If the type name is unknown, it is assumed to be a class
 486 name.
 487
 488 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 489
 490 If you I<also> provide a C<does> option, then your C<isa> option must
 491 be a class name, and that class must do the role specified with
 492 C<does>.
 493
 494 =item C<< does => Role >>
 495
 496 This is short-hand for saying that the attribute's type must be an
 497 object which does the named role.
 498
 499 B<This option is not yet supported.>
 500
 501 =item C<< coerce => Bool >>
 502
 503 This option is only valid for objects with a type constraint
 504 (C<isa>). If this is true, then coercions will be applied whenever
 505 this attribute is set.
 506
 507 You can make both this and the C<weak_ref> option true.
 508
 509 =item C<< trigger => CodeRef >>
 510
 511 This option accepts a subroutine reference, which will be called after
 512 the attribute is set.
 513
 514 =item C<< required => Bool >>
 515
 516 An attribute which is required must be provided to the constructor. An
 517 attribute which is required can also have a C<default> or C<builder>,
 518 which will satisfy its required-ness.
 519
 520 A required attribute must have a C<default>, C<builder> or a
 521 non-C<undef> C<init_arg>
 522
 523 =item C<< lazy => Bool >>
 524
 525 A lazy attribute must have a C<default> or C<builder>. When an
 526 attribute is lazy, the default value will not be calculated until the
 527 attribute is read.
 528
 529 =item C<< weak_ref => Bool >>
 530
 531 If this is true, the attribute's value will be stored as a weak
 532 reference.
 533
 534 =item C<< auto_deref => Bool >>
 535
 536 If this is true, then the reader will dereference the value when it is
 537 called. The attribute must have a type constraint which defines the
 538 attribute as an array or hash reference.
 539
 540 =item C<< lazy_build => Bool >>
 541
 542 Setting this to true makes the attribute lazy and provides a number of
 543 default methods.
 544
 545   has 'size' => (
 546       is         => 'ro',
 547       lazy_build => 1,
 548   );
 549
 550 is equivalent to this:
 551
 552   has 'size' => (
 553       is        => 'ro',
 554       lazy      => 1,
 555       builder   => '_build_size',
 556       clearer   => 'clear_size',
 557       predicate => 'has_size',
 558   );
 559
 560 =back
 561
 562 =head2 C<< associate_method(MethodName) >>
 563
 564 Associates a method with the attribute. Typically, this is called internally
 565 when an attribute generates its accessors.
 566
 567 Currently the argument I<MethodName> is ignored in Mouse.
 568
 569 =head2 C<< verify_against_type_constraint(Item) -> TRUE | ERROR >>
 570
 571 Checks that the given value passes this attribute's type constraint. Returns C<true>
 572 on success, otherwise C<confess>es.
 573
 574 =head2 C<< clone_and_inherit_options(options) -> Mouse::Meta::Attribute >>
 575
 576 Creates a new attribute in the owner class, inheriting options from parent classes.
 577 Accessors and helper methods are installed. Some error checking is done.
 578
 579 =head2 C<< get_read_method_ref >>
 580
 581 =head2 C<< get_write_method_ref >>
 582
 583 Returns the subroutine reference of a method suitable for reading or
 584 writing the attribute's value in the associated class. These methods
 585 always return a subroutine reference, regardless of whether or not the
 586 attribute is read- or write-only.
 587
 588 =head1 SEE ALSO
 589
 590 L<Moose::Meta::Attribute>
 591
 592 L<Class::MOP::Attribute>
 593
 594 =cut
 595