lib/Mouse/Meta/Attribute.pm

   1 #!/usr/bin/env perl
   2 package Mouse::Meta::Attribute;
   3 use strict;
   4 use warnings;
   5
   6 use Carp 'confess';
   7 use Mouse::Util qw/blessed weaken/;
   8
   9 sub new {
  10     my $class = shift;
  11     my %args  = @_;
  12
  13     my $name = $args{name};
  14
  15     $args{init_arg} = $name
  16         unless exists $args{init_arg};
  17
  18     $args{is} ||= '';
  19
  20     bless \%args, $class;
  21 }
  22
  23 sub name              { $_[0]->{name}             }
  24 sub associated_class  { $_[0]->{associated_class} }
  25 sub _is_metadata      { $_[0]->{is}               }
  26 sub is_required       { $_[0]->{required}         }
  27 sub default           { $_[0]->{default}          }
  28 sub is_lazy           { $_[0]->{lazy}             }
  29 sub is_lazy_build     { $_[0]->{lazy_build}       }
  30 sub predicate         { $_[0]->{predicate}        }
  31 sub clearer           { $_[0]->{clearer}          }
  32 sub handles           { $_[0]->{handles}          }
  33 sub is_weak_ref       { $_[0]->{weak_ref}         }
  34 sub init_arg          { $_[0]->{init_arg}         }
  35 sub type_constraint   { $_[0]->{type_constraint}  }
  36 sub trigger           { $_[0]->{trigger}          }
  37 sub builder           { $_[0]->{builder}          }
  38 sub should_auto_deref { $_[0]->{auto_deref}       }
  39
  40 sub has_default         { exists $_[0]->{default}         }
  41 sub has_predicate       { exists $_[0]->{predicate}       }
  42 sub has_clearer         { exists $_[0]->{clearer}         }
  43 sub has_handles         { exists $_[0]->{handles}         }
  44 sub has_type_constraint { exists $_[0]->{type_constraint} }
  45 sub has_trigger         { exists $_[0]->{trigger}         }
  46 sub has_builder         { exists $_[0]->{builder}         }
  47
  48 sub _create_args {
  49     $_[0]->{_create_args} = $_[1] if @_ > 1;
  50     $_[0]->{_create_args}
  51 }
  52
  53 sub generate_accessor {
  54     my $attribute = shift;
  55
  56     my $name       = $attribute->name;
  57     my $key        = $name;
  58     my $default    = $attribute->default;
  59     my $type       = $attribute->type_constraint;
  60     my $constraint = $attribute->find_type_constraint;
  61     my $builder    = $attribute->builder;
  62     my $trigger    = $attribute->trigger;
  63
  64     my $accessor = 'sub {
  65         my $self = shift;';
  66
  67     if ($attribute->_is_metadata eq 'rw') {
  68         $accessor .= 'if (@_) {
  69             local $_ = $_[0];';
  70
  71         if ($constraint) {
  72             $accessor .= 'unless ($constraint->()) {
  73                     my $display = defined($_) ? overload::StrVal($_) : "undef";
  74                     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
  75             }'
  76         }
  77
  78         $accessor .= '$self->{$key} = $_;';
  79
  80         if ($attribute->is_weak_ref) {
  81             $accessor .= 'weaken($self->{$key}) if ref($self->{$key});';
  82         }
  83
  84         if ($trigger) {
  85             $accessor .= '$trigger->($self, $_, $attribute);';
  86         }
  87
  88         $accessor .= '}';
  89     }
  90     else {
  91         $accessor .= 'confess "Cannot assign a value to a read-only accessor" if @_;';
  92     }
  93
  94     if ($attribute->is_lazy) {
  95         $accessor .= '$self->{$key} = ';
  96
  97         $accessor .= $attribute->has_builder
  98                    ? '$self->$builder'
  99                      : ref($default) eq 'CODE'
 100                      ? '$default->($self)'
 101                      : '$default';
 102
 103         $accessor .= ' if !exists($self->{$key});';
 104     }
 105
 106     if ($attribute->should_auto_deref) {
 107         if ($attribute->type_constraint eq 'ArrayRef') {
 108             $accessor .= 'if (wantarray) {
 109                 return @{ $self->{$key} || [] };
 110             }';
 111         }
 112         else {
 113             $accessor .= 'if (wantarray) {
 114                 return %{ $self->{$key} || {} };
 115             }';
 116         }
 117     }
 118
 119     $accessor .= 'return $self->{$key};
 120     }';
 121
 122     return eval $accessor;
 123 }
 124
 125 sub generate_predicate {
 126     my $attribute = shift;
 127     my $key = $attribute->name;
 128
 129     my $predicate = 'sub { exists($_[0]->{$key}) }';
 130
 131     return eval $predicate;
 132 }
 133
 134 sub generate_clearer {
 135     my $attribute = shift;
 136     my $key = $attribute->name;
 137
 138     my $predicate = 'sub { delete($_[0]->{$key}) }';
 139
 140     return eval $predicate;
 141 }
 142
 143 sub generate_handles {
 144     my $attribute = shift;
 145     my $reader = $attribute->name;
 146     my %handles = $attribute->_canonicalize_handles($attribute->handles);
 147
 148     my %method_map;
 149
 150     for my $local_method (keys %handles) {
 151         my $remote_method = $handles{$local_method};
 152
 153         my $method = 'sub {
 154             my $self = shift;
 155             $self->$reader->$remote_method(@_)
 156         }';
 157
 158         $method_map{$local_method} = eval $method;
 159     }
 160
 161     return \%method_map;
 162 }
 163
 164 sub create {
 165     my ($self, $class, $name, %args) = @_;
 166
 167     $args{name} = $name;
 168     $args{associated_class} = $class;
 169
 170     %args = $self->canonicalize_args($name, %args);
 171     $self->validate_args($name, \%args);
 172
 173     $args{type_constraint} = delete $args{isa}
 174         if exists $args{isa};
 175
 176     my $attribute = $self->new(%args);
 177
 178     $attribute->_create_args(\%args);
 179
 180     $class->add_attribute($attribute);
 181
 182     # install an accessor
 183     if ($attribute->_is_metadata eq 'rw' || $attribute->_is_metadata eq 'ro') {
 184         my $accessor = $attribute->generate_accessor;
 185         $class->add_method($name => $accessor);
 186     }
 187
 188     for my $method (qw/predicate clearer/) {
 189         my $predicate = "has_$method";
 190         if ($attribute->$predicate) {
 191             my $generator = "generate_$method";
 192             my $coderef = $attribute->$generator;
 193             $class->add_method($attribute->$method => $coderef);
 194         }
 195     }
 196
 197     if ($attribute->has_handles) {
 198         my $method_map = $attribute->generate_handles;
 199         for my $method_name (keys %$method_map) {
 200             $class->add_method($method_name => $method_map->{$method_name});
 201         }
 202     }
 203
 204     return $attribute;
 205 }
 206
 207 sub canonicalize_args {
 208     my $self = shift;
 209     my $name = shift;
 210     my %args = @_;
 211
 212     if ($args{lazy_build}) {
 213         $args{lazy}      = 1;
 214         $args{required}  = 1;
 215         $args{builder}   = "_build_${name}"
 216             if !exists($args{builder});
 217         if ($name =~ /^_/) {
 218             $args{clearer}   = "_clear${name}" if !exists($args{clearer});
 219             $args{predicate} = "_has${name}" if !exists($args{predicate});
 220         }
 221         else {
 222             $args{clearer}   = "clear_${name}" if !exists($args{clearer});
 223             $args{predicate} = "has_${name}" if !exists($args{predicate});
 224         }
 225     }
 226
 227     return %args;
 228 }
 229
 230 sub validate_args {
 231     my $self = shift;
 232     my $name = shift;
 233     my $args = shift;
 234
 235     confess "You can not use lazy_build and default for the same attribute ($name)"
 236         if $args->{lazy_build} && exists $args->{default};
 237
 238     confess "You cannot have lazy attribute ($name) without specifying a default value for it"
 239         if $args->{lazy}
 240         && !exists($args->{default})
 241         && !exists($args->{builder});
 242
 243     confess "References are not allowed as default values, you must wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])"
 244         if ref($args->{default})
 245         && ref($args->{default}) ne 'CODE';
 246
 247     confess "You cannot auto-dereference without specifying a type constraint on attribute ($name)"
 248         if $args->{auto_deref} && !exists($args->{isa});
 249
 250     confess "You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)"
 251         if $args->{auto_deref}
 252         && $args->{isa} ne 'ArrayRef'
 253         && $args->{isa} ne 'HashRef';
 254
 255     if ($args->{trigger}) {
 256         if (ref($args->{trigger}) eq 'HASH') {
 257             Carp::carp "HASH-based form of trigger has been removed. Only the coderef form of triggers are now supported.";
 258         }
 259
 260         confess "Trigger must be a CODE ref on attribute ($name)"
 261             if ref($args->{trigger}) ne 'CODE';
 262     }
 263
 264     return 1;
 265 }
 266
 267 sub find_type_constraint {
 268     my $self = shift;
 269     my $type = $self->type_constraint;
 270
 271     return unless $type;
 272
 273     my $checker = Mouse::TypeRegistry->optimized_constraints->{$type};
 274     return $checker if $checker;
 275
 276     return sub { blessed($_) && blessed($_) eq $type };
 277 }
 278
 279 sub verify_type_constraint {
 280     my $self = shift;
 281     local $_ = shift;
 282
 283     my $type = $self->type_constraint
 284         or return 1;
 285     my $constraint = $self->find_type_constraint;
 286
 287     return 1 if $constraint->($_);
 288
 289     my $name = $self->name;
 290     my $display = defined($_) ? overload::StrVal($_) : 'undef';
 291     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
 292 }
 293
 294 sub _canonicalize_handles {
 295     my $self    = shift;
 296     my $handles = shift;
 297
 298     if (ref($handles) eq 'HASH') {
 299         return %$handles;
 300     }
 301     elsif (ref($handles) eq 'ARRAY') {
 302         return map { $_ => $_ } @$handles;
 303     }
 304     else {
 305         confess "Unable to canonicalize the 'handles' option with $handles";
 306     }
 307 }
 308
 309 sub clone_parent {
 310     my $self  = shift;
 311     my $class = shift;
 312     my $name  = shift;
 313     my %args  = ($self->get_parent_args($class, $name), @_);
 314
 315     $self->create($class, $name, %args);
 316 }
 317
 318 sub get_parent_args {
 319     my $self  = shift;
 320     my $class = shift;
 321     my $name  = shift;
 322
 323     for my $super ($class->linearized_isa) {
 324         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 325             or next;
 326         return %{ $super_attr->_create_args };
 327     }
 328
 329     confess "Could not find an attribute by the name of '$name' to inherit from";
 330 }
 331
 332 1;
 333
 334 __END__
 335
 336 =head1 NAME
 337
 338 Mouse::Meta::Attribute - attribute metaclass
 339
 340 =head1 METHODS
 341
 342 =head2 new %args -> Mouse::Meta::Attribute
 343
 344 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 345
 346 =head2 create OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 347
 348 Creates a new attribute in OwnerClass. Accessors and helper methods are
 349 installed. Some error checking is done.
 350
 351 =head2 name -> AttributeName
 352
 353 =head2 associated_class -> OwnerClass
 354
 355 =head2 is_required -> Bool
 356
 357 =head2 default -> Item
 358
 359 =head2 has_default -> Bool
 360
 361 =head2 is_lazy -> Bool
 362
 363 =head2 predicate -> MethodName | Undef
 364
 365 =head2 has_predicate -> Bool
 366
 367 =head2 clearer -> MethodName | Undef
 368
 369 =head2 has_clearer -> Bool
 370
 371 =head2 handles -> { LocalName => RemoteName }
 372
 373 =head2 has_handles -> Bool
 374
 375 =head2 is_weak_ref -> Bool
 376
 377 =head2 init_arg -> Str
 378
 379 =head2 type_constraint -> Str
 380
 381 =head2 has_type_constraint -> Bool
 382
 383 =head2 trigger => CODE | Undef
 384
 385 =head2 has_trigger -> Bool
 386
 387 =head2 builder => MethodName | Undef
 388
 389 =head2 has_builder -> Bool
 390
 391 =head2 is_lazy_build => Bool
 392
 393 =head2 should_auto_deref -> Bool
 394
 395 Informational methods.
 396
 397 =head2 generate_accessor -> CODE
 398
 399 Creates a new code reference for the attribute's accessor.
 400
 401 =head2 generate_predicate -> CODE
 402
 403 Creates a new code reference for the attribute's predicate.
 404
 405 =head2 generate_clearer -> CODE
 406
 407 Creates a new code reference for the attribute's clearer.
 408
 409 =head2 generate_handles -> { MethodName => CODE }
 410
 411 Creates a new code reference for each of the attribute's handles methods.
 412
 413 =head2 find_type_constraint -> CODE
 414
 415 Returns a code reference which can be used to check that a given value passes
 416 this attribute's type constraint;
 417
 418 =head2 verify_type_constraint Item -> 1 | ERROR
 419
 420 Checks that the given value passes this attribute's type constraint. Returns 1
 421 on success, otherwise C<confess>es.
 422
 423 =head2 canonicalize_args Name, %args -> %args
 424
 425 Canonicalizes some arguments to create. In particular, C<lazy_build> is
 426 canonicalized into C<lazy>, C<builder>, etc.
 427
 428 =head2 validate_args Name, \%args -> 1 | ERROR
 429
 430 Checks that the arguments to create the attribute (ie those specified by
 431 C<has>) are valid.
 432
 433 =head2 clone_parent OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 434
 435 Creates a new attribute in OwnerClass, inheriting options from parent classes.
 436 Accessors and helper methods are installed. Some error checking is done.
 437
 438 =head2 get_parent_args OwnerClass, AttributeName -> Hash
 439
 440 Returns the options that the parent class of C<OwnerClass> used for attribute
 441 C<AttributeName>.
 442
 443 =cut
 444