lib/Mouse/Meta/Attribute.pm

   1 #!/usr/bin/env perl
   2 package Mouse::Meta::Attribute;
   3 use strict;
   4 use warnings;
   5
   6 use Carp 'confess';
   7 use Mouse::Util qw/blessed weaken/;
   8
   9 sub new {
  10     my $class = shift;
  11     my %args  = @_;
  12
  13     my $name = $args{name};
  14
  15     $args{init_arg} = $name
  16         unless exists $args{init_arg};
  17
  18     $args{is} ||= '';
  19
  20     bless \%args, $class;
  21 }
  22
  23 sub name              { $_[0]->{name}             }
  24 sub associated_class  { $_[0]->{associated_class} }
  25 sub _is_metadata      { $_[0]->{is}               }
  26 sub is_required       { $_[0]->{required}         }
  27 sub default           { $_[0]->{default}          }
  28 sub is_lazy           { $_[0]->{lazy}             }
  29 sub is_lazy_build     { $_[0]->{lazy_build}       }
  30 sub predicate         { $_[0]->{predicate}        }
  31 sub clearer           { $_[0]->{clearer}          }
  32 sub handles           { $_[0]->{handles}          }
  33 sub is_weak_ref       { $_[0]->{weak_ref}         }
  34 sub init_arg          { $_[0]->{init_arg}         }
  35 sub type_constraint   { $_[0]->{type_constraint}  }
  36 sub trigger           { $_[0]->{trigger}          }
  37 sub builder           { $_[0]->{builder}          }
  38 sub should_auto_deref { $_[0]->{auto_deref}       }
  39 sub is_coerce         { $_[0]->{is_coerce}        }
  40
  41 sub has_default         { exists $_[0]->{default}         }
  42 sub has_predicate       { exists $_[0]->{predicate}       }
  43 sub has_clearer         { exists $_[0]->{clearer}         }
  44 sub has_handles         { exists $_[0]->{handles}         }
  45 sub has_type_constraint { exists $_[0]->{type_constraint} }
  46 sub has_trigger         { exists $_[0]->{trigger}         }
  47 sub has_builder         { exists $_[0]->{builder}         }
  48
  49 sub _create_args {
  50     $_[0]->{_create_args} = $_[1] if @_ > 1;
  51     $_[0]->{_create_args}
  52 }
  53
  54 sub inlined_name {
  55     my $self = shift;
  56     my $name = $self->name;
  57     my $key   = "'" . $name . "'";
  58     return $key;
  59 }
  60
  61 sub generate_accessor {
  62     my $attribute = shift;
  63
  64     my $name         = $attribute->name;
  65     my $default      = $attribute->default;
  66     my $type         = $attribute->type_constraint;
  67     my $constraint   = $attribute->find_type_constraint;
  68     my $builder      = $attribute->builder;
  69     my $trigger      = $attribute->trigger;
  70     my $is_weak      = $attribute->is_weak_ref;
  71     my $should_deref = $attribute->should_auto_deref;
  72     my $is_coerce    = $attribute->is_coerce;
  73
  74     my $self  = '$_[0]';
  75     my $key   = $attribute->inlined_name;
  76
  77     my $accessor = "sub {\n";
  78     if ($attribute->_is_metadata eq 'rw') {
  79         $accessor .= 'if (scalar(@_) >= 2) {' . "\n";
  80
  81         my $value = '$_[1]';
  82
  83         if ($constraint) {
  84             if ($is_coerce) {
  85                 $accessor .= $value.' = $attribute->coerce_constraint('.$value.');';
  86             }
  87             $accessor .= 'local $_ = '.$value.';';
  88             $accessor .= '
  89                 unless ($constraint->()) {
  90                     my $display = defined($_) ? overload::StrVal($_) : "undef";
  91                     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
  92             }' . "\n"
  93         }
  94
  95         # if there's nothing left to do for the attribute we can return during
  96         # this setter
  97         $accessor .= 'return ' if !$is_weak && !$trigger && !$should_deref;
  98
  99         $accessor .= $self.'->{'.$key.'} = '.$value.';' . "\n";
 100
 101         if ($is_weak) {
 102             $accessor .= 'weaken('.$self.'->{'.$key.'}) if ref('.$self.'->{'.$key.'});' . "\n";
 103         }
 104
 105         if ($trigger) {
 106             $accessor .= '$trigger->('.$self.', '.$value.', $attribute);' . "\n";
 107         }
 108
 109         $accessor .= "}\n";
 110     }
 111     else {
 112         $accessor .= 'confess "Cannot assign a value to a read-only accessor" if scalar(@_) >= 2;' . "\n";
 113     }
 114
 115     if ($attribute->is_lazy) {
 116         $accessor .= $self.'->{'.$key.'} = ';
 117
 118         $accessor .= $attribute->has_builder
 119                 ? $self.'->$builder'
 120                     : ref($default) eq 'CODE'
 121                     ? '$default->('.$self.')'
 122                     : '$default';
 123         $accessor .= ' if !exists '.$self.'->{'.$key.'};' . "\n";
 124     }
 125
 126     if ($should_deref) {
 127         if ($attribute->type_constraint eq 'ArrayRef') {
 128             $accessor .= 'if (wantarray) {
 129                 return @{ '.$self.'->{'.$key.'} || [] };
 130             }';
 131         }
 132         else {
 133             $accessor .= 'if (wantarray) {
 134                 return %{ '.$self.'->{'.$key.'} || {} };
 135             }';
 136         }
 137     }
 138
 139     $accessor .= 'return '.$self.'->{'.$key.'};
 140     }';
 141
 142     my $sub = eval $accessor;
 143     confess $@ if $@;
 144     return $sub;
 145 }
 146
 147 sub generate_predicate {
 148     my $attribute = shift;
 149     my $key = $attribute->inlined_name;
 150
 151     my $predicate = 'sub { exists($_[0]->{'.$key.'}) }';
 152
 153     my $sub = eval $predicate;
 154     confess $@ if $@;
 155     return $sub;
 156 }
 157
 158 sub generate_clearer {
 159     my $attribute = shift;
 160     my $key = $attribute->inlined_name;
 161
 162     my $clearer = 'sub { delete($_[0]->{'.$key.'}) }';
 163
 164     my $sub = eval $clearer;
 165     confess $@ if $@;
 166     return $sub;
 167 }
 168
 169 sub generate_handles {
 170     my $attribute = shift;
 171     my $reader = $attribute->name;
 172     my %handles = $attribute->_canonicalize_handles($attribute->handles);
 173
 174     my %method_map;
 175
 176     for my $local_method (keys %handles) {
 177         my $remote_method = $handles{$local_method};
 178
 179         my $method = 'sub {
 180             my $self = shift;
 181             $self->$reader->$remote_method(@_)
 182         }';
 183
 184         $method_map{$local_method} = eval $method;
 185         confess $@ if $@;
 186     }
 187
 188     return \%method_map;
 189 }
 190
 191 sub create {
 192     my ($self, $class, $name, %args) = @_;
 193
 194     $args{name} = $name;
 195     $args{associated_class} = $class;
 196
 197     %args = $self->canonicalize_args($name, %args);
 198     $self->validate_args($name, \%args);
 199
 200     $args{is_coerce} = delete $args{coerce}
 201         if exists $args{coerce};
 202
 203     $args{type_constraint} = delete $args{isa}
 204         if exists $args{isa};
 205
 206     my $attribute = $self->new(%args);
 207
 208     $attribute->_create_args(\%args);
 209
 210     $class->add_attribute($attribute);
 211
 212     # install an accessor
 213     if ($attribute->_is_metadata eq 'rw' || $attribute->_is_metadata eq 'ro') {
 214         my $accessor = $attribute->generate_accessor;
 215         $class->add_method($name => $accessor);
 216     }
 217
 218     for my $method (qw/predicate clearer/) {
 219         my $predicate = "has_$method";
 220         if ($attribute->$predicate) {
 221             my $generator = "generate_$method";
 222             my $coderef = $attribute->$generator;
 223             $class->add_method($attribute->$method => $coderef);
 224         }
 225     }
 226
 227     if ($attribute->has_handles) {
 228         my $method_map = $attribute->generate_handles;
 229         for my $method_name (keys %$method_map) {
 230             $class->add_method($method_name => $method_map->{$method_name});
 231         }
 232     }
 233
 234     return $attribute;
 235 }
 236
 237 sub canonicalize_args {
 238     my $self = shift;
 239     my $name = shift;
 240     my %args = @_;
 241
 242     if ($args{lazy_build}) {
 243         $args{lazy}      = 1;
 244         $args{required}  = 1;
 245         $args{builder}   = "_build_${name}"
 246             if !exists($args{builder});
 247         if ($name =~ /^_/) {
 248             $args{clearer}   = "_clear${name}" if !exists($args{clearer});
 249             $args{predicate} = "_has${name}" if !exists($args{predicate});
 250         }
 251         else {
 252             $args{clearer}   = "clear_${name}" if !exists($args{clearer});
 253             $args{predicate} = "has_${name}" if !exists($args{predicate});
 254         }
 255     }
 256
 257     return %args;
 258 }
 259
 260 sub validate_args {
 261     my $self = shift;
 262     my $name = shift;
 263     my $args = shift;
 264
 265     confess "You can not use lazy_build and default for the same attribute ($name)"
 266         if $args->{lazy_build} && exists $args->{default};
 267
 268     confess "You cannot have lazy attribute ($name) without specifying a default value for it"
 269         if $args->{lazy}
 270         && !exists($args->{default})
 271         && !exists($args->{builder});
 272
 273     confess "References are not allowed as default values, you must wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])"
 274         if ref($args->{default})
 275         && ref($args->{default}) ne 'CODE';
 276
 277     confess "You cannot auto-dereference without specifying a type constraint on attribute ($name)"
 278         if $args->{auto_deref} && !exists($args->{isa});
 279
 280     confess "You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)"
 281         if $args->{auto_deref}
 282         && $args->{isa} ne 'ArrayRef'
 283         && $args->{isa} ne 'HashRef';
 284
 285     if ($args->{trigger}) {
 286         if (ref($args->{trigger}) eq 'HASH') {
 287             Carp::carp "HASH-based form of trigger has been removed. Only the coderef form of triggers are now supported.";
 288         }
 289
 290         confess "Trigger must be a CODE ref on attribute ($name)"
 291             if ref($args->{trigger}) ne 'CODE';
 292     }
 293
 294     return 1;
 295 }
 296
 297 sub find_type_constraint {
 298     my $self = shift;
 299     my $type = $self->type_constraint;
 300
 301     return unless $type;
 302
 303     my $checker = Mouse::TypeRegistry->optimized_constraints($self->associated_class->name)->{$type};
 304     return $checker if $checker;
 305
 306     return sub { blessed($_) && blessed($_) eq $type };
 307 }
 308
 309 sub verify_type_constraint {
 310     my $self = shift;
 311     local $_ = shift;
 312
 313     my $type = $self->type_constraint
 314         or return 1;
 315     my $constraint = $self->find_type_constraint;
 316
 317     return 1 if $constraint->($_);
 318
 319     my $name = $self->name;
 320     my $display = defined($_) ? overload::StrVal($_) : 'undef';
 321     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
 322 }
 323
 324 sub coerce_constraint {
 325     my($self, $value) = @_;
 326     my $type = $self->type_constraint
 327         or return $value;
 328     return Mouse::TypeRegistry->typecast_constraints($self->associated_class->name, $type, $value);
 329 }
 330
 331 sub _canonicalize_handles {
 332     my $self    = shift;
 333     my $handles = shift;
 334
 335     if (ref($handles) eq 'HASH') {
 336         return %$handles;
 337     }
 338     elsif (ref($handles) eq 'ARRAY') {
 339         return map { $_ => $_ } @$handles;
 340     }
 341     else {
 342         confess "Unable to canonicalize the 'handles' option with $handles";
 343     }
 344 }
 345
 346 sub clone_parent {
 347     my $self  = shift;
 348     my $class = shift;
 349     my $name  = shift;
 350     my %args  = ($self->get_parent_args($class, $name), @_);
 351
 352     $self->create($class, $name, %args);
 353 }
 354
 355 sub get_parent_args {
 356     my $self  = shift;
 357     my $class = shift;
 358     my $name  = shift;
 359
 360     for my $super ($class->linearized_isa) {
 361         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 362             or next;
 363         return %{ $super_attr->_create_args };
 364     }
 365
 366     confess "Could not find an attribute by the name of '$name' to inherit from";
 367 }
 368
 369 1;
 370
 371 __END__
 372
 373 =head1 NAME
 374
 375 Mouse::Meta::Attribute - attribute metaclass
 376
 377 =head1 METHODS
 378
 379 =head2 new %args -> Mouse::Meta::Attribute
 380
 381 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 382
 383 =head2 create OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 384
 385 Creates a new attribute in OwnerClass. Accessors and helper methods are
 386 installed. Some error checking is done.
 387
 388 =head2 name -> AttributeName
 389
 390 =head2 associated_class -> OwnerClass
 391
 392 =head2 is_required -> Bool
 393
 394 =head2 default -> Item
 395
 396 =head2 has_default -> Bool
 397
 398 =head2 is_lazy -> Bool
 399
 400 =head2 predicate -> MethodName | Undef
 401
 402 =head2 has_predicate -> Bool
 403
 404 =head2 clearer -> MethodName | Undef
 405
 406 =head2 has_clearer -> Bool
 407
 408 =head2 handles -> { LocalName => RemoteName }
 409
 410 =head2 has_handles -> Bool
 411
 412 =head2 is_weak_ref -> Bool
 413
 414 =head2 init_arg -> Str
 415
 416 =head2 type_constraint -> Str
 417
 418 =head2 has_type_constraint -> Bool
 419
 420 =head2 trigger => CODE | Undef
 421
 422 =head2 has_trigger -> Bool
 423
 424 =head2 builder => MethodName | Undef
 425
 426 =head2 has_builder -> Bool
 427
 428 =head2 is_lazy_build => Bool
 429
 430 =head2 should_auto_deref -> Bool
 431
 432 Informational methods.
 433
 434 =head2 generate_accessor -> CODE
 435
 436 Creates a new code reference for the attribute's accessor.
 437
 438 =head2 generate_predicate -> CODE
 439
 440 Creates a new code reference for the attribute's predicate.
 441
 442 =head2 generate_clearer -> CODE
 443
 444 Creates a new code reference for the attribute's clearer.
 445
 446 =head2 generate_handles -> { MethodName => CODE }
 447
 448 Creates a new code reference for each of the attribute's handles methods.
 449
 450 =head2 find_type_constraint -> CODE
 451
 452 Returns a code reference which can be used to check that a given value passes
 453 this attribute's type constraint;
 454
 455 =head2 verify_type_constraint Item -> 1 | ERROR
 456
 457 Checks that the given value passes this attribute's type constraint. Returns 1
 458 on success, otherwise C<confess>es.
 459
 460 =head2 canonicalize_args Name, %args -> %args
 461
 462 Canonicalizes some arguments to create. In particular, C<lazy_build> is
 463 canonicalized into C<lazy>, C<builder>, etc.
 464
 465 =head2 validate_args Name, \%args -> 1 | ERROR
 466
 467 Checks that the arguments to create the attribute (ie those specified by
 468 C<has>) are valid.
 469
 470 =head2 clone_parent OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 471
 472 Creates a new attribute in OwnerClass, inheriting options from parent classes.
 473 Accessors and helper methods are installed. Some error checking is done.
 474
 475 =head2 get_parent_args OwnerClass, AttributeName -> Hash
 476
 477 Returns the options that the parent class of C<OwnerClass> used for attribute
 478 C<AttributeName>.
 479
 480 =cut
 481