lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use Mouse::Util qw(:meta); # enables strict and warnings
   3
   4 use Carp ();
   5
   6 use Mouse::Meta::TypeConstraint;
   7 use Mouse::Meta::Method::Accessor;
   8
   9
  10 sub _process_options{
  11     my($class, $name, $args) = @_;
  12
  13
  14     # XXX: for backward compatibility (with method modifiers)
  15     if($class->can('canonicalize_args') != \&canonicalize_args){
  16         %{$args} = $class->canonicalize_args($name, %{$args});
  17     }
  18
  19     # taken from Class::MOP::Attribute::new
  20
  21     defined($name)
  22         or $class->throw_error('You must provide a name for the attribute');
  23
  24     if(!exists $args->{init_arg}){
  25         $args->{init_arg} = $name;
  26     }
  27
  28     # 'required' requires eigher 'init_arg', 'builder', or 'default'
  29     my $can_be_required = defined( $args->{init_arg} );
  30
  31     if(exists $args->{builder}){
  32         # XXX:
  33         # Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
  34         # This feature will be changed in a future. (gfx)
  35         $class->throw_error('builder must be a defined scalar value which is a method name')
  36             #if ref $args->{builder} || !defined $args->{builder};
  37             if !defined $args->{builder};
  38
  39         $can_be_required++;
  40     }
  41     elsif(exists $args->{default}){
  42         if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
  43             $class->throw_error("References are not allowed as default values, you must "
  44                               . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
  45         }
  46         $can_be_required++;
  47     }
  48
  49     if( $args->{required} && !$can_be_required ) {
  50         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
  51     }
  52
  53     # taken from Mouse::Meta::Attribute->new and _process_args->
  54
  55     if(exists $args->{is}){
  56         my $is = $args->{is};
  57
  58         if($is eq 'ro'){
  59             $args->{reader} ||= $name;
  60         }
  61         elsif($is eq 'rw'){
  62             if(exists $args->{writer}){
  63                 $args->{reader} ||= $name;
  64              }
  65              else{
  66                 $args->{accessor} ||= $name;
  67              }
  68         }
  69         elsif($is eq 'bare'){
  70             # do nothing, but don't complain (later) about missing methods
  71         }
  72         else{
  73             $is = 'undef' if !defined $is;
  74             $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
  75         }
  76     }
  77
  78     my $tc;
  79     if(exists $args->{isa}){
  80         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
  81     }
  82     elsif(exists $args->{does}){
  83         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
  84     }
  85     $tc = $args->{type_constraint};
  86
  87     if($args->{coerce}){
  88         defined($tc)
  89             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
  90
  91         $args->{weak_ref}
  92             && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
  93     }
  94
  95     if ($args->{lazy_build}) {
  96         exists($args->{default})
  97             && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
  98
  99         $args->{lazy}      = 1;
 100         $args->{builder} ||= "_build_${name}";
 101         if ($name =~ /^_/) {
 102             $args->{clearer}   ||= "_clear${name}";
 103             $args->{predicate} ||= "_has${name}";
 104         }
 105         else {
 106             $args->{clearer}   ||= "clear_${name}";
 107             $args->{predicate} ||= "has_${name}";
 108         }
 109     }
 110
 111     if ($args->{auto_deref}) {
 112         defined($tc)
 113             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
 114
 115         ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
 116             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
 117     }
 118
 119     if (exists $args->{trigger}) {
 120         ('CODE' eq ref $args->{trigger})
 121             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
 122     }
 123
 124     if ($args->{lazy}) {
 125         (exists $args->{default} || defined $args->{builder})
 126             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
 127     }
 128
 129     return;
 130 }
 131
 132 sub new {
 133     my $class = shift;
 134     my $name  = shift;
 135
 136     my %args  = (@_ == 1) ? %{ $_[0] } : @_;
 137
 138     $class->_process_options($name, \%args);
 139
 140     $args{name} = $name;
 141
 142     my $self = bless \%args, $class;
 143
 144     # extra attributes
 145     if($class ne __PACKAGE__){
 146         $class->meta->_initialize_object($self, \%args);
 147     }
 148
 149 # XXX: there is no fast way to check attribute validity
 150 #    my @bad = ...;
 151 #    if(@bad){
 152 #        @bad = sort @bad;
 153 #        Carp::cluck("Found unknown argument(s) passed to '$name' attribute constructor in '$class': @bad");
 154 #    }
 155
 156     return $self;
 157 }
 158
 159 sub has_read_method      { $_[0]->has_reader || $_[0]->has_accessor }
 160 sub has_write_method     { $_[0]->has_writer || $_[0]->has_accessor }
 161
 162 sub _create_args { # DEPRECATED
 163     $_[0]->{_create_args} = $_[1] if @_ > 1;
 164     $_[0]->{_create_args}
 165 }
 166
 167 sub interpolate_class{
 168     my($class, $args) = @_;
 169
 170     if(my $metaclass = delete $args->{metaclass}){
 171         $class = Mouse::Util::resolve_metaclass_alias( Attribute => $metaclass );
 172     }
 173
 174     my @traits;
 175     if(my $traits_ref = delete $args->{traits}){
 176
 177         for (my $i = 0; $i < @{$traits_ref}; $i++) {
 178             my $trait = Mouse::Util::resolve_metaclass_alias(Attribute => $traits_ref->[$i], trait => 1);
 179
 180             next if $class->does($trait);
 181
 182             push @traits, $trait;
 183
 184             # are there options?
 185             push @traits, $traits_ref->[++$i]
 186                 if ref($traits_ref->[$i+1]);
 187         }
 188
 189         if (@traits) {
 190             $class = Mouse::Meta::Class->create_anon_class(
 191                 superclasses => [ $class ],
 192                 roles        => \@traits,
 193                 cache        => 1,
 194             )->name;
 195         }
 196     }
 197
 198     return( $class, @traits );
 199 }
 200
 201 sub canonicalize_args{ # DEPRECATED
 202     my ($self, $name, %args) = @_;
 203
 204     Carp::cluck("$self->canonicalize_args has been deprecated."
 205         . "Use \$self->_process_options instead.")
 206             if _MOUSE_VERBOSE;
 207
 208     return %args;
 209 }
 210
 211 sub create { # DEPRECATED
 212     my ($self, $class, $name, %args) = @_;
 213
 214     Carp::cluck("$self->create has been deprecated."
 215         . "Use \$meta->add_attribute and \$attr->install_accessors instead.")
 216             if _MOUSE_VERBOSE;
 217
 218     # noop
 219     return $self;
 220 }
 221
 222 sub _coerce_and_verify {
 223     my($self, $value, $instance) = @_;
 224
 225     my $type_constraint = $self->{type_constraint};
 226     return $value if !defined $type_constraint;
 227
 228     if ($self->should_coerce && $type_constraint->has_coercion) {
 229         $value = $type_constraint->coerce($value);
 230     }
 231
 232     $self->verify_against_type_constraint($value);
 233
 234     return $value;
 235 }
 236
 237 sub verify_against_type_constraint {
 238     my ($self, $value) = @_;
 239
 240     my $type_constraint = $self->{type_constraint};
 241     return 1 if !$type_constraint;
 242     return 1 if $type_constraint->check($value);
 243
 244     $self->verify_type_constraint_error($self->name, $value, $type_constraint);
 245 }
 246
 247 sub verify_type_constraint_error {
 248     my($self, $name, $value, $type) = @_;
 249     $self->throw_error("Attribute ($name) does not pass the type constraint because: "
 250         . $type->get_message($value));
 251 }
 252
 253 sub coerce_constraint { # DEPRECATED
 254     my $type = $_[0]->{type_constraint}
 255         or return $_[1];
 256
 257     Carp::cluck("coerce_constraint() has been deprecated, which was an internal utility anyway");
 258
 259     return Mouse::Util::TypeConstraints->typecast_constraints($_[0]->associated_class->name, $type, $_[1]);
 260 }
 261
 262 sub clone_and_inherit_options{
 263     my($self, %args) = @_;
 264
 265     my($attribute_class, @traits) = ref($self)->interpolate_class(\%args);
 266
 267     $args{traits} = \@traits if @traits;
 268     return $attribute_class->new($self->name, %{$self}, %args);
 269 }
 270
 271 sub clone_parent { # DEPRECATED
 272     my $self  = shift;
 273     my $class = shift;
 274     my $name  = shift;
 275     my %args  = ($self->get_parent_args($class, $name), @_);
 276
 277     Carp::cluck("$self->clone_parent has been deprecated."
 278         . "Use \$meta->add_attribute and \$attr->install_accessors instead.")
 279         if _MOUSE_VERBOSE;
 280
 281     $self->clone_and_inherited_args($class, $name, %args);
 282 }
 283
 284 sub get_parent_args { # DEPRECATED
 285     my $self  = shift;
 286     my $class = shift;
 287     my $name  = shift;
 288
 289     for my $super ($class->linearized_isa) {
 290         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 291             or next;
 292         return %{ $super_attr->_create_args };
 293     }
 294
 295     $self->throw_error("Could not find an attribute by the name of '$name' to inherit from");
 296 }
 297
 298
 299 sub get_read_method {
 300     $_[0]->reader || $_[0]->accessor
 301 }
 302 sub get_write_method {
 303     $_[0]->writer || $_[0]->accessor
 304 }
 305
 306 sub get_read_method_ref{
 307     my($self) = @_;
 308
 309     $self->{_read_method_ref} ||= do{
 310         my $metaclass = $self->associated_class
 311             or $self->throw_error('No asocciated class for ' . $self->name);
 312
 313         my $reader = $self->{reader} || $self->{accessor};
 314         if($reader){
 315             $metaclass->name->can($reader);
 316         }
 317         else{
 318             $self->accessor_metaclass->_generate_reader($self, $metaclass);
 319         }
 320     };
 321 }
 322
 323 sub get_write_method_ref{
 324     my($self) = @_;
 325
 326     $self->{_write_method_ref} ||= do{
 327         my $metaclass = $self->associated_class
 328             or $self->throw_error('No asocciated class for ' . $self->name);
 329
 330         my $reader = $self->{writer} || $self->{accessor};
 331         if($reader){
 332             $metaclass->name->can($reader);
 333         }
 334         else{
 335             $self->accessor_metaclass->_generate_writer($self, $metaclass);
 336         }
 337     };
 338 }
 339
 340 sub _canonicalize_handles {
 341     my($self, $handles) = @_;
 342
 343     if (ref($handles) eq 'HASH') {
 344         return %$handles;
 345     }
 346     elsif (ref($handles) eq 'ARRAY') {
 347         return map { $_ => $_ } @$handles;
 348     }
 349     elsif (ref($handles) eq 'Regexp') {
 350         my $class_or_role = ($self->{isa} || $self->{does})
 351             || $self->throw_error("Cannot delegate methods based on a Regexp without a type constraint (isa)");
 352
 353         my $meta = Mouse::Meta::Class->initialize("$class_or_role"); # "" for stringify
 354         return map  { $_ => $_ }
 355                grep { $_ ne 'meta' && !Mouse::Object->can($_) && $_ =~ $handles }
 356                    $meta->isa('Mouse::Meta::Class') ? $meta->get_all_method_names : $meta->get_method_list;
 357     }
 358     else {
 359         $self->throw_error("Unable to canonicalize the 'handles' option with $handles");
 360     }
 361 }
 362
 363 sub associate_method{
 364     my ($attribute, $method) = @_;
 365     $attribute->{associated_methods}++;
 366     return;
 367 }
 368
 369 sub install_accessors{
 370     my($attribute) = @_;
 371
 372     my $metaclass      = $attribute->associated_class;
 373     my $accessor_class = $attribute->accessor_metaclass;
 374
 375     foreach my $type(qw(accessor reader writer predicate clearer)){
 376         if(exists $attribute->{$type}){
 377             my $generator = '_generate_' . $type;
 378             my $code      = $accessor_class->$generator($attribute, $metaclass);
 379             $metaclass->add_method($attribute->{$type} => $code);
 380             $attribute->associate_method($code);
 381         }
 382     }
 383
 384     # install delegation
 385     if(exists $attribute->{handles}){
 386         my %handles = $attribute->_canonicalize_handles($attribute->{handles});
 387         my $reader  = $attribute->get_read_method_ref;
 388
 389         while(my($handle_name, $method_to_call) = each %handles){
 390             my $code = $accessor_class->_generate_delegation($attribute, $metaclass,
 391                 $reader, $handle_name, $method_to_call);
 392
 393             $metaclass->add_method($handle_name => $code);
 394             $attribute->associate_method($code);
 395         }
 396     }
 397
 398
 399     if($attribute->can('create') != \&create){
 400         # backword compatibility
 401         $attribute->create($metaclass, $attribute->name, %{$attribute});
 402     }
 403
 404     return;
 405 }
 406
 407 sub throw_error{
 408     my $self = shift;
 409
 410     my $metaclass = (ref $self && $self->associated_class) || 'Mouse::Meta::Class';
 411     $metaclass->throw_error(@_, depth => 1);
 412 }
 413
 414 1;
 415
 416 __END__
 417
 418 =head1 NAME
 419
 420 Mouse::Meta::Attribute - The Mouse attribute metaclass
 421
 422 =head1 VERSION
 423
 424 This document describes Mouse version 0.40
 425
 426 =head1 METHODS
 427
 428 =head2 C<< new(%options) -> Mouse::Meta::Attribute >>
 429
 430 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 431
 432 It adds the following options to the constructor:
 433
 434 =over 4
 435
 436 =item C<< is => 'ro', 'rw', 'bare' >>
 437
 438 This provides a shorthand for specifying the C<reader>, C<writer>, or
 439 C<accessor> names. If the attribute is read-only ('ro') then it will
 440 have a C<reader> method with the same attribute as the name.
 441
 442 If it is read-write ('rw') then it will have an C<accessor> method
 443 with the same name. If you provide an explicit C<writer> for a
 444 read-write attribute, then you will have a C<reader> with the same
 445 name as the attribute, and a C<writer> with the name you provided.
 446
 447 Use 'bare' when you are deliberately not installing any methods
 448 (accessor, reader, etc.) associated with this attribute; otherwise,
 449 Moose will issue a deprecation warning when this attribute is added to a
 450 metaclass.
 451
 452 =item C<< isa => Type >>
 453
 454 This option accepts a type. The type can be a string, which should be
 455 a type name. If the type name is unknown, it is assumed to be a class
 456 name.
 457
 458 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 459
 460 If you I<also> provide a C<does> option, then your C<isa> option must
 461 be a class name, and that class must do the role specified with
 462 C<does>.
 463
 464 =item C<< does => Role >>
 465
 466 This is short-hand for saying that the attribute's type must be an
 467 object which does the named role.
 468
 469 B<This option is not yet supported.>
 470
 471 =item C<< coerce => Bool >>
 472
 473 This option is only valid for objects with a type constraint
 474 (C<isa>). If this is true, then coercions will be applied whenever
 475 this attribute is set.
 476
 477 You can make both this and the C<weak_ref> option true.
 478
 479 =item C<< trigger => CodeRef >>
 480
 481 This option accepts a subroutine reference, which will be called after
 482 the attribute is set.
 483
 484 =item C<< required => Bool >>
 485
 486 An attribute which is required must be provided to the constructor. An
 487 attribute which is required can also have a C<default> or C<builder>,
 488 which will satisfy its required-ness.
 489
 490 A required attribute must have a C<default>, C<builder> or a
 491 non-C<undef> C<init_arg>
 492
 493 =item C<< lazy => Bool >>
 494
 495 A lazy attribute must have a C<default> or C<builder>. When an
 496 attribute is lazy, the default value will not be calculated until the
 497 attribute is read.
 498
 499 =item C<< weak_ref => Bool >>
 500
 501 If this is true, the attribute's value will be stored as a weak
 502 reference.
 503
 504 =item C<< auto_deref => Bool >>
 505
 506 If this is true, then the reader will dereference the value when it is
 507 called. The attribute must have a type constraint which defines the
 508 attribute as an array or hash reference.
 509
 510 =item C<< lazy_build => Bool >>
 511
 512 Setting this to true makes the attribute lazy and provides a number of
 513 default methods.
 514
 515   has 'size' => (
 516       is         => 'ro',
 517       lazy_build => 1,
 518   );
 519
 520 is equivalent to this:
 521
 522   has 'size' => (
 523       is        => 'ro',
 524       lazy      => 1,
 525       builder   => '_build_size',
 526       clearer   => 'clear_size',
 527       predicate => 'has_size',
 528   );
 529
 530 =back
 531
 532 =head2 C<< associate_method(Method) >>
 533
 534 Associates a method with the attribute. Typically, this is called internally
 535 when an attribute generates its accessors.
 536
 537 Currently the argument I<Method> is ignored in Mouse.
 538
 539 =head2 C<< verify_against_type_constraint(Item) -> TRUE | ERROR >>
 540
 541 Checks that the given value passes this attribute's type constraint. Returns C<true>
 542 on success, otherwise C<confess>es.
 543
 544 =head2 C<< clone_and_inherit_options(options) -> Mouse::Meta::Attribute >>
 545
 546 Creates a new attribute in the owner class, inheriting options from parent classes.
 547 Accessors and helper methods are installed. Some error checking is done.
 548
 549 =head2 C<< get_read_method_ref >>
 550
 551 =head2 C<< get_write_method_ref >>
 552
 553 Returns the subroutine reference of a method suitable for reading or
 554 writing the attribute's value in the associated class. These methods
 555 always return a subroutine reference, regardless of whether or not the
 556 attribute is read- or write-only.
 557
 558 =head1 SEE ALSO
 559
 560 L<Moose::Meta::Attribute>
 561
 562 L<Class::MOP::Attribute>
 563
 564 =cut
 565