lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use strict;
   3 use warnings;
   4
   5 use Carp ();
   6
   7 use Mouse::Util qw(:meta);
   8
   9 use Mouse::Meta::TypeConstraint;
  10 use Mouse::Meta::Method::Accessor;
  11
  12 sub _process_options{
  13     my($class, $name, $args) = @_;
  14
  15
  16     # XXX: for backward compatibility (with method modifiers)
  17     if($class->can('canonicalize_args') != \&canonicalize_args){
  18         %{$args} = $class->canonicalize_args($name, %{$args});
  19     }
  20
  21     # taken from Class::MOP::Attribute::new
  22
  23     defined($name)
  24         or $class->throw_error('You must provide a name for the attribute');
  25
  26     if(!exists $args->{init_arg}){
  27         $args->{init_arg} = $name;
  28     }
  29
  30     # 'required' requires eigher 'init_arg', 'builder', or 'default'
  31     my $can_be_required = defined( $args->{init_arg} );
  32
  33     if(exists $args->{builder}){
  34         # XXX:
  35         # Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
  36         # This feature will be changed in a future. (gfx)
  37         $class->throw_error('builder must be a defined scalar value which is a method name')
  38             #if ref $args->{builder} || !defined $args->{builder};
  39             if !defined $args->{builder};
  40
  41         $can_be_required++;
  42     }
  43     elsif(exists $args->{default}){
  44         if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
  45             $class->throw_error("References are not allowed as default values, you must "
  46                               . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
  47         }
  48         $can_be_required++;
  49     }
  50
  51     if( $args->{required} && !$can_be_required ) {
  52         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
  53     }
  54
  55     # taken from Mouse::Meta::Attribute->new and _process_args->
  56
  57     if(exists $args->{is}){
  58         my $is = $args->{is};
  59
  60         if($is eq 'ro'){
  61             $args->{reader} ||= $name;
  62         }
  63         elsif($is eq 'rw'){
  64             if(exists $args->{writer}){
  65                 $args->{reader} ||= $name;
  66              }
  67              else{
  68                 $args->{accessor} ||= $name;
  69              }
  70         }
  71         elsif($is eq 'bare'){
  72             # do nothing, but don't complain (later) about missing methods
  73         }
  74         else{
  75             $is = 'undef' if !defined $is;
  76             $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
  77         }
  78     }
  79
  80     my $tc;
  81     if(exists $args->{isa}){
  82         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
  83     }
  84     elsif(exists $args->{does}){
  85         # TODO
  86         # $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
  87     }
  88     $tc = $args->{type_constraint};
  89
  90     if($args->{coerce}){
  91         defined($tc)
  92             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
  93
  94         $args->{weak_ref}
  95             && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
  96     }
  97
  98     if ($args->{lazy_build}) {
  99         exists($args->{default})
 100             && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
 101
 102         $args->{lazy}      = 1;
 103         $args->{builder} ||= "_build_${name}";
 104         if ($name =~ /^_/) {
 105             $args->{clearer}   ||= "_clear${name}";
 106             $args->{predicate} ||= "_has${name}";
 107         }
 108         else {
 109             $args->{clearer}   ||= "clear_${name}";
 110             $args->{predicate} ||= "has_${name}";
 111         }
 112     }
 113
 114     if ($args->{auto_deref}) {
 115         defined($tc)
 116             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
 117
 118         ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
 119             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
 120     }
 121
 122     if (exists $args->{trigger}) {
 123         ('CODE' eq ref $args->{trigger})
 124             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
 125     }
 126
 127     if ($args->{lazy}) {
 128         (exists $args->{default} || defined $args->{builder})
 129             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
 130     }
 131
 132     return;
 133 }
 134
 135 sub new {
 136     my $class = shift;
 137     my $name  = shift;
 138
 139     my %args  = (@_ == 1) ? %{ $_[0] } : @_;
 140
 141     $class->_process_options($name, \%args);
 142
 143     $args{name} = $name;
 144
 145     my $self = bless \%args, $class;
 146
 147     # extra attributes
 148     if($class ne __PACKAGE__){
 149         $class->meta->_initialize_object($self, \%args);
 150     }
 151
 152 # XXX: there is no fast way to check attribute validity
 153 #    my @bad = ...;
 154 #    if(@bad){
 155 #        @bad = sort @bad;
 156 #        Carp::cluck("Found unknown argument(s) passed to '$name' attribute constructor in '$class': @bad");
 157 #    }
 158
 159     return $self;
 160 }
 161
 162 # readers
 163
 164 sub name                 { $_[0]->{name}                   }
 165 sub associated_class     { $_[0]->{associated_class}       }
 166
 167 sub accessor             { $_[0]->{accessor}               }
 168 sub reader               { $_[0]->{reader}                 }
 169 sub writer               { $_[0]->{writer}                 }
 170 sub predicate            { $_[0]->{predicate}              }
 171 sub clearer              { $_[0]->{clearer}                }
 172 sub handles              { $_[0]->{handles}                }
 173
 174 sub _is_metadata         { $_[0]->{is}                     }
 175 sub is_required          { $_[0]->{required}               }
 176 sub default              { $_[0]->{default}                }
 177 sub is_lazy              { $_[0]->{lazy}                   }
 178 sub is_lazy_build        { $_[0]->{lazy_build}             }
 179 sub is_weak_ref          { $_[0]->{weak_ref}               }
 180 sub init_arg             { $_[0]->{init_arg}               }
 181 sub type_constraint      { $_[0]->{type_constraint}        }
 182
 183 sub trigger              { $_[0]->{trigger}                }
 184 sub builder              { $_[0]->{builder}                }
 185 sub should_auto_deref    { $_[0]->{auto_deref}             }
 186 sub should_coerce        { $_[0]->{coerce}                 }
 187
 188 # predicates
 189
 190 sub has_accessor         { exists $_[0]->{accessor}        }
 191 sub has_reader           { exists $_[0]->{reader}          }
 192 sub has_writer           { exists $_[0]->{writer}          }
 193 sub has_predicate        { exists $_[0]->{predicate}       }
 194 sub has_clearer          { exists $_[0]->{clearer}         }
 195 sub has_handles          { exists $_[0]->{handles}         }
 196
 197 sub has_default          { exists $_[0]->{default}         }
 198 sub has_type_constraint  { exists $_[0]->{type_constraint} }
 199 sub has_trigger          { exists $_[0]->{trigger}         }
 200 sub has_builder          { exists $_[0]->{builder}         }
 201
 202 sub has_read_method      { exists $_[0]->{reader} || exists $_[0]->{accessor} }
 203 sub has_write_method     { exists $_[0]->{writer} || exists $_[0]->{accessor} }
 204
 205 sub _create_args { # DEPRECATED
 206     $_[0]->{_create_args} = $_[1] if @_ > 1;
 207     $_[0]->{_create_args}
 208 }
 209
 210 sub interpolate_class{
 211     my($class, $name, $args) = @_;
 212
 213     if(my $metaclass = delete $args->{metaclass}){
 214         $class = Mouse::Util::resolve_metaclass_alias( Attribute => $metaclass );
 215     }
 216
 217     my @traits;
 218     if(my $traits_ref = delete $args->{traits}){
 219
 220         for (my $i = 0; $i < @{$traits_ref}; $i++) {
 221             my $trait = Mouse::Util::resolve_metaclass_alias(Attribute => $traits_ref->[$i], trait => 1);
 222
 223             next if $class->does($trait);
 224
 225             push @traits, $trait;
 226
 227             # are there options?
 228             push @traits, $traits_ref->[++$i]
 229                 if ref($traits_ref->[$i+1]);
 230         }
 231
 232         if (@traits) {
 233             warn "traits [@traits] for $class\n";
 234             $class = Mouse::Meta::Class->create_anon_class(
 235                 superclasses => [ $class ],
 236                 roles        => \@traits,
 237                 cache        => 1,
 238             )->name;
 239         }
 240     }
 241
 242     return( $class, @traits );
 243 }
 244
 245 sub canonicalize_args{ # DEPRECATED
 246     my ($self, $name, %args) = @_;
 247
 248     Carp::cluck("$self->canonicalize_args has been deprecated."
 249         . "Use \$self->_process_options instead.")
 250             if _MOUSE_VERBOSE;
 251
 252     return %args;
 253 }
 254
 255 sub create {
 256     my ($self, $class, $name, %args) = @_;
 257
 258     Carp::cluck("$self->create has been deprecated."
 259         . "Use \$meta->add_attribute and \$attr->install_accessors instead.")
 260             if _MOUSE_VERBOSE;
 261
 262     # noop
 263     return $self;
 264 }
 265
 266 sub _coerce_and_verify {
 267     my($self, $value, $instance) = @_;
 268
 269     my $type_constraint = $self->{type_constraint};
 270
 271     return $value if !$type_constraint;
 272
 273     if ($self->should_coerce && $type_constraint->has_coercion) {
 274         $value = $type_constraint->coerce($value);
 275     }
 276
 277     return $value if $type_constraint->check($value);
 278
 279     $self->verify_against_type_constraint($value);
 280
 281     return $value;
 282 }
 283
 284 sub verify_against_type_constraint {
 285     my ($self, $value) = @_;
 286
 287     my $type_constraint = $self->{type_constraint};
 288     return 1 if !$type_constraint;;
 289     return 1 if $type_constraint->check($value);
 290
 291     $self->verify_type_constraint_error($self->name, $value, $type_constraint);
 292 }
 293
 294 sub verify_type_constraint_error {
 295     my($self, $name, $value, $type) = @_;
 296     $self->throw_error("Attribute ($name) does not pass the type constraint because: " . $type->get_message($value));
 297 }
 298
 299 sub coerce_constraint { # DEPRECATED
 300     my $type = $_[0]->{type_constraint}
 301         or return $_[1];
 302
 303     Carp::cluck("coerce_constraint() has been deprecated, which was an internal utility anyway");
 304
 305     return Mouse::Util::TypeConstraints->typecast_constraints($_[0]->associated_class->name, $type, $_[1]);
 306 }
 307
 308 sub _canonicalize_handles {
 309     my $self    = shift;
 310     my $handles = shift;
 311
 312     if (ref($handles) eq 'HASH') {
 313         return %$handles;
 314     }
 315     elsif (ref($handles) eq 'ARRAY') {
 316         return map { $_ => $_ } @$handles;
 317     }
 318     else {
 319         $self->throw_error("Unable to canonicalize the 'handles' option with $handles");
 320     }
 321 }
 322
 323 sub clone_and_inherit_options{
 324     my $self = shift;
 325     my $name = shift;
 326
 327     return ref($self)->new($name, %{$self}, (@_ == 1) ? %{$_[0]} : @_);
 328 }
 329
 330 sub clone_parent { # DEPRECATED
 331     my $self  = shift;
 332     my $class = shift;
 333     my $name  = shift;
 334     my %args  = ($self->get_parent_args($class, $name), @_);
 335
 336     Carp::cluck("$self->clone_parent has been deprecated."
 337         . "Use \$meta->add_attribute and \$attr->install_accessors instead.")
 338         if _MOUSE_VERBOSE;
 339
 340     $self->clone_and_inherited_args($class, $name, %args);
 341 }
 342
 343 sub get_parent_args { # DEPRECATED
 344     my $self  = shift;
 345     my $class = shift;
 346     my $name  = shift;
 347
 348     for my $super ($class->linearized_isa) {
 349         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 350             or next;
 351         return %{ $super_attr->_create_args };
 352     }
 353
 354     $self->throw_error("Could not find an attribute by the name of '$name' to inherit from");
 355 }
 356
 357
 358 sub get_read_method { # DEPRECATED
 359     $_[0]->{reader} || $_[0]->{accessor}
 360 }
 361 sub get_write_method { # DEPRECATED
 362     $_[0]->{writer} || $_[0]->{accessor}
 363 }
 364
 365 sub get_read_method_ref{
 366     my($self) = @_;
 367
 368     $self->{_read_method_ref} ||= do{
 369         my $metaclass = $self->associated_class
 370             or $self->throw_error('No asocciated class for ' . $self->name);
 371
 372         my $reader = $self->{reader} || $self->{accessor};
 373         if($reader){
 374             $metaclass->name->can($reader);
 375         }
 376         else{
 377             Mouse::Meta::Method::Accessor->_generate_reader($self, undef, $metaclass);
 378         }
 379     };
 380 }
 381
 382 sub get_write_method_ref{
 383     my($self) = @_;
 384
 385     $self->{_write_method_ref} ||= do{
 386         my $metaclass = $self->associated_class
 387             or $self->throw_error('No asocciated class for ' . $self->name);
 388
 389         my $reader = $self->{writer} || $self->{accessor};
 390         if($reader){
 391             $metaclass->name->can($reader);
 392         }
 393         else{
 394             Mouse::Meta::Method::Accessor->_generate_writer($self, undef, $metaclass);
 395         }
 396     };
 397 }
 398
 399 sub associate_method{
 400     my ($attribute, $method) = @_;
 401     $attribute->{associated_methods}++;
 402     return;
 403 }
 404
 405 sub install_accessors{
 406     my($attribute) = @_;
 407
 408     my $metaclass       = $attribute->{associated_class};
 409
 410     foreach my $type(qw(accessor reader writer predicate clearer handles)){
 411         if(exists $attribute->{$type}){
 412             my $installer    = '_generate_' . $type;
 413
 414             Mouse::Meta::Method::Accessor->$installer($attribute, $attribute->{$type}, $metaclass);
 415
 416             $attribute->{associated_methods}++;
 417         }
 418     }
 419
 420     if($attribute->can('create') != \&create){
 421         # backword compatibility
 422         $attribute->create($metaclass, $attribute->name, %{$attribute});
 423     }
 424
 425     return;
 426 }
 427
 428 sub throw_error{
 429     my $self = shift;
 430
 431     my $metaclass = (ref $self && $self->associated_class) || 'Mouse::Meta::Class';
 432     $metaclass->throw_error(@_, depth => 1);
 433 }
 434
 435 1;
 436
 437 __END__
 438
 439 =head1 NAME
 440
 441 Mouse::Meta::Attribute - The Mouse attribute metaclass
 442
 443 =head1 METHODS
 444
 445 =head2 C<< new(%options) -> Mouse::Meta::Attribute >>
 446
 447 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 448
 449 It adds the following options to the constructor:
 450
 451 =over 4
 452
 453 =item C<< is => 'ro', 'rw', 'bare' >>
 454
 455 This provides a shorthand for specifying the C<reader>, C<writer>, or
 456 C<accessor> names. If the attribute is read-only ('ro') then it will
 457 have a C<reader> method with the same attribute as the name.
 458
 459 If it is read-write ('rw') then it will have an C<accessor> method
 460 with the same name. If you provide an explicit C<writer> for a
 461 read-write attribute, then you will have a C<reader> with the same
 462 name as the attribute, and a C<writer> with the name you provided.
 463
 464 Use 'bare' when you are deliberately not installing any methods
 465 (accessor, reader, etc.) associated with this attribute; otherwise,
 466 Moose will issue a deprecation warning when this attribute is added to a
 467 metaclass.
 468
 469 =item C<< isa => Type >>
 470
 471 This option accepts a type. The type can be a string, which should be
 472 a type name. If the type name is unknown, it is assumed to be a class
 473 name.
 474
 475 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 476
 477 If you I<also> provide a C<does> option, then your C<isa> option must
 478 be a class name, and that class must do the role specified with
 479 C<does>.
 480
 481 =item C<< does => Role >>
 482
 483 This is short-hand for saying that the attribute's type must be an
 484 object which does the named role.
 485
 486 B<This option is not yet supported.>
 487
 488 =item C<< coerce => Bool >>
 489
 490 This option is only valid for objects with a type constraint
 491 (C<isa>). If this is true, then coercions will be applied whenever
 492 this attribute is set.
 493
 494 You can make both this and the C<weak_ref> option true.
 495
 496 =item C<< trigger => CodeRef >>
 497
 498 This option accepts a subroutine reference, which will be called after
 499 the attribute is set.
 500
 501 =item C<< required => Bool >>
 502
 503 An attribute which is required must be provided to the constructor. An
 504 attribute which is required can also have a C<default> or C<builder>,
 505 which will satisfy its required-ness.
 506
 507 A required attribute must have a C<default>, C<builder> or a
 508 non-C<undef> C<init_arg>
 509
 510 =item C<< lazy => Bool >>
 511
 512 A lazy attribute must have a C<default> or C<builder>. When an
 513 attribute is lazy, the default value will not be calculated until the
 514 attribute is read.
 515
 516 =item C<< weak_ref => Bool >>
 517
 518 If this is true, the attribute's value will be stored as a weak
 519 reference.
 520
 521 =item C<< auto_deref => Bool >>
 522
 523 If this is true, then the reader will dereference the value when it is
 524 called. The attribute must have a type constraint which defines the
 525 attribute as an array or hash reference.
 526
 527 =item C<< lazy_build => Bool >>
 528
 529 Setting this to true makes the attribute lazy and provides a number of
 530 default methods.
 531
 532   has 'size' => (
 533       is         => 'ro',
 534       lazy_build => 1,
 535   );
 536
 537 is equivalent to this:
 538
 539   has 'size' => (
 540       is        => 'ro',
 541       lazy      => 1,
 542       builder   => '_build_size',
 543       clearer   => 'clear_size',
 544       predicate => 'has_size',
 545   );
 546
 547 =back
 548
 549 =head2 C<< associate_method(Method) >>
 550
 551 Associates a method with the attribute. Typically, this is called internally
 552 when an attribute generates its accessors.
 553
 554 Currently the argument I<Method> is ignored in Mouse.
 555
 556 =head2 C<< verify_against_type_constraint(Item) -> TRUE | ERROR >>
 557
 558 Checks that the given value passes this attribute's type constraint. Returns C<true>
 559 on success, otherwise C<confess>es.
 560
 561 =head2 C<< clone_and_inherit_options(options) -> Mouse::Meta::Attribute >>
 562
 563 Creates a new attribute in the owner class, inheriting options from parent classes.
 564 Accessors and helper methods are installed. Some error checking is done.
 565
 566 =head2 C<< get_read_method_ref >>\r
 567 \r
 568 =head2 C<< get_write_method_ref >>\r
 569 \r
 570 Returns the subroutine reference of a method suitable for reading or\r
 571 writing the attribute's value in the associated class. These methods\r
 572 always return a subroutine reference, regardless of whether or not the\r
 573 attribute is read- or write-only.
 574
 575 =head1 SEE ALSO
 576
 577 L<Moose::Meta::Attribute>
 578
 579 L<Class::MOP::Attribute>
 580
 581 =cut
 582