lib/Mouse/Meta/Attribute.pm

   1 #!/usr/bin/env perl
   2 package Mouse::Meta::Attribute;
   3 use strict;
   4 use warnings;
   5
   6 use Carp 'confess';
   7 use Scalar::Util 'blessed';
   8
   9 sub new {
  10     my $class = shift;
  11     my %args  = @_;
  12
  13     my $name = $args{name};
  14
  15     $args{init_arg} = $name
  16         unless exists $args{init_arg};
  17
  18     $args{is} ||= '';
  19
  20     bless \%args, $class;
  21 }
  22
  23 sub name              { $_[0]->{name}             }
  24 sub associated_class  { $_[0]->{associated_class} }
  25 sub _is_metadata      { $_[0]->{is}               }
  26 sub is_required       { $_[0]->{required}         }
  27 sub default           { $_[0]->{default}          }
  28 sub is_lazy           { $_[0]->{lazy}             }
  29 sub is_lazy_build     { $_[0]->{lazy_build}       }
  30 sub predicate         { $_[0]->{predicate}        }
  31 sub clearer           { $_[0]->{clearer}          }
  32 sub handles           { $_[0]->{handles}          }
  33 sub is_weak_ref       { $_[0]->{weak_ref}         }
  34 sub init_arg          { $_[0]->{init_arg}         }
  35 sub type_constraint   { $_[0]->{type_constraint}  }
  36 sub trigger           { $_[0]->{trigger}          }
  37 sub builder           { $_[0]->{builder}          }
  38 sub should_auto_deref { $_[0]->{auto_deref}       }
  39
  40 sub has_default         { exists $_[0]->{default}         }
  41 sub has_predicate       { exists $_[0]->{predicate}       }
  42 sub has_clearer         { exists $_[0]->{clearer}         }
  43 sub has_handles         { exists $_[0]->{handles}         }
  44 sub has_type_constraint { exists $_[0]->{type_constraint} }
  45 sub has_trigger         { exists $_[0]->{trigger}         }
  46 sub has_builder         { exists $_[0]->{builder}         }
  47
  48 sub _create_args {
  49     $_[0]->{_create_args} = $_[1] if @_ > 1;
  50     $_[0]->{_create_args}
  51 }
  52
  53 sub generate_accessor {
  54     my $attribute = shift;
  55
  56     my $name       = $attribute->name;
  57     my $key        = $name;
  58     my $default    = $attribute->default;
  59     my $type       = $attribute->type_constraint;
  60     my $constraint = $attribute->find_type_constraint;
  61     my $builder    = $attribute->builder;
  62
  63     my $trigger = $attribute->trigger;
  64     my $before  = $trigger->{before};
  65     my $after   = $trigger->{after};
  66     my $around  = $trigger->{around};
  67
  68     my $accessor = 'sub {
  69         my $self = shift;';
  70
  71     if ($attribute->_is_metadata eq 'rw') {
  72         $accessor .= 'if (@_) {
  73             local $_ = $_[0];';
  74
  75         if ($before) {
  76             $accessor .= '$before->($self, $_, $attribute);';
  77         }
  78
  79         if ($around) {
  80             $accessor .= '$around->(sub {
  81                 my $self = shift;
  82                 $_ = $_[0];
  83             ';
  84         }
  85
  86             if ($constraint) {
  87                 $accessor .= 'unless ($constraint->()) {
  88                         my $display = defined($_) ? overload::StrVal($_) : "undef";
  89                         Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
  90                 }'
  91             }
  92
  93             $accessor .= '$self->{$key} = $_;';
  94
  95             if ($attribute->is_weak_ref) {
  96                 $accessor .= 'Scalar::Util::weaken($self->{$key}) if ref($self->{$key});';
  97             }
  98
  99         if ($around) {
 100             $accessor .= '}, $self, $_, $attribute);';
 101         }
 102
 103         if ($after) {
 104             $accessor .= '$after->($self, $_, $attribute);';
 105         }
 106
 107         $accessor .= '}';
 108     }
 109     else {
 110         $accessor .= 'confess "Cannot assign a value to a read-only accessor" if @_;';
 111     }
 112
 113     if ($attribute->is_lazy) {
 114         $accessor .= '$self->{$key} = ';
 115
 116         $accessor .= $attribute->has_builder
 117                    ? '$self->$builder'
 118                      : ref($default) eq 'CODE'
 119                      ? '$default->($self)'
 120                      : '$default';
 121
 122         $accessor .= ' if !exists($self->{$key});';
 123     }
 124
 125     if ($attribute->should_auto_deref) {
 126         if ($attribute->type_constraint eq 'ArrayRef') {
 127             $accessor .= 'if (wantarray) {
 128                 return @{ $self->{$key} || [] };
 129             }';
 130         }
 131         else {
 132             $accessor .= 'if (wantarray) {
 133                 return %{ $self->{$key} || {} };
 134             }';
 135         }
 136     }
 137
 138     $accessor .= 'return $self->{$key};
 139     }';
 140
 141     return eval $accessor;
 142 }
 143
 144 sub generate_predicate {
 145     my $attribute = shift;
 146     my $key = $attribute->name;
 147
 148     my $predicate = 'sub { exists($_[0]->{$key}) }';
 149
 150     return eval $predicate;
 151 }
 152
 153 sub generate_clearer {
 154     my $attribute = shift;
 155     my $key = $attribute->name;
 156
 157     my $predicate = 'sub { delete($_[0]->{$key}) }';
 158
 159     return eval $predicate;
 160 }
 161
 162 sub generate_handles {
 163     my $attribute = shift;
 164     my $reader = $attribute->name;
 165     my %handles = $attribute->_canonicalize_handles($attribute->handles);
 166
 167     my %method_map;
 168
 169     for my $local_method (keys %handles) {
 170         my $remote_method = $handles{$local_method};
 171
 172         my $method = 'sub {
 173             my $self = shift;
 174             $self->$reader->$remote_method(@_)
 175         }';
 176
 177         $method_map{$local_method} = eval $method;
 178     }
 179
 180     return \%method_map;
 181 }
 182
 183 sub create {
 184     my ($self, $class, $name, %args) = @_;
 185
 186     $args{name} = $name;
 187     $args{associated_class} = $class;
 188
 189     %args = $self->canonicalize_args($name, %args);
 190     $self->validate_args($name, \%args);
 191
 192     $args{type_constraint} = delete $args{isa}
 193         if exists $args{isa};
 194
 195     my $attribute = $self->new(%args);
 196     $attribute->_create_args(\%args);
 197
 198     my $meta = $class->meta;
 199
 200     $meta->add_attribute($attribute);
 201
 202     # install an accessor
 203     if ($attribute->_is_metadata eq 'rw' || $attribute->_is_metadata eq 'ro') {
 204         my $accessor = $attribute->generate_accessor;
 205         no strict 'refs';
 206         *{ $class . '::' . $name } = $accessor;
 207     }
 208
 209     for my $method (qw/predicate clearer/) {
 210         my $predicate = "has_$method";
 211         if ($attribute->$predicate) {
 212             my $generator = "generate_$method";
 213             my $coderef = $attribute->$generator;
 214             no strict 'refs';
 215             *{ $class . '::' . $attribute->$method } = $coderef;
 216         }
 217     }
 218
 219     if ($attribute->has_handles) {
 220         my $method_map = $attribute->generate_handles;
 221         for my $method_name (keys %$method_map) {
 222             no strict 'refs';
 223             *{ $class . '::' . $method_name } = $method_map->{$method_name};
 224         }
 225     }
 226
 227     return $attribute;
 228 }
 229
 230 sub canonicalize_args {
 231     my $self = shift;
 232     my $name = shift;
 233     my %args = @_;
 234
 235     if ($args{lazy_build}) {
 236         $args{lazy}      = 1;
 237         $args{required}  = 1;
 238         $args{builder}   = "_build_${name}"
 239             if !exists($args{builder});
 240         if ($name =~ /^_/) {
 241             $args{clearer}   = "_clear${name}" if !exists($args{clearer});
 242             $args{predicate} = "_has${name}" if !exists($args{predicate});
 243         }
 244         else {
 245             $args{clearer}   = "clear_${name}" if !exists($args{clearer});
 246             $args{predicate} = "has_${name}" if !exists($args{predicate});
 247         }
 248     }
 249
 250     return %args;
 251 }
 252
 253 sub validate_args {
 254     my $self = shift;
 255     my $name = shift;
 256     my $args = shift;
 257
 258     confess "You can not use lazy_build and default for the same attribute ($name)"
 259         if $args->{lazy_build} && exists $args->{default};
 260
 261     confess "You cannot have lazy attribute ($name) without specifying a default value for it"
 262         if $args->{lazy}
 263         && !exists($args->{default})
 264         && !exists($args->{builder});
 265
 266     confess "References are not allowed as default values, you must wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])"
 267         if ref($args->{default})
 268         && ref($args->{default}) ne 'CODE';
 269
 270     confess "You cannot auto-dereference without specifying a type constraint on attribute ($name)"
 271         if $args->{auto_deref} && !exists($args->{isa});
 272
 273     confess "You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)"
 274         if $args->{auto_deref}
 275         && $args->{isa} ne 'ArrayRef'
 276         && $args->{isa} ne 'HashRef';
 277
 278     if ($args->{trigger}) {
 279         if (ref($args->{trigger}) eq 'CODE') {
 280             $args->{trigger} = {
 281                 after => $args->{trigger},
 282             };
 283         }
 284
 285         confess "Trigger must be a CODE or HASH ref on attribute ($name)"
 286             if ref($args->{trigger}) ne 'HASH';
 287     }
 288
 289     return 1;
 290 }
 291
 292 sub find_type_constraint {
 293     my $self = shift;
 294     my $type = $self->type_constraint;
 295
 296     return unless $type;
 297
 298     my $checker = Mouse::TypeRegistry->optimized_constraints->{$type};
 299     return $checker if $checker;
 300
 301     return sub { blessed($_) && blessed($_) eq $type };
 302 }
 303
 304 sub verify_type_constraint {
 305     my $self = shift;
 306     local $_ = shift;
 307
 308     my $type = $self->type_constraint
 309         or return 1;
 310     my $constraint = $self->find_type_constraint;
 311
 312     return 1 if $constraint->($_);
 313
 314     my $name = $self->name;
 315     my $display = defined($_) ? overload::StrVal($_) : 'undef';
 316     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
 317 }
 318
 319 sub _canonicalize_handles {
 320     my $self    = shift;
 321     my $handles = shift;
 322
 323     if (ref($handles) eq 'HASH') {
 324         return %$handles;
 325     }
 326     elsif (ref($handles) eq 'ARRAY') {
 327         return map { $_ => $_ } @$handles;
 328     }
 329     else {
 330         confess "Unable to canonicalize the 'handles' option with $handles";
 331     }
 332 }
 333
 334 sub clone_parent {
 335     my $self  = shift;
 336     my $class = shift;
 337     my $name  = shift;
 338     my %args  = ($self->get_parent_args($class, $name), @_);
 339
 340     $self->create($class, $name, %args);
 341 }
 342
 343 sub get_parent_args {
 344     my $self  = shift;
 345     my $class = shift;
 346     my $name  = shift;
 347
 348     for my $super ($class->meta->linearized_isa) {
 349         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 350             or next;
 351         return %{ $super_attr->_create_args };
 352     }
 353
 354     confess "Could not find an attribute by the name of '$name' to inherit from";
 355 }
 356
 357 1;
 358
 359 __END__
 360
 361 =head1 NAME
 362
 363 Mouse::Meta::Attribute - attribute metaclass
 364
 365 =head1 METHODS
 366
 367 =head2 new %args -> Mouse::Meta::Attribute
 368
 369 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 370
 371 =head2 create OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 372
 373 Creates a new attribute in OwnerClass. Accessors and helper methods are
 374 installed. Some error checking is done.
 375
 376 =head2 name -> AttributeName
 377
 378 =head2 associated_class -> OwnerClass
 379
 380 =head2 is_required -> Bool
 381
 382 =head2 default -> Item
 383
 384 =head2 has_default -> Bool
 385
 386 =head2 is_lazy -> Bool
 387
 388 =head2 predicate -> MethodName | Undef
 389
 390 =head2 has_predicate -> Bool
 391
 392 =head2 clearer -> MethodName | Undef
 393
 394 =head2 has_clearer -> Bool
 395
 396 =head2 handles -> { LocalName => RemoteName }
 397
 398 =head2 has_handles -> Bool
 399
 400 =head2 is_weak_ref -> Bool
 401
 402 =head2 init_arg -> Str
 403
 404 =head2 type_constraint -> Str
 405
 406 =head2 has_type_constraint -> Bool
 407
 408 =head2 trigger => CODE | Undef
 409
 410 =head2 has_trigger -> Bool
 411
 412 =head2 builder => MethodName | Undef
 413
 414 =head2 has_builder -> Bool
 415
 416 =head2 is_lazy_build => Bool
 417
 418 =head2 should_auto_deref -> Bool
 419
 420 Informational methods.
 421
 422 =head2 generate_accessor -> CODE
 423
 424 Creates a new code reference for the attribute's accessor.
 425
 426 =head2 generate_predicate -> CODE
 427
 428 Creates a new code reference for the attribute's predicate.
 429
 430 =head2 generate_clearer -> CODE
 431
 432 Creates a new code reference for the attribute's clearer.
 433
 434 =head2 generate_handles -> { MethodName => CODE }
 435
 436 Creates a new code reference for each of the attribute's handles methods.
 437
 438 =head2 find_type_constraint -> CODE
 439
 440 Returns a code reference which can be used to check that a given value passes
 441 this attribute's type constraint;
 442
 443 =head2 verify_type_constraint Item -> 1 | ERROR
 444
 445 Checks that the given value passes this attribute's type constraint. Returns 1
 446 on success, otherwise C<confess>es.
 447
 448 =head2 canonicalize_args Name, %args -> %args
 449
 450 Canonicalizes some arguments to create. In particular, C<lazy_build> is
 451 canonicalized into C<lazy>, C<builder>, etc.
 452
 453 =head2 validate_args Name, \%args -> 1 | ERROR
 454
 455 Checks that the arguments to create the attribute (ie those specified by
 456 C<has>) are valid.
 457
 458 =head2 clone_parent OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 459
 460 Creates a new attribute in OwnerClass, inheriting options from parent classes.
 461 Accessors and helper methods are installed. Some error checking is done.
 462
 463 =head2 get_parent_args OwnerClass, AttributeName -> Hash
 464
 465 Returns the options that the parent class of C<OwnerClass> used for attribute
 466 C<AttributeName>.
 467
 468 =cut
 469