lib/Mouse/Meta/Attribute.pm

   1 #!/usr/bin/env perl
   2 package Mouse::Meta::Attribute;
   3 use strict;
   4 use warnings;
   5 require overload;
   6
   7 use Carp 'confess';
   8 use Mouse::Util qw/blessed weaken/;
   9
  10 sub new {
  11     my $class = shift;
  12     my %args  = @_;
  13
  14     my $name = $args{name};
  15
  16     $args{init_arg} = $name
  17         unless exists $args{init_arg};
  18
  19     $args{is} ||= '';
  20
  21     bless \%args, $class;
  22 }
  23
  24 sub name              { $_[0]->{name}             }
  25 sub associated_class  { $_[0]->{associated_class} }
  26 sub _is_metadata      { $_[0]->{is}               }
  27 sub is_required       { $_[0]->{required}         }
  28 sub default           { $_[0]->{default}          }
  29 sub is_lazy           { $_[0]->{lazy}             }
  30 sub is_lazy_build     { $_[0]->{lazy_build}       }
  31 sub predicate         { $_[0]->{predicate}        }
  32 sub clearer           { $_[0]->{clearer}          }
  33 sub handles           { $_[0]->{handles}          }
  34 sub is_weak_ref       { $_[0]->{weak_ref}         }
  35 sub init_arg          { $_[0]->{init_arg}         }
  36 sub type_constraint   { $_[0]->{type_constraint}  }
  37 sub trigger           { $_[0]->{trigger}          }
  38 sub builder           { $_[0]->{builder}          }
  39 sub should_auto_deref { $_[0]->{auto_deref}       }
  40 sub should_coerce     { $_[0]->{should_coerce}    }
  41
  42 sub has_default         { exists $_[0]->{default}         }
  43 sub has_predicate       { exists $_[0]->{predicate}       }
  44 sub has_clearer         { exists $_[0]->{clearer}         }
  45 sub has_handles         { exists $_[0]->{handles}         }
  46 sub has_type_constraint { exists $_[0]->{type_constraint} }
  47 sub has_trigger         { exists $_[0]->{trigger}         }
  48 sub has_builder         { exists $_[0]->{builder}         }
  49
  50 sub _create_args {
  51     $_[0]->{_create_args} = $_[1] if @_ > 1;
  52     $_[0]->{_create_args}
  53 }
  54
  55 sub inlined_name {
  56     my $self = shift;
  57     my $name = $self->name;
  58     my $key   = "'" . $name . "'";
  59     return $key;
  60 }
  61
  62 sub generate_accessor {
  63     my $attribute = shift;
  64
  65     my $name          = $attribute->name;
  66     my $default       = $attribute->default;
  67     my $type          = $attribute->type_constraint;
  68     my $constraint    = $attribute->find_type_constraint;
  69     my $builder       = $attribute->builder;
  70     my $trigger       = $attribute->trigger;
  71     my $is_weak       = $attribute->is_weak_ref;
  72     my $should_deref  = $attribute->should_auto_deref;
  73     my $should_coerce = $attribute->should_coerce;
  74
  75     my $self  = '$_[0]';
  76     my $key   = $attribute->inlined_name;
  77
  78     my $accessor = "sub {\n";
  79     if ($attribute->_is_metadata eq 'rw') {
  80         $accessor .= 'if (scalar(@_) >= 2) {' . "\n";
  81
  82         my $value = '$_[1]';
  83
  84         if ($constraint) {
  85             if ($should_coerce) {
  86                 $accessor .= $value.' = $attribute->coerce_constraint('.$value.');';
  87             }
  88             $accessor .= 'local $_ = '.$value.';';
  89             $accessor .= '
  90                 unless ($constraint->()) {
  91                     my $display = defined($_) ? overload::StrVal($_) : "undef";
  92                     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
  93             }' . "\n"
  94         }
  95
  96         # if there's nothing left to do for the attribute we can return during
  97         # this setter
  98         $accessor .= 'return ' if !$is_weak && !$trigger && !$should_deref;
  99
 100         $accessor .= $self.'->{'.$key.'} = '.$value.';' . "\n";
 101
 102         if ($is_weak) {
 103             $accessor .= 'weaken('.$self.'->{'.$key.'}) if ref('.$self.'->{'.$key.'});' . "\n";
 104         }
 105
 106         if ($trigger) {
 107             $accessor .= '$trigger->('.$self.', '.$value.', $attribute);' . "\n";
 108         }
 109
 110         $accessor .= "}\n";
 111     }
 112     else {
 113         $accessor .= 'confess "Cannot assign a value to a read-only accessor" if scalar(@_) >= 2;' . "\n";
 114     }
 115
 116     if ($attribute->is_lazy) {
 117         $accessor .= $self.'->{'.$key.'} = ';
 118
 119         $accessor .= $attribute->has_builder
 120                 ? $self.'->$builder'
 121                     : ref($default) eq 'CODE'
 122                     ? '$default->('.$self.')'
 123                     : '$default';
 124         $accessor .= ' if !exists '.$self.'->{'.$key.'};' . "\n";
 125     }
 126
 127     if ($should_deref) {
 128         if ($attribute->type_constraint eq 'ArrayRef') {
 129             $accessor .= 'if (wantarray) {
 130                 return @{ '.$self.'->{'.$key.'} || [] };
 131             }';
 132         }
 133         else {
 134             $accessor .= 'if (wantarray) {
 135                 return %{ '.$self.'->{'.$key.'} || {} };
 136             }';
 137         }
 138     }
 139
 140     $accessor .= 'return '.$self.'->{'.$key.'};
 141     }';
 142
 143     my $sub = eval $accessor;
 144     confess $@ if $@;
 145     return $sub;
 146 }
 147
 148 sub generate_predicate {
 149     my $attribute = shift;
 150     my $key = $attribute->inlined_name;
 151
 152     my $predicate = 'sub { exists($_[0]->{'.$key.'}) }';
 153
 154     my $sub = eval $predicate;
 155     confess $@ if $@;
 156     return $sub;
 157 }
 158
 159 sub generate_clearer {
 160     my $attribute = shift;
 161     my $key = $attribute->inlined_name;
 162
 163     my $clearer = 'sub { delete($_[0]->{'.$key.'}) }';
 164
 165     my $sub = eval $clearer;
 166     confess $@ if $@;
 167     return $sub;
 168 }
 169
 170 sub generate_handles {
 171     my $attribute = shift;
 172     my $reader = $attribute->name;
 173     my %handles = $attribute->_canonicalize_handles($attribute->handles);
 174
 175     my %method_map;
 176
 177     for my $local_method (keys %handles) {
 178         my $remote_method = $handles{$local_method};
 179
 180         my $method = 'sub {
 181             my $self = shift;
 182             $self->$reader->$remote_method(@_)
 183         }';
 184
 185         $method_map{$local_method} = eval $method;
 186         confess $@ if $@;
 187     }
 188
 189     return \%method_map;
 190 }
 191
 192 sub create {
 193     my ($self, $class, $name, %args) = @_;
 194
 195     $args{name} = $name;
 196     $args{associated_class} = $class;
 197
 198     %args = $self->canonicalize_args($name, %args);
 199     $self->validate_args($name, \%args);
 200
 201     $args{should_coerce} = delete $args{coerce}
 202         if exists $args{coerce};
 203
 204     $args{type_constraint} = delete $args{isa}
 205         if exists $args{isa};
 206
 207     my $attribute = $self->new(%args);
 208
 209     $attribute->_create_args(\%args);
 210
 211     $class->add_attribute($attribute);
 212
 213     # install an accessor
 214     if ($attribute->_is_metadata eq 'rw' || $attribute->_is_metadata eq 'ro') {
 215         my $accessor = $attribute->generate_accessor;
 216         $class->add_method($name => $accessor);
 217     }
 218
 219     for my $method (qw/predicate clearer/) {
 220         my $predicate = "has_$method";
 221         if ($attribute->$predicate) {
 222             my $generator = "generate_$method";
 223             my $coderef = $attribute->$generator;
 224             $class->add_method($attribute->$method => $coderef);
 225         }
 226     }
 227
 228     if ($attribute->has_handles) {
 229         my $method_map = $attribute->generate_handles;
 230         for my $method_name (keys %$method_map) {
 231             $class->add_method($method_name => $method_map->{$method_name});
 232         }
 233     }
 234
 235     return $attribute;
 236 }
 237
 238 sub canonicalize_args {
 239     my $self = shift;
 240     my $name = shift;
 241     my %args = @_;
 242
 243     if ($args{lazy_build}) {
 244         $args{lazy}      = 1;
 245         $args{required}  = 1;
 246         $args{builder}   = "_build_${name}"
 247             if !exists($args{builder});
 248         if ($name =~ /^_/) {
 249             $args{clearer}   = "_clear${name}" if !exists($args{clearer});
 250             $args{predicate} = "_has${name}" if !exists($args{predicate});
 251         }
 252         else {
 253             $args{clearer}   = "clear_${name}" if !exists($args{clearer});
 254             $args{predicate} = "has_${name}" if !exists($args{predicate});
 255         }
 256     }
 257
 258     return %args;
 259 }
 260
 261 sub validate_args {
 262     my $self = shift;
 263     my $name = shift;
 264     my $args = shift;
 265
 266     confess "You can not use lazy_build and default for the same attribute ($name)"
 267         if $args->{lazy_build} && exists $args->{default};
 268
 269     confess "You cannot have lazy attribute ($name) without specifying a default value for it"
 270         if $args->{lazy}
 271         && !exists($args->{default})
 272         && !exists($args->{builder});
 273
 274     confess "References are not allowed as default values, you must wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])"
 275         if ref($args->{default})
 276         && ref($args->{default}) ne 'CODE';
 277
 278     confess "You cannot auto-dereference without specifying a type constraint on attribute ($name)"
 279         if $args->{auto_deref} && !exists($args->{isa});
 280
 281     confess "You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)"
 282         if $args->{auto_deref}
 283         && $args->{isa} ne 'ArrayRef'
 284         && $args->{isa} ne 'HashRef';
 285
 286     if ($args->{trigger}) {
 287         if (ref($args->{trigger}) eq 'HASH') {
 288             Carp::carp "HASH-based form of trigger has been removed. Only the coderef form of triggers are now supported.";
 289         }
 290
 291         confess "Trigger must be a CODE ref on attribute ($name)"
 292             if ref($args->{trigger}) ne 'CODE';
 293     }
 294
 295     return 1;
 296 }
 297
 298 sub find_type_constraint {
 299     my $self = shift;
 300     my $type = $self->type_constraint;
 301
 302     return unless $type;
 303
 304     my $checker = Mouse::TypeRegistry->optimized_constraints($self->associated_class->name)->{$type};
 305     return $checker if $checker;
 306
 307     return sub { blessed($_) && blessed($_) eq $type };
 308 }
 309
 310 sub verify_type_constraint {
 311     my $self = shift;
 312     local $_ = shift;
 313
 314     my $type = $self->type_constraint
 315         or return 1;
 316     my $constraint = $self->find_type_constraint;
 317
 318     return 1 if $constraint->($_);
 319
 320     my $name = $self->name;
 321     my $display = defined($_) ? overload::StrVal($_) : 'undef';
 322     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
 323 }
 324
 325 sub coerce_constraint {
 326     my($self, $value) = @_;
 327     my $type = $self->type_constraint
 328         or return $value;
 329     return Mouse::TypeRegistry->typecast_constraints($self->associated_class->name, $type, $value);
 330 }
 331
 332 sub _canonicalize_handles {
 333     my $self    = shift;
 334     my $handles = shift;
 335
 336     if (ref($handles) eq 'HASH') {
 337         return %$handles;
 338     }
 339     elsif (ref($handles) eq 'ARRAY') {
 340         return map { $_ => $_ } @$handles;
 341     }
 342     else {
 343         confess "Unable to canonicalize the 'handles' option with $handles";
 344     }
 345 }
 346
 347 sub clone_parent {
 348     my $self  = shift;
 349     my $class = shift;
 350     my $name  = shift;
 351     my %args  = ($self->get_parent_args($class, $name), @_);
 352
 353     $self->create($class, $name, %args);
 354 }
 355
 356 sub get_parent_args {
 357     my $self  = shift;
 358     my $class = shift;
 359     my $name  = shift;
 360
 361     for my $super ($class->linearized_isa) {
 362         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 363             or next;
 364         return %{ $super_attr->_create_args };
 365     }
 366
 367     confess "Could not find an attribute by the name of '$name' to inherit from";
 368 }
 369
 370 1;
 371
 372 __END__
 373
 374 =head1 NAME
 375
 376 Mouse::Meta::Attribute - attribute metaclass
 377
 378 =head1 METHODS
 379
 380 =head2 new %args -> Mouse::Meta::Attribute
 381
 382 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 383
 384 =head2 create OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 385
 386 Creates a new attribute in OwnerClass. Accessors and helper methods are
 387 installed. Some error checking is done.
 388
 389 =head2 name -> AttributeName
 390
 391 =head2 associated_class -> OwnerClass
 392
 393 =head2 is_required -> Bool
 394
 395 =head2 default -> Item
 396
 397 =head2 has_default -> Bool
 398
 399 =head2 is_lazy -> Bool
 400
 401 =head2 predicate -> MethodName | Undef
 402
 403 =head2 has_predicate -> Bool
 404
 405 =head2 clearer -> MethodName | Undef
 406
 407 =head2 has_clearer -> Bool
 408
 409 =head2 handles -> { LocalName => RemoteName }
 410
 411 =head2 has_handles -> Bool
 412
 413 =head2 is_weak_ref -> Bool
 414
 415 =head2 init_arg -> Str
 416
 417 =head2 type_constraint -> Str
 418
 419 =head2 has_type_constraint -> Bool
 420
 421 =head2 trigger => CODE | Undef
 422
 423 =head2 has_trigger -> Bool
 424
 425 =head2 builder => MethodName | Undef
 426
 427 =head2 has_builder -> Bool
 428
 429 =head2 is_lazy_build => Bool
 430
 431 =head2 should_auto_deref -> Bool
 432
 433 Informational methods.
 434
 435 =head2 generate_accessor -> CODE
 436
 437 Creates a new code reference for the attribute's accessor.
 438
 439 =head2 generate_predicate -> CODE
 440
 441 Creates a new code reference for the attribute's predicate.
 442
 443 =head2 generate_clearer -> CODE
 444
 445 Creates a new code reference for the attribute's clearer.
 446
 447 =head2 generate_handles -> { MethodName => CODE }
 448
 449 Creates a new code reference for each of the attribute's handles methods.
 450
 451 =head2 find_type_constraint -> CODE
 452
 453 Returns a code reference which can be used to check that a given value passes
 454 this attribute's type constraint;
 455
 456 =head2 verify_type_constraint Item -> 1 | ERROR
 457
 458 Checks that the given value passes this attribute's type constraint. Returns 1
 459 on success, otherwise C<confess>es.
 460
 461 =head2 canonicalize_args Name, %args -> %args
 462
 463 Canonicalizes some arguments to create. In particular, C<lazy_build> is
 464 canonicalized into C<lazy>, C<builder>, etc.
 465
 466 =head2 validate_args Name, \%args -> 1 | ERROR
 467
 468 Checks that the arguments to create the attribute (ie those specified by
 469 C<has>) are valid.
 470
 471 =head2 clone_parent OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 472
 473 Creates a new attribute in OwnerClass, inheriting options from parent classes.
 474 Accessors and helper methods are installed. Some error checking is done.
 475
 476 =head2 get_parent_args OwnerClass, AttributeName -> Hash
 477
 478 Returns the options that the parent class of C<OwnerClass> used for attribute
 479 C<AttributeName>.
 480
 481 =cut
 482