lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use strict;
   3 use warnings;
   4
   5 use Carp ();
   6 use Scalar::Util qw(weaken);
   7
   8 use Mouse::Util qw(:meta);
   9
  10 use Mouse::Meta::TypeConstraint;
  11 use Mouse::Meta::Method::Accessor;
  12
  13 sub _process_options{
  14     my($class, $name, $args) = @_;
  15
  16     # taken from Class::MOP::Attribute::new
  17
  18     defined($name)
  19         or $class->throw_error('You must provide a name for the attribute');
  20
  21     if(!exists $args->{init_arg}){
  22         $args->{init_arg} = $name;
  23     }
  24
  25     # 'required' requires eigher 'init_arg', 'builder', or 'default'
  26     my $can_be_required = defined( $args->{init_arg} );
  27
  28     if(exists $args->{builder}){
  29         $class->throw_error('builder must be a defined scalar value which is a method name')
  30             if ref $args->{builder} || !(defined $args->{builder});
  31
  32         $can_be_required++;
  33     }
  34     elsif(exists $args->{default}){
  35         if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
  36             $class->throw_error("References are not allowed as default values, you must "
  37                               . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
  38         }
  39         $can_be_required++;
  40     }
  41
  42     if( $args->{required} && !$can_be_required ) {
  43         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
  44     }
  45
  46     # taken from Mouse::Meta::Attribute->new and _process_args->
  47
  48     if(exists $args->{is}){
  49         my $is = $args->{is};
  50
  51         if($is eq 'ro'){
  52             $args->{reader} ||= $name;
  53         }
  54         elsif($is eq 'rw'){
  55             if(exists $args->{writer}){
  56                 $args->{reader} ||= $name;
  57              }
  58              else{
  59                 $args->{accessor} ||= $name;
  60              }
  61         }
  62         elsif($is eq 'bare'){
  63             # do nothing, but don't complain (later) about missing methods
  64         }
  65         else{
  66             $is = 'undef' if !defined $is;
  67             $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
  68         }
  69     }
  70
  71     my $tc;
  72     if(exists $args->{isa}){
  73         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
  74     }
  75     elsif(exists $args->{does}){
  76         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
  77     }
  78     $tc = $args->{type_constraint};
  79
  80     if($args->{coerce}){
  81         defined($tc)
  82             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
  83
  84         $args->{weak_ref}
  85             && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
  86     }
  87
  88     if ($args->{lazy_build}) {
  89         exists($args->{default})
  90             && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
  91
  92         $args->{lazy}      = 1;
  93         $args->{builder} ||= "_build_${name}";
  94         if ($name =~ /^_/) {
  95             $args->{clearer}   ||= "_clear${name}";
  96             $args->{predicate} ||= "_has${name}";
  97         }
  98         else {
  99             $args->{clearer}   ||= "clear_${name}";
 100             $args->{predicate} ||= "has_${name}";
 101         }
 102     }
 103
 104     if ($args->{auto_deref}) {
 105         defined($tc)
 106             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
 107
 108         ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
 109             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
 110     }
 111
 112     if (exists $args->{trigger}) {
 113         ('CODE' eq ref $args->{trigger})
 114             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
 115     }
 116
 117     if ($args->{lazy}) {
 118         (exists $args->{default} || defined $args->{builder})
 119             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
 120     }
 121
 122     # XXX: for backward compatibility (with method modifiers)
 123     if($class->can('canonicalize_args') != \&canonicalize_args){
 124         %{$args} = $class->canonicalize_args($name, %{$args});
 125     }
 126     return;
 127 }
 128
 129 sub new {
 130     my $class = shift;
 131     my $name  = shift;
 132
 133     my %args  = (@_ == 1) ? %{ $_[0] } : @_;
 134
 135     $class->_process_options($name, \%args);
 136
 137     $args{name} = $name;
 138
 139     my $instance = bless \%args, $class;
 140
 141     # extra attributes
 142     if($class ne __PACKAGE__){
 143         $class->meta->_initialize_instance($instance,\%args);
 144     }
 145
 146 # XXX: there is no fast way to check attribute validity
 147 #    my @bad = ...;
 148 #    if(@bad){
 149 #        @bad = sort @bad;
 150 #        Carp::cluck("Found unknown argument(s) passed to '$name' attribute constructor in '$class': @bad");
 151 #    }
 152
 153     return $instance
 154 }
 155
 156 # readers
 157
 158 sub name                 { $_[0]->{name}                   }
 159 sub associated_class     { $_[0]->{associated_class}       }
 160
 161 sub accessor             { $_[0]->{accessor}               }
 162 sub reader               { $_[0]->{reader}                 }
 163 sub writer               { $_[0]->{writer}                 }
 164 sub predicate            { $_[0]->{predicate}              }
 165 sub clearer              { $_[0]->{clearer}                }
 166 sub handles              { $_[0]->{handles}                }
 167
 168 sub _is_metadata         { $_[0]->{is}                     }
 169 sub is_required          { $_[0]->{required}               }
 170 sub default              { $_[0]->{default}                }
 171 sub is_lazy              { $_[0]->{lazy}                   }
 172 sub is_lazy_build        { $_[0]->{lazy_build}             }
 173 sub is_weak_ref          { $_[0]->{weak_ref}               }
 174 sub init_arg             { $_[0]->{init_arg}               }
 175 sub type_constraint      { $_[0]->{type_constraint}        }
 176
 177 sub trigger              { $_[0]->{trigger}                }
 178 sub builder              { $_[0]->{builder}                }
 179 sub should_auto_deref    { $_[0]->{auto_deref}             }
 180 sub should_coerce        { $_[0]->{coerce}                 }
 181
 182 sub get_read_method      { $_[0]->{reader} || $_[0]->{accessor} }
 183 sub get_write_method     { $_[0]->{writer} || $_[0]->{accessor} }
 184
 185 # predicates
 186
 187 sub has_accessor         { exists $_[0]->{accessor}        }
 188 sub has_reader           { exists $_[0]->{reader}          }
 189 sub has_writer           { exists $_[0]->{writer}          }
 190 sub has_predicate        { exists $_[0]->{predicate}       }
 191 sub has_clearer          { exists $_[0]->{clearer}         }
 192 sub has_handles          { exists $_[0]->{handles}         }
 193
 194 sub has_default          { exists $_[0]->{default}         }
 195 sub has_type_constraint  { exists $_[0]->{type_constraint} }
 196 sub has_trigger          { exists $_[0]->{trigger}         }
 197 sub has_builder          { exists $_[0]->{builder}         }
 198
 199 sub has_read_method      { exists $_[0]->{reader} || exists $_[0]->{accessor} }
 200 sub has_write_method     { exists $_[0]->{writer} || exists $_[0]->{accessor} }
 201
 202 sub _create_args {
 203     $_[0]->{_create_args} = $_[1] if @_ > 1;
 204     $_[0]->{_create_args}
 205 }
 206
 207 sub accessor_metaclass { 'Mouse::Meta::Method::Accessor' }
 208
 209 sub interpolate_class{
 210     my($class, $name, $args) = @_;
 211
 212     if(my $metaclass = delete $args->{metaclass}){
 213         $class = Mouse::Util::resolve_metaclass_alias( Attribute => $metaclass );
 214     }
 215
 216     my @traits;
 217     if(my $traits_ref = delete $args->{traits}){
 218
 219         for (my $i = 0; $i < @{$traits_ref}; $i++) {
 220             my $trait = Mouse::Util::resolve_metaclass_alias(Attribute => $traits_ref->[$i], trait => 1);
 221
 222             next if $class->does($trait);
 223
 224             push @traits, $trait;
 225
 226             # are there options?
 227             push @traits, $traits_ref->[++$i]
 228                 if ref($traits_ref->[$i+1]);
 229         }
 230
 231         if (@traits) {
 232             $class = Mouse::Meta::Class->create_anon_class(
 233                 superclasses => [ $class ],
 234                 roles        => \@traits,
 235                 cache        => 1,
 236             )->name;
 237         }
 238     }
 239
 240     return( $class, @traits );
 241 }
 242
 243 sub canonicalize_args{
 244     my ($self, $name, %args) = @_;
 245
 246     Carp::cluck("$self->canonicalize_args has been deprecated."
 247         . "Use \$self->_process_options instead.");
 248
 249     return %args;
 250 }
 251
 252 sub create {
 253     my ($self, $class, $name, %args) = @_;
 254
 255     Carp::cluck("$self->create has been deprecated."
 256         . "Use \$meta->add_attribute and \$attr->install_accessors instead.");
 257
 258     # noop
 259     return $self;
 260 }
 261
 262 sub verify_against_type_constraint {
 263     my ($self, $value) = @_;
 264     my $tc = $self->type_constraint;
 265     return 1 unless $tc;
 266
 267     local $_ = $value;
 268     return 1 if $tc->check($value);
 269
 270     $self->verify_type_constraint_error($self->name, $value, $tc);
 271 }
 272
 273 sub verify_type_constraint_error {
 274     my($self, $name, $value, $type) = @_;
 275     $self->throw_error("Attribute ($name) does not pass the type constraint because: " . $type->get_message($value));
 276 }
 277
 278 sub coerce_constraint { ## my($self, $value) = @_;
 279     my $type = $_[0]->{type_constraint}
 280         or return $_[1];
 281     return Mouse::Util::TypeConstraints->typecast_constraints($_[0]->associated_class->name, $_[0]->type_constraint, $_[1]);
 282 }
 283
 284 sub _canonicalize_handles {
 285     my $self    = shift;
 286     my $handles = shift;
 287
 288     if (ref($handles) eq 'HASH') {
 289         return %$handles;
 290     }
 291     elsif (ref($handles) eq 'ARRAY') {
 292         return map { $_ => $_ } @$handles;
 293     }
 294     else {
 295         $self->throw_error("Unable to canonicalize the 'handles' option with $handles");
 296     }
 297 }
 298
 299 sub clone_and_inherit_options{
 300     my $self = shift;
 301     my $name = shift;
 302
 303     return ref($self)->new($name, %{$self}, @_ == 1 ? %{$_[0]} : @_);
 304 }
 305
 306 sub clone_parent {
 307     my $self  = shift;
 308     my $class = shift;
 309     my $name  = shift;
 310     my %args  = ($self->get_parent_args($class, $name), @_);
 311
 312     Carp::cluck("$self->clone_parent has been deprecated."
 313         . "Use \$meta->add_attribute and \$attr->install_accessors instead.");
 314
 315
 316     $self->create($class, $name, %args);
 317 }
 318
 319 sub get_parent_args {
 320     my $self  = shift;
 321     my $class = shift;
 322     my $name  = shift;
 323
 324     for my $super ($class->linearized_isa) {
 325         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 326             or next;
 327         return %{ $super_attr->_create_args };
 328     }
 329
 330     $self->throw_error("Could not find an attribute by the name of '$name' to inherit from");
 331 }
 332
 333 sub install_accessors{
 334     my($attribute) = @_;
 335
 336     my $metaclass       = $attribute->{associated_class};
 337     my $generator_class = $attribute->accessor_metaclass;
 338
 339     foreach my $type(qw(accessor reader writer predicate clearer handles)){
 340         if(exists $attribute->{$type}){
 341             my $installer    = '_install_' . $type;
 342             $generator_class->$installer($attribute, $attribute->{$type}, $metaclass);
 343             $attribute->{associated_methods}++;
 344         }
 345     }
 346
 347     if($attribute->can('create') != \&create){
 348         $attribute->create($metaclass, $attribute->name, %{$attribute});
 349     }
 350
 351     return;
 352 }
 353
 354 sub throw_error{
 355     my $self = shift;
 356
 357     my $metaclass = (ref $self && $self->associated_class) || 'Mouse::Meta::Class';
 358     $metaclass->throw_error(@_, depth => 1);
 359 }
 360
 361 1;
 362
 363 __END__
 364
 365 =head1 NAME
 366
 367 Mouse::Meta::Attribute - attribute metaclass
 368
 369 =head1 METHODS
 370
 371 =head2 new %args -> Mouse::Meta::Attribute
 372
 373 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 374
 375 =head2 create OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 376
 377 Creates a new attribute in OwnerClass. Accessors and helper methods are
 378 installed. Some error checking is done.
 379
 380 =head2 name -> AttributeName
 381
 382 =head2 associated_class -> OwnerClass
 383
 384 =head2 is_required -> Bool
 385
 386 =head2 default -> Item
 387
 388 =head2 has_default -> Bool
 389
 390 =head2 is_lazy -> Bool
 391
 392 =head2 predicate -> MethodName | Undef
 393
 394 =head2 has_predicate -> Bool
 395
 396 =head2 clearer -> MethodName | Undef
 397
 398 =head2 has_clearer -> Bool
 399
 400 =head2 handles -> { LocalName => RemoteName }
 401
 402 =head2 has_handles -> Bool
 403
 404 =head2 is_weak_ref -> Bool
 405
 406 =head2 init_arg -> Str
 407
 408 =head2 type_constraint -> Str
 409
 410 =head2 has_type_constraint -> Bool
 411
 412 =head2 trigger => CODE | Undef
 413
 414 =head2 has_trigger -> Bool
 415
 416 =head2 builder => MethodName | Undef
 417
 418 =head2 has_builder -> Bool
 419
 420 =head2 is_lazy_build => Bool
 421
 422 =head2 should_auto_deref -> Bool
 423
 424 Informational methods.
 425
 426 =head2 verify_against_type_constraint Item -> 1 | ERROR
 427
 428 Checks that the given value passes this attribute's type constraint. Returns 1
 429 on success, otherwise C<confess>es.
 430
 431 =head2 canonicalize_args Name, %args -> %args
 432
 433 Canonicalizes some arguments to create. In particular, C<lazy_build> is
 434 canonicalized into C<lazy>, C<builder>, etc.
 435
 436 =head2 validate_args Name, \%args -> 1 | ERROR
 437
 438 Checks that the arguments to create the attribute (ie those specified by
 439 C<has>) are valid.
 440
 441 =head2 clone_parent OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 442
 443 Creates a new attribute in OwnerClass, inheriting options from parent classes.
 444 Accessors and helper methods are installed. Some error checking is done.
 445
 446 =head2 get_parent_args OwnerClass, AttributeName -> Hash
 447
 448 Returns the options that the parent class of C<OwnerClass> used for attribute
 449 C<AttributeName>.
 450
 451 =cut
 452