lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use Mouse::Util qw(:meta); # enables strict and warnings
   3
   4 use Carp ();
   5
   6 use Mouse::Meta::TypeConstraint;
   7
   8 sub _process_options{
   9     my($class, $name, $args) = @_;
  10
  11     # XXX: for backward compatibility (with method modifiers)
  12     if($class->can('canonicalize_args') != \&canonicalize_args){
  13         %{$args} = $class->canonicalize_args($name, %{$args});
  14     }
  15
  16     # taken from Class::MOP::Attribute::new
  17
  18     defined($name)
  19         or $class->throw_error('You must provide a name for the attribute');
  20
  21     if(!exists $args->{init_arg}){
  22         $args->{init_arg} = $name;
  23     }
  24
  25     # 'required' requires eigher 'init_arg', 'builder', or 'default'
  26     my $can_be_required = defined( $args->{init_arg} );
  27
  28     if(exists $args->{builder}){
  29         # XXX:
  30         # Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
  31         # This feature will be changed in a future. (gfx)
  32         $class->throw_error('builder must be a defined scalar value which is a method name')
  33             #if ref $args->{builder} || !defined $args->{builder};
  34             if !defined $args->{builder};
  35
  36         $can_be_required++;
  37     }
  38     elsif(exists $args->{default}){
  39         if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
  40             $class->throw_error("References are not allowed as default values, you must "
  41                               . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
  42         }
  43         $can_be_required++;
  44     }
  45
  46     if( $args->{required} && !$can_be_required ) {
  47         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
  48     }
  49
  50     # taken from Mouse::Meta::Attribute->new and _process_args->
  51
  52     if(exists $args->{is}){
  53         my $is = $args->{is};
  54
  55         if($is eq 'ro'){
  56             $args->{reader} ||= $name;
  57         }
  58         elsif($is eq 'rw'){
  59             if(exists $args->{writer}){
  60                 $args->{reader} ||= $name;
  61              }
  62              else{
  63                 $args->{accessor} ||= $name;
  64              }
  65         }
  66         elsif($is eq 'bare'){
  67             # do nothing, but don't complain (later) about missing methods
  68         }
  69         else{
  70             $is = 'undef' if !defined $is;
  71             $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
  72         }
  73     }
  74
  75     my $tc;
  76     if(exists $args->{isa}){
  77         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
  78     }
  79     elsif(exists $args->{does}){
  80         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
  81     }
  82     $tc = $args->{type_constraint};
  83
  84     if($args->{coerce}){
  85         defined($tc)
  86             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
  87
  88         $args->{weak_ref}
  89             && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
  90     }
  91
  92     if ($args->{lazy_build}) {
  93         exists($args->{default})
  94             && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
  95
  96         $args->{lazy}      = 1;
  97         $args->{builder} ||= "_build_${name}";
  98         if ($name =~ /^_/) {
  99             $args->{clearer}   ||= "_clear${name}";
 100             $args->{predicate} ||= "_has${name}";
 101         }
 102         else {
 103             $args->{clearer}   ||= "clear_${name}";
 104             $args->{predicate} ||= "has_${name}";
 105         }
 106     }
 107
 108     if ($args->{auto_deref}) {
 109         defined($tc)
 110             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
 111
 112         ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
 113             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
 114     }
 115
 116     if (exists $args->{trigger}) {
 117         ('CODE' eq ref $args->{trigger})
 118             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
 119     }
 120
 121     if ($args->{lazy}) {
 122         (exists $args->{default} || defined $args->{builder})
 123             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
 124     }
 125
 126     return;
 127 }
 128
 129 sub new {
 130     my $class = shift;
 131     my $name  = shift;
 132
 133     my %args  = (@_ == 1) ? %{ $_[0] } : @_;
 134
 135     $class->_process_options($name, \%args);
 136
 137     $args{name} = $name;
 138
 139     my $self = bless \%args, $class;
 140
 141     # extra attributes
 142     if($class ne __PACKAGE__){
 143         $class->meta->_initialize_object($self, \%args);
 144     }
 145
 146 # XXX: there is no fast way to check attribute validity
 147 #    my @bad = ...;
 148 #    if(@bad){
 149 #        @bad = sort @bad;
 150 #        Carp::cluck("Found unknown argument(s) passed to '$name' attribute constructor in '$class': @bad");
 151 #    }
 152
 153     return $self;
 154 }
 155
 156 sub has_read_method      { $_[0]->has_reader || $_[0]->has_accessor }
 157 sub has_write_method     { $_[0]->has_writer || $_[0]->has_accessor }
 158
 159 sub _create_args { # DEPRECATED
 160     $_[0]->{_create_args} = $_[1] if @_ > 1;
 161     $_[0]->{_create_args}
 162 }
 163
 164 sub interpolate_class{
 165     my($class, $args) = @_;
 166
 167     if(my $metaclass = delete $args->{metaclass}){
 168         $class = Mouse::Util::resolve_metaclass_alias( Attribute => $metaclass );
 169     }
 170
 171     my @traits;
 172     if(my $traits_ref = delete $args->{traits}){
 173
 174         for (my $i = 0; $i < @{$traits_ref}; $i++) {
 175             my $trait = Mouse::Util::resolve_metaclass_alias(Attribute => $traits_ref->[$i], trait => 1);
 176
 177             next if $class->does($trait);
 178
 179             push @traits, $trait;
 180
 181             # are there options?
 182             push @traits, $traits_ref->[++$i]
 183                 if ref($traits_ref->[$i+1]);
 184         }
 185
 186         if (@traits) {
 187             $class = Mouse::Meta::Class->create_anon_class(
 188                 superclasses => [ $class ],
 189                 roles        => \@traits,
 190                 cache        => 1,
 191             )->name;
 192         }
 193     }
 194
 195     return( $class, @traits );
 196 }
 197
 198 sub canonicalize_args{ # DEPRECATED
 199     my ($self, $name, %args) = @_;
 200
 201     Carp::cluck("$self->canonicalize_args has been deprecated."
 202         . "Use \$self->_process_options instead.");
 203
 204     return %args;
 205 }
 206
 207 sub create { # DEPRECATED
 208     my ($self, $class, $name, %args) = @_;
 209
 210     Carp::cluck("$self->create has been deprecated."
 211         . "Use \$meta->add_attribute and \$attr->install_accessors instead.");
 212
 213     # noop
 214     return $self;
 215 }
 216
 217 sub _coerce_and_verify {
 218     my($self, $value, $instance) = @_;
 219
 220     my $type_constraint = $self->{type_constraint};
 221     return $value if !defined $type_constraint;
 222
 223     if ($self->should_coerce && $type_constraint->has_coercion) {
 224         $value = $type_constraint->coerce($value);
 225     }
 226
 227     $self->verify_against_type_constraint($value);
 228
 229     return $value;
 230 }
 231
 232 sub verify_against_type_constraint {
 233     my ($self, $value) = @_;
 234
 235     my $type_constraint = $self->{type_constraint};
 236     return 1 if !$type_constraint;
 237     return 1 if $type_constraint->check($value);
 238
 239     $self->_throw_type_constraint_error($value, $type_constraint);
 240 }
 241
 242 sub _throw_type_constraint_error {
 243     my($self, $value, $type) = @_;
 244
 245     $self->throw_error(
 246         sprintf q{Attribute (%s) does not pass the type constraint because: %s},
 247             $self->name,
 248             $type->get_message($value),
 249     );
 250 }
 251
 252 sub coerce_constraint { # DEPRECATED
 253     my $type = $_[0]->{type_constraint}
 254         or return $_[1];
 255
 256     Carp::cluck("coerce_constraint() has been deprecated, which was an internal utility anyway");
 257
 258     return Mouse::Util::TypeConstraints->typecast_constraints($_[0]->associated_class->name, $type, $_[1]);
 259 }
 260
 261 sub clone_and_inherit_options{
 262     my($self, %args) = @_;
 263
 264     my($attribute_class, @traits) = ref($self)->interpolate_class(\%args);
 265
 266     $args{traits} = \@traits if @traits;
 267     # do not inherit the 'handles' attribute
 268     foreach my $name(keys %{$self}){
 269         if(!exists $args{$name} && $name ne 'handles'){
 270             $args{$name} = $self->{$name};
 271         }
 272     }
 273     return $attribute_class->new($self->name, %args);
 274 }
 275
 276 sub clone_parent { # DEPRECATED
 277     my $self  = shift;
 278     my $class = shift;
 279     my $name  = shift;
 280     my %args  = ($self->get_parent_args($class, $name), @_);
 281
 282     Carp::cluck("$self->clone_parent has been deprecated."
 283         . "Use \$meta->add_attribute and \$attr->install_accessors instead.");
 284
 285     $self->clone_and_inherited_args($class, $name, %args);
 286 }
 287
 288 sub get_parent_args { # DEPRECATED
 289     my $self  = shift;
 290     my $class = shift;
 291     my $name  = shift;
 292
 293     for my $super ($class->linearized_isa) {
 294         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 295             or next;
 296         return %{ $super_attr->_create_args };
 297     }
 298
 299     $self->throw_error("Could not find an attribute by the name of '$name' to inherit from");
 300 }
 301
 302
 303 sub get_read_method {
 304     return $_[0]->reader || $_[0]->accessor
 305 }
 306 sub get_write_method {
 307     return $_[0]->writer || $_[0]->accessor
 308 }
 309
 310 sub _get_accessor_method_ref {
 311     my($self, $type, $generator) = @_;
 312
 313     my $metaclass = $self->associated_class
 314         || $self->throw_error('No asocciated class for ' . $self->name);
 315
 316     my $accessor = $self->$type();
 317     if($accessor){
 318         return $metaclass->get_method_body($accessor);
 319     }
 320     else{
 321         return $self->accessor_metaclass->$generator($self, $metaclass);
 322     }
 323 }
 324
 325 sub get_read_method_ref{
 326     my($self) = @_;
 327     return $self->{_read_method_ref} ||= $self->_get_accessor_method_ref('get_read_method', '_generate_reader');
 328 }
 329
 330 sub get_write_method_ref{
 331     my($self) = @_;
 332     return $self->{_write_method_ref} ||= $self->_get_accessor_method_ref('get_write_method', '_generate_writer');
 333 }
 334
 335 sub set_value {
 336     my($self, $object, $value) = @_;
 337     return $self->get_write_method_ref()->($object, $value);
 338 }
 339
 340 sub get_value {
 341     my($self, $object) = @_;
 342     return $self->get_read_method_ref()->($object);
 343 }
 344
 345 sub has_value {
 346     my($self, $object) = @_;
 347     my $accessor_ref = $self->{_predicate_ref}
 348         ||= $self->_get_accessor_method_ref('predicate', '_generate_predicate');
 349
 350     return $accessor_ref->($object);
 351 }
 352
 353 sub clear_value {
 354     my($self, $object) = @_;
 355     my $accessor_ref = $self->{_crealer_ref}
 356         ||= $self->_get_accessor_method_ref('clearer', '_generate_clearer');
 357
 358     return $accessor_ref->($object);
 359 }
 360
 361
 362 sub associate_method{
 363     my ($attribute, $method_name) = @_;
 364     $attribute->{associated_methods}++;
 365     return;
 366 }
 367
 368 sub install_accessors{
 369     my($attribute) = @_;
 370
 371     my $metaclass      = $attribute->associated_class;
 372     my $accessor_class = $attribute->accessor_metaclass;
 373
 374     foreach my $type(qw(accessor reader writer predicate clearer)){
 375         if(exists $attribute->{$type}){
 376             my $generator = '_generate_' . $type;
 377             my $code      = $accessor_class->$generator($attribute, $metaclass);
 378             $metaclass->add_method($attribute->{$type} => $code);
 379             $attribute->associate_method($attribute->{$type});
 380         }
 381     }
 382
 383     # install delegation
 384     if(exists $attribute->{handles}){
 385         my %handles = $attribute->_canonicalize_handles($attribute->{handles});
 386
 387         while(my($handle, $method_to_call) = each %handles){
 388             $metaclass->add_method($handle =>
 389                 $attribute->_make_delegation_method(
 390                     $handle, $method_to_call));
 391
 392             $attribute->associate_method($handle);
 393         }
 394     }
 395
 396     if($attribute->can('create') != \&create){
 397         # backword compatibility
 398         $attribute->create($metaclass, $attribute->name, %{$attribute});
 399     }
 400
 401     return;
 402 }
 403
 404 sub delegation_metaclass() { 'Mouse::Meta::Method::Delegation' }
 405
 406 sub _canonicalize_handles {
 407     my($self, $handles) = @_;
 408
 409     if (ref($handles) eq 'HASH') {
 410         return %$handles;
 411     }
 412     elsif (ref($handles) eq 'ARRAY') {
 413         return map { $_ => $_ } @$handles;
 414     }
 415     elsif (ref($handles) eq 'Regexp') {
 416         my $class_or_role = ($self->{isa} || $self->{does})
 417             || $self->throw_error("Cannot delegate methods based on a Regexp without a type constraint (isa)");
 418
 419         my $meta = Mouse::Meta::Class->initialize("$class_or_role"); # "" for stringify
 420         return map  { $_ => $_ }
 421                grep { !Mouse::Object->can($_) && $_ =~ $handles }
 422                    Mouse::Util::is_a_metarole($meta)
 423                         ? $meta->get_method_list
 424                         : $meta->get_all_method_names;
 425     }
 426     else {
 427         $self->throw_error("Unable to canonicalize the 'handles' option with $handles");
 428     }
 429 }
 430
 431 sub _make_delegation_method {
 432     my($self, $handle, $method_to_call) = @_;
 433     my $delegator = $self->delegation_metaclass;
 434     Mouse::Util::load_class($delegator);
 435
 436     return $delegator->_generate_delegation($self, $handle, $method_to_call);
 437 }
 438
 439 sub throw_error{
 440     my $self = shift;
 441
 442     my $metaclass = (ref $self && $self->associated_class) || 'Mouse::Meta::Class';
 443     $metaclass->throw_error(@_, depth => 1);
 444 }
 445
 446 1;
 447 __END__
 448
 449 =head1 NAME
 450
 451 Mouse::Meta::Attribute - The Mouse attribute metaclass
 452
 453 =head1 VERSION
 454
 455 This document describes Mouse version 0.4501
 456
 457 =head1 METHODS
 458
 459 =head2 C<< new(%options) -> Mouse::Meta::Attribute >>
 460
 461 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 462
 463 It adds the following options to the constructor:
 464
 465 =over 4
 466
 467 =item C<< is => 'ro', 'rw', 'bare' >>
 468
 469 This provides a shorthand for specifying the C<reader>, C<writer>, or
 470 C<accessor> names. If the attribute is read-only ('ro') then it will
 471 have a C<reader> method with the same attribute as the name.
 472
 473 If it is read-write ('rw') then it will have an C<accessor> method
 474 with the same name. If you provide an explicit C<writer> for a
 475 read-write attribute, then you will have a C<reader> with the same
 476 name as the attribute, and a C<writer> with the name you provided.
 477
 478 Use 'bare' when you are deliberately not installing any methods
 479 (accessor, reader, etc.) associated with this attribute; otherwise,
 480 Moose will issue a deprecation warning when this attribute is added to a
 481 metaclass.
 482
 483 =item C<< isa => Type >>
 484
 485 This option accepts a type. The type can be a string, which should be
 486 a type name. If the type name is unknown, it is assumed to be a class
 487 name.
 488
 489 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 490
 491 If you I<also> provide a C<does> option, then your C<isa> option must
 492 be a class name, and that class must do the role specified with
 493 C<does>.
 494
 495 =item C<< does => Role >>
 496
 497 This is short-hand for saying that the attribute's type must be an
 498 object which does the named role.
 499
 500 B<This option is not yet supported.>
 501
 502 =item C<< coerce => Bool >>
 503
 504 This option is only valid for objects with a type constraint
 505 (C<isa>). If this is true, then coercions will be applied whenever
 506 this attribute is set.
 507
 508 You can make both this and the C<weak_ref> option true.
 509
 510 =item C<< trigger => CodeRef >>
 511
 512 This option accepts a subroutine reference, which will be called after
 513 the attribute is set.
 514
 515 =item C<< required => Bool >>
 516
 517 An attribute which is required must be provided to the constructor. An
 518 attribute which is required can also have a C<default> or C<builder>,
 519 which will satisfy its required-ness.
 520
 521 A required attribute must have a C<default>, C<builder> or a
 522 non-C<undef> C<init_arg>
 523
 524 =item C<< lazy => Bool >>
 525
 526 A lazy attribute must have a C<default> or C<builder>. When an
 527 attribute is lazy, the default value will not be calculated until the
 528 attribute is read.
 529
 530 =item C<< weak_ref => Bool >>
 531
 532 If this is true, the attribute's value will be stored as a weak
 533 reference.
 534
 535 =item C<< auto_deref => Bool >>
 536
 537 If this is true, then the reader will dereference the value when it is
 538 called. The attribute must have a type constraint which defines the
 539 attribute as an array or hash reference.
 540
 541 =item C<< lazy_build => Bool >>
 542
 543 Setting this to true makes the attribute lazy and provides a number of
 544 default methods.
 545
 546   has 'size' => (
 547       is         => 'ro',
 548       lazy_build => 1,
 549   );
 550
 551 is equivalent to this:
 552
 553   has 'size' => (
 554       is        => 'ro',
 555       lazy      => 1,
 556       builder   => '_build_size',
 557       clearer   => 'clear_size',
 558       predicate => 'has_size',
 559   );
 560
 561 =back
 562
 563 =head2 C<< associate_method(MethodName) >>
 564
 565 Associates a method with the attribute. Typically, this is called internally
 566 when an attribute generates its accessors.
 567
 568 Currently the argument I<MethodName> is ignored in Mouse.
 569
 570 =head2 C<< verify_against_type_constraint(Item) -> TRUE | ERROR >>
 571
 572 Checks that the given value passes this attribute's type constraint. Returns C<true>
 573 on success, otherwise C<confess>es.
 574
 575 =head2 C<< clone_and_inherit_options(options) -> Mouse::Meta::Attribute >>
 576
 577 Creates a new attribute in the owner class, inheriting options from parent classes.
 578 Accessors and helper methods are installed. Some error checking is done.
 579
 580 =head2 C<< get_read_method_ref >>
 581
 582 =head2 C<< get_write_method_ref >>
 583
 584 Returns the subroutine reference of a method suitable for reading or
 585 writing the attribute's value in the associated class. These methods
 586 always return a subroutine reference, regardless of whether or not the
 587 attribute is read- or write-only.
 588
 589 =head1 SEE ALSO
 590
 591 L<Moose::Meta::Attribute>
 592
 593 L<Class::MOP::Attribute>
 594
 595 =cut
 596