lib/Mouse/Meta/Attribute.pm

   1 #!/usr/bin/env perl
   2 package Mouse::Meta::Attribute;
   3 use strict;
   4 use warnings;
   5
   6 use Carp 'confess';
   7 use Scalar::Util qw/blessed weaken/;
   8
   9 sub new {
  10     my $class = shift;
  11     my %args  = @_;
  12
  13     my $name = $args{name};
  14
  15     $args{init_arg} = $name
  16         unless exists $args{init_arg};
  17
  18     $args{is} ||= '';
  19
  20     bless \%args, $class;
  21 }
  22
  23 sub name              { $_[0]->{name}             }
  24 sub associated_class  { $_[0]->{associated_class} }
  25 sub _is_metadata      { $_[0]->{is}               }
  26 sub is_required       { $_[0]->{required}         }
  27 sub default           { $_[0]->{default}          }
  28 sub is_lazy           { $_[0]->{lazy}             }
  29 sub is_lazy_build     { $_[0]->{lazy_build}       }
  30 sub predicate         { $_[0]->{predicate}        }
  31 sub clearer           { $_[0]->{clearer}          }
  32 sub handles           { $_[0]->{handles}          }
  33 sub is_weak_ref       { $_[0]->{weak_ref}         }
  34 sub init_arg          { $_[0]->{init_arg}         }
  35 sub type_constraint   { $_[0]->{type_constraint}  }
  36 sub trigger           { $_[0]->{trigger}          }
  37 sub builder           { $_[0]->{builder}          }
  38 sub should_auto_deref { $_[0]->{auto_deref}       }
  39
  40 sub has_default         { exists $_[0]->{default}         }
  41 sub has_predicate       { exists $_[0]->{predicate}       }
  42 sub has_clearer         { exists $_[0]->{clearer}         }
  43 sub has_handles         { exists $_[0]->{handles}         }
  44 sub has_type_constraint { exists $_[0]->{type_constraint} }
  45 sub has_trigger         { exists $_[0]->{trigger}         }
  46 sub has_builder         { exists $_[0]->{builder}         }
  47
  48 sub _create_args {
  49     $_[0]->{_create_args} = $_[1] if @_ > 1;
  50     $_[0]->{_create_args}
  51 }
  52
  53 sub generate_accessor {
  54     my $attribute = shift;
  55
  56     my $name       = $attribute->name;
  57     my $key        = $name;
  58     my $default    = $attribute->default;
  59     my $type       = $attribute->type_constraint;
  60     my $constraint = $attribute->find_type_constraint;
  61     my $builder    = $attribute->builder;
  62
  63     my $trigger = $attribute->trigger;
  64     my $before  = $trigger->{before};
  65     my $after   = $trigger->{after};
  66     my $around  = $trigger->{around};
  67
  68     my $accessor = 'sub {
  69         my $self = shift;';
  70
  71     if ($attribute->_is_metadata eq 'rw') {
  72         $accessor .= 'if (@_) {
  73             local $_ = $_[0];';
  74
  75         if ($before) {
  76             $accessor .= '$before->($self, $_, $attribute);';
  77         }
  78
  79         if ($around) {
  80             $accessor .= '$around->(sub {
  81                 my $self = shift;
  82                 $_ = $_[0];
  83             ';
  84         }
  85
  86             if ($constraint) {
  87                 $accessor .= 'unless ($constraint->()) {
  88                         my $display = defined($_) ? overload::StrVal($_) : "undef";
  89                         Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
  90                 }'
  91             }
  92
  93             $accessor .= '$self->{$key} = $_;';
  94
  95             if ($attribute->is_weak_ref) {
  96                 $accessor .= 'Scalar::Util::weaken($self->{$key}) if ref($self->{$key});';
  97             }
  98
  99         if ($around) {
 100             $accessor .= '}, $self, $_, $attribute);';
 101         }
 102
 103         if ($after) {
 104             $accessor .= '$after->($self, $_, $attribute);';
 105         }
 106
 107         $accessor .= '}';
 108     }
 109     else {
 110         $accessor .= 'confess "Cannot assign a value to a read-only accessor" if @_;';
 111     }
 112
 113     if ($attribute->is_lazy) {
 114         $accessor .= '$self->{$key} = ';
 115
 116         $accessor .= $attribute->has_builder
 117                    ? '$self->$builder'
 118                      : ref($default) eq 'CODE'
 119                      ? '$default->($self)'
 120                      : '$default';
 121
 122         $accessor .= ' if !exists($self->{$key});';
 123     }
 124
 125     if ($attribute->should_auto_deref) {
 126         if ($attribute->type_constraint eq 'ArrayRef') {
 127             $accessor .= 'if (wantarray) {
 128                 return @{ $self->{$key} || [] };
 129             }';
 130         }
 131         else {
 132             $accessor .= 'if (wantarray) {
 133                 return %{ $self->{$key} || {} };
 134             }';
 135         }
 136     }
 137
 138     $accessor .= 'return $self->{$key};
 139     }';
 140
 141     return eval $accessor;
 142 }
 143
 144 sub generate_predicate {
 145     my $attribute = shift;
 146     my $key = $attribute->name;
 147
 148     my $predicate = 'sub { exists($_[0]->{$key}) }';
 149
 150     return eval $predicate;
 151 }
 152
 153 sub generate_clearer {
 154     my $attribute = shift;
 155     my $key = $attribute->name;
 156
 157     my $predicate = 'sub { delete($_[0]->{$key}) }';
 158
 159     return eval $predicate;
 160 }
 161
 162 sub generate_handles {
 163     my $attribute = shift;
 164     my $reader = $attribute->name;
 165     my %handles = $attribute->_canonicalize_handles($attribute->handles);
 166
 167     my %method_map;
 168
 169     for my $local_method (keys %handles) {
 170         my $remote_method = $handles{$local_method};
 171
 172         my $method = 'sub {
 173             my $self = shift;
 174             $self->$reader->$remote_method(@_)
 175         }';
 176
 177         $method_map{$local_method} = eval $method;
 178     }
 179
 180     return \%method_map;
 181 }
 182
 183 sub create {
 184     my ($self, $class, $name, %args) = @_;
 185
 186     $args{name} = $name;
 187     $args{associated_class} = $class;
 188
 189     %args = $self->canonicalize_args($name, %args);
 190     $self->validate_args($name, \%args);
 191
 192     $args{type_constraint} = delete $args{isa}
 193         if exists $args{isa};
 194
 195     my $attribute = $self->new(%args);
 196
 197     $attribute->_create_args(\%args);
 198
 199     $class->add_attribute($attribute);
 200
 201     # install an accessor
 202     if ($attribute->_is_metadata eq 'rw' || $attribute->_is_metadata eq 'ro') {
 203         my $accessor = $attribute->generate_accessor;
 204         $class->add_method($name => $accessor);
 205     }
 206
 207     for my $method (qw/predicate clearer/) {
 208         my $predicate = "has_$method";
 209         if ($attribute->$predicate) {
 210             my $generator = "generate_$method";
 211             my $coderef = $attribute->$generator;
 212             $class->add_method($attribute->$method => $coderef);
 213         }
 214     }
 215
 216     if ($attribute->has_handles) {
 217         my $method_map = $attribute->generate_handles;
 218         for my $method_name (keys %$method_map) {
 219             $class->add_method($method_name => $method_map->{$method_name});
 220         }
 221     }
 222
 223     return $attribute;
 224 }
 225
 226 sub canonicalize_args {
 227     my $self = shift;
 228     my $name = shift;
 229     my %args = @_;
 230
 231     if ($args{lazy_build}) {
 232         $args{lazy}      = 1;
 233         $args{required}  = 1;
 234         $args{builder}   = "_build_${name}"
 235             if !exists($args{builder});
 236         if ($name =~ /^_/) {
 237             $args{clearer}   = "_clear${name}" if !exists($args{clearer});
 238             $args{predicate} = "_has${name}" if !exists($args{predicate});
 239         }
 240         else {
 241             $args{clearer}   = "clear_${name}" if !exists($args{clearer});
 242             $args{predicate} = "has_${name}" if !exists($args{predicate});
 243         }
 244     }
 245
 246     return %args;
 247 }
 248
 249 sub validate_args {
 250     my $self = shift;
 251     my $name = shift;
 252     my $args = shift;
 253
 254     confess "You can not use lazy_build and default for the same attribute ($name)"
 255         if $args->{lazy_build} && exists $args->{default};
 256
 257     confess "You cannot have lazy attribute ($name) without specifying a default value for it"
 258         if $args->{lazy}
 259         && !exists($args->{default})
 260         && !exists($args->{builder});
 261
 262     confess "References are not allowed as default values, you must wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])"
 263         if ref($args->{default})
 264         && ref($args->{default}) ne 'CODE';
 265
 266     confess "You cannot auto-dereference without specifying a type constraint on attribute ($name)"
 267         if $args->{auto_deref} && !exists($args->{isa});
 268
 269     confess "You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)"
 270         if $args->{auto_deref}
 271         && $args->{isa} ne 'ArrayRef'
 272         && $args->{isa} ne 'HashRef';
 273
 274     if ($args->{trigger}) {
 275         if (ref($args->{trigger}) eq 'CODE') {
 276             $args->{trigger} = {
 277                 after => $args->{trigger},
 278             };
 279         }
 280         elsif (ref($args->{trigger}) eq 'HASH') {
 281             Carp::carp "HASH-based form of trigger is deprecated. Please switch back to using the coderef form of trigger.";
 282         }
 283
 284         confess "Trigger must be a CODE ref on attribute ($name)"
 285             if ref($args->{trigger}) ne 'HASH';
 286     }
 287
 288     return 1;
 289 }
 290
 291 sub find_type_constraint {
 292     my $self = shift;
 293     my $type = $self->type_constraint;
 294
 295     return unless $type;
 296
 297     my $checker = Mouse::TypeRegistry->optimized_constraints->{$type};
 298     return $checker if $checker;
 299
 300     return sub { blessed($_) && blessed($_) eq $type };
 301 }
 302
 303 sub verify_type_constraint {
 304     my $self = shift;
 305     local $_ = shift;
 306
 307     my $type = $self->type_constraint
 308         or return 1;
 309     my $constraint = $self->find_type_constraint;
 310
 311     return 1 if $constraint->($_);
 312
 313     my $name = $self->name;
 314     my $display = defined($_) ? overload::StrVal($_) : 'undef';
 315     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
 316 }
 317
 318 sub _canonicalize_handles {
 319     my $self    = shift;
 320     my $handles = shift;
 321
 322     if (ref($handles) eq 'HASH') {
 323         return %$handles;
 324     }
 325     elsif (ref($handles) eq 'ARRAY') {
 326         return map { $_ => $_ } @$handles;
 327     }
 328     else {
 329         confess "Unable to canonicalize the 'handles' option with $handles";
 330     }
 331 }
 332
 333 sub clone_parent {
 334     my $self  = shift;
 335     my $class = shift;
 336     my $name  = shift;
 337     my %args  = ($self->get_parent_args($class, $name), @_);
 338
 339     $self->create($class, $name, %args);
 340 }
 341
 342 sub get_parent_args {
 343     my $self  = shift;
 344     my $class = shift;
 345     my $name  = shift;
 346
 347     for my $super ($class->linearized_isa) {
 348         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 349             or next;
 350         return %{ $super_attr->_create_args };
 351     }
 352
 353     confess "Could not find an attribute by the name of '$name' to inherit from";
 354 }
 355
 356 1;
 357
 358 __END__
 359
 360 =head1 NAME
 361
 362 Mouse::Meta::Attribute - attribute metaclass
 363
 364 =head1 METHODS
 365
 366 =head2 new %args -> Mouse::Meta::Attribute
 367
 368 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 369
 370 =head2 create OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 371
 372 Creates a new attribute in OwnerClass. Accessors and helper methods are
 373 installed. Some error checking is done.
 374
 375 =head2 name -> AttributeName
 376
 377 =head2 associated_class -> OwnerClass
 378
 379 =head2 is_required -> Bool
 380
 381 =head2 default -> Item
 382
 383 =head2 has_default -> Bool
 384
 385 =head2 is_lazy -> Bool
 386
 387 =head2 predicate -> MethodName | Undef
 388
 389 =head2 has_predicate -> Bool
 390
 391 =head2 clearer -> MethodName | Undef
 392
 393 =head2 has_clearer -> Bool
 394
 395 =head2 handles -> { LocalName => RemoteName }
 396
 397 =head2 has_handles -> Bool
 398
 399 =head2 is_weak_ref -> Bool
 400
 401 =head2 init_arg -> Str
 402
 403 =head2 type_constraint -> Str
 404
 405 =head2 has_type_constraint -> Bool
 406
 407 =head2 trigger => CODE | Undef
 408
 409 =head2 has_trigger -> Bool
 410
 411 =head2 builder => MethodName | Undef
 412
 413 =head2 has_builder -> Bool
 414
 415 =head2 is_lazy_build => Bool
 416
 417 =head2 should_auto_deref -> Bool
 418
 419 Informational methods.
 420
 421 =head2 generate_accessor -> CODE
 422
 423 Creates a new code reference for the attribute's accessor.
 424
 425 =head2 generate_predicate -> CODE
 426
 427 Creates a new code reference for the attribute's predicate.
 428
 429 =head2 generate_clearer -> CODE
 430
 431 Creates a new code reference for the attribute's clearer.
 432
 433 =head2 generate_handles -> { MethodName => CODE }
 434
 435 Creates a new code reference for each of the attribute's handles methods.
 436
 437 =head2 find_type_constraint -> CODE
 438
 439 Returns a code reference which can be used to check that a given value passes
 440 this attribute's type constraint;
 441
 442 =head2 verify_type_constraint Item -> 1 | ERROR
 443
 444 Checks that the given value passes this attribute's type constraint. Returns 1
 445 on success, otherwise C<confess>es.
 446
 447 =head2 canonicalize_args Name, %args -> %args
 448
 449 Canonicalizes some arguments to create. In particular, C<lazy_build> is
 450 canonicalized into C<lazy>, C<builder>, etc.
 451
 452 =head2 validate_args Name, \%args -> 1 | ERROR
 453
 454 Checks that the arguments to create the attribute (ie those specified by
 455 C<has>) are valid.
 456
 457 =head2 clone_parent OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 458
 459 Creates a new attribute in OwnerClass, inheriting options from parent classes.
 460 Accessors and helper methods are installed. Some error checking is done.
 461
 462 =head2 get_parent_args OwnerClass, AttributeName -> Hash
 463
 464 Returns the options that the parent class of C<OwnerClass> used for attribute
 465 C<AttributeName>.
 466
 467 =cut
 468