lib/Mouse/Meta/Attribute.pm

   1 #!/usr/bin/env perl
   2 package Mouse::Meta::Attribute;
   3 use strict;
   4 use warnings;
   5 require overload;
   6
   7 use Carp 'confess';
   8 require Mouse::Util;
   9
  10 sub new {
  11     my $class = shift;
  12     my %args  = @_;
  13
  14     my $name = $args{name};
  15
  16     $args{init_arg} = $name
  17         unless exists $args{init_arg};
  18
  19     $args{is} ||= '';
  20
  21     bless \%args, $class;
  22 }
  23
  24 sub name              { $_[0]->{name}             }
  25 sub associated_class  { $_[0]->{associated_class} }
  26 sub _is_metadata      { $_[0]->{is}               }
  27 sub is_required       { $_[0]->{required}         }
  28 sub default           { $_[0]->{default}          }
  29 sub is_lazy           { $_[0]->{lazy}             }
  30 sub is_lazy_build     { $_[0]->{lazy_build}       }
  31 sub predicate         { $_[0]->{predicate}        }
  32 sub clearer           { $_[0]->{clearer}          }
  33 sub handles           { $_[0]->{handles}          }
  34 sub is_weak_ref       { $_[0]->{weak_ref}         }
  35 sub init_arg          { $_[0]->{init_arg}         }
  36 sub type_constraint   { $_[0]->{type_constraint}  }
  37 sub trigger           { $_[0]->{trigger}          }
  38 sub builder           { $_[0]->{builder}          }
  39 sub should_auto_deref { $_[0]->{auto_deref}       }
  40 sub should_coerce     { $_[0]->{should_coerce}    }
  41
  42 sub has_default         { exists $_[0]->{default}         }
  43 sub has_predicate       { exists $_[0]->{predicate}       }
  44 sub has_clearer         { exists $_[0]->{clearer}         }
  45 sub has_handles         { exists $_[0]->{handles}         }
  46 sub has_type_constraint { exists $_[0]->{type_constraint} }
  47 sub has_trigger         { exists $_[0]->{trigger}         }
  48 sub has_builder         { exists $_[0]->{builder}         }
  49
  50 sub find_type_constraint      { $_[0]->{find_type_constraint}  }
  51 sub type_constraint_as_string {
  52     ref($_[0]->{type_constraint}) eq 'ARRAY' ? join '|', @{ $_[0]->{type_constraint} } : $_[0]->{type_constraint}
  53 }
  54
  55 sub _create_args {
  56     $_[0]->{_create_args} = $_[1] if @_ > 1;
  57     $_[0]->{_create_args}
  58 }
  59
  60 sub inlined_name {
  61     my $self = shift;
  62     my $name = $self->name;
  63     my $key   = "'" . $name . "'";
  64     return $key;
  65 }
  66
  67 sub generate_accessor {
  68     my $attribute = shift;
  69
  70     my $name          = $attribute->name;
  71     my $default       = $attribute->default;
  72     my $type          = $attribute->type_constraint_as_string;
  73     my $constraint    = $attribute->find_type_constraint;
  74     my $builder       = $attribute->builder;
  75     my $trigger       = $attribute->trigger;
  76     my $is_weak       = $attribute->is_weak_ref;
  77     my $should_deref  = $attribute->should_auto_deref;
  78     my $should_coerce = $attribute->should_coerce;
  79
  80     my $self  = '$_[0]';
  81     my $key   = $attribute->inlined_name;
  82
  83     my $accessor = "sub {\n";
  84     if ($attribute->_is_metadata eq 'rw') {
  85         $accessor .= 'if (scalar(@_) >= 2) {' . "\n";
  86
  87         my $value = '$_[1]';
  88
  89         if ($constraint) {
  90             $accessor .= 'local $_ = '.$self.'->{'.$key.'} = ';
  91             if ($should_coerce) {
  92                 $accessor .= '$attribute->coerce_constraint('.$value.');';
  93             } else {
  94                 $accessor .= $value.';';
  95             }
  96             $accessor .= '
  97                 unless ($constraint->()) {
  98                     my $display = defined($_) ? overload::StrVal($_) : "undef";
  99                     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
 100             }' . "\n"
 101         }
 102
 103         # if there's nothing left to do for the attribute we can return during
 104         # this setter
 105         $accessor .= 'return ' if !$is_weak && !$trigger && !$should_deref;
 106
 107         if ($is_weak) {
 108             $accessor .= 'Mouse::Util::weaken('.$self.'->{'.$key.'}) if ref('.$self.'->{'.$key.'});' . "\n";
 109         }
 110
 111         if ($trigger) {
 112             $accessor .= '$trigger->('.$self.', '.$value.', $attribute);' . "\n";
 113         }
 114
 115         $accessor .= "}\n";
 116     }
 117     else {
 118         $accessor .= 'confess "Cannot assign a value to a read-only accessor" if scalar(@_) >= 2;' . "\n";
 119     }
 120
 121     if ($attribute->is_lazy) {
 122         $accessor .= $self.'->{'.$key.'} = ';
 123
 124         $accessor .= $attribute->has_builder
 125                 ? $self.'->$builder'
 126                     : ref($default) eq 'CODE'
 127                     ? '$default->('.$self.')'
 128                     : '$default';
 129         $accessor .= ' if !exists '.$self.'->{'.$key.'};' . "\n";
 130     }
 131
 132     if ($should_deref) {
 133         my $type_constraint = $attribute->type_constraint;
 134         if (!ref($type_constraint) && $type_constraint eq 'ArrayRef') {
 135             $accessor .= 'if (wantarray) {
 136                 return @{ '.$self.'->{'.$key.'} || [] };
 137             }';
 138         }
 139         else {
 140             $accessor .= 'if (wantarray) {
 141                 return %{ '.$self.'->{'.$key.'} || {} };
 142             }';
 143         }
 144     }
 145
 146     $accessor .= 'return '.$self.'->{'.$key.'};
 147     }';
 148
 149     my $sub = eval $accessor;
 150     confess $@ if $@;
 151     return $sub;
 152 }
 153
 154 sub generate_predicate {
 155     my $attribute = shift;
 156     my $key = $attribute->inlined_name;
 157
 158     my $predicate = 'sub { exists($_[0]->{'.$key.'}) }';
 159
 160     my $sub = eval $predicate;
 161     confess $@ if $@;
 162     return $sub;
 163 }
 164
 165 sub generate_clearer {
 166     my $attribute = shift;
 167     my $key = $attribute->inlined_name;
 168
 169     my $clearer = 'sub { delete($_[0]->{'.$key.'}) }';
 170
 171     my $sub = eval $clearer;
 172     confess $@ if $@;
 173     return $sub;
 174 }
 175
 176 sub generate_handles {
 177     my $attribute = shift;
 178     my $reader = $attribute->name;
 179     my %handles = $attribute->_canonicalize_handles($attribute->handles);
 180
 181     my %method_map;
 182
 183     for my $local_method (keys %handles) {
 184         my $remote_method = $handles{$local_method};
 185
 186         my $method = 'sub {
 187             my $self = shift;
 188             $self->$reader->$remote_method(@_)
 189         }';
 190
 191         $method_map{$local_method} = eval $method;
 192         confess $@ if $@;
 193     }
 194
 195     return \%method_map;
 196 }
 197
 198 sub create {
 199     my ($self, $class, $name, %args) = @_;
 200
 201     $args{name} = $name;
 202     $args{associated_class} = $class;
 203
 204     %args = $self->canonicalize_args($name, %args);
 205     $self->validate_args($name, \%args);
 206
 207     $args{should_coerce} = delete $args{coerce}
 208         if exists $args{coerce};
 209
 210     if (exists $args{isa}) {
 211         my $type_constraint = delete $args{isa};
 212         $type_constraint =~ s/\s//g;
 213         my @type_constraints = split /\|/, $type_constraint;
 214
 215         my $code;
 216         my $optimized_constraints = Mouse::TypeRegistry->optimized_constraints;
 217         if (@type_constraints == 1) {
 218             $code = $optimized_constraints->{$type_constraints[0]} ||
 219                 sub { Mouse::Util::blessed($_) && Mouse::Util::blessed($_) eq $type_constraints[0] };
 220             $args{type_constraint} = $type_constraints[0];
 221         } else {
 222             my @code_list = map {
 223                 my $type = $_;
 224                 $optimized_constraints->{$type} ||
 225                     sub { Mouse::Util::blessed($_) && Mouse::Util::blessed($_) eq $type }
 226             } @type_constraints;
 227             $code = sub {
 228                 for my $code (@code_list) {
 229                     return 1 if $code->();
 230                 }
 231                 return 0;
 232             };
 233             $args{type_constraint} = \@type_constraints;
 234         }
 235         $args{find_type_constraint} = $code;
 236     }
 237
 238     my $attribute = $self->new(%args);
 239
 240     $attribute->_create_args(\%args);
 241
 242     $class->add_attribute($attribute);
 243
 244     # install an accessor
 245     if ($attribute->_is_metadata eq 'rw' || $attribute->_is_metadata eq 'ro') {
 246         my $accessor = $attribute->generate_accessor;
 247         $class->add_method($name => $accessor);
 248     }
 249
 250     for my $method (qw/predicate clearer/) {
 251         my $predicate = "has_$method";
 252         if ($attribute->$predicate) {
 253             my $generator = "generate_$method";
 254             my $coderef = $attribute->$generator;
 255             $class->add_method($attribute->$method => $coderef);
 256         }
 257     }
 258
 259     if ($attribute->has_handles) {
 260         my $method_map = $attribute->generate_handles;
 261         for my $method_name (keys %$method_map) {
 262             $class->add_method($method_name => $method_map->{$method_name});
 263         }
 264     }
 265
 266     return $attribute;
 267 }
 268
 269 sub canonicalize_args {
 270     my $self = shift;
 271     my $name = shift;
 272     my %args = @_;
 273
 274     if ($args{lazy_build}) {
 275         $args{lazy}      = 1;
 276         $args{required}  = 1;
 277         $args{builder}   = "_build_${name}"
 278             if !exists($args{builder});
 279         if ($name =~ /^_/) {
 280             $args{clearer}   = "_clear${name}" if !exists($args{clearer});
 281             $args{predicate} = "_has${name}" if !exists($args{predicate});
 282         }
 283         else {
 284             $args{clearer}   = "clear_${name}" if !exists($args{clearer});
 285             $args{predicate} = "has_${name}" if !exists($args{predicate});
 286         }
 287     }
 288
 289     return %args;
 290 }
 291
 292 sub validate_args {
 293     my $self = shift;
 294     my $name = shift;
 295     my $args = shift;
 296
 297     confess "You can not use lazy_build and default for the same attribute ($name)"
 298         if $args->{lazy_build} && exists $args->{default};
 299
 300     confess "You cannot have lazy attribute ($name) without specifying a default value for it"
 301         if $args->{lazy}
 302         && !exists($args->{default})
 303         && !exists($args->{builder});
 304
 305     confess "References are not allowed as default values, you must wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])"
 306         if ref($args->{default})
 307         && ref($args->{default}) ne 'CODE';
 308
 309     confess "You cannot auto-dereference without specifying a type constraint on attribute ($name)"
 310         if $args->{auto_deref} && !exists($args->{isa});
 311
 312     confess "You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)"
 313         if $args->{auto_deref}
 314         && $args->{isa} ne 'ArrayRef'
 315         && $args->{isa} ne 'HashRef';
 316
 317     if ($args->{trigger}) {
 318         if (ref($args->{trigger}) eq 'HASH') {
 319             Carp::carp "HASH-based form of trigger has been removed. Only the coderef form of triggers are now supported.";
 320         }
 321
 322         confess "Trigger must be a CODE ref on attribute ($name)"
 323             if ref($args->{trigger}) ne 'CODE';
 324     }
 325
 326     return 1;
 327 }
 328
 329 sub verify_type_constraint {
 330     my $self = shift;
 331     local $_ = shift;
 332
 333     my $type = $self->type_constraint_as_string
 334         or return 1;
 335     my $constraint = $self->find_type_constraint;
 336
 337     return 1 if $constraint->($_);
 338
 339     my $name = $self->name;
 340     my $display = defined($_) ? overload::StrVal($_) : 'undef';
 341     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
 342 }
 343
 344 sub coerce_constraint {
 345     my($self, $value) = @_;
 346     my $type = $self->type_constraint
 347         or return $value;
 348     return Mouse::TypeRegistry->typecast_constraints($self->associated_class->name, $self->find_type_constraint, $type, $value);
 349 }
 350
 351 sub _canonicalize_handles {
 352     my $self    = shift;
 353     my $handles = shift;
 354
 355     if (ref($handles) eq 'HASH') {
 356         return %$handles;
 357     }
 358     elsif (ref($handles) eq 'ARRAY') {
 359         return map { $_ => $_ } @$handles;
 360     }
 361     else {
 362         confess "Unable to canonicalize the 'handles' option with $handles";
 363     }
 364 }
 365
 366 sub clone_parent {
 367     my $self  = shift;
 368     my $class = shift;
 369     my $name  = shift;
 370     my %args  = ($self->get_parent_args($class, $name), @_);
 371
 372     $self->create($class, $name, %args);
 373 }
 374
 375 sub get_parent_args {
 376     my $self  = shift;
 377     my $class = shift;
 378     my $name  = shift;
 379
 380     for my $super ($class->linearized_isa) {
 381         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 382             or next;
 383         return %{ $super_attr->_create_args };
 384     }
 385
 386     confess "Could not find an attribute by the name of '$name' to inherit from";
 387 }
 388
 389 1;
 390
 391 __END__
 392
 393 =head1 NAME
 394
 395 Mouse::Meta::Attribute - attribute metaclass
 396
 397 =head1 METHODS
 398
 399 =head2 new %args -> Mouse::Meta::Attribute
 400
 401 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 402
 403 =head2 create OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 404
 405 Creates a new attribute in OwnerClass. Accessors and helper methods are
 406 installed. Some error checking is done.
 407
 408 =head2 name -> AttributeName
 409
 410 =head2 associated_class -> OwnerClass
 411
 412 =head2 is_required -> Bool
 413
 414 =head2 default -> Item
 415
 416 =head2 has_default -> Bool
 417
 418 =head2 is_lazy -> Bool
 419
 420 =head2 predicate -> MethodName | Undef
 421
 422 =head2 has_predicate -> Bool
 423
 424 =head2 clearer -> MethodName | Undef
 425
 426 =head2 has_clearer -> Bool
 427
 428 =head2 handles -> { LocalName => RemoteName }
 429
 430 =head2 has_handles -> Bool
 431
 432 =head2 is_weak_ref -> Bool
 433
 434 =head2 init_arg -> Str
 435
 436 =head2 type_constraint -> Str
 437
 438 =head2 has_type_constraint -> Bool
 439
 440 =head2 trigger => CODE | Undef
 441
 442 =head2 has_trigger -> Bool
 443
 444 =head2 builder => MethodName | Undef
 445
 446 =head2 has_builder -> Bool
 447
 448 =head2 is_lazy_build => Bool
 449
 450 =head2 should_auto_deref -> Bool
 451
 452 Informational methods.
 453
 454 =head2 generate_accessor -> CODE
 455
 456 Creates a new code reference for the attribute's accessor.
 457
 458 =head2 generate_predicate -> CODE
 459
 460 Creates a new code reference for the attribute's predicate.
 461
 462 =head2 generate_clearer -> CODE
 463
 464 Creates a new code reference for the attribute's clearer.
 465
 466 =head2 generate_handles -> { MethodName => CODE }
 467
 468 Creates a new code reference for each of the attribute's handles methods.
 469
 470 =head2 find_type_constraint -> CODE
 471
 472 Returns a code reference which can be used to check that a given value passes
 473 this attribute's type constraint;
 474
 475 =head2 verify_type_constraint Item -> 1 | ERROR
 476
 477 Checks that the given value passes this attribute's type constraint. Returns 1
 478 on success, otherwise C<confess>es.
 479
 480 =head2 canonicalize_args Name, %args -> %args
 481
 482 Canonicalizes some arguments to create. In particular, C<lazy_build> is
 483 canonicalized into C<lazy>, C<builder>, etc.
 484
 485 =head2 validate_args Name, \%args -> 1 | ERROR
 486
 487 Checks that the arguments to create the attribute (ie those specified by
 488 C<has>) are valid.
 489
 490 =head2 clone_parent OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 491
 492 Creates a new attribute in OwnerClass, inheriting options from parent classes.
 493 Accessors and helper methods are installed. Some error checking is done.
 494
 495 =head2 get_parent_args OwnerClass, AttributeName -> Hash
 496
 497 Returns the options that the parent class of C<OwnerClass> used for attribute
 498 C<AttributeName>.
 499
 500 =cut
 501