lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use Mouse::Util qw(:meta); # enables strict and warnings
   3
   4 use Carp ();
   5
   6 use Mouse::Meta::TypeConstraint;
   7 use Mouse::Meta::Method::Accessor;
   8
   9
  10 sub _process_options{
  11     my($class, $name, $args) = @_;
  12
  13
  14     # XXX: for backward compatibility (with method modifiers)
  15     if($class->can('canonicalize_args') != \&canonicalize_args){
  16         %{$args} = $class->canonicalize_args($name, %{$args});
  17     }
  18
  19     # taken from Class::MOP::Attribute::new
  20
  21     defined($name)
  22         or $class->throw_error('You must provide a name for the attribute');
  23
  24     if(!exists $args->{init_arg}){
  25         $args->{init_arg} = $name;
  26     }
  27
  28     # 'required' requires eigher 'init_arg', 'builder', or 'default'
  29     my $can_be_required = defined( $args->{init_arg} );
  30
  31     if(exists $args->{builder}){
  32         # XXX:
  33         # Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
  34         # This feature will be changed in a future. (gfx)
  35         $class->throw_error('builder must be a defined scalar value which is a method name')
  36             #if ref $args->{builder} || !defined $args->{builder};
  37             if !defined $args->{builder};
  38
  39         $can_be_required++;
  40     }
  41     elsif(exists $args->{default}){
  42         if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
  43             $class->throw_error("References are not allowed as default values, you must "
  44                               . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
  45         }
  46         $can_be_required++;
  47     }
  48
  49     if( $args->{required} && !$can_be_required ) {
  50         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
  51     }
  52
  53     # taken from Mouse::Meta::Attribute->new and _process_args->
  54
  55     if(exists $args->{is}){
  56         my $is = $args->{is};
  57
  58         if($is eq 'ro'){
  59             $args->{reader} ||= $name;
  60         }
  61         elsif($is eq 'rw'){
  62             if(exists $args->{writer}){
  63                 $args->{reader} ||= $name;
  64              }
  65              else{
  66                 $args->{accessor} ||= $name;
  67              }
  68         }
  69         elsif($is eq 'bare'){
  70             # do nothing, but don't complain (later) about missing methods
  71         }
  72         else{
  73             $is = 'undef' if !defined $is;
  74             $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
  75         }
  76     }
  77
  78     my $tc;
  79     if(exists $args->{isa}){
  80         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
  81     }
  82     elsif(exists $args->{does}){
  83         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
  84     }
  85     $tc = $args->{type_constraint};
  86
  87     if($args->{coerce}){
  88         defined($tc)
  89             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
  90
  91         $args->{weak_ref}
  92             && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
  93     }
  94
  95     if ($args->{lazy_build}) {
  96         exists($args->{default})
  97             && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
  98
  99         $args->{lazy}      = 1;
 100         $args->{builder} ||= "_build_${name}";
 101         if ($name =~ /^_/) {
 102             $args->{clearer}   ||= "_clear${name}";
 103             $args->{predicate} ||= "_has${name}";
 104         }
 105         else {
 106             $args->{clearer}   ||= "clear_${name}";
 107             $args->{predicate} ||= "has_${name}";
 108         }
 109     }
 110
 111     if ($args->{auto_deref}) {
 112         defined($tc)
 113             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
 114
 115         ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
 116             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
 117     }
 118
 119     if (exists $args->{trigger}) {
 120         ('CODE' eq ref $args->{trigger})
 121             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
 122     }
 123
 124     if ($args->{lazy}) {
 125         (exists $args->{default} || defined $args->{builder})
 126             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
 127     }
 128
 129     return;
 130 }
 131
 132 sub new {
 133     my $class = shift;
 134     my $name  = shift;
 135
 136     my %args  = (@_ == 1) ? %{ $_[0] } : @_;
 137
 138     $class->_process_options($name, \%args);
 139
 140     $args{name} = $name;
 141
 142     my $self = bless \%args, $class;
 143
 144     # extra attributes
 145     if($class ne __PACKAGE__){
 146         $class->meta->_initialize_object($self, \%args);
 147     }
 148
 149 # XXX: there is no fast way to check attribute validity
 150 #    my @bad = ...;
 151 #    if(@bad){
 152 #        @bad = sort @bad;
 153 #        Carp::cluck("Found unknown argument(s) passed to '$name' attribute constructor in '$class': @bad");
 154 #    }
 155
 156     return $self;
 157 }
 158
 159 # readers
 160
 161 sub name                 { $_[0]->{name}                   }
 162 sub associated_class     { $_[0]->{associated_class}       }
 163
 164 sub accessor             { $_[0]->{accessor}               }
 165 sub reader               { $_[0]->{reader}                 }
 166 sub writer               { $_[0]->{writer}                 }
 167 sub predicate            { $_[0]->{predicate}              }
 168 sub clearer              { $_[0]->{clearer}                }
 169 sub handles              { $_[0]->{handles}                }
 170
 171 sub _is_metadata         { $_[0]->{is}                     }
 172 sub is_required          { $_[0]->{required}               }
 173 sub default              { $_[0]->{default}                }
 174 sub is_lazy              { $_[0]->{lazy}                   }
 175 sub is_lazy_build        { $_[0]->{lazy_build}             }
 176 sub is_weak_ref          { $_[0]->{weak_ref}               }
 177 sub init_arg             { $_[0]->{init_arg}               }
 178 sub type_constraint      { $_[0]->{type_constraint}        }
 179
 180 sub trigger              { $_[0]->{trigger}                }
 181 sub builder              { $_[0]->{builder}                }
 182 sub should_auto_deref    { $_[0]->{auto_deref}             }
 183 sub should_coerce        { $_[0]->{coerce}                 }
 184
 185 # predicates
 186
 187 sub has_accessor         { exists $_[0]->{accessor}        }
 188 sub has_reader           { exists $_[0]->{reader}          }
 189 sub has_writer           { exists $_[0]->{writer}          }
 190 sub has_predicate        { exists $_[0]->{predicate}       }
 191 sub has_clearer          { exists $_[0]->{clearer}         }
 192 sub has_handles          { exists $_[0]->{handles}         }
 193
 194 sub has_default          { exists $_[0]->{default}         }
 195 sub has_type_constraint  { exists $_[0]->{type_constraint} }
 196 sub has_trigger          { exists $_[0]->{trigger}         }
 197 sub has_builder          { exists $_[0]->{builder}         }
 198
 199 sub has_read_method      { exists $_[0]->{reader} || exists $_[0]->{accessor} }
 200 sub has_write_method     { exists $_[0]->{writer} || exists $_[0]->{accessor} }
 201
 202 sub _create_args { # DEPRECATED
 203     $_[0]->{_create_args} = $_[1] if @_ > 1;
 204     $_[0]->{_create_args}
 205 }
 206
 207 sub interpolate_class{
 208     my($class, $args) = @_;
 209
 210     if(my $metaclass = delete $args->{metaclass}){
 211         $class = Mouse::Util::resolve_metaclass_alias( Attribute => $metaclass );
 212     }
 213
 214     my @traits;
 215     if(my $traits_ref = delete $args->{traits}){
 216
 217         local $@;
 218         eval{
 219             for (my $i = 0; $i < @{$traits_ref}; $i++) {
 220                 my $trait = Mouse::Util::resolve_metaclass_alias(Attribute => $traits_ref->[$i], trait => 1);
 221
 222                 next if $class->does($trait);
 223
 224                 push @traits, $trait;
 225
 226                 # are there options?
 227                 push @traits, $traits_ref->[++$i]
 228                     if ref($traits_ref->[$i+1]);
 229             }
 230         };
 231         warn "Fatal error in traits: $@" if _MOUSE_VERBOSE;
 232
 233         if (@traits) {
 234             $class = Mouse::Meta::Class->create_anon_class(
 235                 superclasses => [ $class ],
 236                 roles        => \@traits,
 237                 cache        => 1,
 238             )->name;
 239         }
 240     }
 241
 242     return( $class, @traits );
 243 }
 244
 245 sub canonicalize_args{ # DEPRECATED
 246     my ($self, $name, %args) = @_;
 247
 248     Carp::cluck("$self->canonicalize_args has been deprecated."
 249         . "Use \$self->_process_options instead.")
 250             if _MOUSE_VERBOSE;
 251
 252     return %args;
 253 }
 254
 255 sub create { # DEPRECATED
 256     my ($self, $class, $name, %args) = @_;
 257
 258     Carp::cluck("$self->create has been deprecated."
 259         . "Use \$meta->add_attribute and \$attr->install_accessors instead.")
 260             if _MOUSE_VERBOSE;
 261
 262     # noop
 263     return $self;
 264 }
 265
 266 sub _coerce_and_verify {
 267     my($self, $value, $instance) = @_;
 268
 269     my $type_constraint = $self->{type_constraint};
 270     return $value if !defined $type_constraint;
 271
 272     if ($self->should_coerce && $type_constraint->has_coercion) {
 273         $value = $type_constraint->coerce($value);
 274     }
 275
 276     $self->verify_against_type_constraint($value);
 277
 278     return $value;
 279 }
 280
 281 sub verify_against_type_constraint {
 282     my ($self, $value) = @_;
 283
 284     my $type_constraint = $self->{type_constraint};
 285     return 1 if !$type_constraint;
 286     return 1 if $type_constraint->check($value);
 287
 288     $self->verify_type_constraint_error($self->name, $value, $type_constraint);
 289 }
 290
 291 sub verify_type_constraint_error {
 292     my($self, $name, $value, $type) = @_;
 293     $self->throw_error("Attribute ($name) does not pass the type constraint because: "
 294         . $type->get_message($value));
 295 }
 296
 297 sub coerce_constraint { # DEPRECATED
 298     my $type = $_[0]->{type_constraint}
 299         or return $_[1];
 300
 301     Carp::cluck("coerce_constraint() has been deprecated, which was an internal utility anyway");
 302
 303     return Mouse::Util::TypeConstraints->typecast_constraints($_[0]->associated_class->name, $type, $_[1]);
 304 }
 305
 306 sub clone_and_inherit_options{
 307     my($self, %args) = @_;
 308
 309     my($attribute_class, @traits) = ref($self)->interpolate_class(\%args);
 310
 311     $args{traits} = \@traits if @traits;
 312     return $attribute_class->new($self->name, %{$self}, %args);
 313 }
 314
 315 sub clone_parent { # DEPRECATED
 316     my $self  = shift;
 317     my $class = shift;
 318     my $name  = shift;
 319     my %args  = ($self->get_parent_args($class, $name), @_);
 320
 321     Carp::cluck("$self->clone_parent has been deprecated."
 322         . "Use \$meta->add_attribute and \$attr->install_accessors instead.")
 323         if _MOUSE_VERBOSE;
 324
 325     $self->clone_and_inherited_args($class, $name, %args);
 326 }
 327
 328 sub get_parent_args { # DEPRECATED
 329     my $self  = shift;
 330     my $class = shift;
 331     my $name  = shift;
 332
 333     for my $super ($class->linearized_isa) {
 334         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 335             or next;
 336         return %{ $super_attr->_create_args };
 337     }
 338
 339     $self->throw_error("Could not find an attribute by the name of '$name' to inherit from");
 340 }
 341
 342
 343 sub get_read_method {
 344     $_[0]->{reader} || $_[0]->{accessor}
 345 }
 346 sub get_write_method {
 347     $_[0]->{writer} || $_[0]->{accessor}
 348 }
 349
 350 sub get_read_method_ref{
 351     my($self) = @_;
 352
 353     $self->{_read_method_ref} ||= do{
 354         my $metaclass = $self->associated_class
 355             or $self->throw_error('No asocciated class for ' . $self->name);
 356
 357         my $reader = $self->{reader} || $self->{accessor};
 358         if($reader){
 359             $metaclass->name->can($reader);
 360         }
 361         else{
 362             $self->accessor_metaclass->_generate_reader($self, $metaclass);
 363         }
 364     };
 365 }
 366
 367 sub get_write_method_ref{
 368     my($self) = @_;
 369
 370     $self->{_write_method_ref} ||= do{
 371         my $metaclass = $self->associated_class
 372             or $self->throw_error('No asocciated class for ' . $self->name);
 373
 374         my $reader = $self->{writer} || $self->{accessor};
 375         if($reader){
 376             $metaclass->name->can($reader);
 377         }
 378         else{
 379             $self->accessor_metaclass->_generate_writer($self, $metaclass);
 380         }
 381     };
 382 }
 383
 384 sub _canonicalize_handles {
 385     my($self, $handles) = @_;
 386
 387     if (ref($handles) eq 'HASH') {
 388         return %$handles;
 389     }
 390     elsif (ref($handles) eq 'ARRAY') {
 391         return map { $_ => $_ } @$handles;
 392     }
 393     elsif (ref($handles) eq 'Regexp') {
 394         my $class_or_role = ($self->{isa} || $self->{does})
 395             || $self->throw_error("Cannot delegate methods based on a Regexp without a type constraint (isa)");
 396
 397         my $meta = Mouse::Meta::Class->initialize("$class_or_role"); # "" for stringify
 398         return map  { $_ => $_ }
 399                grep { $_ ne 'meta' && !Mouse::Object->can($_) && $_ =~ $handles }
 400                    $meta->isa('Mouse::Meta::Class') ? $meta->get_all_method_names : $meta->get_method_list;
 401     }
 402     else {
 403         $self->throw_error("Unable to canonicalize the 'handles' option with $handles");
 404     }
 405 }
 406
 407
 408 sub associate_method{
 409     my ($attribute, $method) = @_;
 410     $attribute->{associated_methods}++;
 411     return;
 412 }
 413
 414 sub accessor_metaclass(){ 'Mouse::Meta::Method::Accessor' }
 415
 416 sub install_accessors{
 417     my($attribute) = @_;
 418
 419     my $metaclass      = $attribute->{associated_class};
 420     my $accessor_class = $attribute->accessor_metaclass;
 421
 422     foreach my $type(qw(accessor reader writer predicate clearer)){
 423         if(exists $attribute->{$type}){
 424             my $generator = '_generate_' . $type;
 425             my $code      = $accessor_class->$generator($attribute, $metaclass);
 426             $metaclass->add_method($attribute->{$type} => $code);
 427             $attribute->associate_method($code);
 428         }
 429     }
 430
 431     # install delegation
 432     if(exists $attribute->{handles}){
 433         my %handles = $attribute->_canonicalize_handles($attribute->{handles});
 434         my $reader  = $attribute->get_read_method_ref;
 435
 436         while(my($handle_name, $method_to_call) = each %handles){
 437             my $code = $accessor_class->_generate_delegation($attribute, $metaclass,
 438                 $reader, $handle_name, $method_to_call);
 439
 440             $metaclass->add_method($handle_name => $code);
 441             $attribute->associate_method($code);
 442         }
 443     }
 444
 445
 446     if($attribute->can('create') != \&create){
 447         # backword compatibility
 448         $attribute->create($metaclass, $attribute->name, %{$attribute});
 449     }
 450
 451     return;
 452 }
 453
 454 sub throw_error{
 455     my $self = shift;
 456
 457     my $metaclass = (ref $self && $self->associated_class) || 'Mouse::Meta::Class';
 458     $metaclass->throw_error(@_, depth => 1);
 459 }
 460
 461 1;
 462
 463 __END__
 464
 465 =head1 NAME
 466
 467 Mouse::Meta::Attribute - The Mouse attribute metaclass
 468
 469 =head1 VERSION
 470
 471 This document describes Mouse version 0.39
 472
 473 =head1 METHODS
 474
 475 =head2 C<< new(%options) -> Mouse::Meta::Attribute >>
 476
 477 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 478
 479 It adds the following options to the constructor:
 480
 481 =over 4
 482
 483 =item C<< is => 'ro', 'rw', 'bare' >>
 484
 485 This provides a shorthand for specifying the C<reader>, C<writer>, or
 486 C<accessor> names. If the attribute is read-only ('ro') then it will
 487 have a C<reader> method with the same attribute as the name.
 488
 489 If it is read-write ('rw') then it will have an C<accessor> method
 490 with the same name. If you provide an explicit C<writer> for a
 491 read-write attribute, then you will have a C<reader> with the same
 492 name as the attribute, and a C<writer> with the name you provided.
 493
 494 Use 'bare' when you are deliberately not installing any methods
 495 (accessor, reader, etc.) associated with this attribute; otherwise,
 496 Moose will issue a deprecation warning when this attribute is added to a
 497 metaclass.
 498
 499 =item C<< isa => Type >>
 500
 501 This option accepts a type. The type can be a string, which should be
 502 a type name. If the type name is unknown, it is assumed to be a class
 503 name.
 504
 505 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 506
 507 If you I<also> provide a C<does> option, then your C<isa> option must
 508 be a class name, and that class must do the role specified with
 509 C<does>.
 510
 511 =item C<< does => Role >>
 512
 513 This is short-hand for saying that the attribute's type must be an
 514 object which does the named role.
 515
 516 B<This option is not yet supported.>
 517
 518 =item C<< coerce => Bool >>
 519
 520 This option is only valid for objects with a type constraint
 521 (C<isa>). If this is true, then coercions will be applied whenever
 522 this attribute is set.
 523
 524 You can make both this and the C<weak_ref> option true.
 525
 526 =item C<< trigger => CodeRef >>
 527
 528 This option accepts a subroutine reference, which will be called after
 529 the attribute is set.
 530
 531 =item C<< required => Bool >>
 532
 533 An attribute which is required must be provided to the constructor. An
 534 attribute which is required can also have a C<default> or C<builder>,
 535 which will satisfy its required-ness.
 536
 537 A required attribute must have a C<default>, C<builder> or a
 538 non-C<undef> C<init_arg>
 539
 540 =item C<< lazy => Bool >>
 541
 542 A lazy attribute must have a C<default> or C<builder>. When an
 543 attribute is lazy, the default value will not be calculated until the
 544 attribute is read.
 545
 546 =item C<< weak_ref => Bool >>
 547
 548 If this is true, the attribute's value will be stored as a weak
 549 reference.
 550
 551 =item C<< auto_deref => Bool >>
 552
 553 If this is true, then the reader will dereference the value when it is
 554 called. The attribute must have a type constraint which defines the
 555 attribute as an array or hash reference.
 556
 557 =item C<< lazy_build => Bool >>
 558
 559 Setting this to true makes the attribute lazy and provides a number of
 560 default methods.
 561
 562   has 'size' => (
 563       is         => 'ro',
 564       lazy_build => 1,
 565   );
 566
 567 is equivalent to this:
 568
 569   has 'size' => (
 570       is        => 'ro',
 571       lazy      => 1,
 572       builder   => '_build_size',
 573       clearer   => 'clear_size',
 574       predicate => 'has_size',
 575   );
 576
 577 =back
 578
 579 =head2 C<< associate_method(Method) >>
 580
 581 Associates a method with the attribute. Typically, this is called internally
 582 when an attribute generates its accessors.
 583
 584 Currently the argument I<Method> is ignored in Mouse.
 585
 586 =head2 C<< verify_against_type_constraint(Item) -> TRUE | ERROR >>
 587
 588 Checks that the given value passes this attribute's type constraint. Returns C<true>
 589 on success, otherwise C<confess>es.
 590
 591 =head2 C<< clone_and_inherit_options(options) -> Mouse::Meta::Attribute >>
 592
 593 Creates a new attribute in the owner class, inheriting options from parent classes.
 594 Accessors and helper methods are installed. Some error checking is done.
 595
 596 =head2 C<< get_read_method_ref >>
 597
 598 =head2 C<< get_write_method_ref >>
 599
 600 Returns the subroutine reference of a method suitable for reading or
 601 writing the attribute's value in the associated class. These methods
 602 always return a subroutine reference, regardless of whether or not the
 603 attribute is read- or write-only.
 604
 605 =head1 SEE ALSO
 606
 607 L<Moose::Meta::Attribute>
 608
 609 L<Class::MOP::Attribute>
 610
 611 =cut
 612