lib/Mouse/Meta/Attribute.pm

   1 #!/usr/bin/env perl
   2 package Mouse::Meta::Attribute;
   3 use strict;
   4 use warnings;
   5 require overload;
   6
   7 use Carp 'confess';
   8 require Mouse::Util;
   9
  10 sub new {
  11     my $class = shift;
  12     my %args  = @_;
  13
  14     my $name = $args{name};
  15
  16     $args{init_arg} = $name
  17         unless exists $args{init_arg};
  18
  19     $args{is} ||= '';
  20
  21     bless \%args, $class;
  22 }
  23
  24 sub name              { $_[0]->{name}             }
  25 sub associated_class  { $_[0]->{associated_class} }
  26 sub _is_metadata      { $_[0]->{is}               }
  27 sub is_required       { $_[0]->{required}         }
  28 sub default           { $_[0]->{default}          }
  29 sub is_lazy           { $_[0]->{lazy}             }
  30 sub is_lazy_build     { $_[0]->{lazy_build}       }
  31 sub predicate         { $_[0]->{predicate}        }
  32 sub clearer           { $_[0]->{clearer}          }
  33 sub handles           { $_[0]->{handles}          }
  34 sub is_weak_ref       { $_[0]->{weak_ref}         }
  35 sub init_arg          { $_[0]->{init_arg}         }
  36 sub type_constraint   { $_[0]->{type_constraint}  }
  37 sub trigger           { $_[0]->{trigger}          }
  38 sub builder           { $_[0]->{builder}          }
  39 sub should_auto_deref { $_[0]->{auto_deref}       }
  40 sub should_coerce     { $_[0]->{should_coerce}    }
  41
  42 sub has_default         { exists $_[0]->{default}         }
  43 sub has_predicate       { exists $_[0]->{predicate}       }
  44 sub has_clearer         { exists $_[0]->{clearer}         }
  45 sub has_handles         { exists $_[0]->{handles}         }
  46 sub has_type_constraint { exists $_[0]->{type_constraint} }
  47 sub has_trigger         { exists $_[0]->{trigger}         }
  48 sub has_builder         { exists $_[0]->{builder}         }
  49
  50 sub find_type_constraint      { $_[0]->{find_type_constraint}  }
  51 sub type_constraint_as_string {
  52     ref($_[0]->{type_constraint}) eq 'ARRAY' ? join '|', @{ $_[0]->{type_constraint} } : $_[0]->{type_constraint}
  53 }
  54
  55 sub _create_args {
  56     $_[0]->{_create_args} = $_[1] if @_ > 1;
  57     $_[0]->{_create_args}
  58 }
  59
  60 sub inlined_name {
  61     my $self = shift;
  62     my $name = $self->name;
  63     my $key   = "'" . $name . "'";
  64     return $key;
  65 }
  66
  67 sub generate_accessor {
  68     my $attribute = shift;
  69
  70     my $name          = $attribute->name;
  71     my $default       = $attribute->default;
  72     my $type          = $attribute->type_constraint_as_string;
  73     my $constraint    = $attribute->find_type_constraint;
  74     my $builder       = $attribute->builder;
  75     my $trigger       = $attribute->trigger;
  76     my $is_weak       = $attribute->is_weak_ref;
  77     my $should_deref  = $attribute->should_auto_deref;
  78     my $should_coerce = $attribute->should_coerce;
  79
  80     my $self  = '$_[0]';
  81     my $key   = $attribute->inlined_name;
  82
  83     my $accessor = "sub {\n";
  84     if ($attribute->_is_metadata eq 'rw') {
  85         $accessor .= 'if (scalar(@_) >= 2) {' . "\n";
  86
  87         my $value = '$_[1]';
  88
  89         if ($constraint) {
  90             $accessor .= 'my $val = ';
  91             if ($should_coerce) {
  92                 $accessor .= '$attribute->coerce_constraint('.$value.');';
  93             } else {
  94                 $accessor .= $value.';';
  95             }
  96             $accessor .= 'local $_ = $val;';
  97             $accessor .= '
  98                 unless ($constraint->()) {
  99                     my $display = defined($_) ? overload::StrVal($_) : "undef";
 100                     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
 101             }' . "\n";
 102             $value = '$val';
 103         }
 104
 105         # if there's nothing left to do for the attribute we can return during
 106         # this setter
 107         $accessor .= 'return ' if !$is_weak && !$trigger && !$should_deref;
 108
 109         $accessor .= $self.'->{'.$key.'} = '.$value.';' . "\n";
 110
 111         if ($is_weak) {
 112             $accessor .= 'Mouse::Util::weaken('.$self.'->{'.$key.'}) if ref('.$self.'->{'.$key.'});' . "\n";
 113         }
 114
 115         if ($trigger) {
 116             $accessor .= '$trigger->('.$self.', '.$value.', $attribute);' . "\n";
 117         }
 118
 119         $accessor .= "}\n";
 120     }
 121     else {
 122         $accessor .= 'confess "Cannot assign a value to a read-only accessor" if scalar(@_) >= 2;' . "\n";
 123     }
 124
 125     if ($attribute->is_lazy) {
 126         $accessor .= $self.'->{'.$key.'} = ';
 127
 128         $accessor .= $attribute->has_builder
 129                 ? $self.'->$builder'
 130                     : ref($default) eq 'CODE'
 131                     ? '$default->('.$self.')'
 132                     : '$default';
 133         $accessor .= ' if !exists '.$self.'->{'.$key.'};' . "\n";
 134     }
 135
 136     if ($should_deref) {
 137         my $type_constraint = $attribute->type_constraint;
 138         if (!ref($type_constraint) && $type_constraint eq 'ArrayRef') {
 139             $accessor .= 'if (wantarray) {
 140                 return @{ '.$self.'->{'.$key.'} || [] };
 141             }';
 142         }
 143         else {
 144             $accessor .= 'if (wantarray) {
 145                 return %{ '.$self.'->{'.$key.'} || {} };
 146             }';
 147         }
 148     }
 149
 150     $accessor .= 'return '.$self.'->{'.$key.'};
 151     }';
 152
 153     my $sub = eval $accessor;
 154     confess $@ if $@;
 155     return $sub;
 156 }
 157
 158 sub generate_predicate {
 159     my $attribute = shift;
 160     my $key = $attribute->inlined_name;
 161
 162     my $predicate = 'sub { exists($_[0]->{'.$key.'}) }';
 163
 164     my $sub = eval $predicate;
 165     confess $@ if $@;
 166     return $sub;
 167 }
 168
 169 sub generate_clearer {
 170     my $attribute = shift;
 171     my $key = $attribute->inlined_name;
 172
 173     my $clearer = 'sub { delete($_[0]->{'.$key.'}) }';
 174
 175     my $sub = eval $clearer;
 176     confess $@ if $@;
 177     return $sub;
 178 }
 179
 180 sub generate_handles {
 181     my $attribute = shift;
 182     my $reader = $attribute->name;
 183     my %handles = $attribute->_canonicalize_handles($attribute->handles);
 184
 185     my %method_map;
 186
 187     for my $local_method (keys %handles) {
 188         my $remote_method = $handles{$local_method};
 189
 190         my $method = 'sub {
 191             my $self = shift;
 192             $self->$reader->$remote_method(@_)
 193         }';
 194
 195         $method_map{$local_method} = eval $method;
 196         confess $@ if $@;
 197     }
 198
 199     return \%method_map;
 200 }
 201
 202 sub create {
 203     my ($self, $class, $name, %args) = @_;
 204
 205     $args{name} = $name;
 206     $args{associated_class} = $class;
 207
 208     %args = $self->canonicalize_args($name, %args);
 209     $self->validate_args($name, \%args);
 210
 211     $args{should_coerce} = delete $args{coerce}
 212         if exists $args{coerce};
 213
 214     if (exists $args{isa}) {
 215         my $type_constraint = delete $args{isa};
 216         $type_constraint =~ s/\s//g;
 217         my @type_constraints = split /\|/, $type_constraint;
 218
 219         my $code;
 220         my $optimized_constraints = Mouse::TypeRegistry->optimized_constraints;
 221         if (@type_constraints == 1) {
 222             $code = $optimized_constraints->{$type_constraints[0]} ||
 223                 sub { Mouse::Util::blessed($_) && Mouse::Util::blessed($_) eq $type_constraints[0] };
 224             $args{type_constraint} = $type_constraints[0];
 225         } else {
 226             my @code_list = map {
 227                 my $type = $_;
 228                 $optimized_constraints->{$type} ||
 229                     sub { Mouse::Util::blessed($_) && Mouse::Util::blessed($_) eq $type }
 230             } @type_constraints;
 231             $code = sub {
 232                 for my $code (@code_list) {
 233                     return 1 if $code->();
 234                 }
 235                 return 0;
 236             };
 237             $args{type_constraint} = \@type_constraints;
 238         }
 239         $args{find_type_constraint} = $code;
 240     }
 241
 242     my $attribute = $self->new(%args);
 243
 244     $attribute->_create_args(\%args);
 245
 246     $class->add_attribute($attribute);
 247
 248     # install an accessor
 249     if ($attribute->_is_metadata eq 'rw' || $attribute->_is_metadata eq 'ro') {
 250         my $accessor = $attribute->generate_accessor;
 251         $class->add_method($name => $accessor);
 252     }
 253
 254     for my $method (qw/predicate clearer/) {
 255         my $predicate = "has_$method";
 256         if ($attribute->$predicate) {
 257             my $generator = "generate_$method";
 258             my $coderef = $attribute->$generator;
 259             $class->add_method($attribute->$method => $coderef);
 260         }
 261     }
 262
 263     if ($attribute->has_handles) {
 264         my $method_map = $attribute->generate_handles;
 265         for my $method_name (keys %$method_map) {
 266             $class->add_method($method_name => $method_map->{$method_name});
 267         }
 268     }
 269
 270     return $attribute;
 271 }
 272
 273 sub canonicalize_args {
 274     my $self = shift;
 275     my $name = shift;
 276     my %args = @_;
 277
 278     if ($args{lazy_build}) {
 279         $args{lazy}      = 1;
 280         $args{required}  = 1;
 281         $args{builder}   = "_build_${name}"
 282             if !exists($args{builder});
 283         if ($name =~ /^_/) {
 284             $args{clearer}   = "_clear${name}" if !exists($args{clearer});
 285             $args{predicate} = "_has${name}" if !exists($args{predicate});
 286         }
 287         else {
 288             $args{clearer}   = "clear_${name}" if !exists($args{clearer});
 289             $args{predicate} = "has_${name}" if !exists($args{predicate});
 290         }
 291     }
 292
 293     return %args;
 294 }
 295
 296 sub validate_args {
 297     my $self = shift;
 298     my $name = shift;
 299     my $args = shift;
 300
 301     confess "You can not use lazy_build and default for the same attribute ($name)"
 302         if $args->{lazy_build} && exists $args->{default};
 303
 304     confess "You cannot have lazy attribute ($name) without specifying a default value for it"
 305         if $args->{lazy}
 306         && !exists($args->{default})
 307         && !exists($args->{builder});
 308
 309     confess "References are not allowed as default values, you must wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])"
 310         if ref($args->{default})
 311         && ref($args->{default}) ne 'CODE';
 312
 313     confess "You cannot auto-dereference without specifying a type constraint on attribute ($name)"
 314         if $args->{auto_deref} && !exists($args->{isa});
 315
 316     confess "You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)"
 317         if $args->{auto_deref}
 318         && $args->{isa} ne 'ArrayRef'
 319         && $args->{isa} ne 'HashRef';
 320
 321     if ($args->{trigger}) {
 322         if (ref($args->{trigger}) eq 'HASH') {
 323             Carp::carp "HASH-based form of trigger has been removed. Only the coderef form of triggers are now supported.";
 324         }
 325
 326         confess "Trigger must be a CODE ref on attribute ($name)"
 327             if ref($args->{trigger}) ne 'CODE';
 328     }
 329
 330     return 1;
 331 }
 332
 333 sub verify_type_constraint {
 334     return 1 unless $_[0]->{type_constraint};
 335
 336     local $_ = $_[1];
 337     return 1 if $_[0]->{find_type_constraint}->($_);
 338
 339     my $self = shift;
 340     my $type = $self->type_constraint_as_string;
 341
 342     my $name = $self->name;
 343     my $display = defined($_) ? overload::StrVal($_) : 'undef';
 344     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
 345 }
 346
 347 sub coerce_constraint { ## my($self, $value) = @_;
 348     my $type = $_[0]->{type_constraint}
 349         or return $_[1];
 350     return Mouse::TypeRegistry->typecast_constraints($_[0]->associated_class->name, $_[0]->find_type_constraint, $type, $_[1]);
 351 }
 352
 353 sub _canonicalize_handles {
 354     my $self    = shift;
 355     my $handles = shift;
 356
 357     if (ref($handles) eq 'HASH') {
 358         return %$handles;
 359     }
 360     elsif (ref($handles) eq 'ARRAY') {
 361         return map { $_ => $_ } @$handles;
 362     }
 363     else {
 364         confess "Unable to canonicalize the 'handles' option with $handles";
 365     }
 366 }
 367
 368 sub clone_parent {
 369     my $self  = shift;
 370     my $class = shift;
 371     my $name  = shift;
 372     my %args  = ($self->get_parent_args($class, $name), @_);
 373
 374     $self->create($class, $name, %args);
 375 }
 376
 377 sub get_parent_args {
 378     my $self  = shift;
 379     my $class = shift;
 380     my $name  = shift;
 381
 382     for my $super ($class->linearized_isa) {
 383         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 384             or next;
 385         return %{ $super_attr->_create_args };
 386     }
 387
 388     confess "Could not find an attribute by the name of '$name' to inherit from";
 389 }
 390
 391 1;
 392
 393 __END__
 394
 395 =head1 NAME
 396
 397 Mouse::Meta::Attribute - attribute metaclass
 398
 399 =head1 METHODS
 400
 401 =head2 new %args -> Mouse::Meta::Attribute
 402
 403 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 404
 405 =head2 create OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 406
 407 Creates a new attribute in OwnerClass. Accessors and helper methods are
 408 installed. Some error checking is done.
 409
 410 =head2 name -> AttributeName
 411
 412 =head2 associated_class -> OwnerClass
 413
 414 =head2 is_required -> Bool
 415
 416 =head2 default -> Item
 417
 418 =head2 has_default -> Bool
 419
 420 =head2 is_lazy -> Bool
 421
 422 =head2 predicate -> MethodName | Undef
 423
 424 =head2 has_predicate -> Bool
 425
 426 =head2 clearer -> MethodName | Undef
 427
 428 =head2 has_clearer -> Bool
 429
 430 =head2 handles -> { LocalName => RemoteName }
 431
 432 =head2 has_handles -> Bool
 433
 434 =head2 is_weak_ref -> Bool
 435
 436 =head2 init_arg -> Str
 437
 438 =head2 type_constraint -> Str
 439
 440 =head2 has_type_constraint -> Bool
 441
 442 =head2 trigger => CODE | Undef
 443
 444 =head2 has_trigger -> Bool
 445
 446 =head2 builder => MethodName | Undef
 447
 448 =head2 has_builder -> Bool
 449
 450 =head2 is_lazy_build => Bool
 451
 452 =head2 should_auto_deref -> Bool
 453
 454 Informational methods.
 455
 456 =head2 generate_accessor -> CODE
 457
 458 Creates a new code reference for the attribute's accessor.
 459
 460 =head2 generate_predicate -> CODE
 461
 462 Creates a new code reference for the attribute's predicate.
 463
 464 =head2 generate_clearer -> CODE
 465
 466 Creates a new code reference for the attribute's clearer.
 467
 468 =head2 generate_handles -> { MethodName => CODE }
 469
 470 Creates a new code reference for each of the attribute's handles methods.
 471
 472 =head2 find_type_constraint -> CODE
 473
 474 Returns a code reference which can be used to check that a given value passes
 475 this attribute's type constraint;
 476
 477 =head2 verify_type_constraint Item -> 1 | ERROR
 478
 479 Checks that the given value passes this attribute's type constraint. Returns 1
 480 on success, otherwise C<confess>es.
 481
 482 =head2 canonicalize_args Name, %args -> %args
 483
 484 Canonicalizes some arguments to create. In particular, C<lazy_build> is
 485 canonicalized into C<lazy>, C<builder>, etc.
 486
 487 =head2 validate_args Name, \%args -> 1 | ERROR
 488
 489 Checks that the arguments to create the attribute (ie those specified by
 490 C<has>) are valid.
 491
 492 =head2 clone_parent OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 493
 494 Creates a new attribute in OwnerClass, inheriting options from parent classes.
 495 Accessors and helper methods are installed. Some error checking is done.
 496
 497 =head2 get_parent_args OwnerClass, AttributeName -> Hash
 498
 499 Returns the options that the parent class of C<OwnerClass> used for attribute
 500 C<AttributeName>.
 501
 502 =cut
 503