lib/Mouse/Meta/Attribute.pm

   1 #!/usr/bin/env perl
   2 package Mouse::Meta::Attribute;
   3 use strict;
   4 use warnings;
   5
   6 use Carp 'confess';
   7 use Mouse::Util qw/blessed weaken/;
   8
   9 sub new {
  10     my $class = shift;
  11     my %args  = @_;
  12
  13     my $name = $args{name};
  14
  15     $args{init_arg} = $name
  16         unless exists $args{init_arg};
  17
  18     $args{is} ||= '';
  19
  20     bless \%args, $class;
  21 }
  22
  23 sub name              { $_[0]->{name}             }
  24 sub associated_class  { $_[0]->{associated_class} }
  25 sub _is_metadata      { $_[0]->{is}               }
  26 sub is_required       { $_[0]->{required}         }
  27 sub default           { $_[0]->{default}          }
  28 sub is_lazy           { $_[0]->{lazy}             }
  29 sub is_lazy_build     { $_[0]->{lazy_build}       }
  30 sub predicate         { $_[0]->{predicate}        }
  31 sub clearer           { $_[0]->{clearer}          }
  32 sub handles           { $_[0]->{handles}          }
  33 sub is_weak_ref       { $_[0]->{weak_ref}         }
  34 sub init_arg          { $_[0]->{init_arg}         }
  35 sub type_constraint   { $_[0]->{type_constraint}  }
  36 sub trigger           { $_[0]->{trigger}          }
  37 sub builder           { $_[0]->{builder}          }
  38 sub should_auto_deref { $_[0]->{auto_deref}       }
  39
  40 sub has_default         { exists $_[0]->{default}         }
  41 sub has_predicate       { exists $_[0]->{predicate}       }
  42 sub has_clearer         { exists $_[0]->{clearer}         }
  43 sub has_handles         { exists $_[0]->{handles}         }
  44 sub has_type_constraint { exists $_[0]->{type_constraint} }
  45 sub has_trigger         { exists $_[0]->{trigger}         }
  46 sub has_builder         { exists $_[0]->{builder}         }
  47
  48 sub _create_args {
  49     $_[0]->{_create_args} = $_[1] if @_ > 1;
  50     $_[0]->{_create_args}
  51 }
  52
  53 sub inlined_name {
  54     my $self = shift;
  55     my $name = $self->name;
  56     my $key   = "'" . $name . "'";
  57     return $key;
  58 }
  59
  60 sub generate_accessor {
  61     my $attribute = shift;
  62
  63     my $name       = $attribute->name;
  64     my $default    = $attribute->default;
  65     my $type       = $attribute->type_constraint;
  66     my $constraint = $attribute->find_type_constraint;
  67     my $builder    = $attribute->builder;
  68     my $trigger    = $attribute->trigger;
  69
  70     my $self  = '$_[0]';
  71     my $value = '$_[1]';
  72     my $key   = $attribute->inlined_name;
  73
  74     my $accessor = "sub {\n";
  75     if ($attribute->_is_metadata eq 'rw') {
  76         $accessor .= 'if (scalar(@_) >= 2) {
  77         ';
  78
  79         if ($constraint) {
  80             $accessor .= 'local $_ = ' . $value . ';
  81                 unless ($constraint->()) {
  82                     my $display = defined($_) ? overload::StrVal($_) : "undef";
  83                     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
  84             }' . "\n"
  85         }
  86
  87         $accessor .= $self . '->{'.$key.'} = '. $value .';' . "\n";
  88
  89         if ($attribute->is_weak_ref) {
  90             $accessor .= 'weaken('.$self.'->{'.$key.'}) if ref('.$self.'->{'.$key.'});' . "\n";
  91         }
  92
  93         if ($trigger) {
  94             $accessor .= '$trigger->('.$self.', '.$value.', $attribute);' . "\n";
  95         }
  96
  97         $accessor .= "}\n";
  98     }
  99     else {
 100         $accessor .= 'confess "Cannot assign a value to a read-only accessor" if scalar(@_) >= 2;' . "\n";
 101     }
 102
 103     if ($attribute->is_lazy) {
 104         $accessor .= $self.'->{'.$key.'} = ';
 105
 106         $accessor .= $attribute->has_builder
 107                 ? $self.'->$builder'
 108                     : ref($default) eq 'CODE'
 109                     ? '$default->('.$self.')'
 110                     : '$default';
 111         $accessor .= ' if !exists '.$self.'->{'.$key.'};' . "\n";
 112     }
 113
 114     if ($attribute->should_auto_deref) {
 115         if ($attribute->type_constraint eq 'ArrayRef') {
 116             $accessor .= 'if (wantarray) {
 117                 return @{ '.$self.'->{'.$key.'} || [] };
 118             }' . "\n";
 119         }
 120         else {
 121             $accessor .= 'if (wantarray) {
 122                 return %{ '.$self.'->{'.$key.'} || {} };
 123             }' . "\n";
 124         }
 125     }
 126
 127     $accessor .= 'return '.$self.'->{'.$key.'};
 128     }';
 129
 130     my $sub = eval $accessor;
 131     confess $@ if $@;
 132     return $sub;
 133 }
 134
 135 sub generate_predicate {
 136     my $attribute = shift;
 137     my $key = $attribute->name;
 138
 139     my $predicate = 'sub { exists($_[0]->{$key}) }';
 140
 141     my $sub = eval $predicate;
 142     confess $@ if $@;
 143     return $sub;
 144 }
 145
 146 sub generate_clearer {
 147     my $attribute = shift;
 148     my $key = $attribute->name;
 149
 150     my $clearer = 'sub { delete($_[0]->{$key}) }';
 151
 152     my $sub = eval $clearer;
 153     confess $@ if $@;
 154     return $sub;
 155 }
 156
 157 sub generate_handles {
 158     my $attribute = shift;
 159     my $reader = $attribute->name;
 160     my %handles = $attribute->_canonicalize_handles($attribute->handles);
 161
 162     my %method_map;
 163
 164     for my $local_method (keys %handles) {
 165         my $remote_method = $handles{$local_method};
 166
 167         my $method = 'sub {
 168             my $self = shift;
 169             $self->$reader->$remote_method(@_)
 170         }';
 171
 172         $method_map{$local_method} = eval $method;
 173         confess $@ if $@;
 174     }
 175
 176     return \%method_map;
 177 }
 178
 179 sub create {
 180     my ($self, $class, $name, %args) = @_;
 181
 182     $args{name} = $name;
 183     $args{associated_class} = $class;
 184
 185     %args = $self->canonicalize_args($name, %args);
 186     $self->validate_args($name, \%args);
 187
 188     $args{type_constraint} = delete $args{isa}
 189         if exists $args{isa};
 190
 191     my $attribute = $self->new(%args);
 192
 193     $attribute->_create_args(\%args);
 194
 195     $class->add_attribute($attribute);
 196
 197     # install an accessor
 198     if ($attribute->_is_metadata eq 'rw' || $attribute->_is_metadata eq 'ro') {
 199         my $accessor = $attribute->generate_accessor;
 200         $class->add_method($name => $accessor);
 201     }
 202
 203     for my $method (qw/predicate clearer/) {
 204         my $predicate = "has_$method";
 205         if ($attribute->$predicate) {
 206             my $generator = "generate_$method";
 207             my $coderef = $attribute->$generator;
 208             $class->add_method($attribute->$method => $coderef);
 209         }
 210     }
 211
 212     if ($attribute->has_handles) {
 213         my $method_map = $attribute->generate_handles;
 214         for my $method_name (keys %$method_map) {
 215             $class->add_method($method_name => $method_map->{$method_name});
 216         }
 217     }
 218
 219     return $attribute;
 220 }
 221
 222 sub canonicalize_args {
 223     my $self = shift;
 224     my $name = shift;
 225     my %args = @_;
 226
 227     if ($args{lazy_build}) {
 228         $args{lazy}      = 1;
 229         $args{required}  = 1;
 230         $args{builder}   = "_build_${name}"
 231             if !exists($args{builder});
 232         if ($name =~ /^_/) {
 233             $args{clearer}   = "_clear${name}" if !exists($args{clearer});
 234             $args{predicate} = "_has${name}" if !exists($args{predicate});
 235         }
 236         else {
 237             $args{clearer}   = "clear_${name}" if !exists($args{clearer});
 238             $args{predicate} = "has_${name}" if !exists($args{predicate});
 239         }
 240     }
 241
 242     return %args;
 243 }
 244
 245 sub validate_args {
 246     my $self = shift;
 247     my $name = shift;
 248     my $args = shift;
 249
 250     confess "You can not use lazy_build and default for the same attribute ($name)"
 251         if $args->{lazy_build} && exists $args->{default};
 252
 253     confess "You cannot have lazy attribute ($name) without specifying a default value for it"
 254         if $args->{lazy}
 255         && !exists($args->{default})
 256         && !exists($args->{builder});
 257
 258     confess "References are not allowed as default values, you must wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])"
 259         if ref($args->{default})
 260         && ref($args->{default}) ne 'CODE';
 261
 262     confess "You cannot auto-dereference without specifying a type constraint on attribute ($name)"
 263         if $args->{auto_deref} && !exists($args->{isa});
 264
 265     confess "You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)"
 266         if $args->{auto_deref}
 267         && $args->{isa} ne 'ArrayRef'
 268         && $args->{isa} ne 'HashRef';
 269
 270     if ($args->{trigger}) {
 271         if (ref($args->{trigger}) eq 'HASH') {
 272             Carp::carp "HASH-based form of trigger has been removed. Only the coderef form of triggers are now supported.";
 273         }
 274
 275         confess "Trigger must be a CODE ref on attribute ($name)"
 276             if ref($args->{trigger}) ne 'CODE';
 277     }
 278
 279     return 1;
 280 }
 281
 282 sub find_type_constraint {
 283     my $self = shift;
 284     my $type = $self->type_constraint;
 285
 286     return unless $type;
 287
 288     my $checker = Mouse::TypeRegistry->optimized_constraints->{$type};
 289     return $checker if $checker;
 290
 291     return sub { blessed($_) && blessed($_) eq $type };
 292 }
 293
 294 sub verify_type_constraint {
 295     my $self = shift;
 296     local $_ = shift;
 297
 298     my $type = $self->type_constraint
 299         or return 1;
 300     my $constraint = $self->find_type_constraint;
 301
 302     return 1 if $constraint->($_);
 303
 304     my $name = $self->name;
 305     my $display = defined($_) ? overload::StrVal($_) : 'undef';
 306     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
 307 }
 308
 309 sub _canonicalize_handles {
 310     my $self    = shift;
 311     my $handles = shift;
 312
 313     if (ref($handles) eq 'HASH') {
 314         return %$handles;
 315     }
 316     elsif (ref($handles) eq 'ARRAY') {
 317         return map { $_ => $_ } @$handles;
 318     }
 319     else {
 320         confess "Unable to canonicalize the 'handles' option with $handles";
 321     }
 322 }
 323
 324 sub clone_parent {
 325     my $self  = shift;
 326     my $class = shift;
 327     my $name  = shift;
 328     my %args  = ($self->get_parent_args($class, $name), @_);
 329
 330     $self->create($class, $name, %args);
 331 }
 332
 333 sub get_parent_args {
 334     my $self  = shift;
 335     my $class = shift;
 336     my $name  = shift;
 337
 338     for my $super ($class->linearized_isa) {
 339         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 340             or next;
 341         return %{ $super_attr->_create_args };
 342     }
 343
 344     confess "Could not find an attribute by the name of '$name' to inherit from";
 345 }
 346
 347 1;
 348
 349 __END__
 350
 351 =head1 NAME
 352
 353 Mouse::Meta::Attribute - attribute metaclass
 354
 355 =head1 METHODS
 356
 357 =head2 new %args -> Mouse::Meta::Attribute
 358
 359 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 360
 361 =head2 create OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 362
 363 Creates a new attribute in OwnerClass. Accessors and helper methods are
 364 installed. Some error checking is done.
 365
 366 =head2 name -> AttributeName
 367
 368 =head2 associated_class -> OwnerClass
 369
 370 =head2 is_required -> Bool
 371
 372 =head2 default -> Item
 373
 374 =head2 has_default -> Bool
 375
 376 =head2 is_lazy -> Bool
 377
 378 =head2 predicate -> MethodName | Undef
 379
 380 =head2 has_predicate -> Bool
 381
 382 =head2 clearer -> MethodName | Undef
 383
 384 =head2 has_clearer -> Bool
 385
 386 =head2 handles -> { LocalName => RemoteName }
 387
 388 =head2 has_handles -> Bool
 389
 390 =head2 is_weak_ref -> Bool
 391
 392 =head2 init_arg -> Str
 393
 394 =head2 type_constraint -> Str
 395
 396 =head2 has_type_constraint -> Bool
 397
 398 =head2 trigger => CODE | Undef
 399
 400 =head2 has_trigger -> Bool
 401
 402 =head2 builder => MethodName | Undef
 403
 404 =head2 has_builder -> Bool
 405
 406 =head2 is_lazy_build => Bool
 407
 408 =head2 should_auto_deref -> Bool
 409
 410 Informational methods.
 411
 412 =head2 generate_accessor -> CODE
 413
 414 Creates a new code reference for the attribute's accessor.
 415
 416 =head2 generate_predicate -> CODE
 417
 418 Creates a new code reference for the attribute's predicate.
 419
 420 =head2 generate_clearer -> CODE
 421
 422 Creates a new code reference for the attribute's clearer.
 423
 424 =head2 generate_handles -> { MethodName => CODE }
 425
 426 Creates a new code reference for each of the attribute's handles methods.
 427
 428 =head2 find_type_constraint -> CODE
 429
 430 Returns a code reference which can be used to check that a given value passes
 431 this attribute's type constraint;
 432
 433 =head2 verify_type_constraint Item -> 1 | ERROR
 434
 435 Checks that the given value passes this attribute's type constraint. Returns 1
 436 on success, otherwise C<confess>es.
 437
 438 =head2 canonicalize_args Name, %args -> %args
 439
 440 Canonicalizes some arguments to create. In particular, C<lazy_build> is
 441 canonicalized into C<lazy>, C<builder>, etc.
 442
 443 =head2 validate_args Name, \%args -> 1 | ERROR
 444
 445 Checks that the arguments to create the attribute (ie those specified by
 446 C<has>) are valid.
 447
 448 =head2 clone_parent OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 449
 450 Creates a new attribute in OwnerClass, inheriting options from parent classes.
 451 Accessors and helper methods are installed. Some error checking is done.
 452
 453 =head2 get_parent_args OwnerClass, AttributeName -> Hash
 454
 455 Returns the options that the parent class of C<OwnerClass> used for attribute
 456 C<AttributeName>.
 457
 458 =cut
 459