lib/Mouse/Meta/Attribute.pm

   1 #!/usr/bin/env perl
   2 package Mouse::Meta::Attribute;
   3 use strict;
   4 use warnings;
   5 require overload;
   6
   7 use Carp 'confess';
   8 require Mouse::Util;
   9
  10 sub new {
  11     my $class = shift;
  12     my %args  = @_;
  13
  14     my $name = $args{name};
  15
  16     $args{init_arg} = $name
  17         unless exists $args{init_arg};
  18
  19     $args{is} ||= '';
  20
  21     bless \%args, $class;
  22 }
  23
  24 sub name              { $_[0]->{name}             }
  25 sub associated_class  { $_[0]->{associated_class} }
  26 sub _is_metadata      { $_[0]->{is}               }
  27 sub is_required       { $_[0]->{required}         }
  28 sub default           { $_[0]->{default}          }
  29 sub is_lazy           { $_[0]->{lazy}             }
  30 sub is_lazy_build     { $_[0]->{lazy_build}       }
  31 sub predicate         { $_[0]->{predicate}        }
  32 sub clearer           { $_[0]->{clearer}          }
  33 sub handles           { $_[0]->{handles}          }
  34 sub is_weak_ref       { $_[0]->{weak_ref}         }
  35 sub init_arg          { $_[0]->{init_arg}         }
  36 sub type_constraint   { $_[0]->{type_constraint}  }
  37 sub trigger           { $_[0]->{trigger}          }
  38 sub builder           { $_[0]->{builder}          }
  39 sub should_auto_deref { $_[0]->{auto_deref}       }
  40 sub should_coerce     { $_[0]->{should_coerce}    }
  41
  42 sub has_default         { exists $_[0]->{default}         }
  43 sub has_predicate       { exists $_[0]->{predicate}       }
  44 sub has_clearer         { exists $_[0]->{clearer}         }
  45 sub has_handles         { exists $_[0]->{handles}         }
  46 sub has_type_constraint { exists $_[0]->{type_constraint} }
  47 sub has_trigger         { exists $_[0]->{trigger}         }
  48 sub has_builder         { exists $_[0]->{builder}         }
  49
  50 sub find_type_constraint      { $_[0]->{find_type_constraint}  }
  51
  52 sub _create_args {
  53     $_[0]->{_create_args} = $_[1] if @_ > 1;
  54     $_[0]->{_create_args}
  55 }
  56
  57 sub inlined_name {
  58     my $self = shift;
  59     my $name = $self->name;
  60     my $key   = "'" . $name . "'";
  61     return $key;
  62 }
  63
  64 sub generate_accessor {
  65     my $attribute = shift;
  66
  67     my $name          = $attribute->name;
  68     my $default       = $attribute->default;
  69     my $constraint    = $attribute->find_type_constraint;
  70     my $builder       = $attribute->builder;
  71     my $trigger       = $attribute->trigger;
  72     my $is_weak       = $attribute->is_weak_ref;
  73     my $should_deref  = $attribute->should_auto_deref;
  74     my $should_coerce = $attribute->should_coerce;
  75
  76     my $self  = '$_[0]';
  77     my $key   = $attribute->inlined_name;
  78
  79     my $accessor = "sub {\n";
  80     if ($attribute->_is_metadata eq 'rw') {
  81         $accessor .= 'if (scalar(@_) >= 2) {' . "\n";
  82
  83         my $value = '$_[1]';
  84
  85         if ($constraint) {
  86             $accessor .= 'my $val = ';
  87             if ($should_coerce) {
  88                 $accessor  .= 'Mouse::TypeRegistry->typecast_constraints("'.$attribute->associated_class->name.'", $attribute->{find_type_constraint}, $attribute->{type_constraint}, '.$value.');';
  89             } else {
  90                 $accessor .= $value.';';
  91             }
  92             $accessor .= 'local $_ = $val;';
  93             $accessor .= '
  94                 unless ($constraint->()) {
  95                     $attribute->verify_type_constraint_error($name, $_, $attribute->type_constraint);
  96                 }' . "\n";
  97             $value = '$val';
  98         }
  99
 100         # if there's nothing left to do for the attribute we can return during
 101         # this setter
 102         $accessor .= 'return ' if !$is_weak && !$trigger && !$should_deref;
 103
 104         $accessor .= $self.'->{'.$key.'} = '.$value.';' . "\n";
 105
 106         if ($is_weak) {
 107             $accessor .= 'Mouse::Util::weaken('.$self.'->{'.$key.'}) if ref('.$self.'->{'.$key.'});' . "\n";
 108         }
 109
 110         if ($trigger) {
 111             $accessor .= '$trigger->('.$self.', '.$value.', $attribute);' . "\n";
 112         }
 113
 114         $accessor .= "}\n";
 115     }
 116     else {
 117         $accessor .= 'confess "Cannot assign a value to a read-only accessor" if scalar(@_) >= 2;' . "\n";
 118     }
 119
 120     if ($attribute->is_lazy) {
 121         $accessor .= $self.'->{'.$key.'} = ';
 122
 123         $accessor .= $attribute->has_builder
 124                 ? $self.'->$builder'
 125                     : ref($default) eq 'CODE'
 126                     ? '$default->('.$self.')'
 127                     : '$default';
 128         $accessor .= ' if !exists '.$self.'->{'.$key.'};' . "\n";
 129     }
 130
 131     if ($should_deref) {
 132         my $type_constraint = $attribute->type_constraint;
 133         if (!ref($type_constraint) && $type_constraint eq 'ArrayRef') {
 134             $accessor .= 'if (wantarray) {
 135                 return @{ '.$self.'->{'.$key.'} || [] };
 136             }';
 137         }
 138         else {
 139             $accessor .= 'if (wantarray) {
 140                 return %{ '.$self.'->{'.$key.'} || {} };
 141             }';
 142         }
 143     }
 144
 145     $accessor .= 'return '.$self.'->{'.$key.'};
 146     }';
 147
 148     my $sub = eval $accessor;
 149     confess $@ if $@;
 150     return $sub;
 151 }
 152
 153 sub generate_predicate {
 154     my $attribute = shift;
 155     my $key = $attribute->inlined_name;
 156
 157     my $predicate = 'sub { exists($_[0]->{'.$key.'}) }';
 158
 159     my $sub = eval $predicate;
 160     confess $@ if $@;
 161     return $sub;
 162 }
 163
 164 sub generate_clearer {
 165     my $attribute = shift;
 166     my $key = $attribute->inlined_name;
 167
 168     my $clearer = 'sub { delete($_[0]->{'.$key.'}) }';
 169
 170     my $sub = eval $clearer;
 171     confess $@ if $@;
 172     return $sub;
 173 }
 174
 175 sub generate_handles {
 176     my $attribute = shift;
 177     my $reader = $attribute->name;
 178     my %handles = $attribute->_canonicalize_handles($attribute->handles);
 179
 180     my %method_map;
 181
 182     for my $local_method (keys %handles) {
 183         my $remote_method = $handles{$local_method};
 184
 185         my $method = 'sub {
 186             my $self = shift;
 187             $self->$reader->$remote_method(@_)
 188         }';
 189
 190         $method_map{$local_method} = eval $method;
 191         confess $@ if $@;
 192     }
 193
 194     return \%method_map;
 195 }
 196
 197 sub create {
 198     my ($self, $class, $name, %args) = @_;
 199
 200     $args{name} = $name;
 201     $args{associated_class} = $class;
 202
 203     %args = $self->canonicalize_args($name, %args);
 204     $self->validate_args($name, \%args);
 205
 206     $args{should_coerce} = delete $args{coerce}
 207         if exists $args{coerce};
 208
 209     if (exists $args{isa}) {
 210         my $type_constraint = delete $args{isa};
 211         $type_constraint =~ s/\s//g;
 212         my @type_constraints = split /\|/, $type_constraint;
 213
 214         my $code;
 215         my $optimized_constraints = Mouse::TypeRegistry->optimized_constraints;
 216         if (@type_constraints == 1) {
 217             $code = $optimized_constraints->{$type_constraints[0]} ||
 218                 sub { Mouse::Util::blessed($_) && Mouse::Util::blessed($_) eq $type_constraints[0] };
 219             $args{type_constraint} = $type_constraints[0];
 220         } else {
 221             my @code_list = map {
 222                 my $type = $_;
 223                 $optimized_constraints->{$type} ||
 224                     sub { Mouse::Util::blessed($_) && Mouse::Util::blessed($_) eq $type }
 225             } @type_constraints;
 226             $code = sub {
 227                 for my $code (@code_list) {
 228                     return 1 if $code->();
 229                 }
 230                 return 0;
 231             };
 232             $args{type_constraint} = \@type_constraints;
 233         }
 234         $args{find_type_constraint} = $code;
 235     }
 236
 237     my $attribute = $self->new(%args);
 238
 239     $attribute->_create_args(\%args);
 240
 241     $class->add_attribute($attribute);
 242
 243     # install an accessor
 244     if ($attribute->_is_metadata eq 'rw' || $attribute->_is_metadata eq 'ro') {
 245         my $accessor = $attribute->generate_accessor;
 246         $class->add_method($name => $accessor);
 247     }
 248
 249     for my $method (qw/predicate clearer/) {
 250         my $predicate = "has_$method";
 251         if ($attribute->$predicate) {
 252             my $generator = "generate_$method";
 253             my $coderef = $attribute->$generator;
 254             $class->add_method($attribute->$method => $coderef);
 255         }
 256     }
 257
 258     if ($attribute->has_handles) {
 259         my $method_map = $attribute->generate_handles;
 260         for my $method_name (keys %$method_map) {
 261             $class->add_method($method_name => $method_map->{$method_name});
 262         }
 263     }
 264
 265     return $attribute;
 266 }
 267
 268 sub canonicalize_args {
 269     my $self = shift;
 270     my $name = shift;
 271     my %args = @_;
 272
 273     if ($args{lazy_build}) {
 274         $args{lazy}      = 1;
 275         $args{required}  = 1;
 276         $args{builder}   = "_build_${name}"
 277             if !exists($args{builder});
 278         if ($name =~ /^_/) {
 279             $args{clearer}   = "_clear${name}" if !exists($args{clearer});
 280             $args{predicate} = "_has${name}" if !exists($args{predicate});
 281         }
 282         else {
 283             $args{clearer}   = "clear_${name}" if !exists($args{clearer});
 284             $args{predicate} = "has_${name}" if !exists($args{predicate});
 285         }
 286     }
 287
 288     return %args;
 289 }
 290
 291 sub validate_args {
 292     my $self = shift;
 293     my $name = shift;
 294     my $args = shift;
 295
 296     confess "You can not use lazy_build and default for the same attribute ($name)"
 297         if $args->{lazy_build} && exists $args->{default};
 298
 299     confess "You cannot have lazy attribute ($name) without specifying a default value for it"
 300         if $args->{lazy}
 301         && !exists($args->{default})
 302         && !exists($args->{builder});
 303
 304     confess "References are not allowed as default values, you must wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])"
 305         if ref($args->{default})
 306         && ref($args->{default}) ne 'CODE';
 307
 308     confess "You cannot auto-dereference without specifying a type constraint on attribute ($name)"
 309         if $args->{auto_deref} && !exists($args->{isa});
 310
 311     confess "You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)"
 312         if $args->{auto_deref}
 313         && $args->{isa} ne 'ArrayRef'
 314         && $args->{isa} ne 'HashRef';
 315
 316     if ($args->{trigger}) {
 317         if (ref($args->{trigger}) eq 'HASH') {
 318             Carp::carp "HASH-based form of trigger has been removed. Only the coderef form of triggers are now supported.";
 319         }
 320
 321         confess "Trigger must be a CODE ref on attribute ($name)"
 322             if ref($args->{trigger}) ne 'CODE';
 323     }
 324
 325     return 1;
 326 }
 327
 328 sub verify_type_constraint {
 329     return 1 unless $_[0]->{type_constraint};
 330
 331     local $_ = $_[1];
 332     return 1 if $_[0]->{find_type_constraint}->($_);
 333
 334     my $self = shift;
 335     $self->verify_type_constraint_error($self->name, $_, $self->type_constraint);
 336 }
 337
 338 sub verify_type_constraint_error {
 339     my($self, $name, $value, $type) = @_;
 340     $type = ref($type) eq 'ARRAY' ? join '|', @{ $type } : $type;
 341     my $display = defined($_) ? overload::StrVal($_) : 'undef';
 342     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
 343 }
 344
 345 sub coerce_constraint { ## my($self, $value) = @_;
 346     my $type = $_[0]->{type_constraint}
 347         or return $_[1];
 348     return Mouse::TypeRegistry->typecast_constraints($_[0]->associated_class->name, $_[0]->find_type_constraint, $type, $_[1]);
 349 }
 350
 351 sub _canonicalize_handles {
 352     my $self    = shift;
 353     my $handles = shift;
 354
 355     if (ref($handles) eq 'HASH') {
 356         return %$handles;
 357     }
 358     elsif (ref($handles) eq 'ARRAY') {
 359         return map { $_ => $_ } @$handles;
 360     }
 361     else {
 362         confess "Unable to canonicalize the 'handles' option with $handles";
 363     }
 364 }
 365
 366 sub clone_parent {
 367     my $self  = shift;
 368     my $class = shift;
 369     my $name  = shift;
 370     my %args  = ($self->get_parent_args($class, $name), @_);
 371
 372     $self->create($class, $name, %args);
 373 }
 374
 375 sub get_parent_args {
 376     my $self  = shift;
 377     my $class = shift;
 378     my $name  = shift;
 379
 380     for my $super ($class->linearized_isa) {
 381         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 382             or next;
 383         return %{ $super_attr->_create_args };
 384     }
 385
 386     confess "Could not find an attribute by the name of '$name' to inherit from";
 387 }
 388
 389 1;
 390
 391 __END__
 392
 393 =head1 NAME
 394
 395 Mouse::Meta::Attribute - attribute metaclass
 396
 397 =head1 METHODS
 398
 399 =head2 new %args -> Mouse::Meta::Attribute
 400
 401 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 402
 403 =head2 create OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 404
 405 Creates a new attribute in OwnerClass. Accessors and helper methods are
 406 installed. Some error checking is done.
 407
 408 =head2 name -> AttributeName
 409
 410 =head2 associated_class -> OwnerClass
 411
 412 =head2 is_required -> Bool
 413
 414 =head2 default -> Item
 415
 416 =head2 has_default -> Bool
 417
 418 =head2 is_lazy -> Bool
 419
 420 =head2 predicate -> MethodName | Undef
 421
 422 =head2 has_predicate -> Bool
 423
 424 =head2 clearer -> MethodName | Undef
 425
 426 =head2 has_clearer -> Bool
 427
 428 =head2 handles -> { LocalName => RemoteName }
 429
 430 =head2 has_handles -> Bool
 431
 432 =head2 is_weak_ref -> Bool
 433
 434 =head2 init_arg -> Str
 435
 436 =head2 type_constraint -> Str
 437
 438 =head2 has_type_constraint -> Bool
 439
 440 =head2 trigger => CODE | Undef
 441
 442 =head2 has_trigger -> Bool
 443
 444 =head2 builder => MethodName | Undef
 445
 446 =head2 has_builder -> Bool
 447
 448 =head2 is_lazy_build => Bool
 449
 450 =head2 should_auto_deref -> Bool
 451
 452 Informational methods.
 453
 454 =head2 generate_accessor -> CODE
 455
 456 Creates a new code reference for the attribute's accessor.
 457
 458 =head2 generate_predicate -> CODE
 459
 460 Creates a new code reference for the attribute's predicate.
 461
 462 =head2 generate_clearer -> CODE
 463
 464 Creates a new code reference for the attribute's clearer.
 465
 466 =head2 generate_handles -> { MethodName => CODE }
 467
 468 Creates a new code reference for each of the attribute's handles methods.
 469
 470 =head2 find_type_constraint -> CODE
 471
 472 Returns a code reference which can be used to check that a given value passes
 473 this attribute's type constraint;
 474
 475 =head2 verify_type_constraint Item -> 1 | ERROR
 476
 477 Checks that the given value passes this attribute's type constraint. Returns 1
 478 on success, otherwise C<confess>es.
 479
 480 =head2 canonicalize_args Name, %args -> %args
 481
 482 Canonicalizes some arguments to create. In particular, C<lazy_build> is
 483 canonicalized into C<lazy>, C<builder>, etc.
 484
 485 =head2 validate_args Name, \%args -> 1 | ERROR
 486
 487 Checks that the arguments to create the attribute (ie those specified by
 488 C<has>) are valid.
 489
 490 =head2 clone_parent OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 491
 492 Creates a new attribute in OwnerClass, inheriting options from parent classes.
 493 Accessors and helper methods are installed. Some error checking is done.
 494
 495 =head2 get_parent_args OwnerClass, AttributeName -> Hash
 496
 497 Returns the options that the parent class of C<OwnerClass> used for attribute
 498 C<AttributeName>.
 499
 500 =cut
 501