lib/Mouse/Meta/Attribute.pm

   1 #!/usr/bin/env perl
   2 package Mouse::Meta::Attribute;
   3 use strict;
   4 use warnings;
   5
   6 use Carp 'confess';
   7 use Mouse::Util qw/blessed weaken/;
   8
   9 sub new {
  10     my $class = shift;
  11     my %args  = @_;
  12
  13     my $name = $args{name};
  14
  15     $args{init_arg} = $name
  16         unless exists $args{init_arg};
  17
  18     $args{is} ||= '';
  19
  20     bless \%args, $class;
  21 }
  22
  23 sub name              { $_[0]->{name}             }
  24 sub associated_class  { $_[0]->{associated_class} }
  25 sub _is_metadata      { $_[0]->{is}               }
  26 sub is_required       { $_[0]->{required}         }
  27 sub default           { $_[0]->{default}          }
  28 sub is_lazy           { $_[0]->{lazy}             }
  29 sub is_lazy_build     { $_[0]->{lazy_build}       }
  30 sub predicate         { $_[0]->{predicate}        }
  31 sub clearer           { $_[0]->{clearer}          }
  32 sub handles           { $_[0]->{handles}          }
  33 sub is_weak_ref       { $_[0]->{weak_ref}         }
  34 sub init_arg          { $_[0]->{init_arg}         }
  35 sub type_constraint   { $_[0]->{type_constraint}  }
  36 sub trigger           { $_[0]->{trigger}          }
  37 sub builder           { $_[0]->{builder}          }
  38 sub should_auto_deref { $_[0]->{auto_deref}       }
  39
  40 sub has_default         { exists $_[0]->{default}         }
  41 sub has_predicate       { exists $_[0]->{predicate}       }
  42 sub has_clearer         { exists $_[0]->{clearer}         }
  43 sub has_handles         { exists $_[0]->{handles}         }
  44 sub has_type_constraint { exists $_[0]->{type_constraint} }
  45 sub has_trigger         { exists $_[0]->{trigger}         }
  46 sub has_builder         { exists $_[0]->{builder}         }
  47
  48 sub _create_args {
  49     $_[0]->{_create_args} = $_[1] if @_ > 1;
  50     $_[0]->{_create_args}
  51 }
  52
  53 sub inlined_name {
  54     my $self = shift;
  55     my $name = $self->name;
  56     my $key   = "'" . $name . "'";
  57     return $key;
  58 }
  59
  60 sub generate_accessor {
  61     my $attribute = shift;
  62
  63     my $name       = $attribute->name;
  64     my $default    = $attribute->default;
  65     my $type       = $attribute->type_constraint;
  66     my $constraint = $attribute->find_type_constraint;
  67     my $builder    = $attribute->builder;
  68     my $trigger    = $attribute->trigger;
  69
  70     my $self  = '$_[0]';
  71     my $value = '$_[1]';
  72     my $key   = $attribute->inlined_name;
  73
  74     my $accessor = "sub {\n";
  75     if ($attribute->_is_metadata eq 'rw') {
  76         $accessor .= 'if (scalar(@_) >= 2) {
  77         ';
  78
  79         if ($constraint) {
  80             $accessor .= 'local $_ = ' . $value . ';
  81                 unless ($constraint->()) {
  82                     my $display = defined($_) ? overload::StrVal($_) : "undef";
  83                     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
  84             }' . "\n"
  85         }
  86
  87         $accessor .= 'return '
  88             if !$attribute->is_weak_ref
  89             && !$trigger
  90             && !$attribute->should_auto_deref;
  91
  92         if ($attribute->is_weak_ref) {
  93             $accessor .= 'weaken('.$self.'->{'.$key.'}) if ref('.$self.'->{'.$key.'});' . "\n";
  94         }
  95
  96         if ($trigger) {
  97             $accessor .= '$trigger->('.$self.', '.$value.', $attribute);' . "\n";
  98         }
  99
 100         $accessor .= "}\n";
 101     }
 102     else {
 103         $accessor .= 'confess "Cannot assign a value to a read-only accessor" if scalar(@_) >= 2;' . "\n";
 104     }
 105
 106     if ($attribute->is_lazy) {
 107         $accessor .= $self.'->{'.$key.'} = ';
 108
 109         $accessor .= $attribute->has_builder
 110                 ? $self.'->$builder'
 111                     : ref($default) eq 'CODE'
 112                     ? '$default->('.$self.')'
 113                     : '$default';
 114         $accessor .= ' if !exists '.$self.'->{'.$key.'};' . "\n";
 115     }
 116
 117     if ($attribute->should_auto_deref) {
 118         if ($attribute->type_constraint eq 'ArrayRef') {
 119             $accessor .= 'if (wantarray) {
 120                 return @{ '.$self.'->{'.$key.'} || [] };
 121             }' . "\n";
 122         }
 123         else {
 124             $accessor .= 'if (wantarray) {
 125                 return %{ '.$self.'->{'.$key.'} || {} };
 126             }' . "\n";
 127         }
 128     }
 129
 130     $accessor .= 'return '.$self.'->{'.$key.'};
 131     }';
 132
 133     my $sub = eval $accessor;
 134     confess $@ if $@;
 135     return $sub;
 136 }
 137
 138 sub generate_predicate {
 139     my $attribute = shift;
 140     my $key = $attribute->inlined_name;
 141
 142     my $predicate = 'sub { exists($_[0]->{'.$key.'}) }';
 143
 144     my $sub = eval $predicate;
 145     confess $@ if $@;
 146     return $sub;
 147 }
 148
 149 sub generate_clearer {
 150     my $attribute = shift;
 151     my $key = $attribute->inlined_name;
 152
 153     my $clearer = 'sub { delete($_[0]->{'.$key.'}) }';
 154
 155     my $sub = eval $clearer;
 156     confess $@ if $@;
 157     return $sub;
 158 }
 159
 160 sub generate_handles {
 161     my $attribute = shift;
 162     my $reader = $attribute->name;
 163     my %handles = $attribute->_canonicalize_handles($attribute->handles);
 164
 165     my %method_map;
 166
 167     for my $local_method (keys %handles) {
 168         my $remote_method = $handles{$local_method};
 169
 170         my $method = 'sub {
 171             my $self = shift;
 172             $self->$reader->$remote_method(@_)
 173         }';
 174
 175         $method_map{$local_method} = eval $method;
 176         confess $@ if $@;
 177     }
 178
 179     return \%method_map;
 180 }
 181
 182 sub create {
 183     my ($self, $class, $name, %args) = @_;
 184
 185     $args{name} = $name;
 186     $args{associated_class} = $class;
 187
 188     %args = $self->canonicalize_args($name, %args);
 189     $self->validate_args($name, \%args);
 190
 191     $args{type_constraint} = delete $args{isa}
 192         if exists $args{isa};
 193
 194     my $attribute = $self->new(%args);
 195
 196     $attribute->_create_args(\%args);
 197
 198     $class->add_attribute($attribute);
 199
 200     # install an accessor
 201     if ($attribute->_is_metadata eq 'rw' || $attribute->_is_metadata eq 'ro') {
 202         my $accessor = $attribute->generate_accessor;
 203         $class->add_method($name => $accessor);
 204     }
 205
 206     for my $method (qw/predicate clearer/) {
 207         my $predicate = "has_$method";
 208         if ($attribute->$predicate) {
 209             my $generator = "generate_$method";
 210             my $coderef = $attribute->$generator;
 211             $class->add_method($attribute->$method => $coderef);
 212         }
 213     }
 214
 215     if ($attribute->has_handles) {
 216         my $method_map = $attribute->generate_handles;
 217         for my $method_name (keys %$method_map) {
 218             $class->add_method($method_name => $method_map->{$method_name});
 219         }
 220     }
 221
 222     return $attribute;
 223 }
 224
 225 sub canonicalize_args {
 226     my $self = shift;
 227     my $name = shift;
 228     my %args = @_;
 229
 230     if ($args{lazy_build}) {
 231         $args{lazy}      = 1;
 232         $args{required}  = 1;
 233         $args{builder}   = "_build_${name}"
 234             if !exists($args{builder});
 235         if ($name =~ /^_/) {
 236             $args{clearer}   = "_clear${name}" if !exists($args{clearer});
 237             $args{predicate} = "_has${name}" if !exists($args{predicate});
 238         }
 239         else {
 240             $args{clearer}   = "clear_${name}" if !exists($args{clearer});
 241             $args{predicate} = "has_${name}" if !exists($args{predicate});
 242         }
 243     }
 244
 245     return %args;
 246 }
 247
 248 sub validate_args {
 249     my $self = shift;
 250     my $name = shift;
 251     my $args = shift;
 252
 253     confess "You can not use lazy_build and default for the same attribute ($name)"
 254         if $args->{lazy_build} && exists $args->{default};
 255
 256     confess "You cannot have lazy attribute ($name) without specifying a default value for it"
 257         if $args->{lazy}
 258         && !exists($args->{default})
 259         && !exists($args->{builder});
 260
 261     confess "References are not allowed as default values, you must wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])"
 262         if ref($args->{default})
 263         && ref($args->{default}) ne 'CODE';
 264
 265     confess "You cannot auto-dereference without specifying a type constraint on attribute ($name)"
 266         if $args->{auto_deref} && !exists($args->{isa});
 267
 268     confess "You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)"
 269         if $args->{auto_deref}
 270         && $args->{isa} ne 'ArrayRef'
 271         && $args->{isa} ne 'HashRef';
 272
 273     if ($args->{trigger}) {
 274         if (ref($args->{trigger}) eq 'HASH') {
 275             Carp::carp "HASH-based form of trigger has been removed. Only the coderef form of triggers are now supported.";
 276         }
 277
 278         confess "Trigger must be a CODE ref on attribute ($name)"
 279             if ref($args->{trigger}) ne 'CODE';
 280     }
 281
 282     return 1;
 283 }
 284
 285 sub find_type_constraint {
 286     my $self = shift;
 287     my $type = $self->type_constraint;
 288
 289     return unless $type;
 290
 291     my $checker = Mouse::TypeRegistry->optimized_constraints->{$type};
 292     return $checker if $checker;
 293
 294     return sub { blessed($_) && blessed($_) eq $type };
 295 }
 296
 297 sub verify_type_constraint {
 298     my $self = shift;
 299     local $_ = shift;
 300
 301     my $type = $self->type_constraint
 302         or return 1;
 303     my $constraint = $self->find_type_constraint;
 304
 305     return 1 if $constraint->($_);
 306
 307     my $name = $self->name;
 308     my $display = defined($_) ? overload::StrVal($_) : 'undef';
 309     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
 310 }
 311
 312 sub _canonicalize_handles {
 313     my $self    = shift;
 314     my $handles = shift;
 315
 316     if (ref($handles) eq 'HASH') {
 317         return %$handles;
 318     }
 319     elsif (ref($handles) eq 'ARRAY') {
 320         return map { $_ => $_ } @$handles;
 321     }
 322     else {
 323         confess "Unable to canonicalize the 'handles' option with $handles";
 324     }
 325 }
 326
 327 sub clone_parent {
 328     my $self  = shift;
 329     my $class = shift;
 330     my $name  = shift;
 331     my %args  = ($self->get_parent_args($class, $name), @_);
 332
 333     $self->create($class, $name, %args);
 334 }
 335
 336 sub get_parent_args {
 337     my $self  = shift;
 338     my $class = shift;
 339     my $name  = shift;
 340
 341     for my $super ($class->linearized_isa) {
 342         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 343             or next;
 344         return %{ $super_attr->_create_args };
 345     }
 346
 347     confess "Could not find an attribute by the name of '$name' to inherit from";
 348 }
 349
 350 1;
 351
 352 __END__
 353
 354 =head1 NAME
 355
 356 Mouse::Meta::Attribute - attribute metaclass
 357
 358 =head1 METHODS
 359
 360 =head2 new %args -> Mouse::Meta::Attribute
 361
 362 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 363
 364 =head2 create OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 365
 366 Creates a new attribute in OwnerClass. Accessors and helper methods are
 367 installed. Some error checking is done.
 368
 369 =head2 name -> AttributeName
 370
 371 =head2 associated_class -> OwnerClass
 372
 373 =head2 is_required -> Bool
 374
 375 =head2 default -> Item
 376
 377 =head2 has_default -> Bool
 378
 379 =head2 is_lazy -> Bool
 380
 381 =head2 predicate -> MethodName | Undef
 382
 383 =head2 has_predicate -> Bool
 384
 385 =head2 clearer -> MethodName | Undef
 386
 387 =head2 has_clearer -> Bool
 388
 389 =head2 handles -> { LocalName => RemoteName }
 390
 391 =head2 has_handles -> Bool
 392
 393 =head2 is_weak_ref -> Bool
 394
 395 =head2 init_arg -> Str
 396
 397 =head2 type_constraint -> Str
 398
 399 =head2 has_type_constraint -> Bool
 400
 401 =head2 trigger => CODE | Undef
 402
 403 =head2 has_trigger -> Bool
 404
 405 =head2 builder => MethodName | Undef
 406
 407 =head2 has_builder -> Bool
 408
 409 =head2 is_lazy_build => Bool
 410
 411 =head2 should_auto_deref -> Bool
 412
 413 Informational methods.
 414
 415 =head2 generate_accessor -> CODE
 416
 417 Creates a new code reference for the attribute's accessor.
 418
 419 =head2 generate_predicate -> CODE
 420
 421 Creates a new code reference for the attribute's predicate.
 422
 423 =head2 generate_clearer -> CODE
 424
 425 Creates a new code reference for the attribute's clearer.
 426
 427 =head2 generate_handles -> { MethodName => CODE }
 428
 429 Creates a new code reference for each of the attribute's handles methods.
 430
 431 =head2 find_type_constraint -> CODE
 432
 433 Returns a code reference which can be used to check that a given value passes
 434 this attribute's type constraint;
 435
 436 =head2 verify_type_constraint Item -> 1 | ERROR
 437
 438 Checks that the given value passes this attribute's type constraint. Returns 1
 439 on success, otherwise C<confess>es.
 440
 441 =head2 canonicalize_args Name, %args -> %args
 442
 443 Canonicalizes some arguments to create. In particular, C<lazy_build> is
 444 canonicalized into C<lazy>, C<builder>, etc.
 445
 446 =head2 validate_args Name, \%args -> 1 | ERROR
 447
 448 Checks that the arguments to create the attribute (ie those specified by
 449 C<has>) are valid.
 450
 451 =head2 clone_parent OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 452
 453 Creates a new attribute in OwnerClass, inheriting options from parent classes.
 454 Accessors and helper methods are installed. Some error checking is done.
 455
 456 =head2 get_parent_args OwnerClass, AttributeName -> Hash
 457
 458 Returns the options that the parent class of C<OwnerClass> used for attribute
 459 C<AttributeName>.
 460
 461 =cut
 462