lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use Mouse::Util qw(:meta); # enables strict and warnings
   3
   4 use Carp ();
   5
   6 use Mouse::Meta::TypeConstraint;
   7
   8 my %valid_options = map { $_ => undef } (
   9   'accessor',
  10   'auto_deref',
  11   'builder',
  12   'clearer',
  13   'coerce',
  14   'default',
  15   'documentation',
  16   'does',
  17   'handles',
  18   'init_arg',
  19   'is',
  20   'isa',
  21   'lazy',
  22   'lazy_build',
  23   'name',
  24   'predicate',
  25   'reader',
  26   'required',
  27   'traits',
  28   'trigger',
  29   'type_constraint',
  30   'weak_ref',
  31   'writer',
  32
  33   # internally used
  34   'associated_class',
  35   'associated_methods',
  36
  37   # Moose defines, but Mouse doesn't
  38   #'definition_context',
  39   #'initializer',
  40   #'insertion_order',
  41
  42   # special case for AttributeHelpers
  43   'provides',
  44   'curries',
  45 );
  46
  47 our @CARP_NOT = qw(Mouse::Meta::Class);
  48
  49 sub new {
  50     my $class = shift;
  51     my $name  = shift;
  52
  53     my $args  = $class->Mouse::Object::BUILDARGS(@_);
  54
  55     # XXX: for backward compatibility (with method modifiers)
  56     if($class->can('canonicalize_args') != \&canonicalize_args){
  57         %{$args} = $class->canonicalize_args($name, %{$args});
  58     }
  59
  60     $class->_process_options($name, $args);
  61
  62     $args->{name} = $name;
  63
  64     # check options
  65     # (1) known by core
  66     my @bad = grep{ !exists $valid_options{$_} } keys %{$args};
  67
  68     # (2) known by subclasses
  69     if(@bad && $class ne __PACKAGE__){
  70         my %valid_attrs = (
  71             map { $_ => undef }
  72             grep { defined }
  73             map { $_->init_arg() }
  74             $class->meta->get_all_attributes()
  75         );
  76         @bad = grep{ !exists $valid_attrs{$_} } @bad;
  77     }
  78
  79     # (3) bad options found
  80     if(@bad){
  81         Carp::carp(
  82             "Found unknown argument(s) passed to '$name' attribute constructor in '$class': "
  83             . Mouse::Util::english_list(@bad));
  84     }
  85
  86     my $self = bless $args, $class;
  87
  88     # extra attributes
  89     if($class ne __PACKAGE__){
  90         $class->meta->_initialize_object($self, $args);
  91     }
  92
  93     return $self;
  94 }
  95
  96 sub has_read_method      { $_[0]->has_reader || $_[0]->has_accessor }
  97 sub has_write_method     { $_[0]->has_writer || $_[0]->has_accessor }
  98
  99 sub _create_args { # DEPRECATED
 100     $_[0]->{_create_args} = $_[1] if @_ > 1;
 101     $_[0]->{_create_args}
 102 }
 103
 104 sub interpolate_class{
 105     my($class, $args) = @_;
 106
 107     if(my $metaclass = delete $args->{metaclass}){
 108         $class = Mouse::Util::resolve_metaclass_alias( Attribute => $metaclass );
 109     }
 110
 111     my @traits;
 112     if(my $traits_ref = delete $args->{traits}){
 113
 114         for (my $i = 0; $i < @{$traits_ref}; $i++) {
 115             my $trait = Mouse::Util::resolve_metaclass_alias(Attribute => $traits_ref->[$i], trait => 1);
 116
 117             next if $class->does($trait);
 118
 119             push @traits, $trait;
 120
 121             # are there options?
 122             push @traits, $traits_ref->[++$i]
 123                 if ref($traits_ref->[$i+1]);
 124         }
 125
 126         if (@traits) {
 127             $class = Mouse::Meta::Class->create_anon_class(
 128                 superclasses => [ $class ],
 129                 roles        => \@traits,
 130                 cache        => 1,
 131             )->name;
 132         }
 133     }
 134
 135     return( $class, @traits );
 136 }
 137
 138 sub canonicalize_args{ # DEPRECATED
 139     #my($self, $name, %args) = @_;
 140     my($self, undef, %args) = @_;
 141
 142     Carp::cluck("$self->canonicalize_args has been deprecated."
 143         . "Use \$self->_process_options instead.");
 144
 145     return %args;
 146 }
 147
 148 sub create { # DEPRECATED
 149     #my($self, $class, $name, %args) = @_;
 150     my($self) = @_;
 151
 152     Carp::cluck("$self->create has been deprecated."
 153         . "Use \$meta->add_attribute and \$attr->install_accessors instead.");
 154
 155     # noop
 156     return $self;
 157 }
 158
 159 sub _coerce_and_verify {
 160     #my($self, $value, $instance) = @_;
 161     my($self, $value) = @_;
 162
 163     my $type_constraint = $self->{type_constraint};
 164     return $value if !defined $type_constraint;
 165
 166     if ($self->should_coerce && $type_constraint->has_coercion) {
 167         $value = $type_constraint->coerce($value);
 168     }
 169
 170     $self->verify_against_type_constraint($value);
 171
 172     return $value;
 173 }
 174
 175 sub verify_against_type_constraint {
 176     my ($self, $value) = @_;
 177
 178     my $type_constraint = $self->{type_constraint};
 179     return 1 if !$type_constraint;
 180     return 1 if $type_constraint->check($value);
 181
 182     $self->_throw_type_constraint_error($value, $type_constraint);
 183 }
 184
 185 sub _throw_type_constraint_error {
 186     my($self, $value, $type) = @_;
 187
 188     $self->throw_error(
 189         sprintf q{Attribute (%s) does not pass the type constraint because: %s},
 190             $self->name,
 191             $type->get_message($value),
 192     );
 193 }
 194
 195 sub clone_and_inherit_options{
 196     my $self = shift;
 197     my $args = $self->Mouse::Object::BUILDARGS(@_);
 198
 199     my($attribute_class, @traits) = ref($self)->interpolate_class($args);
 200
 201     $args->{traits} = \@traits if @traits;
 202     # do not inherit the 'handles' attribute
 203     foreach my $name(keys %{$self}){
 204         if(!exists $args->{$name} && $name ne 'handles'){
 205             $args->{$name} = $self->{$name};
 206         }
 207     }
 208
 209     # remove temporary caches
 210     foreach my $attr(keys %{$args}){
 211         if($attr =~ /\A _/xms){
 212             delete $args->{$attr};
 213         }
 214     }
 215
 216     return $attribute_class->new($self->name, $args);
 217 }
 218
 219 sub clone_parent { # DEPRECATED
 220     my $self  = shift;
 221     my $class = shift;
 222     my $name  = shift;
 223     my %args  = ($self->get_parent_args($class, $name), @_);
 224
 225     Carp::cluck("$self->clone_parent has been deprecated."
 226         . "Use \$meta->add_attribute and \$attr->install_accessors instead.");
 227
 228     $self->clone_and_inherited_args($class, $name, %args);
 229 }
 230
 231 sub get_parent_args { # DEPRECATED
 232     my $self  = shift;
 233     my $class = shift;
 234     my $name  = shift;
 235
 236     for my $super ($class->linearized_isa) {
 237         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 238             or next;
 239         return %{ $super_attr->_create_args };
 240     }
 241
 242     $self->throw_error("Could not find an attribute by the name of '$name' to inherit from");
 243 }
 244
 245
 246 sub get_read_method {
 247     return $_[0]->reader || $_[0]->accessor
 248 }
 249 sub get_write_method {
 250     return $_[0]->writer || $_[0]->accessor
 251 }
 252
 253 sub _get_accessor_method_ref {
 254     my($self, $type, $generator) = @_;
 255
 256     my $metaclass = $self->associated_class
 257         || $self->throw_error('No asocciated class for ' . $self->name);
 258
 259     my $accessor = $self->$type();
 260     if($accessor){
 261         return $metaclass->get_method_body($accessor);
 262     }
 263     else{
 264         return $self->accessor_metaclass->$generator($self, $metaclass);
 265     }
 266 }
 267
 268 sub get_read_method_ref{
 269     my($self) = @_;
 270     return $self->{_read_method_ref} ||= $self->_get_accessor_method_ref('get_read_method', '_generate_reader');
 271 }
 272
 273 sub get_write_method_ref{
 274     my($self) = @_;
 275     return $self->{_write_method_ref} ||= $self->_get_accessor_method_ref('get_write_method', '_generate_writer');
 276 }
 277
 278 sub set_value {
 279     my($self, $object, $value) = @_;
 280     return $self->get_write_method_ref()->($object, $value);
 281 }
 282
 283 sub get_value {
 284     my($self, $object) = @_;
 285     return $self->get_read_method_ref()->($object);
 286 }
 287
 288 sub has_value {
 289     my($self, $object) = @_;
 290     my $accessor_ref = $self->{_predicate_ref}
 291         ||= $self->_get_accessor_method_ref('predicate', '_generate_predicate');
 292
 293     return $accessor_ref->($object);
 294 }
 295
 296 sub clear_value {
 297     my($self, $object) = @_;
 298     my $accessor_ref = $self->{_crealer_ref}
 299         ||= $self->_get_accessor_method_ref('clearer', '_generate_clearer');
 300
 301     return $accessor_ref->($object);
 302 }
 303
 304
 305 sub associate_method{
 306     #my($attribute, $method_name) = @_;
 307     my($attribute) = @_;
 308     $attribute->{associated_methods}++;
 309     return;
 310 }
 311
 312 sub install_accessors{
 313     my($attribute) = @_;
 314
 315     my $metaclass      = $attribute->associated_class;
 316     my $accessor_class = $attribute->accessor_metaclass;
 317
 318     foreach my $type(qw(accessor reader writer predicate clearer)){
 319         if(exists $attribute->{$type}){
 320             my $generator = '_generate_' . $type;
 321             my $code      = $accessor_class->$generator($attribute, $metaclass);
 322             $metaclass->add_method($attribute->{$type} => $code);
 323             $attribute->associate_method($attribute->{$type});
 324         }
 325     }
 326
 327     # install delegation
 328     if(exists $attribute->{handles}){
 329         my %handles = $attribute->_canonicalize_handles($attribute->{handles});
 330
 331         while(my($handle, $method_to_call) = each %handles){
 332             $metaclass->add_method($handle =>
 333                 $attribute->_make_delegation_method(
 334                     $handle, $method_to_call));
 335
 336             $attribute->associate_method($handle);
 337         }
 338     }
 339
 340     if($attribute->can('create') != \&create){
 341         # backword compatibility
 342         $attribute->create($metaclass, $attribute->name, %{$attribute});
 343     }
 344
 345     return;
 346 }
 347
 348 sub delegation_metaclass() { ## no critic
 349     'Mouse::Meta::Method::Delegation'
 350 }
 351
 352 sub _canonicalize_handles {
 353     my($self, $handles) = @_;
 354
 355     if (ref($handles) eq 'HASH') {
 356         return %$handles;
 357     }
 358     elsif (ref($handles) eq 'ARRAY') {
 359         return map { $_ => $_ } @$handles;
 360     }
 361     elsif ( ref($handles) eq 'CODE' ) {
 362         my $class_or_role = ( $self->{isa} || $self->{does} )
 363             || $self->throw_error( "Cannot find delegate metaclass for attribute " . $self->name );
 364         return $handles->( $self, Mouse::Meta::Class->initialize("$class_or_role"));
 365     }
 366     elsif (ref($handles) eq 'Regexp') {
 367         my $class_or_role = ($self->{isa} || $self->{does})
 368             || $self->throw_error("Cannot delegate methods based on a Regexp without a type constraint (isa)");
 369
 370         my $meta = Mouse::Meta::Class->initialize("$class_or_role"); # "" for stringify
 371         return map  { $_ => $_ }
 372                grep { !Mouse::Object->can($_) && $_ =~ $handles }
 373                    Mouse::Util::is_a_metarole($meta)
 374                         ? $meta->get_method_list
 375                         : $meta->get_all_method_names;
 376     }
 377     else {
 378         $self->throw_error("Unable to canonicalize the 'handles' option with $handles");
 379     }
 380 }
 381
 382 sub _make_delegation_method {
 383     my($self, $handle, $method_to_call) = @_;
 384     return Mouse::Util::load_class($self->delegation_metaclass)
 385         ->_generate_delegation($self, $handle, $method_to_call);
 386 }
 387
 388 sub throw_error{
 389     my $self = shift;
 390
 391     my $metaclass = (ref $self && $self->associated_class) || 'Mouse::Meta::Class';
 392     $metaclass->throw_error(@_, depth => 1);
 393 }
 394
 395 1;
 396 __END__
 397
 398 =head1 NAME
 399
 400 Mouse::Meta::Attribute - The Mouse attribute metaclass
 401
 402 =head1 VERSION
 403
 404 This document describes Mouse version 0.50_08
 405
 406 =head1 METHODS
 407
 408 =head2 C<< new(%options) -> Mouse::Meta::Attribute >>
 409
 410 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 411
 412 It adds the following options to the constructor:
 413
 414 =over 4
 415
 416 =item C<< is => 'ro', 'rw', 'bare' >>
 417
 418 This provides a shorthand for specifying the C<reader>, C<writer>, or
 419 C<accessor> names. If the attribute is read-only ('ro') then it will
 420 have a C<reader> method with the same attribute as the name.
 421
 422 If it is read-write ('rw') then it will have an C<accessor> method
 423 with the same name. If you provide an explicit C<writer> for a
 424 read-write attribute, then you will have a C<reader> with the same
 425 name as the attribute, and a C<writer> with the name you provided.
 426
 427 Use 'bare' when you are deliberately not installing any methods
 428 (accessor, reader, etc.) associated with this attribute; otherwise,
 429 Moose will issue a deprecation warning when this attribute is added to a
 430 metaclass.
 431
 432 =item C<< isa => Type >>
 433
 434 This option accepts a type. The type can be a string, which should be
 435 a type name. If the type name is unknown, it is assumed to be a class
 436 name.
 437
 438 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 439
 440 If you I<also> provide a C<does> option, then your C<isa> option must
 441 be a class name, and that class must do the role specified with
 442 C<does>.
 443
 444 =item C<< does => Role >>
 445
 446 This is short-hand for saying that the attribute's type must be an
 447 object which does the named role.
 448
 449 B<This option is not yet supported.>
 450
 451 =item C<< coerce => Bool >>
 452
 453 This option is only valid for objects with a type constraint
 454 (C<isa>). If this is true, then coercions will be applied whenever
 455 this attribute is set.
 456
 457 You can make both this and the C<weak_ref> option true.
 458
 459 =item C<< trigger => CodeRef >>
 460
 461 This option accepts a subroutine reference, which will be called after
 462 the attribute is set.
 463
 464 =item C<< required => Bool >>
 465
 466 An attribute which is required must be provided to the constructor. An
 467 attribute which is required can also have a C<default> or C<builder>,
 468 which will satisfy its required-ness.
 469
 470 A required attribute must have a C<default>, C<builder> or a
 471 non-C<undef> C<init_arg>
 472
 473 =item C<< lazy => Bool >>
 474
 475 A lazy attribute must have a C<default> or C<builder>. When an
 476 attribute is lazy, the default value will not be calculated until the
 477 attribute is read.
 478
 479 =item C<< weak_ref => Bool >>
 480
 481 If this is true, the attribute's value will be stored as a weak
 482 reference.
 483
 484 =item C<< auto_deref => Bool >>
 485
 486 If this is true, then the reader will dereference the value when it is
 487 called. The attribute must have a type constraint which defines the
 488 attribute as an array or hash reference.
 489
 490 =item C<< lazy_build => Bool >>
 491
 492 Setting this to true makes the attribute lazy and provides a number of
 493 default methods.
 494
 495   has 'size' => (
 496       is         => 'ro',
 497       lazy_build => 1,
 498   );
 499
 500 is equivalent to this:
 501
 502   has 'size' => (
 503       is        => 'ro',
 504       lazy      => 1,
 505       builder   => '_build_size',
 506       clearer   => 'clear_size',
 507       predicate => 'has_size',
 508   );
 509
 510 =back
 511
 512 =head2 C<< associate_method(MethodName) >>
 513
 514 Associates a method with the attribute. Typically, this is called internally
 515 when an attribute generates its accessors.
 516
 517 Currently the argument I<MethodName> is ignored in Mouse.
 518
 519 =head2 C<< verify_against_type_constraint(Item) -> TRUE | ERROR >>
 520
 521 Checks that the given value passes this attribute's type constraint. Returns C<true>
 522 on success, otherwise C<confess>es.
 523
 524 =head2 C<< clone_and_inherit_options(options) -> Mouse::Meta::Attribute >>
 525
 526 Creates a new attribute in the owner class, inheriting options from parent classes.
 527 Accessors and helper methods are installed. Some error checking is done.
 528
 529 =head2 C<< get_read_method_ref >>
 530
 531 =head2 C<< get_write_method_ref >>
 532
 533 Returns the subroutine reference of a method suitable for reading or
 534 writing the attribute's value in the associated class. These methods
 535 always return a subroutine reference, regardless of whether or not the
 536 attribute is read- or write-only.
 537
 538 =head1 SEE ALSO
 539
 540 L<Moose::Meta::Attribute>
 541
 542 L<Class::MOP::Attribute>
 543
 544 =cut
 545