lib/Mouse/Meta/Attribute.pm

   1 #!/usr/bin/env perl
   2 package Mouse::Meta::Attribute;
   3 use strict;
   4 use warnings;
   5
   6 use Carp 'confess';
   7 use Scalar::Util 'blessed';
   8
   9 sub new {
  10     my $class = shift;
  11     my %args  = @_;
  12
  13     my $name = $args{name};
  14
  15     $args{init_arg} = $name
  16         unless exists $args{init_arg};
  17
  18     $args{is} ||= '';
  19
  20     bless \%args, $class;
  21 }
  22
  23 sub name              { $_[0]->{name}            }
  24 sub class             { $_[0]->{class}           }
  25 sub _is_metadata      { $_[0]->{is}              }
  26 sub is_required       { $_[0]->{required}        }
  27 sub default           { $_[0]->{default}         }
  28 sub is_lazy           { $_[0]->{lazy}            }
  29 sub is_lazy_build     { $_[0]->{lazy_build}      }
  30 sub predicate         { $_[0]->{predicate}       }
  31 sub clearer           { $_[0]->{clearer}         }
  32 sub handles           { $_[0]->{handles}         }
  33 sub is_weak_ref       { $_[0]->{weak_ref}        }
  34 sub init_arg          { $_[0]->{init_arg}        }
  35 sub type_constraint   { $_[0]->{type_constraint} }
  36 sub trigger           { $_[0]->{trigger}         }
  37 sub builder           { $_[0]->{builder}         }
  38 sub should_auto_deref { $_[0]->{auto_deref}      }
  39
  40 sub has_default         { exists $_[0]->{default}         }
  41 sub has_predicate       { exists $_[0]->{predicate}       }
  42 sub has_clearer         { exists $_[0]->{clearer}         }
  43 sub has_handles         { exists $_[0]->{handles}         }
  44 sub has_type_constraint { exists $_[0]->{type_constraint} }
  45 sub has_trigger         { exists $_[0]->{trigger}         }
  46 sub has_builder         { exists $_[0]->{builder}         }
  47
  48 sub _create_args {
  49     $_[0]->{_create_args} = $_[1] if @_ > 1;
  50     $_[0]->{_create_args}
  51 }
  52
  53 sub generate_accessor {
  54     my $attribute = shift;
  55
  56     my $name       = $attribute->name;
  57     my $key        = $name;
  58     my $default    = $attribute->default;
  59     my $type       = $attribute->type_constraint;
  60     my $constraint = $attribute->find_type_constraint;
  61     my $builder    = $attribute->builder;
  62
  63     my $trigger = $attribute->trigger;
  64     my $before  = $trigger->{before};
  65     my $after   = $trigger->{after};
  66     my $around  = $trigger->{around};
  67
  68     my $accessor = 'sub {
  69         my $self = shift;';
  70
  71     if ($attribute->_is_metadata eq 'rw') {
  72         $accessor .= 'if (@_) {
  73             local $_ = $_[0];';
  74
  75         if ($before) {
  76             $accessor .= '$before->($self, $_, $attribute);';
  77         }
  78
  79         if ($constraint) {
  80             $accessor .= 'do {
  81                 my $display = defined($_) ? overload::StrVal($_) : "undef";
  82                 Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display") unless $constraint->();
  83             };'
  84         }
  85
  86         $accessor .= '$self->{$key} = $_;';
  87
  88         if ($attribute->is_weak_ref) {
  89             $accessor .= 'Scalar::Util::weaken($self->{$key}) if ref($self->{$key});';
  90         }
  91
  92         if ($after) {
  93             $accessor .= '$after->($self, $_, $attribute);';
  94         }
  95
  96         $accessor .= '}';
  97     }
  98     else {
  99         $accessor .= 'confess "Cannot assign a value to a read-only accessor" if @_;';
 100     }
 101
 102     if ($attribute->is_lazy) {
 103         $accessor .= '$self->{$key} = ';
 104
 105         $accessor .= $attribute->has_builder
 106                    ? '$self->$builder'
 107                      : ref($default) eq 'CODE'
 108                      ? '$default->($self)'
 109                      : '$default';
 110
 111         $accessor .= ' if !exists($self->{$key});';
 112     }
 113
 114     if ($attribute->should_auto_deref) {
 115         if ($attribute->type_constraint eq 'ArrayRef') {
 116             $accessor .= 'if (wantarray) {
 117                 return @{ $self->{$key} || [] };
 118             }';
 119         }
 120         else {
 121             $accessor .= 'if (wantarray) {
 122                 return %{ $self->{$key} || {} };
 123             }';
 124         }
 125     }
 126
 127     $accessor .= 'return $self->{$key};
 128     }';
 129
 130     return eval $accessor;
 131 }
 132
 133 sub generate_predicate {
 134     my $attribute = shift;
 135     my $key = $attribute->name;
 136
 137     my $predicate = 'sub { exists($_[0]->{$key}) }';
 138
 139     return eval $predicate;
 140 }
 141
 142 sub generate_clearer {
 143     my $attribute = shift;
 144     my $key = $attribute->name;
 145
 146     my $predicate = 'sub { delete($_[0]->{$key}) }';
 147
 148     return eval $predicate;
 149 }
 150
 151 sub generate_handles {
 152     my $attribute = shift;
 153     my $reader = $attribute->name;
 154     my %handles = $attribute->_canonicalize_handles($attribute->handles);
 155
 156     my %method_map;
 157
 158     for my $local_method (keys %handles) {
 159         my $remote_method = $handles{$local_method};
 160
 161         my $method = 'sub {
 162             my $self = shift;
 163             $self->$reader->$remote_method(@_)
 164         }';
 165
 166         $method_map{$local_method} = eval $method;
 167     }
 168
 169     return \%method_map;
 170 }
 171
 172 sub create {
 173     my ($self, $class, $name, %args) = @_;
 174
 175     $args{name} = $name;
 176     $args{class} = $class;
 177
 178     %args = $self->canonicalize_args($name, %args);
 179     $self->validate_args($name, \%args);
 180
 181     $args{type_constraint} = delete $args{isa}
 182         if exists $args{isa};
 183
 184     my $attribute = $self->new(%args);
 185     $attribute->_create_args(\%args);
 186
 187     my $meta = $class->meta;
 188
 189     $meta->add_attribute($attribute);
 190
 191     # install an accessor
 192     if ($attribute->_is_metadata eq 'rw' || $attribute->_is_metadata eq 'ro') {
 193         my $accessor = $attribute->generate_accessor;
 194         no strict 'refs';
 195         *{ $class . '::' . $name } = $accessor;
 196     }
 197
 198     for my $method (qw/predicate clearer/) {
 199         my $predicate = "has_$method";
 200         if ($attribute->$predicate) {
 201             my $generator = "generate_$method";
 202             my $coderef = $attribute->$generator;
 203             no strict 'refs';
 204             *{ $class . '::' . $attribute->$method } = $coderef;
 205         }
 206     }
 207
 208     if ($attribute->has_handles) {
 209         my $method_map = $attribute->generate_handles;
 210         for my $method_name (keys %$method_map) {
 211             no strict 'refs';
 212             *{ $class . '::' . $method_name } = $method_map->{$method_name};
 213         }
 214     }
 215
 216     return $attribute;
 217 }
 218
 219 sub canonicalize_args {
 220     my $self = shift;
 221     my $name = shift;
 222     my %args = @_;
 223
 224     if ($args{lazy_build}) {
 225         $args{lazy}      = 1;
 226         $args{required}  = 1;
 227         $args{builder}   = "_build_${name}"
 228             if !exists($args{builder});
 229         if ($name =~ /^_/) {
 230             $args{clearer}   = "_clear${name}" if !exists($args{clearer});
 231             $args{predicate} = "_has${name}" if !exists($args{predicate});
 232         }
 233         else {
 234             $args{clearer}   = "clear_${name}" if !exists($args{clearer});
 235             $args{predicate} = "has_${name}" if !exists($args{predicate});
 236         }
 237     }
 238
 239     return %args;
 240 }
 241
 242 sub validate_args {
 243     my $self = shift;
 244     my $name = shift;
 245     my $args = shift;
 246
 247     confess "You can not use lazy_build and default for the same attribute ($name)"
 248         if $args->{lazy_build} && exists $args->{default};
 249
 250     confess "You cannot have lazy attribute ($name) without specifying a default value for it"
 251         if $args->{lazy}
 252         && !exists($args->{default})
 253         && !exists($args->{builder});
 254
 255     confess "References are not allowed as default values, you must wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])"
 256         if ref($args->{default})
 257         && ref($args->{default}) ne 'CODE';
 258
 259     confess "You cannot auto-dereference without specifying a type constraint on attribute $name"
 260         if $args->{auto_deref} && !exists($args->{isa});
 261
 262     confess "You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute $name"
 263         if $args->{auto_deref}
 264         && $args->{isa} ne 'ArrayRef'
 265         && $args->{isa} ne 'HashRef';
 266
 267     if ($args->{trigger}) {
 268         if (ref($args->{trigger}) eq 'CODE') {
 269             $args->{trigger} = {
 270                 after => $args->{trigger},
 271             };
 272         }
 273
 274         confess "Trigger must be a CODE or HASH ref on attribute ($name)"
 275             if $args->{trigger}
 276             && ref($args->{trigger}) ne 'HASH';
 277     }
 278
 279     return 1;
 280 }
 281
 282 sub find_type_constraint {
 283     my $self = shift;
 284     my $type = $self->type_constraint;
 285
 286     return unless $type;
 287
 288     my $checker = Mouse::TypeRegistry->optimized_constraints->{$type};
 289     return $checker if $checker;
 290
 291     return sub { blessed($_) && blessed($_) eq $type };
 292 }
 293
 294 sub verify_type_constraint {
 295     my $self = shift;
 296     local $_ = shift;
 297
 298     my $type = $self->type_constraint
 299         or return 1;
 300     my $constraint = $self->find_type_constraint;
 301
 302     return 1 if $constraint->($_);
 303
 304     my $name = $self->name;
 305     my $display = defined($_) ? overload::StrVal($_) : 'undef';
 306     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
 307 }
 308
 309 sub _canonicalize_handles {
 310     my $self    = shift;
 311     my $handles = shift;
 312
 313     if (ref($handles) eq 'HASH') {
 314         return %$handles;
 315     }
 316     elsif (ref($handles) eq 'ARRAY') {
 317         return map { $_ => $_ } @$handles;
 318     }
 319     else {
 320         confess "Unable to canonicalize the 'handles' option with $handles";
 321     }
 322 }
 323
 324 sub clone_parent {
 325     my $self  = shift;
 326     my $class = shift;
 327     my $name  = shift;
 328     my %args  = ($self->get_parent_args($class, $name), @_);
 329
 330     $self->create($class, $name, %args);
 331 }
 332
 333 sub get_parent_args {
 334     my $self  = shift;
 335     my $class = shift;
 336     my $name  = shift;
 337
 338     for my $super ($class->meta->linearized_isa) {
 339         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 340             or next;
 341         return %{ $super_attr->_create_args };
 342     }
 343
 344     confess "Could not find an attribute by the name of '$name' to inherit from";
 345 }
 346
 347 1;
 348
 349 __END__
 350
 351 =head1 NAME
 352
 353 Mouse::Meta::Attribute - attribute metaclass
 354
 355 =head1 METHODS
 356
 357 =head2 new %args -> Mouse::Meta::Attribute
 358
 359 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 360
 361 =head2 create OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 362
 363 Creates a new attribute in OwnerClass. Accessors and helper methods are
 364 installed. Some error checking is done.
 365
 366 =head2 name -> AttributeName
 367
 368 =head2 class -> OwnerClass
 369
 370 =head2 is_required -> Bool
 371
 372 =head2 default -> Item
 373
 374 =head2 has_default -> Bool
 375
 376 =head2 is_lazy -> Bool
 377
 378 =head2 predicate -> MethodName | Undef
 379
 380 =head2 has_predicate -> Bool
 381
 382 =head2 clearer -> MethodName | Undef
 383
 384 =head2 has_clearer -> Bool
 385
 386 =head2 handles -> { LocalName => RemoteName }
 387
 388 =head2 has_handles -> Bool
 389
 390 =head2 is_weak_ref -> Bool
 391
 392 =head2 init_arg -> Str
 393
 394 =head2 type_constraint -> Str
 395
 396 =head2 has_type_constraint -> Bool
 397
 398 =head2 trigger => CODE | Undef
 399
 400 =head2 has_trigger -> Bool
 401
 402 =head2 builder => MethodName | Undef
 403
 404 =head2 has_builder -> Bool
 405
 406 =head2 is_lazy_build => Bool
 407
 408 =head2 should_auto_deref -> Bool
 409
 410 Informational methods.
 411
 412 =head2 generate_accessor -> CODE
 413
 414 Creates a new code reference for the attribute's accessor.
 415
 416 =head2 generate_predicate -> CODE
 417
 418 Creates a new code reference for the attribute's predicate.
 419
 420 =head2 generate_clearer -> CODE
 421
 422 Creates a new code reference for the attribute's clearer.
 423
 424 =head2 generate_handles -> { MethodName => CODE }
 425
 426 Creates a new code reference for each of the attribute's handles methods.
 427
 428 =head2 find_type_constraint -> CODE
 429
 430 Returns a code reference which can be used to check that a given value passes
 431 this attribute's type constraint;
 432
 433 =head2 verify_type_constraint Item -> 1 | ERROR
 434
 435 Checks that the given value passes this attribute's type constraint. Returns 1
 436 on success, otherwise C<confess>es.
 437
 438 =head2 canonicalize_args Name, %args -> %args
 439
 440 Canonicalizes some arguments to create. In particular, C<lazy_build> is
 441 canonicalized into C<lazy>, C<builder>, etc.
 442
 443 =head2 validate_args Name, \%args -> 1 | ERROR
 444
 445 Checks that the arguments to create the attribute (ie those specified by
 446 C<has>) are valid.
 447
 448 =head2 clone_parent OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 449
 450 Creates a new attribute in OwnerClass, inheriting options from parent classes.
 451 Accessors and helper methods are installed. Some error checking is done.
 452
 453 =head2 get_parent_args OwnerClass, AttributeName -> Hash
 454
 455 Returns the options that the parent class of C<OwnerClass> used for attribute
 456 C<AttributeName>.
 457
 458 =cut
 459