lib/Mouse/Meta/Attribute.pm

   1 #!/usr/bin/env perl
   2 package Mouse::Meta::Attribute;
   3 use strict;
   4 use warnings;
   5
   6 use Carp 'confess';
   7 use Scalar::Util 'blessed';
   8
   9 sub new {
  10     my $class = shift;
  11     my %args  = @_;
  12
  13     my $name = $args{name};
  14
  15     $args{init_arg} = $name
  16         unless exists $args{init_arg};
  17
  18     $args{is} ||= '';
  19
  20     bless \%args, $class;
  21 }
  22
  23 sub name              { $_[0]->{name}            }
  24 sub class             { $_[0]->{class}           }
  25 sub _is_metadata      { $_[0]->{is}              }
  26 sub is_required       { $_[0]->{required}        }
  27 sub default           { $_[0]->{default}         }
  28 sub is_lazy           { $_[0]->{lazy}            }
  29 sub is_lazy_build     { $_[0]->{lazy_build}      }
  30 sub predicate         { $_[0]->{predicate}       }
  31 sub clearer           { $_[0]->{clearer}         }
  32 sub handles           { $_[0]->{handles}         }
  33 sub is_weak_ref       { $_[0]->{weak_ref}        }
  34 sub init_arg          { $_[0]->{init_arg}        }
  35 sub type_constraint   { $_[0]->{type_constraint} }
  36 sub trigger           { $_[0]->{trigger}         }
  37 sub builder           { $_[0]->{builder}         }
  38 sub should_auto_deref { $_[0]->{auto_deref}      }
  39
  40 sub has_default         { exists $_[0]->{default}         }
  41 sub has_predicate       { exists $_[0]->{predicate}       }
  42 sub has_clearer         { exists $_[0]->{clearer}         }
  43 sub has_handles         { exists $_[0]->{handles}         }
  44 sub has_type_constraint { exists $_[0]->{type_constraint} }
  45 sub has_trigger         { exists $_[0]->{trigger}         }
  46 sub has_builder         { exists $_[0]->{builder}         }
  47
  48 sub _create_args {
  49     $_[0]->{_create_args} = $_[1] if @_ > 1;
  50     $_[0]->{_create_args}
  51 }
  52
  53 sub generate_accessor {
  54     my $attribute = shift;
  55
  56     my $name       = $attribute->name;
  57     my $key        = $name;
  58     my $default    = $attribute->default;
  59     my $trigger    = $attribute->trigger;
  60     my $type       = $attribute->type_constraint;
  61     my $constraint = $attribute->find_type_constraint;
  62     my $builder    = $attribute->builder;
  63
  64     my $accessor = 'sub {
  65         my $self = shift;';
  66
  67     if ($attribute->_is_metadata eq 'rw') {
  68         $accessor .= 'if (@_) {
  69             local $_ = $_[0];';
  70
  71         if ($constraint) {
  72             $accessor .= 'do {
  73                 my $display = defined($_) ? overload::StrVal($_) : "undef";
  74                 Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display") unless $constraint->();
  75             };'
  76         }
  77
  78         $accessor .= '$self->{$key} = $_;';
  79
  80         if ($attribute->is_weak_ref) {
  81             $accessor .= 'Scalar::Util::weaken($self->{$key}) if ref($self->{$key});';
  82         }
  83
  84         if ($trigger) {
  85             $accessor .= '$trigger->($self, $_, $attribute);';
  86         }
  87
  88         $accessor .= '}';
  89     }
  90     else {
  91         $accessor .= 'confess "Cannot assign a value to a read-only accessor" if @_;';
  92     }
  93
  94     if ($attribute->is_lazy) {
  95         $accessor .= '$self->{$key} = ';
  96
  97         $accessor .= $attribute->has_builder
  98                    ? '$self->$builder'
  99                      : ref($default) eq 'CODE'
 100                      ? '$default->($self)'
 101                      : '$default';
 102
 103         $accessor .= ' if !exists($self->{$key});';
 104     }
 105
 106     if ($attribute->should_auto_deref) {
 107         if ($attribute->type_constraint eq 'ArrayRef') {
 108             $accessor .= 'if (wantarray) {
 109                 return @{ $self->{$key} || [] };
 110             }';
 111         }
 112         else {
 113             $accessor .= 'if (wantarray) {
 114                 return %{ $self->{$key} || {} };
 115             }';
 116         }
 117     }
 118
 119     $accessor .= 'return $self->{$key};
 120     }';
 121
 122     return eval $accessor;
 123 }
 124
 125 sub generate_predicate {
 126     my $attribute = shift;
 127     my $key = $attribute->name;
 128
 129     my $predicate = 'sub { exists($_[0]->{$key}) }';
 130
 131     return eval $predicate;
 132 }
 133
 134 sub generate_clearer {
 135     my $attribute = shift;
 136     my $key = $attribute->name;
 137
 138     my $predicate = 'sub { delete($_[0]->{$key}) }';
 139
 140     return eval $predicate;
 141 }
 142
 143 sub generate_handles {
 144     my $attribute = shift;
 145     my $reader = $attribute->name;
 146     my %handles = $attribute->_canonicalize_handles($attribute->handles);
 147
 148     my %method_map;
 149
 150     for my $local_method (keys %handles) {
 151         my $remote_method = $handles{$local_method};
 152
 153         my $method = 'sub {
 154             my $self = shift;
 155             $self->$reader->$remote_method(@_)
 156         }';
 157
 158         $method_map{$local_method} = eval $method;
 159     }
 160
 161     return \%method_map;
 162 }
 163
 164 sub create {
 165     my ($self, $class, $name, %args) = @_;
 166
 167     $args{name} = $name;
 168     $args{class} = $class;
 169
 170     %args = $self->canonicalize_args($name, %args);
 171     $self->validate_args($name, \%args);
 172
 173     $args{type_constraint} = delete $args{isa}
 174         if exists $args{isa};
 175
 176     my $attribute = $self->new(%args);
 177     $attribute->_create_args(\%args);
 178
 179     my $meta = $class->meta;
 180
 181     $meta->add_attribute($attribute);
 182
 183     # install an accessor
 184     if ($attribute->_is_metadata eq 'rw' || $attribute->_is_metadata eq 'ro') {
 185         my $accessor = $attribute->generate_accessor;
 186         no strict 'refs';
 187         *{ $class . '::' . $name } = $accessor;
 188     }
 189
 190     for my $method (qw/predicate clearer/) {
 191         my $predicate = "has_$method";
 192         if ($attribute->$predicate) {
 193             my $generator = "generate_$method";
 194             my $coderef = $attribute->$generator;
 195             no strict 'refs';
 196             *{ $class . '::' . $attribute->$method } = $coderef;
 197         }
 198     }
 199
 200     if ($attribute->has_handles) {
 201         my $method_map = $attribute->generate_handles;
 202         for my $method_name (keys %$method_map) {
 203             no strict 'refs';
 204             *{ $class . '::' . $method_name } = $method_map->{$method_name};
 205         }
 206     }
 207
 208     return $attribute;
 209 }
 210
 211 sub canonicalize_args {
 212     my $self = shift;
 213     my $name = shift;
 214     my %args = @_;
 215
 216     if ($args{lazy_build}) {
 217         $args{lazy}      = 1;
 218         $args{required}  = 1;
 219         $args{builder}   = "_build_${name}"
 220             if !exists($args{builder});
 221         if ($name =~ /^_/) {
 222             $args{clearer}   = "_clear${name}" if !exists($args{clearer});
 223             $args{predicate} = "_has${name}" if !exists($args{predicate});
 224         }
 225         else {
 226             $args{clearer}   = "clear_${name}" if !exists($args{clearer});
 227             $args{predicate} = "has_${name}" if !exists($args{predicate});
 228         }
 229     }
 230
 231     return %args;
 232 }
 233
 234 sub validate_args {
 235     my $self = shift;
 236     my $name = shift;
 237     my $args = shift;
 238
 239     confess "You can not use lazy_build and default for the same attribute ($name)"
 240         if $args->{lazy_build} && exists $args->{default};
 241
 242     confess "You cannot have lazy attribute ($name) without specifying a default value for it"
 243         if $args->{lazy}
 244         && !exists($args->{default})
 245         && !exists($args->{builder});
 246
 247     confess "References are not allowed as default values, you must wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])"
 248         if ref($args->{default})
 249         && ref($args->{default}) ne 'CODE';
 250
 251     confess "You cannot auto-dereference without specifying a type constraint on attribute $name"
 252         if $args->{auto_deref} && !exists($args->{isa});
 253
 254     confess "You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute $name"
 255         if $args->{auto_deref}
 256         && $args->{isa} ne 'ArrayRef'
 257         && $args->{isa} ne 'HashRef';
 258
 259     if ($args->{trigger}) {
 260         if (ref($args->{trigger}) eq 'CODE') {
 261             $args->{trigger} = {
 262                 after => $args->{trigger},
 263             };
 264         }
 265
 266         confess "Trigger must be a CODE or HASH ref on attribute ($name)"
 267             if $args->{trigger}
 268             && ref($args->{trigger}) ne 'HASH';
 269     }
 270
 271     return 1;
 272 }
 273
 274 sub find_type_constraint {
 275     my $self = shift;
 276     my $type = $self->type_constraint;
 277
 278     return unless $type;
 279
 280     my $checker = Mouse::TypeRegistry->optimized_constraints->{$type};
 281     return $checker if $checker;
 282
 283     return sub { blessed($_) && blessed($_) eq $type };
 284 }
 285
 286 sub verify_type_constraint {
 287     my $self = shift;
 288     local $_ = shift;
 289
 290     my $type = $self->type_constraint
 291         or return 1;
 292     my $constraint = $self->find_type_constraint;
 293
 294     return 1 if $constraint->($_);
 295
 296     my $name = $self->name;
 297     my $display = defined($_) ? overload::StrVal($_) : 'undef';
 298     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
 299 }
 300
 301 sub _canonicalize_handles {
 302     my $self    = shift;
 303     my $handles = shift;
 304
 305     if (ref($handles) eq 'HASH') {
 306         return %$handles;
 307     }
 308     elsif (ref($handles) eq 'ARRAY') {
 309         return map { $_ => $_ } @$handles;
 310     }
 311     else {
 312         confess "Unable to canonicalize the 'handles' option with $handles";
 313     }
 314 }
 315
 316 sub clone_parent {
 317     my $self  = shift;
 318     my $class = shift;
 319     my $name  = shift;
 320     my %args  = ($self->get_parent_args($class, $name), @_);
 321
 322     $self->create($class, $name, %args);
 323 }
 324
 325 sub get_parent_args {
 326     my $self  = shift;
 327     my $class = shift;
 328     my $name  = shift;
 329
 330     for my $super ($class->meta->linearized_isa) {
 331         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 332             or next;
 333         return %{ $super_attr->_create_args };
 334     }
 335
 336     confess "Could not find an attribute by the name of '$name' to inherit from";
 337 }
 338
 339 1;
 340
 341 __END__
 342
 343 =head1 NAME
 344
 345 Mouse::Meta::Attribute - attribute metaclass
 346
 347 =head1 METHODS
 348
 349 =head2 new %args -> Mouse::Meta::Attribute
 350
 351 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 352
 353 =head2 create OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 354
 355 Creates a new attribute in OwnerClass. Accessors and helper methods are
 356 installed. Some error checking is done.
 357
 358 =head2 name -> AttributeName
 359
 360 =head2 class -> OwnerClass
 361
 362 =head2 is_required -> Bool
 363
 364 =head2 default -> Item
 365
 366 =head2 has_default -> Bool
 367
 368 =head2 is_lazy -> Bool
 369
 370 =head2 predicate -> MethodName | Undef
 371
 372 =head2 has_predicate -> Bool
 373
 374 =head2 clearer -> MethodName | Undef
 375
 376 =head2 has_clearer -> Bool
 377
 378 =head2 handles -> { LocalName => RemoteName }
 379
 380 =head2 has_handles -> Bool
 381
 382 =head2 is_weak_ref -> Bool
 383
 384 =head2 init_arg -> Str
 385
 386 =head2 type_constraint -> Str
 387
 388 =head2 has_type_constraint -> Bool
 389
 390 =head2 trigger => CODE | Undef
 391
 392 =head2 has_trigger -> Bool
 393
 394 =head2 builder => MethodName | Undef
 395
 396 =head2 has_builder -> Bool
 397
 398 =head2 is_lazy_build => Bool
 399
 400 =head2 should_auto_deref -> Bool
 401
 402 Informational methods.
 403
 404 =head2 generate_accessor -> CODE
 405
 406 Creates a new code reference for the attribute's accessor.
 407
 408 =head2 generate_predicate -> CODE
 409
 410 Creates a new code reference for the attribute's predicate.
 411
 412 =head2 generate_clearer -> CODE
 413
 414 Creates a new code reference for the attribute's clearer.
 415
 416 =head2 generate_handles -> { MethodName => CODE }
 417
 418 Creates a new code reference for each of the attribute's handles methods.
 419
 420 =head2 find_type_constraint -> CODE
 421
 422 Returns a code reference which can be used to check that a given value passes
 423 this attribute's type constraint;
 424
 425 =head2 verify_type_constraint Item -> 1 | ERROR
 426
 427 Checks that the given value passes this attribute's type constraint. Returns 1
 428 on success, otherwise C<confess>es.
 429
 430 =head2 canonicalize_args Name, %args -> %args
 431
 432 Canonicalizes some arguments to create. In particular, C<lazy_build> is
 433 canonicalized into C<lazy>, C<builder>, etc.
 434
 435 =head2 validate_args Name, \%args -> 1 | ERROR
 436
 437 Checks that the arguments to create the attribute (ie those specified by
 438 C<has>) are valid.
 439
 440 =head2 clone_parent OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 441
 442 Creates a new attribute in OwnerClass, inheriting options from parent classes.
 443 Accessors and helper methods are installed. Some error checking is done.
 444
 445 =head2 get_parent_args OwnerClass, AttributeName -> Hash
 446
 447 Returns the options that the parent class of C<OwnerClass> used for attribute
 448 C<AttributeName>.
 449
 450 =cut
 451