lib/Mouse/Meta/Attribute.pm

   1 #!/usr/bin/env perl
   2 package Mouse::Meta::Attribute;
   3 use strict;
   4 use warnings;
   5
   6 use Carp 'confess';
   7 use Mouse::Util qw/blessed weaken/;
   8
   9 sub new {
  10     my $class = shift;
  11     my %args  = @_;
  12
  13     my $name = $args{name};
  14
  15     $args{init_arg} = $name
  16         unless exists $args{init_arg};
  17
  18     $args{is} ||= '';
  19
  20     bless \%args, $class;
  21 }
  22
  23 sub name              { $_[0]->{name}             }
  24 sub associated_class  { $_[0]->{associated_class} }
  25 sub _is_metadata      { $_[0]->{is}               }
  26 sub is_required       { $_[0]->{required}         }
  27 sub default           { $_[0]->{default}          }
  28 sub is_lazy           { $_[0]->{lazy}             }
  29 sub is_lazy_build     { $_[0]->{lazy_build}       }
  30 sub predicate         { $_[0]->{predicate}        }
  31 sub clearer           { $_[0]->{clearer}          }
  32 sub handles           { $_[0]->{handles}          }
  33 sub is_weak_ref       { $_[0]->{weak_ref}         }
  34 sub init_arg          { $_[0]->{init_arg}         }
  35 sub type_constraint   { $_[0]->{type_constraint}  }
  36 sub trigger           { $_[0]->{trigger}          }
  37 sub builder           { $_[0]->{builder}          }
  38 sub should_auto_deref { $_[0]->{auto_deref}       }
  39
  40 sub has_default         { exists $_[0]->{default}         }
  41 sub has_predicate       { exists $_[0]->{predicate}       }
  42 sub has_clearer         { exists $_[0]->{clearer}         }
  43 sub has_handles         { exists $_[0]->{handles}         }
  44 sub has_type_constraint { exists $_[0]->{type_constraint} }
  45 sub has_trigger         { exists $_[0]->{trigger}         }
  46 sub has_builder         { exists $_[0]->{builder}         }
  47
  48 sub _create_args {
  49     $_[0]->{_create_args} = $_[1] if @_ > 1;
  50     $_[0]->{_create_args}
  51 }
  52
  53 sub generate_accessor {
  54     my $attribute = shift;
  55
  56     my $name       = $attribute->name;
  57     my $key        = $name;
  58     my $default    = $attribute->default;
  59     my $type       = $attribute->type_constraint;
  60     my $constraint = $attribute->find_type_constraint;
  61     my $builder    = $attribute->builder;
  62     my $trigger    = $attribute->trigger;
  63
  64     my $accessor = 'sub {
  65         my $self = shift;';
  66
  67     if ($attribute->_is_metadata eq 'rw') {
  68         $accessor .= 'if (@_) {
  69         ';
  70
  71         if ($constraint) {
  72             $accessor .= 'local $_ = $_[0];
  73                 unless ($constraint->()) {
  74                     my $display = defined($_) ? overload::StrVal($_) : "undef";
  75                     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
  76             }'
  77         }
  78
  79         $accessor .= '$self->{$key} = $_[0];';
  80
  81         if ($attribute->is_weak_ref) {
  82             $accessor .= 'weaken($self->{$key}) if ref($self->{$key});';
  83         }
  84
  85         if ($trigger) {
  86             $accessor .= '$trigger->($self, $_[0], $attribute);';
  87         }
  88
  89         $accessor .= '}';
  90     }
  91     else {
  92         $accessor .= 'confess "Cannot assign a value to a read-only accessor" if @_;';
  93     }
  94
  95     if ($attribute->is_lazy) {
  96         $accessor .= '$self->{$key} = ';
  97
  98         $accessor .= $attribute->has_builder
  99                    ? '$self->$builder'
 100                      : ref($default) eq 'CODE'
 101                      ? '$default->($self)'
 102                      : '$default';
 103
 104         $accessor .= ' if !exists($self->{$key});';
 105     }
 106
 107     if ($attribute->should_auto_deref) {
 108         if ($attribute->type_constraint eq 'ArrayRef') {
 109             $accessor .= 'if (wantarray) {
 110                 return @{ $self->{$key} || [] };
 111             }';
 112         }
 113         else {
 114             $accessor .= 'if (wantarray) {
 115                 return %{ $self->{$key} || {} };
 116             }';
 117         }
 118     }
 119
 120     $accessor .= 'return $self->{$key};
 121     }';
 122
 123     my $sub = eval $accessor;
 124     confess $@ if $@;
 125     return $sub;
 126 }
 127
 128 sub generate_predicate {
 129     my $attribute = shift;
 130     my $key = $attribute->name;
 131
 132     my $predicate = 'sub { exists($_[0]->{$key}) }';
 133
 134     my $sub = eval $predicate;
 135     confess $@ if $@;
 136     return $sub;
 137 }
 138
 139 sub generate_clearer {
 140     my $attribute = shift;
 141     my $key = $attribute->name;
 142
 143     my $clearer = 'sub { delete($_[0]->{$key}) }';
 144
 145     my $sub = eval $clearer;
 146     confess $@ if $@;
 147     return $sub;
 148 }
 149
 150 sub generate_handles {
 151     my $attribute = shift;
 152     my $reader = $attribute->name;
 153     my %handles = $attribute->_canonicalize_handles($attribute->handles);
 154
 155     my %method_map;
 156
 157     for my $local_method (keys %handles) {
 158         my $remote_method = $handles{$local_method};
 159
 160         my $method = 'sub {
 161             my $self = shift;
 162             $self->$reader->$remote_method(@_)
 163         }';
 164
 165         $method_map{$local_method} = eval $method;
 166         confess $@ if $@;
 167     }
 168
 169     return \%method_map;
 170 }
 171
 172 sub create {
 173     my ($self, $class, $name, %args) = @_;
 174
 175     $args{name} = $name;
 176     $args{associated_class} = $class;
 177
 178     %args = $self->canonicalize_args($name, %args);
 179     $self->validate_args($name, \%args);
 180
 181     $args{type_constraint} = delete $args{isa}
 182         if exists $args{isa};
 183
 184     my $attribute = $self->new(%args);
 185
 186     $attribute->_create_args(\%args);
 187
 188     $class->add_attribute($attribute);
 189
 190     # install an accessor
 191     if ($attribute->_is_metadata eq 'rw' || $attribute->_is_metadata eq 'ro') {
 192         my $accessor = $attribute->generate_accessor;
 193         $class->add_method($name => $accessor);
 194     }
 195
 196     for my $method (qw/predicate clearer/) {
 197         my $predicate = "has_$method";
 198         if ($attribute->$predicate) {
 199             my $generator = "generate_$method";
 200             my $coderef = $attribute->$generator;
 201             $class->add_method($attribute->$method => $coderef);
 202         }
 203     }
 204
 205     if ($attribute->has_handles) {
 206         my $method_map = $attribute->generate_handles;
 207         for my $method_name (keys %$method_map) {
 208             $class->add_method($method_name => $method_map->{$method_name});
 209         }
 210     }
 211
 212     return $attribute;
 213 }
 214
 215 sub canonicalize_args {
 216     my $self = shift;
 217     my $name = shift;
 218     my %args = @_;
 219
 220     if ($args{lazy_build}) {
 221         $args{lazy}      = 1;
 222         $args{required}  = 1;
 223         $args{builder}   = "_build_${name}"
 224             if !exists($args{builder});
 225         if ($name =~ /^_/) {
 226             $args{clearer}   = "_clear${name}" if !exists($args{clearer});
 227             $args{predicate} = "_has${name}" if !exists($args{predicate});
 228         }
 229         else {
 230             $args{clearer}   = "clear_${name}" if !exists($args{clearer});
 231             $args{predicate} = "has_${name}" if !exists($args{predicate});
 232         }
 233     }
 234
 235     return %args;
 236 }
 237
 238 sub validate_args {
 239     my $self = shift;
 240     my $name = shift;
 241     my $args = shift;
 242
 243     confess "You can not use lazy_build and default for the same attribute ($name)"
 244         if $args->{lazy_build} && exists $args->{default};
 245
 246     confess "You cannot have lazy attribute ($name) without specifying a default value for it"
 247         if $args->{lazy}
 248         && !exists($args->{default})
 249         && !exists($args->{builder});
 250
 251     confess "References are not allowed as default values, you must wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])"
 252         if ref($args->{default})
 253         && ref($args->{default}) ne 'CODE';
 254
 255     confess "You cannot auto-dereference without specifying a type constraint on attribute ($name)"
 256         if $args->{auto_deref} && !exists($args->{isa});
 257
 258     confess "You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)"
 259         if $args->{auto_deref}
 260         && $args->{isa} ne 'ArrayRef'
 261         && $args->{isa} ne 'HashRef';
 262
 263     if ($args->{trigger}) {
 264         if (ref($args->{trigger}) eq 'HASH') {
 265             Carp::carp "HASH-based form of trigger has been removed. Only the coderef form of triggers are now supported.";
 266         }
 267
 268         confess "Trigger must be a CODE ref on attribute ($name)"
 269             if ref($args->{trigger}) ne 'CODE';
 270     }
 271
 272     return 1;
 273 }
 274
 275 sub find_type_constraint {
 276     my $self = shift;
 277     my $type = $self->type_constraint;
 278
 279     return unless $type;
 280
 281     my $checker = Mouse::TypeRegistry->optimized_constraints->{$type};
 282     return $checker if $checker;
 283
 284     return sub { blessed($_) && blessed($_) eq $type };
 285 }
 286
 287 sub verify_type_constraint {
 288     my $self = shift;
 289     local $_ = shift;
 290
 291     my $type = $self->type_constraint
 292         or return 1;
 293     my $constraint = $self->find_type_constraint;
 294
 295     return 1 if $constraint->($_);
 296
 297     my $name = $self->name;
 298     my $display = defined($_) ? overload::StrVal($_) : 'undef';
 299     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
 300 }
 301
 302 sub _canonicalize_handles {
 303     my $self    = shift;
 304     my $handles = shift;
 305
 306     if (ref($handles) eq 'HASH') {
 307         return %$handles;
 308     }
 309     elsif (ref($handles) eq 'ARRAY') {
 310         return map { $_ => $_ } @$handles;
 311     }
 312     else {
 313         confess "Unable to canonicalize the 'handles' option with $handles";
 314     }
 315 }
 316
 317 sub clone_parent {
 318     my $self  = shift;
 319     my $class = shift;
 320     my $name  = shift;
 321     my %args  = ($self->get_parent_args($class, $name), @_);
 322
 323     $self->create($class, $name, %args);
 324 }
 325
 326 sub get_parent_args {
 327     my $self  = shift;
 328     my $class = shift;
 329     my $name  = shift;
 330
 331     for my $super ($class->linearized_isa) {
 332         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 333             or next;
 334         return %{ $super_attr->_create_args };
 335     }
 336
 337     confess "Could not find an attribute by the name of '$name' to inherit from";
 338 }
 339
 340 1;
 341
 342 __END__
 343
 344 =head1 NAME
 345
 346 Mouse::Meta::Attribute - attribute metaclass
 347
 348 =head1 METHODS
 349
 350 =head2 new %args -> Mouse::Meta::Attribute
 351
 352 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 353
 354 =head2 create OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 355
 356 Creates a new attribute in OwnerClass. Accessors and helper methods are
 357 installed. Some error checking is done.
 358
 359 =head2 name -> AttributeName
 360
 361 =head2 associated_class -> OwnerClass
 362
 363 =head2 is_required -> Bool
 364
 365 =head2 default -> Item
 366
 367 =head2 has_default -> Bool
 368
 369 =head2 is_lazy -> Bool
 370
 371 =head2 predicate -> MethodName | Undef
 372
 373 =head2 has_predicate -> Bool
 374
 375 =head2 clearer -> MethodName | Undef
 376
 377 =head2 has_clearer -> Bool
 378
 379 =head2 handles -> { LocalName => RemoteName }
 380
 381 =head2 has_handles -> Bool
 382
 383 =head2 is_weak_ref -> Bool
 384
 385 =head2 init_arg -> Str
 386
 387 =head2 type_constraint -> Str
 388
 389 =head2 has_type_constraint -> Bool
 390
 391 =head2 trigger => CODE | Undef
 392
 393 =head2 has_trigger -> Bool
 394
 395 =head2 builder => MethodName | Undef
 396
 397 =head2 has_builder -> Bool
 398
 399 =head2 is_lazy_build => Bool
 400
 401 =head2 should_auto_deref -> Bool
 402
 403 Informational methods.
 404
 405 =head2 generate_accessor -> CODE
 406
 407 Creates a new code reference for the attribute's accessor.
 408
 409 =head2 generate_predicate -> CODE
 410
 411 Creates a new code reference for the attribute's predicate.
 412
 413 =head2 generate_clearer -> CODE
 414
 415 Creates a new code reference for the attribute's clearer.
 416
 417 =head2 generate_handles -> { MethodName => CODE }
 418
 419 Creates a new code reference for each of the attribute's handles methods.
 420
 421 =head2 find_type_constraint -> CODE
 422
 423 Returns a code reference which can be used to check that a given value passes
 424 this attribute's type constraint;
 425
 426 =head2 verify_type_constraint Item -> 1 | ERROR
 427
 428 Checks that the given value passes this attribute's type constraint. Returns 1
 429 on success, otherwise C<confess>es.
 430
 431 =head2 canonicalize_args Name, %args -> %args
 432
 433 Canonicalizes some arguments to create. In particular, C<lazy_build> is
 434 canonicalized into C<lazy>, C<builder>, etc.
 435
 436 =head2 validate_args Name, \%args -> 1 | ERROR
 437
 438 Checks that the arguments to create the attribute (ie those specified by
 439 C<has>) are valid.
 440
 441 =head2 clone_parent OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 442
 443 Creates a new attribute in OwnerClass, inheriting options from parent classes.
 444 Accessors and helper methods are installed. Some error checking is done.
 445
 446 =head2 get_parent_args OwnerClass, AttributeName -> Hash
 447
 448 Returns the options that the parent class of C<OwnerClass> used for attribute
 449 C<AttributeName>.
 450
 451 =cut
 452