lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use strict;
   3 use warnings;
   4 require overload;
   5
   6 use Carp 'confess';
   7 use Scalar::Util ();
   8
   9 sub new {
  10     my ($class, $name, %options) = @_;
  11
  12     $options{name} = $name;
  13
  14     $options{init_arg} = $name
  15         unless exists $options{init_arg};
  16
  17     $options{is} ||= '';
  18
  19     bless \%options, $class;
  20 }
  21
  22 sub name                 { $_[0]->{name}                   }
  23 sub associated_class     { $_[0]->{associated_class}       }
  24 sub _is_metadata         { $_[0]->{is}                     }
  25 sub is_required          { $_[0]->{required}               }
  26 sub default              { $_[0]->{default}                }
  27 sub is_lazy              { $_[0]->{lazy}                   }
  28 sub is_lazy_build        { $_[0]->{lazy_build}             }
  29 sub predicate            { $_[0]->{predicate}              }
  30 sub clearer              { $_[0]->{clearer}                }
  31 sub handles              { $_[0]->{handles}                }
  32 sub is_weak_ref          { $_[0]->{weak_ref}               }
  33 sub init_arg             { $_[0]->{init_arg}               }
  34 sub type_constraint      { $_[0]->{type_constraint}        }
  35 sub trigger              { $_[0]->{trigger}                }
  36 sub builder              { $_[0]->{builder}                }
  37 sub should_auto_deref    { $_[0]->{auto_deref}             }
  38 sub should_coerce        { $_[0]->{should_coerce}          }
  39 sub find_type_constraint { $_[0]->{find_type_constraint}   }
  40
  41 sub has_default          { exists $_[0]->{default}         }
  42 sub has_predicate        { exists $_[0]->{predicate}       }
  43 sub has_clearer          { exists $_[0]->{clearer}         }
  44 sub has_handles          { exists $_[0]->{handles}         }
  45 sub has_type_constraint  { exists $_[0]->{type_constraint} }
  46 sub has_trigger          { exists $_[0]->{trigger}         }
  47 sub has_builder          { exists $_[0]->{builder}         }
  48
  49 sub _create_args {
  50     $_[0]->{_create_args} = $_[1] if @_ > 1;
  51     $_[0]->{_create_args}
  52 }
  53
  54 sub inlined_name {
  55     my $self = shift;
  56     my $name = $self->name;
  57     my $key   = "'" . $name . "'";
  58     return $key;
  59 }
  60
  61 sub generate_accessor {
  62     my $attribute = shift;
  63
  64     my $name          = $attribute->name;
  65     my $default       = $attribute->default;
  66     my $constraint    = $attribute->find_type_constraint;
  67     my $builder       = $attribute->builder;
  68     my $trigger       = $attribute->trigger;
  69     my $is_weak       = $attribute->is_weak_ref;
  70     my $should_deref  = $attribute->should_auto_deref;
  71     my $should_coerce = $attribute->should_coerce;
  72
  73     my $self  = '$_[0]';
  74     my $key   = $attribute->inlined_name;
  75
  76     my $accessor = "sub {\n";
  77     if ($attribute->_is_metadata eq 'rw') {
  78         $accessor .= 'if (@_ >= 2) {' . "\n";
  79
  80         my $value = '$_[1]';
  81
  82         if ($constraint) {
  83             $accessor .= 'my $val = ';
  84             if ($should_coerce) {
  85                 $accessor  .= 'Mouse::Util::TypeConstraints->typecast_constraints("'.$attribute->associated_class->name.'", $attribute->{find_type_constraint}, $attribute->{type_constraint}, '.$value.');';
  86             } else {
  87                 $accessor .= $value.';';
  88             }
  89             $accessor .= 'local $_ = $val;';
  90             $accessor .= '
  91                 unless ($constraint->()) {
  92                     $attribute->verify_type_constraint_error($name, $_, $attribute->type_constraint);
  93                 }' . "\n";
  94             $value = '$val';
  95         }
  96
  97         # if there's nothing left to do for the attribute we can return during
  98         # this setter
  99         $accessor .= 'return ' if !$is_weak && !$trigger && !$should_deref;
 100
 101         $accessor .= $self.'->{'.$key.'} = '.$value.';' . "\n";
 102
 103         if ($is_weak) {
 104             $accessor .= 'Scalar::Util::weaken('.$self.'->{'.$key.'}) if ref('.$self.'->{'.$key.'});' . "\n";
 105         }
 106
 107         if ($trigger) {
 108             $accessor .= '$trigger->('.$self.', '.$value.', $attribute);' . "\n";
 109         }
 110
 111         $accessor .= "}\n";
 112     }
 113     else {
 114         $accessor .= 'confess "Cannot assign a value to a read-only accessor" if scalar(@_) >= 2;' . "\n";
 115     }
 116
 117     if ($attribute->is_lazy) {
 118         $accessor .= $self.'->{'.$key.'} = ';
 119
 120         $accessor .= $attribute->has_builder
 121                 ? $self.'->$builder'
 122                     : ref($default) eq 'CODE'
 123                     ? '$default->('.$self.')'
 124                     : '$default';
 125         $accessor .= ' if !exists '.$self.'->{'.$key.'};' . "\n";
 126     }
 127
 128     if ($should_deref) {
 129         my $type_constraint = $attribute->type_constraint;
 130         if (!ref($type_constraint) && $type_constraint eq 'ArrayRef') {
 131             $accessor .= 'if (wantarray) {
 132                 return @{ '.$self.'->{'.$key.'} || [] };
 133             }';
 134         }
 135         else {
 136             $accessor .= 'if (wantarray) {
 137                 return %{ '.$self.'->{'.$key.'} || {} };
 138             }';
 139         }
 140     }
 141
 142     $accessor .= 'return '.$self.'->{'.$key.'};
 143     }';
 144
 145     my $sub = eval $accessor;
 146     confess $@ if $@;
 147     return $sub;
 148 }
 149
 150 sub generate_predicate {
 151     my $attribute = shift;
 152     my $key = $attribute->inlined_name;
 153
 154     my $predicate = 'sub { exists($_[0]->{'.$key.'}) }';
 155
 156     my $sub = eval $predicate;
 157     confess $@ if $@;
 158     return $sub;
 159 }
 160
 161 sub generate_clearer {
 162     my $attribute = shift;
 163     my $key = $attribute->inlined_name;
 164
 165     my $clearer = 'sub { delete($_[0]->{'.$key.'}) }';
 166
 167     my $sub = eval $clearer;
 168     confess $@ if $@;
 169     return $sub;
 170 }
 171
 172 sub generate_handles {
 173     my $attribute = shift;
 174     my $reader = $attribute->name;
 175     my %handles = $attribute->_canonicalize_handles($attribute->handles);
 176
 177     my %method_map;
 178
 179     for my $local_method (keys %handles) {
 180         my $remote_method = $handles{$local_method};
 181
 182         my $method = 'sub {
 183             my $self = shift;
 184             $self->'.$reader.'->'.$remote_method.'(@_)
 185         }';
 186
 187         $method_map{$local_method} = eval $method;
 188         confess $@ if $@;
 189     }
 190
 191     return \%method_map;
 192 }
 193
 194 my $optimized_constraints;
 195 sub _build_type_constraint {
 196     my $spec = shift;
 197     $optimized_constraints ||= Mouse::Util::TypeConstraints->optimized_constraints;
 198     my $code;
 199     if ($spec =~ /^([^\[]+)\[(.+)\]$/) {
 200         # parameterized
 201         my $constraint = $1;
 202         my $param      = $2;
 203         my $parent     = _build_type_constraint($constraint);
 204         my $child      = _build_type_constraint($param);
 205         if ($constraint eq 'ArrayRef') {
 206             my $code_str =
 207                 "sub {\n" .
 208                 "    if (\$parent->(\$_)) {\n" .
 209                 "        foreach my \$e (@\$_) {\n" .
 210                 "            local \$_ = \$e;\n" .
 211                 "            return () unless \$child->(\$_);\n" .
 212                 "        }\n" .
 213                 "        return 1;\n" .
 214                 "    }\n" .
 215                 "    return ();\n" .
 216                 "};\n"
 217             ;
 218             $code = eval $code_str or Carp::confess($@);
 219         } elsif ($constraint eq 'HashRef') {
 220             my $code_str =
 221                 "sub {\n" .
 222                 "    if (\$parent->(\$_)) {\n" .
 223                 "        foreach my \$e (values %\$_) {\n" .
 224                 "            local \$_ = \$e;\n" .
 225                 "            return () unless \$child->(\$_);\n" .
 226                 "        }\n" .
 227                 "        return 1;\n" .
 228                 "    }\n" .
 229                 "    return ();\n" .
 230                 "};\n"
 231             ;
 232             $code = eval $code_str or Carp::confess($@);
 233         } else {
 234             Carp::confess("Support for parameterized types other than ArrayRef or HashRef is not implemented yet");
 235         }
 236         $optimized_constraints->{$spec} = $code;
 237     } else {
 238         $code = $optimized_constraints->{ $spec };
 239         if (! $code) {
 240             $code = sub { Scalar::Util::blessed($_) && $_->isa($spec) };
 241             $optimized_constraints->{$spec} = $code;
 242         }
 243     }
 244     return $code;
 245 }
 246
 247 sub create {
 248     my ($self, $class, $name, %args) = @_;
 249
 250     $args{name} = $name;
 251     $args{associated_class} = $class;
 252
 253     %args = $self->canonicalize_args($name, %args);
 254     $self->validate_args($name, \%args);
 255
 256     $args{should_coerce} = delete $args{coerce}
 257         if exists $args{coerce};
 258
 259     if (exists $args{isa}) {
 260         confess "Got isa => $args{isa}, but Mouse does not yet support parameterized types for containers other than ArrayRef and HashRef (rt.cpan.org #39795)"
 261             if $args{isa} =~ /^([^\[]+)\[.+\]$/ &&
 262                $1 ne 'ArrayRef' &&
 263                $1 ne 'HashRef';
 264
 265         my $type_constraint = delete $args{isa};
 266         $type_constraint =~ s/\s//g;
 267         my @type_constraints = split /\|/, $type_constraint;
 268
 269         my $code;
 270         if (@type_constraints == 1) {
 271             $code = _build_type_constraint($type_constraints[0]);
 272             $args{type_constraint} = $type_constraints[0];
 273         } else {
 274             my @code_list = map {
 275                 _build_type_constraint($_)
 276             } @type_constraints;
 277             $code = sub {
 278                 for my $code (@code_list) {
 279                     return 1 if $code->();
 280                 }
 281                 return 0;
 282             };
 283             $args{type_constraint} = \@type_constraints;
 284         }
 285         $args{find_type_constraint} = $code;
 286     }
 287
 288     my $attribute = $self->new($name, %args);
 289
 290     $attribute->_create_args(\%args);
 291
 292     $class->add_attribute($attribute);
 293
 294     # install an accessor
 295     if ($attribute->_is_metadata eq 'rw' || $attribute->_is_metadata eq 'ro') {
 296         my $accessor = $attribute->generate_accessor;
 297         $class->add_method($name => $accessor);
 298     }
 299
 300     for my $method (qw/predicate clearer/) {
 301         my $predicate = "has_$method";
 302         if ($attribute->$predicate) {
 303             my $generator = "generate_$method";
 304             my $coderef = $attribute->$generator;
 305             $class->add_method($attribute->$method => $coderef);
 306         }
 307     }
 308
 309     if ($attribute->has_handles) {
 310         my $method_map = $attribute->generate_handles;
 311         for my $method_name (keys %$method_map) {
 312             $class->add_method($method_name => $method_map->{$method_name});
 313         }
 314     }
 315
 316     return $attribute;
 317 }
 318
 319 sub canonicalize_args {
 320     my $self = shift;
 321     my $name = shift;
 322     my %args = @_;
 323
 324     if ($args{lazy_build}) {
 325         $args{lazy}      = 1;
 326         $args{required}  = 1;
 327         $args{builder}   = "_build_${name}"
 328             if !exists($args{builder});
 329         if ($name =~ /^_/) {
 330             $args{clearer}   = "_clear${name}" if !exists($args{clearer});
 331             $args{predicate} = "_has${name}" if !exists($args{predicate});
 332         }
 333         else {
 334             $args{clearer}   = "clear_${name}" if !exists($args{clearer});
 335             $args{predicate} = "has_${name}" if !exists($args{predicate});
 336         }
 337     }
 338
 339     return %args;
 340 }
 341
 342 sub validate_args {
 343     my $self = shift;
 344     my $name = shift;
 345     my $args = shift;
 346
 347     confess "You can not use lazy_build and default for the same attribute ($name)"
 348         if $args->{lazy_build} && exists $args->{default};
 349
 350     confess "You cannot have lazy attribute ($name) without specifying a default value for it"
 351         if $args->{lazy}
 352         && !exists($args->{default})
 353         && !exists($args->{builder});
 354
 355     confess "References are not allowed as default values, you must wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])"
 356         if ref($args->{default})
 357         && ref($args->{default}) ne 'CODE';
 358
 359     confess "You cannot auto-dereference without specifying a type constraint on attribute ($name)"
 360         if $args->{auto_deref} && !exists($args->{isa});
 361
 362     confess "You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)"
 363         if $args->{auto_deref}
 364         && $args->{isa} ne 'ArrayRef'
 365         && $args->{isa} ne 'HashRef';
 366
 367     if ($args->{trigger}) {
 368         if (ref($args->{trigger}) eq 'HASH') {
 369             Carp::carp "HASH-based form of trigger has been removed. Only the coderef form of triggers are now supported.";
 370         }
 371
 372         confess "Trigger must be a CODE ref on attribute ($name)"
 373             if ref($args->{trigger}) ne 'CODE';
 374     }
 375
 376     return 1;
 377 }
 378
 379 sub verify_against_type_constraint {
 380     return 1 unless $_[0]->{type_constraint};
 381
 382     local $_ = $_[1];
 383     return 1 if $_[0]->{find_type_constraint}->($_);
 384
 385     my $self = shift;
 386     $self->verify_type_constraint_error($self->name, $_, $self->type_constraint);
 387 }
 388
 389 sub verify_type_constraint_error {
 390     my($self, $name, $value, $type) = @_;
 391     $type = ref($type) eq 'ARRAY' ? join '|', @{ $type } : $type;
 392     my $display = defined($_) ? overload::StrVal($_) : 'undef';
 393     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
 394 }
 395
 396 sub coerce_constraint { ## my($self, $value) = @_;
 397     my $type = $_[0]->{type_constraint}
 398         or return $_[1];
 399     return Mouse::Util::TypeConstraints->typecast_constraints($_[0]->associated_class->name, $_[0]->find_type_constraint, $type, $_[1]);
 400 }
 401
 402 sub _canonicalize_handles {
 403     my $self    = shift;
 404     my $handles = shift;
 405
 406     if (ref($handles) eq 'HASH') {
 407         return %$handles;
 408     }
 409     elsif (ref($handles) eq 'ARRAY') {
 410         return map { $_ => $_ } @$handles;
 411     }
 412     else {
 413         confess "Unable to canonicalize the 'handles' option with $handles";
 414     }
 415 }
 416
 417 sub clone_parent {
 418     my $self  = shift;
 419     my $class = shift;
 420     my $name  = shift;
 421     my %args  = ($self->get_parent_args($class, $name), @_);
 422
 423     $self->create($class, $name, %args);
 424 }
 425
 426 sub get_parent_args {
 427     my $self  = shift;
 428     my $class = shift;
 429     my $name  = shift;
 430
 431     for my $super ($class->linearized_isa) {
 432         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 433             or next;
 434         return %{ $super_attr->_create_args };
 435     }
 436
 437     confess "Could not find an attribute by the name of '$name' to inherit from";
 438 }
 439
 440 1;
 441
 442 __END__
 443
 444 =head1 NAME
 445
 446 Mouse::Meta::Attribute - attribute metaclass
 447
 448 =head1 METHODS
 449
 450 =head2 new %args -> Mouse::Meta::Attribute
 451
 452 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 453
 454 =head2 create OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 455
 456 Creates a new attribute in OwnerClass. Accessors and helper methods are
 457 installed. Some error checking is done.
 458
 459 =head2 name -> AttributeName
 460
 461 =head2 associated_class -> OwnerClass
 462
 463 =head2 is_required -> Bool
 464
 465 =head2 default -> Item
 466
 467 =head2 has_default -> Bool
 468
 469 =head2 is_lazy -> Bool
 470
 471 =head2 predicate -> MethodName | Undef
 472
 473 =head2 has_predicate -> Bool
 474
 475 =head2 clearer -> MethodName | Undef
 476
 477 =head2 has_clearer -> Bool
 478
 479 =head2 handles -> { LocalName => RemoteName }
 480
 481 =head2 has_handles -> Bool
 482
 483 =head2 is_weak_ref -> Bool
 484
 485 =head2 init_arg -> Str
 486
 487 =head2 type_constraint -> Str
 488
 489 =head2 has_type_constraint -> Bool
 490
 491 =head2 trigger => CODE | Undef
 492
 493 =head2 has_trigger -> Bool
 494
 495 =head2 builder => MethodName | Undef
 496
 497 =head2 has_builder -> Bool
 498
 499 =head2 is_lazy_build => Bool
 500
 501 =head2 should_auto_deref -> Bool
 502
 503 Informational methods.
 504
 505 =head2 generate_accessor -> CODE
 506
 507 Creates a new code reference for the attribute's accessor.
 508
 509 =head2 generate_predicate -> CODE
 510
 511 Creates a new code reference for the attribute's predicate.
 512
 513 =head2 generate_clearer -> CODE
 514
 515 Creates a new code reference for the attribute's clearer.
 516
 517 =head2 generate_handles -> { MethodName => CODE }
 518
 519 Creates a new code reference for each of the attribute's handles methods.
 520
 521 =head2 find_type_constraint -> CODE
 522
 523 Returns a code reference which can be used to check that a given value passes
 524 this attribute's type constraint;
 525
 526 =head2 verify_against_type_constraint Item -> 1 | ERROR
 527
 528 Checks that the given value passes this attribute's type constraint. Returns 1
 529 on success, otherwise C<confess>es.
 530
 531 =head2 canonicalize_args Name, %args -> %args
 532
 533 Canonicalizes some arguments to create. In particular, C<lazy_build> is
 534 canonicalized into C<lazy>, C<builder>, etc.
 535
 536 =head2 validate_args Name, \%args -> 1 | ERROR
 537
 538 Checks that the arguments to create the attribute (ie those specified by
 539 C<has>) are valid.
 540
 541 =head2 clone_parent OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 542
 543 Creates a new attribute in OwnerClass, inheriting options from parent classes.
 544 Accessors and helper methods are installed. Some error checking is done.
 545
 546 =head2 get_parent_args OwnerClass, AttributeName -> Hash
 547
 548 Returns the options that the parent class of C<OwnerClass> used for attribute
 549 C<AttributeName>.
 550
 551 =cut
 552