lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use strict;
   3 use warnings;
   4 require overload;
   5
   6 use Carp 'confess';
   7 use Scalar::Util ();
   8
   9 sub new {
  10     my ($class, $name, %options) = @_;
  11
  12     $options{name} = $name;
  13
  14     $options{init_arg} = $name
  15         unless exists $options{init_arg};
  16
  17     $options{is} ||= '';
  18
  19     bless \%options, $class;
  20 }
  21
  22 sub name                 { $_[0]->{name}                   }
  23 sub associated_class     { $_[0]->{associated_class}       }
  24 sub _is_metadata         { $_[0]->{is}                     }
  25 sub is_required          { $_[0]->{required}               }
  26 sub default              { $_[0]->{default}                }
  27 sub is_lazy              { $_[0]->{lazy}                   }
  28 sub is_lazy_build        { $_[0]->{lazy_build}             }
  29 sub predicate            { $_[0]->{predicate}              }
  30 sub clearer              { $_[0]->{clearer}                }
  31 sub handles              { $_[0]->{handles}                }
  32 sub is_weak_ref          { $_[0]->{weak_ref}               }
  33 sub init_arg             { $_[0]->{init_arg}               }
  34 sub type_constraint      { $_[0]->{type_constraint}        }
  35 sub trigger              { $_[0]->{trigger}                }
  36 sub builder              { $_[0]->{builder}                }
  37 sub should_auto_deref    { $_[0]->{auto_deref}             }
  38 sub should_coerce        { $_[0]->{should_coerce}          }
  39 sub find_type_constraint { $_[0]->{find_type_constraint}   }
  40
  41 sub has_default          { exists $_[0]->{default}         }
  42 sub has_predicate        { exists $_[0]->{predicate}       }
  43 sub has_clearer          { exists $_[0]->{clearer}         }
  44 sub has_handles          { exists $_[0]->{handles}         }
  45 sub has_type_constraint  { exists $_[0]->{type_constraint} }
  46 sub has_trigger          { exists $_[0]->{trigger}         }
  47 sub has_builder          { exists $_[0]->{builder}         }
  48
  49 sub _create_args {
  50     $_[0]->{_create_args} = $_[1] if @_ > 1;
  51     $_[0]->{_create_args}
  52 }
  53
  54 sub inlined_name {
  55     my $self = shift;
  56     my $name = $self->name;
  57     my $key   = "'" . $name . "'";
  58     return $key;
  59 }
  60
  61 sub generate_accessor {
  62     my $attribute = shift;
  63
  64     my $name          = $attribute->name;
  65     my $default       = $attribute->default;
  66     my $constraint    = $attribute->find_type_constraint;
  67     my $builder       = $attribute->builder;
  68     my $trigger       = $attribute->trigger;
  69     my $is_weak       = $attribute->is_weak_ref;
  70     my $should_deref  = $attribute->should_auto_deref;
  71     my $should_coerce = $attribute->should_coerce;
  72
  73     my $self  = '$_[0]';
  74     my $key   = $attribute->inlined_name;
  75
  76     my $accessor =
  77         '#line ' . __LINE__ . ' "' . __FILE__ . "\"\n" .
  78         "sub {\n";
  79     if ($attribute->_is_metadata eq 'rw') {
  80         $accessor .=
  81             '#line ' . __LINE__ . ' "' . __FILE__ . "\"\n" .
  82             'if (@_ >= 2) {' . "\n";
  83
  84         my $value = '$_[1]';
  85
  86         if ($constraint) {
  87             $accessor .= 'my $val = ';
  88             if ($should_coerce) {
  89                 $accessor .=
  90                     "\n".
  91                     '#line ' . __LINE__ . ' "' . __FILE__ . "\"\n" .
  92                     'Mouse::Util::TypeConstraints->typecast_constraints("'.$attribute->associated_class->name.'", $attribute->{find_type_constraint}, $attribute->{type_constraint}, '.$value.');';
  93             } else {
  94                 $accessor .= $value.';';
  95             }
  96             $accessor .=
  97                 "\n".
  98                 '#line ' . __LINE__ . ' "' . __FILE__ . "\"\n" .
  99                 'unless ($constraint->($val)) {
 100                     $attribute->verify_type_constraint_error($name, $val, $attribute->type_constraint);
 101                 }' . "\n";
 102             $value = '$val';
 103         }
 104
 105         # if there's nothing left to do for the attribute we can return during
 106         # this setter
 107         $accessor .= 'return ' if !$is_weak && !$trigger && !$should_deref;
 108
 109         $accessor .= $self.'->{'.$key.'} = '.$value.';' . "\n";
 110
 111         if ($is_weak) {
 112             $accessor .= 'Scalar::Util::weaken('.$self.'->{'.$key.'}) if ref('.$self.'->{'.$key.'});' . "\n";
 113         }
 114
 115         if ($trigger) {
 116             $accessor .= '$trigger->('.$self.', '.$value.');' . "\n";
 117         }
 118
 119         $accessor .= "}\n";
 120     }
 121     else {
 122         $accessor .= 'confess "Cannot assign a value to a read-only accessor" if scalar(@_) >= 2;' . "\n";
 123     }
 124
 125     if ($attribute->is_lazy) {
 126         $accessor .= $self.'->{'.$key.'} = ';
 127
 128         $accessor .= $attribute->has_builder
 129                 ? $self.'->$builder'
 130                     : ref($default) eq 'CODE'
 131                     ? '$default->('.$self.')'
 132                     : '$default';
 133         $accessor .= ' if !exists '.$self.'->{'.$key.'};' . "\n";
 134     }
 135
 136     if ($should_deref) {
 137         my $type_constraint = $attribute->type_constraint;
 138         if (!ref($type_constraint) && $type_constraint eq 'ArrayRef') {
 139             $accessor .= 'if (wantarray) {
 140                 return @{ '.$self.'->{'.$key.'} || [] };
 141             }';
 142         }
 143         else {
 144             $accessor .= 'if (wantarray) {
 145                 return %{ '.$self.'->{'.$key.'} || {} };
 146             }';
 147         }
 148     }
 149
 150     $accessor .= 'return '.$self.'->{'.$key.'};
 151     }';
 152
 153     my $sub = eval $accessor;
 154     confess $@ if $@;
 155     return $sub;
 156 }
 157
 158 sub generate_predicate {
 159     my $attribute = shift;
 160     my $key = $attribute->inlined_name;
 161
 162     my $predicate = 'sub { exists($_[0]->{'.$key.'}) }';
 163
 164     my $sub = eval $predicate;
 165     confess $@ if $@;
 166     return $sub;
 167 }
 168
 169 sub generate_clearer {
 170     my $attribute = shift;
 171     my $key = $attribute->inlined_name;
 172
 173     my $clearer = 'sub { delete($_[0]->{'.$key.'}) }';
 174
 175     my $sub = eval $clearer;
 176     confess $@ if $@;
 177     return $sub;
 178 }
 179
 180 sub generate_handles {
 181     my $attribute = shift;
 182     my $reader = $attribute->name;
 183     my %handles = $attribute->_canonicalize_handles($attribute->handles);
 184
 185     my %method_map;
 186
 187     for my $local_method (keys %handles) {
 188         my $remote_method = $handles{$local_method};
 189
 190         my $method = 'sub {
 191             my $self = shift;
 192             $self->'.$reader.'->'.$remote_method.'(@_)
 193         }';
 194
 195         $method_map{$local_method} = eval $method;
 196         confess $@ if $@;
 197     }
 198
 199     return \%method_map;
 200 }
 201
 202 sub create {
 203     my ($self, $class, $name, %args) = @_;
 204
 205     $args{name} = $name;
 206     $args{associated_class} = $class;
 207
 208     %args = $self->canonicalize_args($name, %args);
 209     $self->validate_args($name, \%args);
 210
 211     $args{should_coerce} = delete $args{coerce}
 212         if exists $args{coerce};
 213
 214     if (exists $args{isa}) {
 215         confess "Got isa => $args{isa}, but Mouse does not yet support parameterized types for containers other than ArrayRef and HashRef (rt.cpan.org #39795)"
 216             if $args{isa} =~ /^([^\[]+)\[.+\]$/ &&
 217                $1 ne 'ArrayRef' &&
 218                $1 ne 'HashRef'  &&
 219                $1 ne 'Maybe'
 220         ;
 221
 222         my $type_constraint = delete $args{isa};
 223         $type_constraint =~ s/\s+//g;
 224         my $code = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($type_constraint);
 225         $args{type_constraint} = $type_constraint =~ /\|/ ?
 226             [ split (/\|/, $type_constraint ) ] :
 227             $type_constraint
 228         ;
 229         $args{find_type_constraint} = $code;
 230     }
 231
 232     my $attribute = $self->new($name, %args);
 233
 234     $attribute->_create_args(\%args);
 235
 236     $class->add_attribute($attribute);
 237
 238     # install an accessor
 239     if ($attribute->_is_metadata eq 'rw' || $attribute->_is_metadata eq 'ro') {
 240         my $accessor = $attribute->generate_accessor;
 241         $class->add_method($name => $accessor);
 242     }
 243
 244     for my $method (qw/predicate clearer/) {
 245         my $predicate = "has_$method";
 246         if ($attribute->$predicate) {
 247             my $generator = "generate_$method";
 248             my $coderef = $attribute->$generator;
 249             $class->add_method($attribute->$method => $coderef);
 250         }
 251     }
 252
 253     if ($attribute->has_handles) {
 254         my $method_map = $attribute->generate_handles;
 255         for my $method_name (keys %$method_map) {
 256             $class->add_method($method_name => $method_map->{$method_name});
 257         }
 258     }
 259
 260     return $attribute;
 261 }
 262
 263 sub canonicalize_args {
 264     my $self = shift;
 265     my $name = shift;
 266     my %args = @_;
 267
 268     if ($args{lazy_build}) {
 269         $args{lazy}      = 1;
 270         $args{required}  = 1;
 271         $args{builder}   = "_build_${name}"
 272             if !exists($args{builder});
 273         if ($name =~ /^_/) {
 274             $args{clearer}   = "_clear${name}" if !exists($args{clearer});
 275             $args{predicate} = "_has${name}" if !exists($args{predicate});
 276         }
 277         else {
 278             $args{clearer}   = "clear_${name}" if !exists($args{clearer});
 279             $args{predicate} = "has_${name}" if !exists($args{predicate});
 280         }
 281     }
 282
 283     return %args;
 284 }
 285
 286 sub validate_args {
 287     my $self = shift;
 288     my $name = shift;
 289     my $args = shift;
 290
 291     confess "You can not use lazy_build and default for the same attribute ($name)"
 292         if $args->{lazy_build} && exists $args->{default};
 293
 294     confess "You cannot have lazy attribute ($name) without specifying a default value for it"
 295         if $args->{lazy}
 296         && !exists($args->{default})
 297         && !exists($args->{builder});
 298
 299     confess "References are not allowed as default values, you must wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])"
 300         if ref($args->{default})
 301         && ref($args->{default}) ne 'CODE';
 302
 303     confess "You cannot auto-dereference without specifying a type constraint on attribute ($name)"
 304         if $args->{auto_deref} && !exists($args->{isa});
 305
 306     confess "You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)"
 307         if $args->{auto_deref}
 308         && $args->{isa} ne 'ArrayRef'
 309         && $args->{isa} ne 'HashRef';
 310
 311     if ($args->{trigger}) {
 312         if (ref($args->{trigger}) eq 'HASH') {
 313             Carp::carp "HASH-based form of trigger has been removed. Only the coderef form of triggers are now supported.";
 314         }
 315
 316         confess "Trigger must be a CODE ref on attribute ($name)"
 317             if ref($args->{trigger}) ne 'CODE';
 318     }
 319
 320     return 1;
 321 }
 322
 323 sub verify_against_type_constraint {
 324     return 1 unless $_[0]->{type_constraint};
 325
 326     local $_ = $_[1];
 327     return 1 if $_[0]->{find_type_constraint}->($_);
 328
 329     my $self = shift;
 330     $self->verify_type_constraint_error($self->name, $_, $self->type_constraint);
 331 }
 332
 333 sub verify_type_constraint_error {
 334     my($self, $name, $value, $type) = @_;
 335     $type = ref($type) eq 'ARRAY' ? join '|', @{ $type } : $type;
 336     my $display = defined($value) ? overload::StrVal($value) : 'undef';
 337     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
 338 }
 339
 340 sub coerce_constraint { ## my($self, $value) = @_;
 341     my $type = $_[0]->{type_constraint}
 342         or return $_[1];
 343     return Mouse::Util::TypeConstraints->typecast_constraints($_[0]->associated_class->name, $_[0]->find_type_constraint, $type, $_[1]);
 344 }
 345
 346 sub _canonicalize_handles {
 347     my $self    = shift;
 348     my $handles = shift;
 349
 350     if (ref($handles) eq 'HASH') {
 351         return %$handles;
 352     }
 353     elsif (ref($handles) eq 'ARRAY') {
 354         return map { $_ => $_ } @$handles;
 355     }
 356     else {
 357         confess "Unable to canonicalize the 'handles' option with $handles";
 358     }
 359 }
 360
 361 sub clone_parent {
 362     my $self  = shift;
 363     my $class = shift;
 364     my $name  = shift;
 365     my %args  = ($self->get_parent_args($class, $name), @_);
 366
 367     $self->create($class, $name, %args);
 368 }
 369
 370 sub get_parent_args {
 371     my $self  = shift;
 372     my $class = shift;
 373     my $name  = shift;
 374
 375     for my $super ($class->linearized_isa) {
 376         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 377             or next;
 378         return %{ $super_attr->_create_args };
 379     }
 380
 381     confess "Could not find an attribute by the name of '$name' to inherit from";
 382 }
 383
 384 1;
 385
 386 __END__
 387
 388 =head1 NAME
 389
 390 Mouse::Meta::Attribute - attribute metaclass
 391
 392 =head1 METHODS
 393
 394 =head2 new %args -> Mouse::Meta::Attribute
 395
 396 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 397
 398 =head2 create OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 399
 400 Creates a new attribute in OwnerClass. Accessors and helper methods are
 401 installed. Some error checking is done.
 402
 403 =head2 name -> AttributeName
 404
 405 =head2 associated_class -> OwnerClass
 406
 407 =head2 is_required -> Bool
 408
 409 =head2 default -> Item
 410
 411 =head2 has_default -> Bool
 412
 413 =head2 is_lazy -> Bool
 414
 415 =head2 predicate -> MethodName | Undef
 416
 417 =head2 has_predicate -> Bool
 418
 419 =head2 clearer -> MethodName | Undef
 420
 421 =head2 has_clearer -> Bool
 422
 423 =head2 handles -> { LocalName => RemoteName }
 424
 425 =head2 has_handles -> Bool
 426
 427 =head2 is_weak_ref -> Bool
 428
 429 =head2 init_arg -> Str
 430
 431 =head2 type_constraint -> Str
 432
 433 =head2 has_type_constraint -> Bool
 434
 435 =head2 trigger => CODE | Undef
 436
 437 =head2 has_trigger -> Bool
 438
 439 =head2 builder => MethodName | Undef
 440
 441 =head2 has_builder -> Bool
 442
 443 =head2 is_lazy_build => Bool
 444
 445 =head2 should_auto_deref -> Bool
 446
 447 Informational methods.
 448
 449 =head2 generate_accessor -> CODE
 450
 451 Creates a new code reference for the attribute's accessor.
 452
 453 =head2 generate_predicate -> CODE
 454
 455 Creates a new code reference for the attribute's predicate.
 456
 457 =head2 generate_clearer -> CODE
 458
 459 Creates a new code reference for the attribute's clearer.
 460
 461 =head2 generate_handles -> { MethodName => CODE }
 462
 463 Creates a new code reference for each of the attribute's handles methods.
 464
 465 =head2 find_type_constraint -> CODE
 466
 467 Returns a code reference which can be used to check that a given value passes
 468 this attribute's type constraint;
 469
 470 =head2 verify_against_type_constraint Item -> 1 | ERROR
 471
 472 Checks that the given value passes this attribute's type constraint. Returns 1
 473 on success, otherwise C<confess>es.
 474
 475 =head2 canonicalize_args Name, %args -> %args
 476
 477 Canonicalizes some arguments to create. In particular, C<lazy_build> is
 478 canonicalized into C<lazy>, C<builder>, etc.
 479
 480 =head2 validate_args Name, \%args -> 1 | ERROR
 481
 482 Checks that the arguments to create the attribute (ie those specified by
 483 C<has>) are valid.
 484
 485 =head2 clone_parent OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 486
 487 Creates a new attribute in OwnerClass, inheriting options from parent classes.
 488 Accessors and helper methods are installed. Some error checking is done.
 489
 490 =head2 get_parent_args OwnerClass, AttributeName -> Hash
 491
 492 Returns the options that the parent class of C<OwnerClass> used for attribute
 493 C<AttributeName>.
 494
 495 =cut
 496