lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use strict;
   3 use warnings;
   4
   5 use Carp ();
   6
   7 use Mouse::Util qw(:meta);
   8
   9 use Mouse::Meta::TypeConstraint;
  10 use Mouse::Meta::Method::Accessor;
  11
  12 sub _process_options{
  13     my($class, $name, $args) = @_;
  14
  15     # taken from Class::MOP::Attribute::new
  16
  17     defined($name)
  18         or $class->throw_error('You must provide a name for the attribute');
  19
  20     if(!exists $args->{init_arg}){
  21         $args->{init_arg} = $name;
  22     }
  23
  24     # 'required' requires eigher 'init_arg', 'builder', or 'default'
  25     my $can_be_required = defined( $args->{init_arg} );
  26
  27     if(exists $args->{builder}){
  28         $class->throw_error('builder must be a defined scalar value which is a method name')
  29             if ref $args->{builder} || !(defined $args->{builder});
  30
  31         $can_be_required++;
  32     }
  33     elsif(exists $args->{default}){
  34         if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
  35             $class->throw_error("References are not allowed as default values, you must "
  36                               . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
  37         }
  38         $can_be_required++;
  39     }
  40
  41     if( $args->{required} && !$can_be_required ) {
  42         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
  43     }
  44
  45     # taken from Mouse::Meta::Attribute->new and _process_args->
  46
  47     if(exists $args->{is}){
  48         my $is = $args->{is};
  49
  50         if($is eq 'ro'){
  51             $args->{reader} ||= $name;
  52         }
  53         elsif($is eq 'rw'){
  54             if(exists $args->{writer}){
  55                 $args->{reader} ||= $name;
  56              }
  57              else{
  58                 $args->{accessor} ||= $name;
  59              }
  60         }
  61         elsif($is eq 'bare'){
  62             # do nothing, but don't complain (later) about missing methods
  63         }
  64         else{
  65             $is = 'undef' if !defined $is;
  66             $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
  67         }
  68     }
  69
  70     my $tc;
  71     if(exists $args->{isa}){
  72         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
  73     }
  74     elsif(exists $args->{does}){
  75         # TODO
  76         # $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
  77     }
  78     $tc = $args->{type_constraint};
  79
  80     if($args->{coerce}){
  81         defined($tc)
  82             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
  83
  84         $args->{weak_ref}
  85             && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
  86     }
  87
  88     if ($args->{lazy_build}) {
  89         exists($args->{default})
  90             && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
  91
  92         $args->{lazy}      = 1;
  93         $args->{builder} ||= "_build_${name}";
  94         if ($name =~ /^_/) {
  95             $args->{clearer}   ||= "_clear${name}";
  96             $args->{predicate} ||= "_has${name}";
  97         }
  98         else {
  99             $args->{clearer}   ||= "clear_${name}";
 100             $args->{predicate} ||= "has_${name}";
 101         }
 102     }
 103
 104     if ($args->{auto_deref}) {
 105         defined($tc)
 106             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
 107
 108         ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
 109             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
 110     }
 111
 112     if (exists $args->{trigger}) {
 113         ('CODE' eq ref $args->{trigger})
 114             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
 115     }
 116
 117     if ($args->{lazy}) {
 118         (exists $args->{default} || defined $args->{builder})
 119             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
 120     }
 121
 122     # XXX: for backward compatibility (with method modifiers)
 123     if($class->can('canonicalize_args') != \&canonicalize_args){
 124         %{$args} = $class->canonicalize_args($name, %{$args});
 125     }
 126     return;
 127 }
 128
 129 sub new {
 130     my $class = shift;
 131     my $name  = shift;
 132
 133     my %args  = (@_ == 1) ? %{ $_[0] } : @_;
 134
 135     $class->_process_options($name, \%args);
 136
 137     $args{name} = $name;
 138
 139     my $instance = bless \%args, $class;
 140
 141     # extra attributes
 142     if($class ne __PACKAGE__){
 143         $class->meta->_initialize_instance($instance,\%args);
 144     }
 145
 146 # XXX: there is no fast way to check attribute validity
 147 #    my @bad = ...;
 148 #    if(@bad){
 149 #        @bad = sort @bad;
 150 #        Carp::cluck("Found unknown argument(s) passed to '$name' attribute constructor in '$class': @bad");
 151 #    }
 152
 153     return $instance
 154 }
 155
 156 # readers
 157
 158 sub name                 { $_[0]->{name}                   }
 159 sub associated_class     { $_[0]->{associated_class}       }
 160
 161 sub accessor             { $_[0]->{accessor}               }
 162 sub reader               { $_[0]->{reader}                 }
 163 sub writer               { $_[0]->{writer}                 }
 164 sub predicate            { $_[0]->{predicate}              }
 165 sub clearer              { $_[0]->{clearer}                }
 166 sub handles              { $_[0]->{handles}                }
 167
 168 sub _is_metadata         { $_[0]->{is}                     }
 169 sub is_required          { $_[0]->{required}               }
 170 sub default              { $_[0]->{default}                }
 171 sub is_lazy              { $_[0]->{lazy}                   }
 172 sub is_lazy_build        { $_[0]->{lazy_build}             }
 173 sub is_weak_ref          { $_[0]->{weak_ref}               }
 174 sub init_arg             { $_[0]->{init_arg}               }
 175 sub type_constraint      { $_[0]->{type_constraint}        }
 176
 177 sub trigger              { $_[0]->{trigger}                }
 178 sub builder              { $_[0]->{builder}                }
 179 sub should_auto_deref    { $_[0]->{auto_deref}             }
 180 sub should_coerce        { $_[0]->{coerce}                 }
 181
 182 sub get_read_method      { $_[0]->{reader} || $_[0]->{accessor} }
 183 sub get_write_method     { $_[0]->{writer} || $_[0]->{accessor} }
 184
 185 # predicates
 186
 187 sub has_accessor         { exists $_[0]->{accessor}        }
 188 sub has_reader           { exists $_[0]->{reader}          }
 189 sub has_writer           { exists $_[0]->{writer}          }
 190 sub has_predicate        { exists $_[0]->{predicate}       }
 191 sub has_clearer          { exists $_[0]->{clearer}         }
 192 sub has_handles          { exists $_[0]->{handles}         }
 193
 194 sub has_default          { exists $_[0]->{default}         }
 195 sub has_type_constraint  { exists $_[0]->{type_constraint} }
 196 sub has_trigger          { exists $_[0]->{trigger}         }
 197 sub has_builder          { exists $_[0]->{builder}         }
 198
 199 sub has_read_method      { exists $_[0]->{reader} || exists $_[0]->{accessor} }
 200 sub has_write_method     { exists $_[0]->{writer} || exists $_[0]->{accessor} }
 201
 202 sub _create_args {
 203     $_[0]->{_create_args} = $_[1] if @_ > 1;
 204     $_[0]->{_create_args}
 205 }
 206
 207 sub interpolate_class{
 208     my($class, $name, $args) = @_;
 209
 210     if(my $metaclass = delete $args->{metaclass}){
 211         $class = Mouse::Util::resolve_metaclass_alias( Attribute => $metaclass );
 212     }
 213
 214     my @traits;
 215     if(my $traits_ref = delete $args->{traits}){
 216
 217         for (my $i = 0; $i < @{$traits_ref}; $i++) {
 218             my $trait = Mouse::Util::resolve_metaclass_alias(Attribute => $traits_ref->[$i], trait => 1);
 219
 220             next if $class->does($trait);
 221
 222             push @traits, $trait;
 223
 224             # are there options?
 225             push @traits, $traits_ref->[++$i]
 226                 if ref($traits_ref->[$i+1]);
 227         }
 228
 229         if (@traits) {
 230             $class = Mouse::Meta::Class->create_anon_class(
 231                 superclasses => [ $class ],
 232                 roles        => \@traits,
 233                 cache        => 1,
 234             )->name;
 235         }
 236     }
 237
 238     return( $class, @traits );
 239 }
 240
 241 sub canonicalize_args{
 242     my ($self, $name, %args) = @_;
 243
 244     Carp::cluck("$self->canonicalize_args has been deprecated."
 245         . "Use \$self->_process_options instead.");
 246
 247     return %args;
 248 }
 249
 250 sub create {
 251     my ($self, $class, $name, %args) = @_;
 252
 253     Carp::cluck("$self->create has been deprecated."
 254         . "Use \$meta->add_attribute and \$attr->install_accessors instead.");
 255
 256     # noop
 257     return $self;
 258 }
 259
 260 sub verify_against_type_constraint {
 261     my ($self, $value) = @_;
 262     my $tc = $self->type_constraint;
 263     return 1 unless $tc;
 264
 265     local $_ = $value;
 266     return 1 if $tc->check($value);
 267
 268     $self->verify_type_constraint_error($self->name, $value, $tc);
 269 }
 270
 271 sub verify_type_constraint_error {
 272     my($self, $name, $value, $type) = @_;
 273     $self->throw_error("Attribute ($name) does not pass the type constraint because: " . $type->get_message($value));
 274 }
 275
 276 sub coerce_constraint { ## my($self, $value) = @_;
 277     my $type = $_[0]->{type_constraint}
 278         or return $_[1];
 279     return Mouse::Util::TypeConstraints->typecast_constraints($_[0]->associated_class->name, $type, $_[1]);
 280 }
 281
 282 sub _canonicalize_handles {
 283     my $self    = shift;
 284     my $handles = shift;
 285
 286     if (ref($handles) eq 'HASH') {
 287         return %$handles;
 288     }
 289     elsif (ref($handles) eq 'ARRAY') {
 290         return map { $_ => $_ } @$handles;
 291     }
 292     else {
 293         $self->throw_error("Unable to canonicalize the 'handles' option with $handles");
 294     }
 295 }
 296
 297 sub clone_and_inherit_options{
 298     my $self = shift;
 299     my $name = shift;
 300
 301     return ref($self)->new($name, %{$self}, (@_ == 1) ? %{$_[0]} : @_);
 302 }
 303
 304 sub clone_parent {
 305     my $self  = shift;
 306     my $class = shift;
 307     my $name  = shift;
 308     my %args  = ($self->get_parent_args($class, $name), @_);
 309
 310     Carp::cluck("$self->clone_parent has been deprecated."
 311         . "Use \$meta->add_attribute and \$attr->install_accessors instead.");
 312
 313
 314     $self->clone_and_inherited_args($class, $name, %args);
 315 }
 316
 317 sub get_parent_args {
 318     my $self  = shift;
 319     my $class = shift;
 320     my $name  = shift;
 321
 322     for my $super ($class->linearized_isa) {
 323         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 324             or next;
 325         return %{ $super_attr->_create_args };
 326     }
 327
 328     $self->throw_error("Could not find an attribute by the name of '$name' to inherit from");
 329 }
 330
 331 sub install_accessors{
 332     my($attribute) = @_;
 333
 334     my $metaclass       = $attribute->{associated_class};
 335
 336     foreach my $type(qw(accessor reader writer predicate clearer handles)){
 337         if(exists $attribute->{$type}){
 338             my $installer    = '_install_' . $type;
 339
 340             Mouse::Meta::Method::Accessor->$installer($attribute, $attribute->{$type}, $metaclass);
 341
 342             $attribute->{associated_methods}++;
 343         }
 344     }
 345
 346     if($attribute->can('create') != \&create){
 347         # backword compatibility
 348         $attribute->create($metaclass, $attribute->name, %{$attribute});
 349     }
 350
 351     return;
 352 }
 353
 354 sub throw_error{
 355     my $self = shift;
 356
 357     my $metaclass = (ref $self && $self->associated_class) || 'Mouse::Meta::Class';
 358     $metaclass->throw_error(@_, depth => 1);
 359 }
 360
 361 1;
 362
 363 __END__
 364
 365 =head1 NAME
 366
 367 Mouse::Meta::Attribute - attribute metaclass
 368
 369 =head1 METHODS
 370
 371 =head2 C<< new(%options) -> Mouse::Meta::Attribute >>
 372
 373 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 374
 375 It adds the following options to the constructor:
 376
 377 =over 4
 378
 379 =item C<< is => 'ro', 'rw', 'bare' >>
 380
 381 This provides a shorthand for specifying the C<reader>, C<writer>, or
 382 C<accessor> names. If the attribute is read-only ('ro') then it will
 383 have a C<reader> method with the same attribute as the name.
 384
 385 If it is read-write ('rw') then it will have an C<accessor> method
 386 with the same name. If you provide an explicit C<writer> for a
 387 read-write attribute, then you will have a C<reader> with the same
 388 name as the attribute, and a C<writer> with the name you provided.
 389
 390 Use 'bare' when you are deliberately not installing any methods
 391 (accessor, reader, etc.) associated with this attribute; otherwise,
 392 Moose will issue a deprecation warning when this attribute is added to a
 393 metaclass.
 394
 395 =item C<< isa => Type >>
 396
 397 This option accepts a type. The type can be a string, which should be
 398 a type name. If the type name is unknown, it is assumed to be a class
 399 name.
 400
 401 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 402
 403 If you I<also> provide a C<does> option, then your C<isa> option must
 404 be a class name, and that class must do the role specified with
 405 C<does>.
 406
 407 =item C<< does => Role >>
 408
 409 This is short-hand for saying that the attribute's type must be an
 410 object which does the named role.
 411
 412 B<This option is not yet supported.>
 413
 414 =item C<< coerce => Bool >>
 415
 416 This option is only valid for objects with a type constraint
 417 (C<isa>). If this is true, then coercions will be applied whenever
 418 this attribute is set.
 419
 420 You can make both this and the C<weak_ref> option true.
 421
 422 =item C<< trigger => CodeRef >>
 423
 424 This option accepts a subroutine reference, which will be called after
 425 the attribute is set.
 426
 427 =item C<< required => Bool >>
 428
 429 An attribute which is required must be provided to the constructor. An
 430 attribute which is required can also have a C<default> or C<builder>,
 431 which will satisfy its required-ness.
 432
 433 A required attribute must have a C<default>, C<builder> or a
 434 non-C<undef> C<init_arg>
 435
 436 =item C<< lazy => Bool >>
 437
 438 A lazy attribute must have a C<default> or C<builder>. When an
 439 attribute is lazy, the default value will not be calculated until the
 440 attribute is read.
 441
 442 =item C<< weak_ref => Bool >>
 443
 444 If this is true, the attribute's value will be stored as a weak
 445 reference.
 446
 447 =item C<< auto_deref => Bool >>
 448
 449 If this is true, then the reader will dereference the value when it is
 450 called. The attribute must have a type constraint which defines the
 451 attribute as an array or hash reference.
 452
 453 =item C<< lazy_build => Bool >>
 454
 455 Setting this to true makes the attribute lazy and provides a number of
 456 default methods.
 457
 458   has 'size' => (
 459       is         => 'ro',
 460       lazy_build => 1,
 461   );
 462
 463 is equivalent to this:
 464
 465   has 'size' => (
 466       is        => 'ro',
 467       lazy      => 1,
 468       builder   => '_build_size',
 469       clearer   => 'clear_size',
 470       predicate => 'has_size',
 471   );
 472
 473 =back
 474
 475 =head2 C<< verify_against_type_constraint(Item) -> TRUE | ERROR >>
 476
 477 Checks that the given value passes this attribute's type constraint. Returns C<true>
 478 on success, otherwise C<confess>es.
 479
 480 =head2 C<< clone_and_inherit_options(options) -> Mouse::Meta::Attribute >>
 481
 482 Creates a new attribute in the owner class, inheriting options from parent classes.
 483 Accessors and helper methods are installed. Some error checking is done.
 484
 485 =head1 SEE ALSO
 486
 487 L<Moose::Meta::Attribute>
 488
 489 =cut
 490