lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use strict;
   3 use warnings;
   4 require overload;
   5
   6 use Carp 'confess';
   7 use Scalar::Util ();
   8
   9 sub new {
  10     my ($class, $name, %options) = @_;
  11
  12     $options{name} = $name;
  13
  14     $options{init_arg} = $name
  15         unless exists $options{init_arg};
  16
  17     $options{is} ||= '';
  18
  19     bless \%options, $class;
  20 }
  21
  22 sub name                 { $_[0]->{name}                   }
  23 sub associated_class     { $_[0]->{associated_class}       }
  24 sub _is_metadata         { $_[0]->{is}                     }
  25 sub is_required          { $_[0]->{required}               }
  26 sub default              { $_[0]->{default}                }
  27 sub is_lazy              { $_[0]->{lazy}                   }
  28 sub is_lazy_build        { $_[0]->{lazy_build}             }
  29 sub predicate            { $_[0]->{predicate}              }
  30 sub clearer              { $_[0]->{clearer}                }
  31 sub handles              { $_[0]->{handles}                }
  32 sub is_weak_ref          { $_[0]->{weak_ref}               }
  33 sub init_arg             { $_[0]->{init_arg}               }
  34 sub type_constraint      { $_[0]->{type_constraint}        }
  35 sub trigger              { $_[0]->{trigger}                }
  36 sub builder              { $_[0]->{builder}                }
  37 sub should_auto_deref    { $_[0]->{auto_deref}             }
  38 sub should_coerce        { $_[0]->{should_coerce}          }
  39 sub find_type_constraint { $_[0]->{find_type_constraint}   }
  40
  41 sub has_default          { exists $_[0]->{default}         }
  42 sub has_predicate        { exists $_[0]->{predicate}       }
  43 sub has_clearer          { exists $_[0]->{clearer}         }
  44 sub has_handles          { exists $_[0]->{handles}         }
  45 sub has_type_constraint  { exists $_[0]->{type_constraint} }
  46 sub has_trigger          { exists $_[0]->{trigger}         }
  47 sub has_builder          { exists $_[0]->{builder}         }
  48
  49 sub _create_args {
  50     $_[0]->{_create_args} = $_[1] if @_ > 1;
  51     $_[0]->{_create_args}
  52 }
  53
  54 sub inlined_name {
  55     my $self = shift;
  56     my $name = $self->name;
  57     my $key   = "'" . $name . "'";
  58     return $key;
  59 }
  60
  61 sub generate_accessor {
  62     my $attribute = shift;
  63
  64     my $name          = $attribute->name;
  65     my $default       = $attribute->default;
  66     my $constraint    = $attribute->find_type_constraint;
  67     my $builder       = $attribute->builder;
  68     my $trigger       = $attribute->trigger;
  69     my $is_weak       = $attribute->is_weak_ref;
  70     my $should_deref  = $attribute->should_auto_deref;
  71     my $should_coerce = $attribute->should_coerce;
  72
  73     my $self  = '$_[0]';
  74     my $key   = $attribute->inlined_name;
  75
  76     my $accessor = "sub {\n";
  77     if ($attribute->_is_metadata eq 'rw') {
  78         $accessor .= 'if (@_ >= 2) {' . "\n";
  79
  80         my $value = '$_[1]';
  81
  82         if ($constraint) {
  83             $accessor .= 'my $val = ';
  84             if ($should_coerce) {
  85                 $accessor  .= 'Mouse::Util::TypeConstraints->typecast_constraints("'.$attribute->associated_class->name.'", $attribute->{find_type_constraint}, $attribute->{type_constraint}, '.$value.');';
  86             } else {
  87                 $accessor .= $value.';';
  88             }
  89             $accessor .= 'local $_ = $val;';
  90             $accessor .= '
  91                 unless ($constraint->()) {
  92                     $attribute->verify_type_constraint_error($name, $_, $attribute->type_constraint);
  93                 }' . "\n";
  94             $value = '$val';
  95         }
  96
  97         # if there's nothing left to do for the attribute we can return during
  98         # this setter
  99         $accessor .= 'return ' if !$is_weak && !$trigger && !$should_deref;
 100
 101         $accessor .= $self.'->{'.$key.'} = '.$value.';' . "\n";
 102
 103         if ($is_weak) {
 104             $accessor .= 'Scalar::Util::weaken('.$self.'->{'.$key.'}) if ref('.$self.'->{'.$key.'});' . "\n";
 105         }
 106
 107         if ($trigger) {
 108             $accessor .= '$trigger->('.$self.', '.$value.', $attribute);' . "\n";
 109         }
 110
 111         $accessor .= "}\n";
 112     }
 113     else {
 114         $accessor .= 'confess "Cannot assign a value to a read-only accessor" if scalar(@_) >= 2;' . "\n";
 115     }
 116
 117     # XXX - edit by lestrrat 20090304:
 118     # I couldn't quite tell why this happened, but I encountered a case
 119     # where the default value was not set. In introspecting the resulting
 120     # $accessor string, I realized that there was no default handling code.
 121     # which led me to adding "|| $attribute->has_default" below.
 122     # Tests passed, so I hope everything will be ok
 123     if ($attribute->is_lazy || $attribute->has_default) {
 124         $accessor .= $self.'->{'.$key.'} = ';
 125
 126         $accessor .= $attribute->has_builder
 127                 ? $self.'->$builder'
 128                     : ref($default) eq 'CODE'
 129                     ? '$default->('.$self.')'
 130                     : '$default';
 131         $accessor .= ' if !exists '.$self.'->{'.$key.'};' . "\n";
 132     }
 133
 134     if ($should_deref) {
 135         my $type_constraint = $attribute->type_constraint;
 136         if (!ref($type_constraint) && $type_constraint eq 'ArrayRef') {
 137             $accessor .= 'if (wantarray) {
 138                 return @{ '.$self.'->{'.$key.'} || [] };
 139             }';
 140         }
 141         else {
 142             $accessor .= 'if (wantarray) {
 143                 return %{ '.$self.'->{'.$key.'} || {} };
 144             }';
 145         }
 146     }
 147
 148     $accessor .= 'return '.$self.'->{'.$key.'};
 149     }';
 150
 151     my $sub = eval $accessor;
 152     confess $@ if $@;
 153     return $sub;
 154 }
 155
 156 sub generate_predicate {
 157     my $attribute = shift;
 158     my $key = $attribute->inlined_name;
 159
 160     my $predicate = 'sub { exists($_[0]->{'.$key.'}) }';
 161
 162     my $sub = eval $predicate;
 163     confess $@ if $@;
 164     return $sub;
 165 }
 166
 167 sub generate_clearer {
 168     my $attribute = shift;
 169     my $key = $attribute->inlined_name;
 170
 171     my $clearer = 'sub { delete($_[0]->{'.$key.'}) }';
 172
 173     my $sub = eval $clearer;
 174     confess $@ if $@;
 175     return $sub;
 176 }
 177
 178 sub generate_handles {
 179     my $attribute = shift;
 180     my $reader = $attribute->name;
 181     my %handles = $attribute->_canonicalize_handles($attribute->handles);
 182
 183     my %method_map;
 184
 185     for my $local_method (keys %handles) {
 186         my $remote_method = $handles{$local_method};
 187
 188         my $method = 'sub {
 189             my $self = shift;
 190             $self->'.$reader.'->'.$remote_method.'(@_)
 191         }';
 192
 193         $method_map{$local_method} = eval $method;
 194         confess $@ if $@;
 195     }
 196
 197     return \%method_map;
 198 }
 199
 200 sub create {
 201     my ($self, $class, $name, %args) = @_;
 202
 203     $args{name} = $name;
 204     $args{associated_class} = $class;
 205
 206     %args = $self->canonicalize_args($name, %args);
 207     $self->validate_args($name, \%args);
 208
 209     $args{should_coerce} = delete $args{coerce}
 210         if exists $args{coerce};
 211
 212     if (exists $args{isa}) {
 213         confess "Mouse does not yet support parameterized types (rt.cpan.org #39795)"
 214             if $args{isa} =~ /\[.*\]/;
 215
 216         my $type_constraint = delete $args{isa};
 217         $type_constraint =~ s/\s//g;
 218         my @type_constraints = split /\|/, $type_constraint;
 219
 220         my $code;
 221         my $optimized_constraints = Mouse::Util::TypeConstraints->optimized_constraints;
 222         if (@type_constraints == 1) {
 223             $code = $optimized_constraints->{$type_constraints[0]} ||
 224                 sub { Scalar::Util::blessed($_) && $_->isa($type_constraints[0]) };
 225             $args{type_constraint} = $type_constraints[0];
 226         } else {
 227             my @code_list = map {
 228                 my $type = $_;
 229                 $optimized_constraints->{$type} ||
 230                     sub { Scalar::Util::blessed($_) && $_->isa($type) }
 231             } @type_constraints;
 232             $code = sub {
 233                 for my $code (@code_list) {
 234                     return 1 if $code->();
 235                 }
 236                 return 0;
 237             };
 238             $args{type_constraint} = \@type_constraints;
 239         }
 240         $args{find_type_constraint} = $code;
 241     }
 242
 243     my $attribute = $self->new($name, %args);
 244
 245     $attribute->_create_args(\%args);
 246
 247     $class->add_attribute($attribute);
 248
 249     # install an accessor
 250     if ($attribute->_is_metadata eq 'rw' || $attribute->_is_metadata eq 'ro') {
 251         my $accessor = $attribute->generate_accessor;
 252         $class->add_method($name => $accessor);
 253     }
 254
 255     for my $method (qw/predicate clearer/) {
 256         my $predicate = "has_$method";
 257         if ($attribute->$predicate) {
 258             my $generator = "generate_$method";
 259             my $coderef = $attribute->$generator;
 260             $class->add_method($attribute->$method => $coderef);
 261         }
 262     }
 263
 264     if ($attribute->has_handles) {
 265         my $method_map = $attribute->generate_handles;
 266         for my $method_name (keys %$method_map) {
 267             $class->add_method($method_name => $method_map->{$method_name});
 268         }
 269     }
 270
 271     return $attribute;
 272 }
 273
 274 sub canonicalize_args {
 275     my $self = shift;
 276     my $name = shift;
 277     my %args = @_;
 278
 279     if ($args{lazy_build}) {
 280         $args{lazy}      = 1;
 281         $args{required}  = 1;
 282         $args{builder}   = "_build_${name}"
 283             if !exists($args{builder});
 284         if ($name =~ /^_/) {
 285             $args{clearer}   = "_clear${name}" if !exists($args{clearer});
 286             $args{predicate} = "_has${name}" if !exists($args{predicate});
 287         }
 288         else {
 289             $args{clearer}   = "clear_${name}" if !exists($args{clearer});
 290             $args{predicate} = "has_${name}" if !exists($args{predicate});
 291         }
 292     }
 293
 294     return %args;
 295 }
 296
 297 sub validate_args {
 298     my $self = shift;
 299     my $name = shift;
 300     my $args = shift;
 301
 302     confess "You can not use lazy_build and default for the same attribute ($name)"
 303         if $args->{lazy_build} && exists $args->{default};
 304
 305     confess "You cannot have lazy attribute ($name) without specifying a default value for it"
 306         if $args->{lazy}
 307         && !exists($args->{default})
 308         && !exists($args->{builder});
 309
 310     confess "References are not allowed as default values, you must wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])"
 311         if ref($args->{default})
 312         && ref($args->{default}) ne 'CODE';
 313
 314     confess "You cannot auto-dereference without specifying a type constraint on attribute ($name)"
 315         if $args->{auto_deref} && !exists($args->{isa});
 316
 317     confess "You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)"
 318         if $args->{auto_deref}
 319         && $args->{isa} ne 'ArrayRef'
 320         && $args->{isa} ne 'HashRef';
 321
 322     if ($args->{trigger}) {
 323         if (ref($args->{trigger}) eq 'HASH') {
 324             Carp::carp "HASH-based form of trigger has been removed. Only the coderef form of triggers are now supported.";
 325         }
 326
 327         confess "Trigger must be a CODE ref on attribute ($name)"
 328             if ref($args->{trigger}) ne 'CODE';
 329     }
 330
 331     return 1;
 332 }
 333
 334 sub verify_against_type_constraint {
 335     return 1 unless $_[0]->{type_constraint};
 336
 337     local $_ = $_[1];
 338     return 1 if $_[0]->{find_type_constraint}->($_);
 339
 340     my $self = shift;
 341     $self->verify_type_constraint_error($self->name, $_, $self->type_constraint);
 342 }
 343
 344 sub verify_type_constraint_error {
 345     my($self, $name, $value, $type) = @_;
 346     $type = ref($type) eq 'ARRAY' ? join '|', @{ $type } : $type;
 347     my $display = defined($_) ? overload::StrVal($_) : 'undef';
 348     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
 349 }
 350
 351 sub coerce_constraint { ## my($self, $value) = @_;
 352     my $type = $_[0]->{type_constraint}
 353         or return $_[1];
 354     return Mouse::Util::TypeConstraints->typecast_constraints($_[0]->associated_class->name, $_[0]->find_type_constraint, $type, $_[1]);
 355 }
 356
 357 sub _canonicalize_handles {
 358     my $self    = shift;
 359     my $handles = shift;
 360
 361     if (ref($handles) eq 'HASH') {
 362         return %$handles;
 363     }
 364     elsif (ref($handles) eq 'ARRAY') {
 365         return map { $_ => $_ } @$handles;
 366     }
 367     else {
 368         confess "Unable to canonicalize the 'handles' option with $handles";
 369     }
 370 }
 371
 372 sub clone_parent {
 373     my $self  = shift;
 374     my $class = shift;
 375     my $name  = shift;
 376     my %args  = ($self->get_parent_args($class, $name), @_);
 377
 378     $self->create($class, $name, %args);
 379 }
 380
 381 sub get_parent_args {
 382     my $self  = shift;
 383     my $class = shift;
 384     my $name  = shift;
 385
 386     for my $super ($class->linearized_isa) {
 387         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 388             or next;
 389         return %{ $super_attr->_create_args };
 390     }
 391
 392     confess "Could not find an attribute by the name of '$name' to inherit from";
 393 }
 394
 395 1;
 396
 397 __END__
 398
 399 =head1 NAME
 400
 401 Mouse::Meta::Attribute - attribute metaclass
 402
 403 =head1 METHODS
 404
 405 =head2 new %args -> Mouse::Meta::Attribute
 406
 407 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 408
 409 =head2 create OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 410
 411 Creates a new attribute in OwnerClass. Accessors and helper methods are
 412 installed. Some error checking is done.
 413
 414 =head2 name -> AttributeName
 415
 416 =head2 associated_class -> OwnerClass
 417
 418 =head2 is_required -> Bool
 419
 420 =head2 default -> Item
 421
 422 =head2 has_default -> Bool
 423
 424 =head2 is_lazy -> Bool
 425
 426 =head2 predicate -> MethodName | Undef
 427
 428 =head2 has_predicate -> Bool
 429
 430 =head2 clearer -> MethodName | Undef
 431
 432 =head2 has_clearer -> Bool
 433
 434 =head2 handles -> { LocalName => RemoteName }
 435
 436 =head2 has_handles -> Bool
 437
 438 =head2 is_weak_ref -> Bool
 439
 440 =head2 init_arg -> Str
 441
 442 =head2 type_constraint -> Str
 443
 444 =head2 has_type_constraint -> Bool
 445
 446 =head2 trigger => CODE | Undef
 447
 448 =head2 has_trigger -> Bool
 449
 450 =head2 builder => MethodName | Undef
 451
 452 =head2 has_builder -> Bool
 453
 454 =head2 is_lazy_build => Bool
 455
 456 =head2 should_auto_deref -> Bool
 457
 458 Informational methods.
 459
 460 =head2 generate_accessor -> CODE
 461
 462 Creates a new code reference for the attribute's accessor.
 463
 464 =head2 generate_predicate -> CODE
 465
 466 Creates a new code reference for the attribute's predicate.
 467
 468 =head2 generate_clearer -> CODE
 469
 470 Creates a new code reference for the attribute's clearer.
 471
 472 =head2 generate_handles -> { MethodName => CODE }
 473
 474 Creates a new code reference for each of the attribute's handles methods.
 475
 476 =head2 find_type_constraint -> CODE
 477
 478 Returns a code reference which can be used to check that a given value passes
 479 this attribute's type constraint;
 480
 481 =head2 verify_against_type_constraint Item -> 1 | ERROR
 482
 483 Checks that the given value passes this attribute's type constraint. Returns 1
 484 on success, otherwise C<confess>es.
 485
 486 =head2 canonicalize_args Name, %args -> %args
 487
 488 Canonicalizes some arguments to create. In particular, C<lazy_build> is
 489 canonicalized into C<lazy>, C<builder>, etc.
 490
 491 =head2 validate_args Name, \%args -> 1 | ERROR
 492
 493 Checks that the arguments to create the attribute (ie those specified by
 494 C<has>) are valid.
 495
 496 =head2 clone_parent OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 497
 498 Creates a new attribute in OwnerClass, inheriting options from parent classes.
 499 Accessors and helper methods are installed. Some error checking is done.
 500
 501 =head2 get_parent_args OwnerClass, AttributeName -> Hash
 502
 503 Returns the options that the parent class of C<OwnerClass> used for attribute
 504 C<AttributeName>.
 505
 506 =cut
 507