lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use strict;
   3 use warnings;
   4 require overload;
   5
   6 use Carp 'confess';
   7 use Scalar::Util ();
   8 use Mouse::Meta::TypeConstraint;
   9
  10 sub new {
  11     my ($class, $name, %options) = @_;
  12
  13     $options{name} = $name;
  14
  15     $options{init_arg} = $name
  16         unless exists $options{init_arg};
  17
  18     $options{is} ||= '';
  19
  20     bless \%options, $class;
  21 }
  22
  23 sub name                 { $_[0]->{name}                   }
  24 sub associated_class     { $_[0]->{associated_class}       }
  25 sub _is_metadata         { $_[0]->{is}                     }
  26 sub is_required          { $_[0]->{required}               }
  27 sub default              { $_[0]->{default}                }
  28 sub is_lazy              { $_[0]->{lazy}                   }
  29 sub is_lazy_build        { $_[0]->{lazy_build}             }
  30 sub predicate            { $_[0]->{predicate}              }
  31 sub clearer              { $_[0]->{clearer}                }
  32 sub handles              { $_[0]->{handles}                }
  33 sub is_weak_ref          { $_[0]->{weak_ref}               }
  34 sub init_arg             { $_[0]->{init_arg}               }
  35 sub type_constraint      { $_[0]->{type_constraint}        }
  36 sub trigger              { $_[0]->{trigger}                }
  37 sub builder              { $_[0]->{builder}                }
  38 sub should_auto_deref    { $_[0]->{auto_deref}             }
  39 sub should_coerce        { $_[0]->{should_coerce}          }
  40
  41 sub has_default          { exists $_[0]->{default}         }
  42 sub has_predicate        { exists $_[0]->{predicate}       }
  43 sub has_clearer          { exists $_[0]->{clearer}         }
  44 sub has_handles          { exists $_[0]->{handles}         }
  45 sub has_type_constraint  { exists $_[0]->{type_constraint} }
  46 sub has_trigger          { exists $_[0]->{trigger}         }
  47 sub has_builder          { exists $_[0]->{builder}         }
  48
  49 sub _create_args {
  50     $_[0]->{_create_args} = $_[1] if @_ > 1;
  51     $_[0]->{_create_args}
  52 }
  53
  54 sub inlined_name {
  55     my $self = shift;
  56     my $name = $self->name;
  57     my $key   = "'" . $name . "'";
  58     return $key;
  59 }
  60
  61 sub generate_accessor {
  62     my $attribute = shift;
  63
  64     my $name          = $attribute->name;
  65     my $default       = $attribute->default;
  66     my $constraint    = $attribute->type_constraint;
  67     my $builder       = $attribute->builder;
  68     my $trigger       = $attribute->trigger;
  69     my $is_weak       = $attribute->is_weak_ref;
  70     my $should_deref  = $attribute->should_auto_deref;
  71     my $should_coerce = $attribute->should_coerce;
  72
  73     my $self  = '$_[0]';
  74     my $key   = $attribute->inlined_name;
  75
  76     my $accessor =
  77         '#line ' . __LINE__ . ' "' . __FILE__ . "\"\n" .
  78         "sub {\n";
  79     if ($attribute->_is_metadata eq 'rw') {
  80         $accessor .=
  81             '#line ' . __LINE__ . ' "' . __FILE__ . "\"\n" .
  82             'if (@_ >= 2) {' . "\n";
  83
  84         my $value = '$_[1]';
  85
  86         if ($constraint) {
  87             $accessor .= 'my $val = ';
  88             if ($should_coerce) {
  89                 $accessor .=
  90                     "\n".
  91                     '#line ' . __LINE__ . ' "' . __FILE__ . "\"\n" .
  92                     'Mouse::Util::TypeConstraints->typecast_constraints("'.$attribute->associated_class->name.'", $attribute->{type_constraint}, '.$value.');';
  93             } else {
  94                 $accessor .= $value.';';
  95             }
  96             $accessor .=
  97                 "\n".
  98                 '#line ' . __LINE__ . ' "' . __FILE__ . "\"\n" .
  99                 'unless ($constraint->check($val)) {
 100                     $attribute->verify_type_constraint_error($name, $val, $attribute->{type_constraint});
 101                 }' . "\n";
 102             $value = '$val';
 103         }
 104
 105         # if there's nothing left to do for the attribute we can return during
 106         # this setter
 107         $accessor .= 'return ' if !$is_weak && !$trigger && !$should_deref;
 108
 109         $accessor .= $self.'->{'.$key.'} = '.$value.';' . "\n";
 110
 111         if ($is_weak) {
 112             $accessor .= 'Scalar::Util::weaken('.$self.'->{'.$key.'}) if ref('.$self.'->{'.$key.'});' . "\n";
 113         }
 114
 115         if ($trigger) {
 116             $accessor .= '$trigger->('.$self.', '.$value.');' . "\n";
 117         }
 118
 119         $accessor .= "}\n";
 120     }
 121     else {
 122         $accessor .= 'confess "Cannot assign a value to a read-only accessor" if scalar(@_) >= 2;' . "\n";
 123     }
 124
 125     if ($attribute->is_lazy) {
 126         $accessor .= $self.'->{'.$key.'} = ';
 127
 128         $accessor .= $attribute->has_builder
 129                 ? $self.'->$builder'
 130                     : ref($default) eq 'CODE'
 131                     ? '$default->('.$self.')'
 132                     : '$default';
 133         $accessor .= ' if !exists '.$self.'->{'.$key.'};' . "\n";
 134     }
 135
 136     if ($should_deref) {
 137         my $type_constraint = $attribute->{type_constraint};
 138         if (ref($type_constraint) && $type_constraint->name eq 'ArrayRef') {
 139             $accessor .= 'if (wantarray) {
 140                 return @{ '.$self.'->{'.$key.'} || [] };
 141             }';
 142         }
 143         else {
 144             $accessor .= 'if (wantarray) {
 145                 return %{ '.$self.'->{'.$key.'} || {} };
 146             }';
 147         }
 148     }
 149
 150     $accessor .= 'return '.$self.'->{'.$key.'};
 151     }';
 152
 153     my $sub = eval $accessor;
 154     confess $@ if $@;
 155     return $sub;
 156 }
 157
 158 sub generate_predicate {
 159     my $attribute = shift;
 160     my $key = $attribute->inlined_name;
 161
 162     my $predicate = 'sub { exists($_[0]->{'.$key.'}) }';
 163
 164     my $sub = eval $predicate;
 165     confess $@ if $@;
 166     return $sub;
 167 }
 168
 169 sub generate_clearer {
 170     my $attribute = shift;
 171     my $key = $attribute->inlined_name;
 172
 173     my $clearer = 'sub { delete($_[0]->{'.$key.'}) }';
 174
 175     my $sub = eval $clearer;
 176     confess $@ if $@;
 177     return $sub;
 178 }
 179
 180 sub generate_handles {
 181     my $attribute = shift;
 182     my $reader = $attribute->name;
 183     my %handles = $attribute->_canonicalize_handles($attribute->handles);
 184
 185     my %method_map;
 186
 187     for my $local_method (keys %handles) {
 188         my $remote_method = $handles{$local_method};
 189
 190         my $method = 'sub {
 191             my $self = shift;
 192             $self->'.$reader.'->'.$remote_method.'(@_)
 193         }';
 194
 195         $method_map{$local_method} = eval $method;
 196         confess $@ if $@;
 197     }
 198
 199     return \%method_map;
 200 }
 201
 202 sub create {
 203     my ($self, $class, $name, %args) = @_;
 204
 205     $args{name} = $name;
 206     $args{associated_class} = $class;
 207
 208     %args = $self->canonicalize_args($name, %args);
 209     $self->validate_args($name, \%args);
 210
 211     $args{should_coerce} = delete $args{coerce}
 212         if exists $args{coerce};
 213
 214     if (exists $args{isa}) {
 215         confess "Got isa => $args{isa}, but Mouse does not yet support parameterized types for containers other than ArrayRef and HashRef (rt.cpan.org #39795)"
 216             if $args{isa} =~ /^([^\[]+)\[.+\]$/ &&
 217                $1 ne 'ArrayRef' &&
 218                $1 ne 'HashRef'  &&
 219                $1 ne 'Maybe'
 220         ;
 221
 222         my $type_constraint = delete $args{isa};
 223         $args{type_constraint}= Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($type_constraint);
 224     }
 225
 226     my $attribute = $self->new($name, %args);
 227
 228     $attribute->_create_args(\%args);
 229
 230     $class->add_attribute($attribute);
 231
 232     # install an accessor
 233     if ($attribute->_is_metadata eq 'rw' || $attribute->_is_metadata eq 'ro') {
 234         my $accessor = $attribute->generate_accessor;
 235         $class->add_method($name => $accessor);
 236     }
 237
 238     for my $method (qw/predicate clearer/) {
 239         my $predicate = "has_$method";
 240         if ($attribute->$predicate) {
 241             my $generator = "generate_$method";
 242             my $coderef = $attribute->$generator;
 243             $class->add_method($attribute->$method => $coderef);
 244         }
 245     }
 246
 247     if ($attribute->has_handles) {
 248         my $method_map = $attribute->generate_handles;
 249         for my $method_name (keys %$method_map) {
 250             $class->add_method($method_name => $method_map->{$method_name});
 251         }
 252     }
 253
 254     return $attribute;
 255 }
 256
 257 sub canonicalize_args {
 258     my $self = shift;
 259     my $name = shift;
 260     my %args = @_;
 261
 262     if ($args{lazy_build}) {
 263         $args{lazy}      = 1;
 264         $args{required}  = 1;
 265         $args{builder}   = "_build_${name}"
 266             if !exists($args{builder});
 267         if ($name =~ /^_/) {
 268             $args{clearer}   = "_clear${name}" if !exists($args{clearer});
 269             $args{predicate} = "_has${name}" if !exists($args{predicate});
 270         }
 271         else {
 272             $args{clearer}   = "clear_${name}" if !exists($args{clearer});
 273             $args{predicate} = "has_${name}" if !exists($args{predicate});
 274         }
 275     }
 276
 277     return %args;
 278 }
 279
 280 sub validate_args {
 281     my $self = shift;
 282     my $name = shift;
 283     my $args = shift;
 284
 285     confess "You can not use lazy_build and default for the same attribute ($name)"
 286         if $args->{lazy_build} && exists $args->{default};
 287
 288     confess "You cannot have lazy attribute ($name) without specifying a default value for it"
 289         if $args->{lazy}
 290         && !exists($args->{default})
 291         && !exists($args->{builder});
 292
 293     confess "References are not allowed as default values, you must wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])"
 294         if ref($args->{default})
 295         && ref($args->{default}) ne 'CODE';
 296
 297     confess "You cannot auto-dereference without specifying a type constraint on attribute ($name)"
 298         if $args->{auto_deref} && !exists($args->{isa});
 299
 300     confess "You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)"
 301         if $args->{auto_deref}
 302         && $args->{isa} ne 'ArrayRef'
 303         && $args->{isa} ne 'HashRef';
 304
 305     if ($args->{trigger}) {
 306         if (ref($args->{trigger}) eq 'HASH') {
 307             Carp::carp "HASH-based form of trigger has been removed. Only the coderef form of triggers are now supported.";
 308         }
 309
 310         confess "Trigger must be a CODE ref on attribute ($name)"
 311             if ref($args->{trigger}) ne 'CODE';
 312     }
 313
 314     return 1;
 315 }
 316
 317 sub verify_against_type_constraint {
 318     return 1 unless $_[0]->{type_constraint};
 319
 320     local $_ = $_[1];
 321     return 1 if $_[0]->{type_constraint}->check($_);
 322
 323     my $self = shift;
 324     $self->verify_type_constraint_error($self->name, $_, $self->{type_constraint});
 325 }
 326
 327 sub verify_type_constraint_error {
 328     my($self, $name, $value, $type) = @_;
 329     $type = ref($type) eq 'ARRAY' ? join '|', map { $_->name } @{ $type } : $type->name;
 330     my $display = defined($value) ? overload::StrVal($value) : 'undef';
 331     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
 332 }
 333
 334 sub coerce_constraint { ## my($self, $value) = @_;
 335     my $type = $_[0]->{type_constraint}
 336         or return $_[1];
 337     return Mouse::Util::TypeConstraints->typecast_constraints($_[0]->associated_class->name, $_[0]->type_constraint, $_[1]);
 338 }
 339
 340 sub _canonicalize_handles {
 341     my $self    = shift;
 342     my $handles = shift;
 343
 344     if (ref($handles) eq 'HASH') {
 345         return %$handles;
 346     }
 347     elsif (ref($handles) eq 'ARRAY') {
 348         return map { $_ => $_ } @$handles;
 349     }
 350     else {
 351         confess "Unable to canonicalize the 'handles' option with $handles";
 352     }
 353 }
 354
 355 sub clone_parent {
 356     my $self  = shift;
 357     my $class = shift;
 358     my $name  = shift;
 359     my %args  = ($self->get_parent_args($class, $name), @_);
 360
 361     $self->create($class, $name, %args);
 362 }
 363
 364 sub get_parent_args {
 365     my $self  = shift;
 366     my $class = shift;
 367     my $name  = shift;
 368
 369     for my $super ($class->linearized_isa) {
 370         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 371             or next;
 372         return %{ $super_attr->_create_args };
 373     }
 374
 375     confess "Could not find an attribute by the name of '$name' to inherit from";
 376 }
 377
 378 1;
 379
 380 __END__
 381
 382 =head1 NAME
 383
 384 Mouse::Meta::Attribute - attribute metaclass
 385
 386 =head1 METHODS
 387
 388 =head2 new %args -> Mouse::Meta::Attribute
 389
 390 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 391
 392 =head2 create OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 393
 394 Creates a new attribute in OwnerClass. Accessors and helper methods are
 395 installed. Some error checking is done.
 396
 397 =head2 name -> AttributeName
 398
 399 =head2 associated_class -> OwnerClass
 400
 401 =head2 is_required -> Bool
 402
 403 =head2 default -> Item
 404
 405 =head2 has_default -> Bool
 406
 407 =head2 is_lazy -> Bool
 408
 409 =head2 predicate -> MethodName | Undef
 410
 411 =head2 has_predicate -> Bool
 412
 413 =head2 clearer -> MethodName | Undef
 414
 415 =head2 has_clearer -> Bool
 416
 417 =head2 handles -> { LocalName => RemoteName }
 418
 419 =head2 has_handles -> Bool
 420
 421 =head2 is_weak_ref -> Bool
 422
 423 =head2 init_arg -> Str
 424
 425 =head2 type_constraint -> Str
 426
 427 =head2 has_type_constraint -> Bool
 428
 429 =head2 trigger => CODE | Undef
 430
 431 =head2 has_trigger -> Bool
 432
 433 =head2 builder => MethodName | Undef
 434
 435 =head2 has_builder -> Bool
 436
 437 =head2 is_lazy_build => Bool
 438
 439 =head2 should_auto_deref -> Bool
 440
 441 Informational methods.
 442
 443 =head2 generate_accessor -> CODE
 444
 445 Creates a new code reference for the attribute's accessor.
 446
 447 =head2 generate_predicate -> CODE
 448
 449 Creates a new code reference for the attribute's predicate.
 450
 451 =head2 generate_clearer -> CODE
 452
 453 Creates a new code reference for the attribute's clearer.
 454
 455 =head2 generate_handles -> { MethodName => CODE }
 456
 457 Creates a new code reference for each of the attribute's handles methods.
 458
 459 =head2 verify_against_type_constraint Item -> 1 | ERROR
 460
 461 Checks that the given value passes this attribute's type constraint. Returns 1
 462 on success, otherwise C<confess>es.
 463
 464 =head2 canonicalize_args Name, %args -> %args
 465
 466 Canonicalizes some arguments to create. In particular, C<lazy_build> is
 467 canonicalized into C<lazy>, C<builder>, etc.
 468
 469 =head2 validate_args Name, \%args -> 1 | ERROR
 470
 471 Checks that the arguments to create the attribute (ie those specified by
 472 C<has>) are valid.
 473
 474 =head2 clone_parent OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 475
 476 Creates a new attribute in OwnerClass, inheriting options from parent classes.
 477 Accessors and helper methods are installed. Some error checking is done.
 478
 479 =head2 get_parent_args OwnerClass, AttributeName -> Hash
 480
 481 Returns the options that the parent class of C<OwnerClass> used for attribute
 482 C<AttributeName>.
 483
 484 =cut
 485