lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use strict;
   3 use warnings;
   4
   5 use Carp ();
   6
   7 use Mouse::Util qw(:meta);
   8
   9 use Mouse::Meta::TypeConstraint;
  10 use Mouse::Meta::Method::Accessor;
  11
  12 sub _process_options{
  13     my($class, $name, $args) = @_;
  14
  15
  16     # XXX: for backward compatibility (with method modifiers)
  17     if($class->can('canonicalize_args') != \&canonicalize_args){
  18         %{$args} = $class->canonicalize_args($name, %{$args});
  19     }
  20
  21     # taken from Class::MOP::Attribute::new
  22
  23     defined($name)
  24         or $class->throw_error('You must provide a name for the attribute');
  25
  26     if(!exists $args->{init_arg}){
  27         $args->{init_arg} = $name;
  28     }
  29
  30     # 'required' requires eigher 'init_arg', 'builder', or 'default'
  31     my $can_be_required = defined( $args->{init_arg} );
  32
  33     if(exists $args->{builder}){
  34         # XXX:
  35         # Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
  36         # This feature will be changed in a future. (gfx)
  37         $class->throw_error('builder must be a defined scalar value which is a method name')
  38             #if ref $args->{builder} || !defined $args->{builder};
  39             if !defined $args->{builder};
  40
  41         $can_be_required++;
  42     }
  43     elsif(exists $args->{default}){
  44         if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
  45             $class->throw_error("References are not allowed as default values, you must "
  46                               . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
  47         }
  48         $can_be_required++;
  49     }
  50
  51     if( $args->{required} && !$can_be_required ) {
  52         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
  53     }
  54
  55     # taken from Mouse::Meta::Attribute->new and _process_args->
  56
  57     if(exists $args->{is}){
  58         my $is = $args->{is};
  59
  60         if($is eq 'ro'){
  61             $args->{reader} ||= $name;
  62         }
  63         elsif($is eq 'rw'){
  64             if(exists $args->{writer}){
  65                 $args->{reader} ||= $name;
  66              }
  67              else{
  68                 $args->{accessor} ||= $name;
  69              }
  70         }
  71         elsif($is eq 'bare'){
  72             # do nothing, but don't complain (later) about missing methods
  73         }
  74         else{
  75             $is = 'undef' if !defined $is;
  76             $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
  77         }
  78     }
  79
  80     my $tc;
  81     if(exists $args->{isa}){
  82         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
  83     }
  84     elsif(exists $args->{does}){
  85         # TODO
  86         # $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
  87     }
  88     $tc = $args->{type_constraint};
  89
  90     if($args->{coerce}){
  91         defined($tc)
  92             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
  93
  94         $args->{weak_ref}
  95             && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
  96     }
  97
  98     if ($args->{lazy_build}) {
  99         exists($args->{default})
 100             && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
 101
 102         $args->{lazy}      = 1;
 103         $args->{builder} ||= "_build_${name}";
 104         if ($name =~ /^_/) {
 105             $args->{clearer}   ||= "_clear${name}";
 106             $args->{predicate} ||= "_has${name}";
 107         }
 108         else {
 109             $args->{clearer}   ||= "clear_${name}";
 110             $args->{predicate} ||= "has_${name}";
 111         }
 112     }
 113
 114     if ($args->{auto_deref}) {
 115         defined($tc)
 116             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
 117
 118         ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
 119             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
 120     }
 121
 122     if (exists $args->{trigger}) {
 123         ('CODE' eq ref $args->{trigger})
 124             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
 125     }
 126
 127     if ($args->{lazy}) {
 128         (exists $args->{default} || defined $args->{builder})
 129             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
 130     }
 131
 132     return;
 133 }
 134
 135 sub new {
 136     my $class = shift;
 137     my $name  = shift;
 138
 139     my %args  = (@_ == 1) ? %{ $_[0] } : @_;
 140
 141     $class->_process_options($name, \%args);
 142
 143     $args{name} = $name;
 144
 145     my $self = bless \%args, $class;
 146
 147     # extra attributes
 148     if($class ne __PACKAGE__){
 149         $class->meta->_initialize_object($self, \%args);
 150     }
 151
 152 # XXX: there is no fast way to check attribute validity
 153 #    my @bad = ...;
 154 #    if(@bad){
 155 #        @bad = sort @bad;
 156 #        Carp::cluck("Found unknown argument(s) passed to '$name' attribute constructor in '$class': @bad");
 157 #    }
 158
 159     return $self;
 160 }
 161
 162 # readers
 163
 164 sub name                 { $_[0]->{name}                   }
 165 sub associated_class     { $_[0]->{associated_class}       }
 166
 167 sub accessor             { $_[0]->{accessor}               }
 168 sub reader               { $_[0]->{reader}                 }
 169 sub writer               { $_[0]->{writer}                 }
 170 sub predicate            { $_[0]->{predicate}              }
 171 sub clearer              { $_[0]->{clearer}                }
 172 sub handles              { $_[0]->{handles}                }
 173
 174 sub _is_metadata         { $_[0]->{is}                     }
 175 sub is_required          { $_[0]->{required}               }
 176 sub default              { $_[0]->{default}                }
 177 sub is_lazy              { $_[0]->{lazy}                   }
 178 sub is_lazy_build        { $_[0]->{lazy_build}             }
 179 sub is_weak_ref          { $_[0]->{weak_ref}               }
 180 sub init_arg             { $_[0]->{init_arg}               }
 181 sub type_constraint      { $_[0]->{type_constraint}        }
 182
 183 sub trigger              { $_[0]->{trigger}                }
 184 sub builder              { $_[0]->{builder}                }
 185 sub should_auto_deref    { $_[0]->{auto_deref}             }
 186 sub should_coerce        { $_[0]->{coerce}                 }
 187
 188 # predicates
 189
 190 sub has_accessor         { exists $_[0]->{accessor}        }
 191 sub has_reader           { exists $_[0]->{reader}          }
 192 sub has_writer           { exists $_[0]->{writer}          }
 193 sub has_predicate        { exists $_[0]->{predicate}       }
 194 sub has_clearer          { exists $_[0]->{clearer}         }
 195 sub has_handles          { exists $_[0]->{handles}         }
 196
 197 sub has_default          { exists $_[0]->{default}         }
 198 sub has_type_constraint  { exists $_[0]->{type_constraint} }
 199 sub has_trigger          { exists $_[0]->{trigger}         }
 200 sub has_builder          { exists $_[0]->{builder}         }
 201
 202 sub has_read_method      { exists $_[0]->{reader} || exists $_[0]->{accessor} }
 203 sub has_write_method     { exists $_[0]->{writer} || exists $_[0]->{accessor} }
 204
 205 sub _create_args { # DEPRECATED
 206     $_[0]->{_create_args} = $_[1] if @_ > 1;
 207     $_[0]->{_create_args}
 208 }
 209
 210 sub interpolate_class{
 211     my($class, $args) = @_;
 212
 213     if(my $metaclass = delete $args->{metaclass}){
 214         $class = Mouse::Util::resolve_metaclass_alias( Attribute => $metaclass );
 215     }
 216
 217     my @traits;
 218     if(my $traits_ref = delete $args->{traits}){
 219
 220         for (my $i = 0; $i < @{$traits_ref}; $i++) {
 221             my $trait = Mouse::Util::resolve_metaclass_alias(Attribute => $traits_ref->[$i], trait => 1);
 222
 223             next if $class->does($trait);
 224
 225             push @traits, $trait;
 226
 227             # are there options?
 228             push @traits, $traits_ref->[++$i]
 229                 if ref($traits_ref->[$i+1]);
 230         }
 231
 232         if (@traits) {
 233             $class = Mouse::Meta::Class->create_anon_class(
 234                 superclasses => [ $class ],
 235                 roles        => \@traits,
 236                 cache        => 1,
 237             )->name;
 238         }
 239     }
 240
 241     return( $class, @traits );
 242 }
 243
 244 sub canonicalize_args{ # DEPRECATED
 245     my ($self, $name, %args) = @_;
 246
 247     Carp::cluck("$self->canonicalize_args has been deprecated."
 248         . "Use \$self->_process_options instead.")
 249             if _MOUSE_VERBOSE;
 250
 251     return %args;
 252 }
 253
 254 sub create {
 255     my ($self, $class, $name, %args) = @_;
 256
 257     Carp::cluck("$self->create has been deprecated."
 258         . "Use \$meta->add_attribute and \$attr->install_accessors instead.")
 259             if _MOUSE_VERBOSE;
 260
 261     # noop
 262     return $self;
 263 }
 264
 265 sub _coerce_and_verify {
 266     my($self, $value, $instance) = @_;
 267
 268     my $type_constraint = $self->{type_constraint};
 269
 270     return $value if !$type_constraint;
 271
 272     if ($self->should_coerce && $type_constraint->has_coercion) {
 273         $value = $type_constraint->coerce($value);
 274     }
 275
 276     return $value if $type_constraint->check($value);
 277
 278     $self->verify_against_type_constraint($value);
 279
 280     return $value;
 281 }
 282
 283 sub verify_against_type_constraint {
 284     my ($self, $value) = @_;
 285
 286     my $type_constraint = $self->{type_constraint};
 287     return 1 if !$type_constraint;;
 288     return 1 if $type_constraint->check($value);
 289
 290     $self->verify_type_constraint_error($self->name, $value, $type_constraint);
 291 }
 292
 293 sub verify_type_constraint_error {
 294     my($self, $name, $value, $type) = @_;
 295     $self->throw_error("Attribute ($name) does not pass the type constraint because: " . $type->get_message($value));
 296 }
 297
 298 sub coerce_constraint { # DEPRECATED
 299     my $type = $_[0]->{type_constraint}
 300         or return $_[1];
 301
 302     Carp::cluck("coerce_constraint() has been deprecated, which was an internal utility anyway");
 303
 304     return Mouse::Util::TypeConstraints->typecast_constraints($_[0]->associated_class->name, $type, $_[1]);
 305 }
 306
 307 sub _canonicalize_handles {
 308     my $self    = shift;
 309     my $handles = shift;
 310
 311     if (ref($handles) eq 'HASH') {
 312         return %$handles;
 313     }
 314     elsif (ref($handles) eq 'ARRAY') {
 315         return map { $_ => $_ } @$handles;
 316     }
 317     else {
 318         $self->throw_error("Unable to canonicalize the 'handles' option with $handles");
 319     }
 320 }
 321
 322 sub clone_and_inherit_options{
 323     my($self, %args) = @_;
 324
 325     my($attribute_class, @traits) = ref($self)->interpolate_class(\%args);
 326
 327     $args{traits} = \@traits if @traits;
 328     return $attribute_class->new($self->name, %{$self}, %args);
 329 }
 330
 331 sub clone_parent { # DEPRECATED
 332     my $self  = shift;
 333     my $class = shift;
 334     my $name  = shift;
 335     my %args  = ($self->get_parent_args($class, $name), @_);
 336
 337     Carp::cluck("$self->clone_parent has been deprecated."
 338         . "Use \$meta->add_attribute and \$attr->install_accessors instead.")
 339         if _MOUSE_VERBOSE;
 340
 341     $self->clone_and_inherited_args($class, $name, %args);
 342 }
 343
 344 sub get_parent_args { # DEPRECATED
 345     my $self  = shift;
 346     my $class = shift;
 347     my $name  = shift;
 348
 349     for my $super ($class->linearized_isa) {
 350         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 351             or next;
 352         return %{ $super_attr->_create_args };
 353     }
 354
 355     $self->throw_error("Could not find an attribute by the name of '$name' to inherit from");
 356 }
 357
 358
 359 sub get_read_method { # DEPRECATED
 360     $_[0]->{reader} || $_[0]->{accessor}
 361 }
 362 sub get_write_method { # DEPRECATED
 363     $_[0]->{writer} || $_[0]->{accessor}
 364 }
 365
 366 sub get_read_method_ref{
 367     my($self) = @_;
 368
 369     $self->{_read_method_ref} ||= do{
 370         my $metaclass = $self->associated_class
 371             or $self->throw_error('No asocciated class for ' . $self->name);
 372
 373         my $reader = $self->{reader} || $self->{accessor};
 374         if($reader){
 375             $metaclass->name->can($reader);
 376         }
 377         else{
 378             Mouse::Meta::Method::Accessor->_generate_reader($self, undef, $metaclass);
 379         }
 380     };
 381 }
 382
 383 sub get_write_method_ref{
 384     my($self) = @_;
 385
 386     $self->{_write_method_ref} ||= do{
 387         my $metaclass = $self->associated_class
 388             or $self->throw_error('No asocciated class for ' . $self->name);
 389
 390         my $reader = $self->{writer} || $self->{accessor};
 391         if($reader){
 392             $metaclass->name->can($reader);
 393         }
 394         else{
 395             Mouse::Meta::Method::Accessor->_generate_writer($self, undef, $metaclass);
 396         }
 397     };
 398 }
 399
 400 sub associate_method{
 401     my ($attribute, $method) = @_;
 402     $attribute->{associated_methods}++;
 403     return;
 404 }
 405
 406 sub install_accessors{
 407     my($attribute) = @_;
 408
 409     my $metaclass       = $attribute->{associated_class};
 410
 411     foreach my $type(qw(accessor reader writer predicate clearer handles)){
 412         if(exists $attribute->{$type}){
 413             my $installer    = '_generate_' . $type;
 414
 415             Mouse::Meta::Method::Accessor->$installer($attribute, $attribute->{$type}, $metaclass);
 416
 417             $attribute->{associated_methods}++;
 418         }
 419     }
 420
 421     if($attribute->can('create') != \&create){
 422         # backword compatibility
 423         $attribute->create($metaclass, $attribute->name, %{$attribute});
 424     }
 425
 426     return;
 427 }
 428
 429 sub throw_error{
 430     my $self = shift;
 431
 432     my $metaclass = (ref $self && $self->associated_class) || 'Mouse::Meta::Class';
 433     $metaclass->throw_error(@_, depth => 1);
 434 }
 435
 436 1;
 437
 438 __END__
 439
 440 =head1 NAME
 441
 442 Mouse::Meta::Attribute - The Mouse attribute metaclass
 443
 444 =head1 METHODS
 445
 446 =head2 C<< new(%options) -> Mouse::Meta::Attribute >>
 447
 448 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 449
 450 It adds the following options to the constructor:
 451
 452 =over 4
 453
 454 =item C<< is => 'ro', 'rw', 'bare' >>
 455
 456 This provides a shorthand for specifying the C<reader>, C<writer>, or
 457 C<accessor> names. If the attribute is read-only ('ro') then it will
 458 have a C<reader> method with the same attribute as the name.
 459
 460 If it is read-write ('rw') then it will have an C<accessor> method
 461 with the same name. If you provide an explicit C<writer> for a
 462 read-write attribute, then you will have a C<reader> with the same
 463 name as the attribute, and a C<writer> with the name you provided.
 464
 465 Use 'bare' when you are deliberately not installing any methods
 466 (accessor, reader, etc.) associated with this attribute; otherwise,
 467 Moose will issue a deprecation warning when this attribute is added to a
 468 metaclass.
 469
 470 =item C<< isa => Type >>
 471
 472 This option accepts a type. The type can be a string, which should be
 473 a type name. If the type name is unknown, it is assumed to be a class
 474 name.
 475
 476 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 477
 478 If you I<also> provide a C<does> option, then your C<isa> option must
 479 be a class name, and that class must do the role specified with
 480 C<does>.
 481
 482 =item C<< does => Role >>
 483
 484 This is short-hand for saying that the attribute's type must be an
 485 object which does the named role.
 486
 487 B<This option is not yet supported.>
 488
 489 =item C<< coerce => Bool >>
 490
 491 This option is only valid for objects with a type constraint
 492 (C<isa>). If this is true, then coercions will be applied whenever
 493 this attribute is set.
 494
 495 You can make both this and the C<weak_ref> option true.
 496
 497 =item C<< trigger => CodeRef >>
 498
 499 This option accepts a subroutine reference, which will be called after
 500 the attribute is set.
 501
 502 =item C<< required => Bool >>
 503
 504 An attribute which is required must be provided to the constructor. An
 505 attribute which is required can also have a C<default> or C<builder>,
 506 which will satisfy its required-ness.
 507
 508 A required attribute must have a C<default>, C<builder> or a
 509 non-C<undef> C<init_arg>
 510
 511 =item C<< lazy => Bool >>
 512
 513 A lazy attribute must have a C<default> or C<builder>. When an
 514 attribute is lazy, the default value will not be calculated until the
 515 attribute is read.
 516
 517 =item C<< weak_ref => Bool >>
 518
 519 If this is true, the attribute's value will be stored as a weak
 520 reference.
 521
 522 =item C<< auto_deref => Bool >>
 523
 524 If this is true, then the reader will dereference the value when it is
 525 called. The attribute must have a type constraint which defines the
 526 attribute as an array or hash reference.
 527
 528 =item C<< lazy_build => Bool >>
 529
 530 Setting this to true makes the attribute lazy and provides a number of
 531 default methods.
 532
 533   has 'size' => (
 534       is         => 'ro',
 535       lazy_build => 1,
 536   );
 537
 538 is equivalent to this:
 539
 540   has 'size' => (
 541       is        => 'ro',
 542       lazy      => 1,
 543       builder   => '_build_size',
 544       clearer   => 'clear_size',
 545       predicate => 'has_size',
 546   );
 547
 548 =back
 549
 550 =head2 C<< associate_method(Method) >>
 551
 552 Associates a method with the attribute. Typically, this is called internally
 553 when an attribute generates its accessors.
 554
 555 Currently the argument I<Method> is ignored in Mouse.
 556
 557 =head2 C<< verify_against_type_constraint(Item) -> TRUE | ERROR >>
 558
 559 Checks that the given value passes this attribute's type constraint. Returns C<true>
 560 on success, otherwise C<confess>es.
 561
 562 =head2 C<< clone_and_inherit_options(options) -> Mouse::Meta::Attribute >>
 563
 564 Creates a new attribute in the owner class, inheriting options from parent classes.
 565 Accessors and helper methods are installed. Some error checking is done.
 566
 567 =head2 C<< get_read_method_ref >>\r
 568 \r
 569 =head2 C<< get_write_method_ref >>\r
 570 \r
 571 Returns the subroutine reference of a method suitable for reading or\r
 572 writing the attribute's value in the associated class. These methods\r
 573 always return a subroutine reference, regardless of whether or not the\r
 574 attribute is read- or write-only.
 575
 576 =head1 SEE ALSO
 577
 578 L<Moose::Meta::Attribute>
 579
 580 L<Class::MOP::Attribute>
 581
 582 =cut
 583