lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use Mouse::Util qw(:meta); # enables strict and warnings
   3
   4 use Carp ();
   5
   6 use Mouse::Meta::TypeConstraint;
   7 use Mouse::Meta::Method::Accessor;
   8
   9
  10 sub _process_options{
  11     my($class, $name, $args) = @_;
  12
  13
  14     # XXX: for backward compatibility (with method modifiers)
  15     if($class->can('canonicalize_args') != \&canonicalize_args){
  16         %{$args} = $class->canonicalize_args($name, %{$args});
  17     }
  18
  19     # taken from Class::MOP::Attribute::new
  20
  21     defined($name)
  22         or $class->throw_error('You must provide a name for the attribute');
  23
  24     if(!exists $args->{init_arg}){
  25         $args->{init_arg} = $name;
  26     }
  27
  28     # 'required' requires eigher 'init_arg', 'builder', or 'default'
  29     my $can_be_required = defined( $args->{init_arg} );
  30
  31     if(exists $args->{builder}){
  32         # XXX:
  33         # Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
  34         # This feature will be changed in a future. (gfx)
  35         $class->throw_error('builder must be a defined scalar value which is a method name')
  36             #if ref $args->{builder} || !defined $args->{builder};
  37             if !defined $args->{builder};
  38
  39         $can_be_required++;
  40     }
  41     elsif(exists $args->{default}){
  42         if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
  43             $class->throw_error("References are not allowed as default values, you must "
  44                               . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
  45         }
  46         $can_be_required++;
  47     }
  48
  49     if( $args->{required} && !$can_be_required ) {
  50         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
  51     }
  52
  53     # taken from Mouse::Meta::Attribute->new and _process_args->
  54
  55     if(exists $args->{is}){
  56         my $is = $args->{is};
  57
  58         if($is eq 'ro'){
  59             $args->{reader} ||= $name;
  60         }
  61         elsif($is eq 'rw'){
  62             if(exists $args->{writer}){
  63                 $args->{reader} ||= $name;
  64              }
  65              else{
  66                 $args->{accessor} ||= $name;
  67              }
  68         }
  69         elsif($is eq 'bare'){
  70             # do nothing, but don't complain (later) about missing methods
  71         }
  72         else{
  73             $is = 'undef' if !defined $is;
  74             $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
  75         }
  76     }
  77
  78     my $tc;
  79     if(exists $args->{isa}){
  80         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
  81     }
  82     elsif(exists $args->{does}){
  83         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
  84     }
  85     $tc = $args->{type_constraint};
  86
  87     if($args->{coerce}){
  88         defined($tc)
  89             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
  90
  91         $args->{weak_ref}
  92             && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
  93     }
  94
  95     if ($args->{lazy_build}) {
  96         exists($args->{default})
  97             && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
  98
  99         $args->{lazy}      = 1;
 100         $args->{builder} ||= "_build_${name}";
 101         if ($name =~ /^_/) {
 102             $args->{clearer}   ||= "_clear${name}";
 103             $args->{predicate} ||= "_has${name}";
 104         }
 105         else {
 106             $args->{clearer}   ||= "clear_${name}";
 107             $args->{predicate} ||= "has_${name}";
 108         }
 109     }
 110
 111     if ($args->{auto_deref}) {
 112         defined($tc)
 113             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
 114
 115         ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
 116             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
 117     }
 118
 119     if (exists $args->{trigger}) {
 120         ('CODE' eq ref $args->{trigger})
 121             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
 122     }
 123
 124     if ($args->{lazy}) {
 125         (exists $args->{default} || defined $args->{builder})
 126             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
 127     }
 128
 129     return;
 130 }
 131
 132 sub new {
 133     my $class = shift;
 134     my $name  = shift;
 135
 136     my %args  = (@_ == 1) ? %{ $_[0] } : @_;
 137
 138     $class->_process_options($name, \%args);
 139
 140     $args{name} = $name;
 141
 142     my $self = bless \%args, $class;
 143
 144     # extra attributes
 145     if($class ne __PACKAGE__){
 146         $class->meta->_initialize_object($self, \%args);
 147     }
 148
 149 # XXX: there is no fast way to check attribute validity
 150 #    my @bad = ...;
 151 #    if(@bad){
 152 #        @bad = sort @bad;
 153 #        Carp::cluck("Found unknown argument(s) passed to '$name' attribute constructor in '$class': @bad");
 154 #    }
 155
 156     return $self;
 157 }
 158
 159 # readers
 160
 161 sub name                 { $_[0]->{name}                   }
 162 sub associated_class     { $_[0]->{associated_class}       }
 163
 164 sub accessor             { $_[0]->{accessor}               }
 165 sub reader               { $_[0]->{reader}                 }
 166 sub writer               { $_[0]->{writer}                 }
 167 sub predicate            { $_[0]->{predicate}              }
 168 sub clearer              { $_[0]->{clearer}                }
 169 sub handles              { $_[0]->{handles}                }
 170
 171 sub _is_metadata         { $_[0]->{is}                     }
 172 sub is_required          { $_[0]->{required}               }
 173 sub default              { $_[0]->{default}                }
 174 sub is_lazy              { $_[0]->{lazy}                   }
 175 sub is_lazy_build        { $_[0]->{lazy_build}             }
 176 sub is_weak_ref          { $_[0]->{weak_ref}               }
 177 sub init_arg             { $_[0]->{init_arg}               }
 178 sub type_constraint      { $_[0]->{type_constraint}        }
 179
 180 sub trigger              { $_[0]->{trigger}                }
 181 sub builder              { $_[0]->{builder}                }
 182 sub should_auto_deref    { $_[0]->{auto_deref}             }
 183 sub should_coerce        { $_[0]->{coerce}                 }
 184
 185 # predicates
 186
 187 sub has_accessor         { exists $_[0]->{accessor}        }
 188 sub has_reader           { exists $_[0]->{reader}          }
 189 sub has_writer           { exists $_[0]->{writer}          }
 190 sub has_predicate        { exists $_[0]->{predicate}       }
 191 sub has_clearer          { exists $_[0]->{clearer}         }
 192 sub has_handles          { exists $_[0]->{handles}         }
 193
 194 sub has_default          { exists $_[0]->{default}         }
 195 sub has_type_constraint  { exists $_[0]->{type_constraint} }
 196 sub has_trigger          { exists $_[0]->{trigger}         }
 197 sub has_builder          { exists $_[0]->{builder}         }
 198
 199 sub has_read_method      { exists $_[0]->{reader} || exists $_[0]->{accessor} }
 200 sub has_write_method     { exists $_[0]->{writer} || exists $_[0]->{accessor} }
 201
 202 sub _create_args { # DEPRECATED
 203     $_[0]->{_create_args} = $_[1] if @_ > 1;
 204     $_[0]->{_create_args}
 205 }
 206
 207 sub interpolate_class{
 208     my($class, $args) = @_;
 209
 210     if(my $metaclass = delete $args->{metaclass}){
 211         $class = Mouse::Util::resolve_metaclass_alias( Attribute => $metaclass );
 212     }
 213
 214     my @traits;
 215     if(my $traits_ref = delete $args->{traits}){
 216
 217         for (my $i = 0; $i < @{$traits_ref}; $i++) {
 218             my $trait = Mouse::Util::resolve_metaclass_alias(Attribute => $traits_ref->[$i], trait => 1);
 219
 220             next if $class->does($trait);
 221
 222             push @traits, $trait;
 223
 224             # are there options?
 225             push @traits, $traits_ref->[++$i]
 226                 if ref($traits_ref->[$i+1]);
 227         }
 228
 229         if (@traits) {
 230             $class = Mouse::Meta::Class->create_anon_class(
 231                 superclasses => [ $class ],
 232                 roles        => \@traits,
 233                 cache        => 1,
 234             )->name;
 235         }
 236     }
 237
 238     return( $class, @traits );
 239 }
 240
 241 sub canonicalize_args{ # DEPRECATED
 242     my ($self, $name, %args) = @_;
 243
 244     Carp::cluck("$self->canonicalize_args has been deprecated."
 245         . "Use \$self->_process_options instead.")
 246             if _MOUSE_VERBOSE;
 247
 248     return %args;
 249 }
 250
 251 sub create {
 252     my ($self, $class, $name, %args) = @_;
 253
 254     Carp::cluck("$self->create has been deprecated."
 255         . "Use \$meta->add_attribute and \$attr->install_accessors instead.")
 256             if _MOUSE_VERBOSE;
 257
 258     # noop
 259     return $self;
 260 }
 261
 262 sub _coerce_and_verify {
 263     my($self, $value, $instance) = @_;
 264
 265     my $type_constraint = $self->{type_constraint};
 266
 267     return $value if !$type_constraint;
 268
 269     if ($self->should_coerce && $type_constraint->has_coercion) {
 270         $value = $type_constraint->coerce($value);
 271     }
 272
 273     return $value if $type_constraint->check($value);
 274
 275     $self->verify_against_type_constraint($value);
 276
 277     return $value;
 278 }
 279
 280 sub verify_against_type_constraint {
 281     my ($self, $value) = @_;
 282
 283     my $type_constraint = $self->{type_constraint};
 284     return 1 if !$type_constraint;;
 285     return 1 if $type_constraint->check($value);
 286
 287     $self->verify_type_constraint_error($self->name, $value, $type_constraint);
 288 }
 289
 290 sub verify_type_constraint_error {
 291     my($self, $name, $value, $type) = @_;
 292     $self->throw_error("Attribute ($name) does not pass the type constraint because: " . $type->get_message($value));
 293 }
 294
 295 sub coerce_constraint { # DEPRECATED
 296     my $type = $_[0]->{type_constraint}
 297         or return $_[1];
 298
 299     Carp::cluck("coerce_constraint() has been deprecated, which was an internal utility anyway");
 300
 301     return Mouse::Util::TypeConstraints->typecast_constraints($_[0]->associated_class->name, $type, $_[1]);
 302 }
 303
 304 sub clone_and_inherit_options{
 305     my($self, %args) = @_;
 306
 307     my($attribute_class, @traits) = ref($self)->interpolate_class(\%args);
 308
 309     $args{traits} = \@traits if @traits;
 310     return $attribute_class->new($self->name, %{$self}, %args);
 311 }
 312
 313 sub clone_parent { # DEPRECATED
 314     my $self  = shift;
 315     my $class = shift;
 316     my $name  = shift;
 317     my %args  = ($self->get_parent_args($class, $name), @_);
 318
 319     Carp::cluck("$self->clone_parent has been deprecated."
 320         . "Use \$meta->add_attribute and \$attr->install_accessors instead.")
 321         if _MOUSE_VERBOSE;
 322
 323     $self->clone_and_inherited_args($class, $name, %args);
 324 }
 325
 326 sub get_parent_args { # DEPRECATED
 327     my $self  = shift;
 328     my $class = shift;
 329     my $name  = shift;
 330
 331     for my $super ($class->linearized_isa) {
 332         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 333             or next;
 334         return %{ $super_attr->_create_args };
 335     }
 336
 337     $self->throw_error("Could not find an attribute by the name of '$name' to inherit from");
 338 }
 339
 340
 341 sub get_read_method { # DEPRECATED
 342     $_[0]->{reader} || $_[0]->{accessor}
 343 }
 344 sub get_write_method { # DEPRECATED
 345     $_[0]->{writer} || $_[0]->{accessor}
 346 }
 347
 348 sub get_read_method_ref{
 349     my($self) = @_;
 350
 351     $self->{_read_method_ref} ||= do{
 352         my $metaclass = $self->associated_class
 353             or $self->throw_error('No asocciated class for ' . $self->name);
 354
 355         my $reader = $self->{reader} || $self->{accessor};
 356         if($reader){
 357             $metaclass->name->can($reader);
 358         }
 359         else{
 360             $self->accessor_metaclass->_generate_reader($self, $metaclass);
 361         }
 362     };
 363 }
 364
 365 sub get_write_method_ref{
 366     my($self) = @_;
 367
 368     $self->{_write_method_ref} ||= do{
 369         my $metaclass = $self->associated_class
 370             or $self->throw_error('No asocciated class for ' . $self->name);
 371
 372         my $reader = $self->{writer} || $self->{accessor};
 373         if($reader){
 374             $metaclass->name->can($reader);
 375         }
 376         else{
 377             $self->accessor_metaclass->_generate_writer($self, $metaclass);
 378         }
 379     };
 380 }
 381
 382 sub _canonicalize_handles {
 383     my($self, $handles) = @_;
 384
 385     if (ref($handles) eq 'HASH') {
 386         return %$handles;
 387     }
 388     elsif (ref($handles) eq 'ARRAY') {
 389         return map { $_ => $_ } @$handles;
 390     }
 391     else {
 392         $self->throw_error("Unable to canonicalize the 'handles' option with $handles");
 393     }
 394 }
 395
 396
 397 sub associate_method{
 398     my ($attribute, $method) = @_;
 399     $attribute->{associated_methods}++;
 400     return;
 401 }
 402
 403 sub accessor_metaclass(){ 'Mouse::Meta::Method::Accessor' }
 404
 405 sub install_accessors{
 406     my($attribute) = @_;
 407
 408     my $metaclass      = $attribute->{associated_class};
 409     my $accessor_class = $attribute->accessor_metaclass;
 410
 411     foreach my $type(qw(accessor reader writer predicate clearer)){
 412         if(exists $attribute->{$type}){
 413             my $generator = '_generate_' . $type;
 414             my $code      = $accessor_class->$generator($attribute, $metaclass);
 415             $metaclass->add_method($attribute->{$type} => $code);
 416             $attribute->associate_method($code);
 417         }
 418     }
 419
 420     # install delegation
 421     if(exists $attribute->{handles}){
 422         my %handles = $attribute->_canonicalize_handles($attribute->{handles});
 423         my $reader  = $attribute->get_read_method_ref;
 424
 425         while(my($handle_name, $method_to_call) = each %handles){
 426             my $code = $accessor_class->_generate_delegation($attribute, $metaclass,
 427                 $reader, $handle_name, $method_to_call);
 428
 429             $metaclass->add_method($handle_name => $code);
 430             $attribute->associate_method($code);
 431         }
 432     }
 433
 434
 435     if($attribute->can('create') != \&create){
 436         # backword compatibility
 437         $attribute->create($metaclass, $attribute->name, %{$attribute});
 438     }
 439
 440     return;
 441 }
 442
 443 sub throw_error{
 444     my $self = shift;
 445
 446     my $metaclass = (ref $self && $self->associated_class) || 'Mouse::Meta::Class';
 447     $metaclass->throw_error(@_, depth => 1);
 448 }
 449
 450 1;
 451
 452 __END__
 453
 454 =head1 NAME
 455
 456 Mouse::Meta::Attribute - The Mouse attribute metaclass
 457
 458 =head1 METHODS
 459
 460 =head2 C<< new(%options) -> Mouse::Meta::Attribute >>
 461
 462 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 463
 464 It adds the following options to the constructor:
 465
 466 =over 4
 467
 468 =item C<< is => 'ro', 'rw', 'bare' >>
 469
 470 This provides a shorthand for specifying the C<reader>, C<writer>, or
 471 C<accessor> names. If the attribute is read-only ('ro') then it will
 472 have a C<reader> method with the same attribute as the name.
 473
 474 If it is read-write ('rw') then it will have an C<accessor> method
 475 with the same name. If you provide an explicit C<writer> for a
 476 read-write attribute, then you will have a C<reader> with the same
 477 name as the attribute, and a C<writer> with the name you provided.
 478
 479 Use 'bare' when you are deliberately not installing any methods
 480 (accessor, reader, etc.) associated with this attribute; otherwise,
 481 Moose will issue a deprecation warning when this attribute is added to a
 482 metaclass.
 483
 484 =item C<< isa => Type >>
 485
 486 This option accepts a type. The type can be a string, which should be
 487 a type name. If the type name is unknown, it is assumed to be a class
 488 name.
 489
 490 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 491
 492 If you I<also> provide a C<does> option, then your C<isa> option must
 493 be a class name, and that class must do the role specified with
 494 C<does>.
 495
 496 =item C<< does => Role >>
 497
 498 This is short-hand for saying that the attribute's type must be an
 499 object which does the named role.
 500
 501 B<This option is not yet supported.>
 502
 503 =item C<< coerce => Bool >>
 504
 505 This option is only valid for objects with a type constraint
 506 (C<isa>). If this is true, then coercions will be applied whenever
 507 this attribute is set.
 508
 509 You can make both this and the C<weak_ref> option true.
 510
 511 =item C<< trigger => CodeRef >>
 512
 513 This option accepts a subroutine reference, which will be called after
 514 the attribute is set.
 515
 516 =item C<< required => Bool >>
 517
 518 An attribute which is required must be provided to the constructor. An
 519 attribute which is required can also have a C<default> or C<builder>,
 520 which will satisfy its required-ness.
 521
 522 A required attribute must have a C<default>, C<builder> or a
 523 non-C<undef> C<init_arg>
 524
 525 =item C<< lazy => Bool >>
 526
 527 A lazy attribute must have a C<default> or C<builder>. When an
 528 attribute is lazy, the default value will not be calculated until the
 529 attribute is read.
 530
 531 =item C<< weak_ref => Bool >>
 532
 533 If this is true, the attribute's value will be stored as a weak
 534 reference.
 535
 536 =item C<< auto_deref => Bool >>
 537
 538 If this is true, then the reader will dereference the value when it is
 539 called. The attribute must have a type constraint which defines the
 540 attribute as an array or hash reference.
 541
 542 =item C<< lazy_build => Bool >>
 543
 544 Setting this to true makes the attribute lazy and provides a number of
 545 default methods.
 546
 547   has 'size' => (
 548       is         => 'ro',
 549       lazy_build => 1,
 550   );
 551
 552 is equivalent to this:
 553
 554   has 'size' => (
 555       is        => 'ro',
 556       lazy      => 1,
 557       builder   => '_build_size',
 558       clearer   => 'clear_size',
 559       predicate => 'has_size',
 560   );
 561
 562 =back
 563
 564 =head2 C<< associate_method(Method) >>
 565
 566 Associates a method with the attribute. Typically, this is called internally
 567 when an attribute generates its accessors.
 568
 569 Currently the argument I<Method> is ignored in Mouse.
 570
 571 =head2 C<< verify_against_type_constraint(Item) -> TRUE | ERROR >>
 572
 573 Checks that the given value passes this attribute's type constraint. Returns C<true>
 574 on success, otherwise C<confess>es.
 575
 576 =head2 C<< clone_and_inherit_options(options) -> Mouse::Meta::Attribute >>
 577
 578 Creates a new attribute in the owner class, inheriting options from parent classes.
 579 Accessors and helper methods are installed. Some error checking is done.
 580
 581 =head2 C<< get_read_method_ref >>\r
 582 \r
 583 =head2 C<< get_write_method_ref >>\r
 584 \r
 585 Returns the subroutine reference of a method suitable for reading or\r
 586 writing the attribute's value in the associated class. These methods\r
 587 always return a subroutine reference, regardless of whether or not the\r
 588 attribute is read- or write-only.
 589
 590 =head1 SEE ALSO
 591
 592 L<Moose::Meta::Attribute>
 593
 594 L<Class::MOP::Attribute>
 595
 596 =cut
 597