lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use strict;
   3 use warnings;
   4 require overload;
   5
   6 use Carp 'confess';
   7 use Scalar::Util ();
   8
   9 sub new {
  10     my ($class, $name, %options) = @_;
  11
  12     $options{name} = $name;
  13
  14     $options{init_arg} = $name
  15         unless exists $options{init_arg};
  16
  17     $options{is} ||= '';
  18
  19     bless \%options, $class;
  20 }
  21
  22 sub name                 { $_[0]->{name}                   }
  23 sub associated_class     { $_[0]->{associated_class}       }
  24 sub _is_metadata         { $_[0]->{is}                     }
  25 sub is_required          { $_[0]->{required}               }
  26 sub default              { $_[0]->{default}                }
  27 sub is_lazy              { $_[0]->{lazy}                   }
  28 sub is_lazy_build        { $_[0]->{lazy_build}             }
  29 sub predicate            { $_[0]->{predicate}              }
  30 sub clearer              { $_[0]->{clearer}                }
  31 sub handles              { $_[0]->{handles}                }
  32 sub is_weak_ref          { $_[0]->{weak_ref}               }
  33 sub init_arg             { $_[0]->{init_arg}               }
  34 sub type_constraint      { $_[0]->{type_constraint}        }
  35 sub trigger              { $_[0]->{trigger}                }
  36 sub builder              { $_[0]->{builder}                }
  37 sub should_auto_deref    { $_[0]->{auto_deref}             }
  38 sub should_coerce        { $_[0]->{should_coerce}          }
  39 sub find_type_constraint { $_[0]->{find_type_constraint}   }
  40
  41 sub has_default          { exists $_[0]->{default}         }
  42 sub has_predicate        { exists $_[0]->{predicate}       }
  43 sub has_clearer          { exists $_[0]->{clearer}         }
  44 sub has_handles          { exists $_[0]->{handles}         }
  45 sub has_type_constraint  { exists $_[0]->{type_constraint} }
  46 sub has_trigger          { exists $_[0]->{trigger}         }
  47 sub has_builder          { exists $_[0]->{builder}         }
  48
  49 sub _create_args {
  50     $_[0]->{_create_args} = $_[1] if @_ > 1;
  51     $_[0]->{_create_args}
  52 }
  53
  54 sub inlined_name {
  55     my $self = shift;
  56     my $name = $self->name;
  57     my $key   = "'" . $name . "'";
  58     return $key;
  59 }
  60
  61 sub generate_accessor {
  62     my $attribute = shift;
  63
  64     my $name          = $attribute->name;
  65     my $default       = $attribute->default;
  66     my $constraint    = $attribute->find_type_constraint;
  67     my $builder       = $attribute->builder;
  68     my $trigger       = $attribute->trigger;
  69     my $is_weak       = $attribute->is_weak_ref;
  70     my $should_deref  = $attribute->should_auto_deref;
  71     my $should_coerce = $attribute->should_coerce;
  72
  73     my $self  = '$_[0]';
  74     my $key   = $attribute->inlined_name;
  75
  76     my $accessor = "sub {\n";
  77     if ($attribute->_is_metadata eq 'rw') {
  78         $accessor .= 'if (@_ >= 2) {' . "\n";
  79
  80         my $value = '$_[1]';
  81
  82         if ($constraint) {
  83             $accessor .= 'my $val = ';
  84             if ($should_coerce) {
  85                 $accessor  .= 'Mouse::Util::TypeConstraints->typecast_constraints("'.$attribute->associated_class->name.'", $attribute->{find_type_constraint}, $attribute->{type_constraint}, '.$value.');';
  86             } else {
  87                 $accessor .= $value.';';
  88             }
  89             $accessor .= 'local $_ = $val;';
  90             $accessor .= '
  91                 unless ($constraint->()) {
  92                     $attribute->verify_type_constraint_error($name, $_, $attribute->type_constraint);
  93                 }' . "\n";
  94             $value = '$val';
  95         }
  96
  97         # if there's nothing left to do for the attribute we can return during
  98         # this setter
  99         $accessor .= 'return ' if !$is_weak && !$trigger && !$should_deref;
 100
 101         $accessor .= $self.'->{'.$key.'} = '.$value.';' . "\n";
 102
 103         if ($is_weak) {
 104             $accessor .= 'Scalar::Util::weaken('.$self.'->{'.$key.'}) if ref('.$self.'->{'.$key.'});' . "\n";
 105         }
 106
 107         if ($trigger) {
 108             $accessor .= '$trigger->('.$self.', '.$value.', $attribute);' . "\n";
 109         }
 110
 111         $accessor .= "}\n";
 112     }
 113     else {
 114         $accessor .= 'confess "Cannot assign a value to a read-only accessor" if scalar(@_) >= 2;' . "\n";
 115     }
 116
 117     if ($attribute->is_lazy) {
 118         $accessor .= $self.'->{'.$key.'} = ';
 119
 120         $accessor .= $attribute->has_builder
 121                 ? $self.'->$builder'
 122                     : ref($default) eq 'CODE'
 123                     ? '$default->('.$self.')'
 124                     : '$default';
 125         $accessor .= ' if !exists '.$self.'->{'.$key.'};' . "\n";
 126     }
 127
 128     if ($should_deref) {
 129         my $type_constraint = $attribute->type_constraint;
 130         if (!ref($type_constraint) && $type_constraint eq 'ArrayRef') {
 131             $accessor .= 'if (wantarray) {
 132                 return @{ '.$self.'->{'.$key.'} || [] };
 133             }';
 134         }
 135         else {
 136             $accessor .= 'if (wantarray) {
 137                 return %{ '.$self.'->{'.$key.'} || {} };
 138             }';
 139         }
 140     }
 141
 142     $accessor .= 'return '.$self.'->{'.$key.'};
 143     }';
 144
 145     my $sub = eval $accessor;
 146     confess $@ if $@;
 147     return $sub;
 148 }
 149
 150 sub generate_predicate {
 151     my $attribute = shift;
 152     my $key = $attribute->inlined_name;
 153
 154     my $predicate = 'sub { exists($_[0]->{'.$key.'}) }';
 155
 156     my $sub = eval $predicate;
 157     confess $@ if $@;
 158     return $sub;
 159 }
 160
 161 sub generate_clearer {
 162     my $attribute = shift;
 163     my $key = $attribute->inlined_name;
 164
 165     my $clearer = 'sub { delete($_[0]->{'.$key.'}) }';
 166
 167     my $sub = eval $clearer;
 168     confess $@ if $@;
 169     return $sub;
 170 }
 171
 172 sub generate_handles {
 173     my $attribute = shift;
 174     my $reader = $attribute->name;
 175     my %handles = $attribute->_canonicalize_handles($attribute->handles);
 176
 177     my %method_map;
 178
 179     for my $local_method (keys %handles) {
 180         my $remote_method = $handles{$local_method};
 181
 182         my $method = 'sub {
 183             my $self = shift;
 184             $self->'.$reader.'->'.$remote_method.'(@_)
 185         }';
 186
 187         $method_map{$local_method} = eval $method;
 188         confess $@ if $@;
 189     }
 190
 191     return \%method_map;
 192 }
 193
 194 sub create {
 195     my ($self, $class, $name, %args) = @_;
 196
 197     $args{name} = $name;
 198     $args{associated_class} = $class;
 199
 200     %args = $self->canonicalize_args($name, %args);
 201     $self->validate_args($name, \%args);
 202
 203     $args{should_coerce} = delete $args{coerce}
 204         if exists $args{coerce};
 205
 206     if (exists $args{isa}) {
 207         confess "Mouse does not yet support parameterized types (rt.cpan.org #39795)"
 208             if $args{isa} =~ /\[.*\]/;
 209
 210         my $type_constraint = delete $args{isa};
 211         $type_constraint =~ s/\s//g;
 212         my @type_constraints = split /\|/, $type_constraint;
 213
 214         my $code;
 215         my $optimized_constraints = Mouse::Util::TypeConstraints->optimized_constraints;
 216         if (@type_constraints == 1) {
 217             $code = $optimized_constraints->{$type_constraints[0]} ||
 218                 sub { Scalar::Util::blessed($_) && $_->isa($type_constraints[0]) };
 219             $args{type_constraint} = $type_constraints[0];
 220         } else {
 221             my @code_list = map {
 222                 my $type = $_;
 223                 $optimized_constraints->{$type} ||
 224                     sub { Scalar::Util::blessed($_) && $_->isa($type) }
 225             } @type_constraints;
 226             $code = sub {
 227                 for my $code (@code_list) {
 228                     return 1 if $code->();
 229                 }
 230                 return 0;
 231             };
 232             $args{type_constraint} = \@type_constraints;
 233         }
 234         $args{find_type_constraint} = $code;
 235     }
 236
 237     my $attribute = $self->new($name, %args);
 238
 239     $attribute->_create_args(\%args);
 240
 241     $class->add_attribute($attribute);
 242
 243     # install an accessor
 244     if ($attribute->_is_metadata eq 'rw' || $attribute->_is_metadata eq 'ro') {
 245         my $accessor = $attribute->generate_accessor;
 246         $class->add_method($name => $accessor);
 247     }
 248
 249     for my $method (qw/predicate clearer/) {
 250         my $predicate = "has_$method";
 251         if ($attribute->$predicate) {
 252             my $generator = "generate_$method";
 253             my $coderef = $attribute->$generator;
 254             $class->add_method($attribute->$method => $coderef);
 255         }
 256     }
 257
 258     if ($attribute->has_handles) {
 259         my $method_map = $attribute->generate_handles;
 260         for my $method_name (keys %$method_map) {
 261             $class->add_method($method_name => $method_map->{$method_name});
 262         }
 263     }
 264
 265     return $attribute;
 266 }
 267
 268 sub canonicalize_args {
 269     my $self = shift;
 270     my $name = shift;
 271     my %args = @_;
 272
 273     if ($args{lazy_build}) {
 274         $args{lazy}      = 1;
 275         $args{required}  = 1;
 276         $args{builder}   = "_build_${name}"
 277             if !exists($args{builder});
 278         if ($name =~ /^_/) {
 279             $args{clearer}   = "_clear${name}" if !exists($args{clearer});
 280             $args{predicate} = "_has${name}" if !exists($args{predicate});
 281         }
 282         else {
 283             $args{clearer}   = "clear_${name}" if !exists($args{clearer});
 284             $args{predicate} = "has_${name}" if !exists($args{predicate});
 285         }
 286     }
 287
 288     return %args;
 289 }
 290
 291 sub validate_args {
 292     my $self = shift;
 293     my $name = shift;
 294     my $args = shift;
 295
 296     confess "You can not use lazy_build and default for the same attribute ($name)"
 297         if $args->{lazy_build} && exists $args->{default};
 298
 299     confess "You cannot have lazy attribute ($name) without specifying a default value for it"
 300         if $args->{lazy}
 301         && !exists($args->{default})
 302         && !exists($args->{builder});
 303
 304     confess "References are not allowed as default values, you must wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])"
 305         if ref($args->{default})
 306         && ref($args->{default}) ne 'CODE';
 307
 308     confess "You cannot auto-dereference without specifying a type constraint on attribute ($name)"
 309         if $args->{auto_deref} && !exists($args->{isa});
 310
 311     confess "You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)"
 312         if $args->{auto_deref}
 313         && $args->{isa} ne 'ArrayRef'
 314         && $args->{isa} ne 'HashRef';
 315
 316     if ($args->{trigger}) {
 317         if (ref($args->{trigger}) eq 'HASH') {
 318             Carp::carp "HASH-based form of trigger has been removed. Only the coderef form of triggers are now supported.";
 319         }
 320
 321         confess "Trigger must be a CODE ref on attribute ($name)"
 322             if ref($args->{trigger}) ne 'CODE';
 323     }
 324
 325     return 1;
 326 }
 327
 328 sub verify_against_type_constraint {
 329     return 1 unless $_[0]->{type_constraint};
 330
 331     local $_ = $_[1];
 332     return 1 if $_[0]->{find_type_constraint}->($_);
 333
 334     my $self = shift;
 335     $self->verify_type_constraint_error($self->name, $_, $self->type_constraint);
 336 }
 337
 338 sub verify_type_constraint_error {
 339     my($self, $name, $value, $type) = @_;
 340     $type = ref($type) eq 'ARRAY' ? join '|', @{ $type } : $type;
 341     my $display = defined($_) ? overload::StrVal($_) : 'undef';
 342     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
 343 }
 344
 345 sub coerce_constraint { ## my($self, $value) = @_;
 346     my $type = $_[0]->{type_constraint}
 347         or return $_[1];
 348     return Mouse::Util::TypeConstraints->typecast_constraints($_[0]->associated_class->name, $_[0]->find_type_constraint, $type, $_[1]);
 349 }
 350
 351 sub _canonicalize_handles {
 352     my $self    = shift;
 353     my $handles = shift;
 354
 355     if (ref($handles) eq 'HASH') {
 356         return %$handles;
 357     }
 358     elsif (ref($handles) eq 'ARRAY') {
 359         return map { $_ => $_ } @$handles;
 360     }
 361     else {
 362         confess "Unable to canonicalize the 'handles' option with $handles";
 363     }
 364 }
 365
 366 sub clone_parent {
 367     my $self  = shift;
 368     my $class = shift;
 369     my $name  = shift;
 370     my %args  = ($self->get_parent_args($class, $name), @_);
 371
 372     $self->create($class, $name, %args);
 373 }
 374
 375 sub get_parent_args {
 376     my $self  = shift;
 377     my $class = shift;
 378     my $name  = shift;
 379
 380     for my $super ($class->linearized_isa) {
 381         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 382             or next;
 383         return %{ $super_attr->_create_args };
 384     }
 385
 386     confess "Could not find an attribute by the name of '$name' to inherit from";
 387 }
 388
 389 1;
 390
 391 __END__
 392
 393 =head1 NAME
 394
 395 Mouse::Meta::Attribute - attribute metaclass
 396
 397 =head1 METHODS
 398
 399 =head2 new %args -> Mouse::Meta::Attribute
 400
 401 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 402
 403 =head2 create OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 404
 405 Creates a new attribute in OwnerClass. Accessors and helper methods are
 406 installed. Some error checking is done.
 407
 408 =head2 name -> AttributeName
 409
 410 =head2 associated_class -> OwnerClass
 411
 412 =head2 is_required -> Bool
 413
 414 =head2 default -> Item
 415
 416 =head2 has_default -> Bool
 417
 418 =head2 is_lazy -> Bool
 419
 420 =head2 predicate -> MethodName | Undef
 421
 422 =head2 has_predicate -> Bool
 423
 424 =head2 clearer -> MethodName | Undef
 425
 426 =head2 has_clearer -> Bool
 427
 428 =head2 handles -> { LocalName => RemoteName }
 429
 430 =head2 has_handles -> Bool
 431
 432 =head2 is_weak_ref -> Bool
 433
 434 =head2 init_arg -> Str
 435
 436 =head2 type_constraint -> Str
 437
 438 =head2 has_type_constraint -> Bool
 439
 440 =head2 trigger => CODE | Undef
 441
 442 =head2 has_trigger -> Bool
 443
 444 =head2 builder => MethodName | Undef
 445
 446 =head2 has_builder -> Bool
 447
 448 =head2 is_lazy_build => Bool
 449
 450 =head2 should_auto_deref -> Bool
 451
 452 Informational methods.
 453
 454 =head2 generate_accessor -> CODE
 455
 456 Creates a new code reference for the attribute's accessor.
 457
 458 =head2 generate_predicate -> CODE
 459
 460 Creates a new code reference for the attribute's predicate.
 461
 462 =head2 generate_clearer -> CODE
 463
 464 Creates a new code reference for the attribute's clearer.
 465
 466 =head2 generate_handles -> { MethodName => CODE }
 467
 468 Creates a new code reference for each of the attribute's handles methods.
 469
 470 =head2 find_type_constraint -> CODE
 471
 472 Returns a code reference which can be used to check that a given value passes
 473 this attribute's type constraint;
 474
 475 =head2 verify_against_type_constraint Item -> 1 | ERROR
 476
 477 Checks that the given value passes this attribute's type constraint. Returns 1
 478 on success, otherwise C<confess>es.
 479
 480 =head2 canonicalize_args Name, %args -> %args
 481
 482 Canonicalizes some arguments to create. In particular, C<lazy_build> is
 483 canonicalized into C<lazy>, C<builder>, etc.
 484
 485 =head2 validate_args Name, \%args -> 1 | ERROR
 486
 487 Checks that the arguments to create the attribute (ie those specified by
 488 C<has>) are valid.
 489
 490 =head2 clone_parent OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 491
 492 Creates a new attribute in OwnerClass, inheriting options from parent classes.
 493 Accessors and helper methods are installed. Some error checking is done.
 494
 495 =head2 get_parent_args OwnerClass, AttributeName -> Hash
 496
 497 Returns the options that the parent class of C<OwnerClass> used for attribute
 498 C<AttributeName>.
 499
 500 =cut
 501