lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use strict;
   3 use warnings;
   4 require overload;
   5
   6 use Carp 'confess';
   7 use Scalar::Util ();
   8
   9 sub new {
  10     my $class = shift;
  11     my %args  = @_;
  12
  13     my $name = $args{name};
  14
  15     $args{init_arg} = $name
  16         unless exists $args{init_arg};
  17
  18     $args{is} ||= '';
  19
  20     bless \%args, $class;
  21 }
  22
  23 sub name              { $_[0]->{name}             }
  24 sub associated_class  { $_[0]->{associated_class} }
  25 sub _is_metadata      { $_[0]->{is}               }
  26 sub is_required       { $_[0]->{required}         }
  27 sub default           { $_[0]->{default}          }
  28 sub is_lazy           { $_[0]->{lazy}             }
  29 sub is_lazy_build     { $_[0]->{lazy_build}       }
  30 sub predicate         { $_[0]->{predicate}        }
  31 sub clearer           { $_[0]->{clearer}          }
  32 sub handles           { $_[0]->{handles}          }
  33 sub is_weak_ref       { $_[0]->{weak_ref}         }
  34 sub init_arg          { $_[0]->{init_arg}         }
  35 sub type_constraint   { $_[0]->{type_constraint}  }
  36 sub trigger           { $_[0]->{trigger}          }
  37 sub builder           { $_[0]->{builder}          }
  38 sub should_auto_deref { $_[0]->{auto_deref}       }
  39 sub should_coerce     { $_[0]->{should_coerce}    }
  40
  41 sub has_default         { exists $_[0]->{default}         }
  42 sub has_predicate       { exists $_[0]->{predicate}       }
  43 sub has_clearer         { exists $_[0]->{clearer}         }
  44 sub has_handles         { exists $_[0]->{handles}         }
  45 sub has_type_constraint { exists $_[0]->{type_constraint} }
  46 sub has_trigger         { exists $_[0]->{trigger}         }
  47 sub has_builder         { exists $_[0]->{builder}         }
  48
  49 sub find_type_constraint      { $_[0]->{find_type_constraint}  }
  50
  51 sub _create_args {
  52     $_[0]->{_create_args} = $_[1] if @_ > 1;
  53     $_[0]->{_create_args}
  54 }
  55
  56 sub inlined_name {
  57     my $self = shift;
  58     my $name = $self->name;
  59     my $key   = "'" . $name . "'";
  60     return $key;
  61 }
  62
  63 sub generate_accessor {
  64     my $attribute = shift;
  65
  66     my $name          = $attribute->name;
  67     my $default       = $attribute->default;
  68     my $constraint    = $attribute->find_type_constraint;
  69     my $builder       = $attribute->builder;
  70     my $trigger       = $attribute->trigger;
  71     my $is_weak       = $attribute->is_weak_ref;
  72     my $should_deref  = $attribute->should_auto_deref;
  73     my $should_coerce = $attribute->should_coerce;
  74
  75     my $self  = '$_[0]';
  76     my $key   = $attribute->inlined_name;
  77
  78     my $accessor = "sub {\n";
  79     if ($attribute->_is_metadata eq 'rw') {
  80         $accessor .= 'if (scalar(@_) >= 2) {' . "\n";
  81
  82         my $value = '$_[1]';
  83
  84         if ($constraint) {
  85             $accessor .= 'my $val = ';
  86             if ($should_coerce) {
  87                 $accessor  .= 'Mouse::TypeRegistry->typecast_constraints("'.$attribute->associated_class->name.'", $attribute->{find_type_constraint}, $attribute->{type_constraint}, '.$value.');';
  88             } else {
  89                 $accessor .= $value.';';
  90             }
  91             $accessor .= 'local $_ = $val;';
  92             $accessor .= '
  93                 unless ($constraint->()) {
  94                     $attribute->verify_type_constraint_error($name, $_, $attribute->type_constraint);
  95                 }' . "\n";
  96             $value = '$val';
  97         }
  98
  99         # if there's nothing left to do for the attribute we can return during
 100         # this setter
 101         $accessor .= 'return ' if !$is_weak && !$trigger && !$should_deref;
 102
 103         $accessor .= $self.'->{'.$key.'} = '.$value.';' . "\n";
 104
 105         if ($is_weak) {
 106             $accessor .= 'Scalar::Util::weaken('.$self.'->{'.$key.'}) if ref('.$self.'->{'.$key.'});' . "\n";
 107         }
 108
 109         if ($trigger) {
 110             $accessor .= '$trigger->('.$self.', '.$value.', $attribute);' . "\n";
 111         }
 112
 113         $accessor .= "}\n";
 114     }
 115     else {
 116         $accessor .= 'confess "Cannot assign a value to a read-only accessor" if scalar(@_) >= 2;' . "\n";
 117     }
 118
 119     if ($attribute->is_lazy) {
 120         $accessor .= $self.'->{'.$key.'} = ';
 121
 122         $accessor .= $attribute->has_builder
 123                 ? $self.'->$builder'
 124                     : ref($default) eq 'CODE'
 125                     ? '$default->('.$self.')'
 126                     : '$default';
 127         $accessor .= ' if !exists '.$self.'->{'.$key.'};' . "\n";
 128     }
 129
 130     if ($should_deref) {
 131         my $type_constraint = $attribute->type_constraint;
 132         if (!ref($type_constraint) && $type_constraint eq 'ArrayRef') {
 133             $accessor .= 'if (wantarray) {
 134                 return @{ '.$self.'->{'.$key.'} || [] };
 135             }';
 136         }
 137         else {
 138             $accessor .= 'if (wantarray) {
 139                 return %{ '.$self.'->{'.$key.'} || {} };
 140             }';
 141         }
 142     }
 143
 144     $accessor .= 'return '.$self.'->{'.$key.'};
 145     }';
 146
 147     my $sub = eval $accessor;
 148     confess $@ if $@;
 149     return $sub;
 150 }
 151
 152 sub generate_predicate {
 153     my $attribute = shift;
 154     my $key = $attribute->inlined_name;
 155
 156     my $predicate = 'sub { exists($_[0]->{'.$key.'}) }';
 157
 158     my $sub = eval $predicate;
 159     confess $@ if $@;
 160     return $sub;
 161 }
 162
 163 sub generate_clearer {
 164     my $attribute = shift;
 165     my $key = $attribute->inlined_name;
 166
 167     my $clearer = 'sub { delete($_[0]->{'.$key.'}) }';
 168
 169     my $sub = eval $clearer;
 170     confess $@ if $@;
 171     return $sub;
 172 }
 173
 174 sub generate_handles {
 175     my $attribute = shift;
 176     my $reader = $attribute->name;
 177     my %handles = $attribute->_canonicalize_handles($attribute->handles);
 178
 179     my %method_map;
 180
 181     for my $local_method (keys %handles) {
 182         my $remote_method = $handles{$local_method};
 183
 184         my $method = 'sub {
 185             my $self = shift;
 186             $self->'.$reader.'->'.$remote_method.'(@_)
 187         }';
 188
 189         $method_map{$local_method} = eval $method;
 190         confess $@ if $@;
 191     }
 192
 193     return \%method_map;
 194 }
 195
 196 sub create {
 197     my ($self, $class, $name, %args) = @_;
 198
 199     $args{name} = $name;
 200     $args{associated_class} = $class;
 201
 202     %args = $self->canonicalize_args($name, %args);
 203     $self->validate_args($name, \%args);
 204
 205     $args{should_coerce} = delete $args{coerce}
 206         if exists $args{coerce};
 207
 208     if (exists $args{isa}) {
 209         my $type_constraint = delete $args{isa};
 210         $type_constraint =~ s/\s//g;
 211         my @type_constraints = split /\|/, $type_constraint;
 212
 213         my $code;
 214         my $optimized_constraints = Mouse::TypeRegistry->optimized_constraints;
 215         if (@type_constraints == 1) {
 216             $code = $optimized_constraints->{$type_constraints[0]} ||
 217                 sub { Scalar::Util::blessed($_) && Scalar::Util::blessed($_) eq $type_constraints[0] };
 218             $args{type_constraint} = $type_constraints[0];
 219         } else {
 220             my @code_list = map {
 221                 my $type = $_;
 222                 $optimized_constraints->{$type} ||
 223                     sub { Scalar::Util::blessed($_) && Scalar::Util::blessed($_) eq $type }
 224             } @type_constraints;
 225             $code = sub {
 226                 for my $code (@code_list) {
 227                     return 1 if $code->();
 228                 }
 229                 return 0;
 230             };
 231             $args{type_constraint} = \@type_constraints;
 232         }
 233         $args{find_type_constraint} = $code;
 234     }
 235
 236     my $attribute = $self->new(%args);
 237
 238     $attribute->_create_args(\%args);
 239
 240     $class->add_attribute($attribute);
 241
 242     # install an accessor
 243     if ($attribute->_is_metadata eq 'rw' || $attribute->_is_metadata eq 'ro') {
 244         my $accessor = $attribute->generate_accessor;
 245         $class->add_method($name => $accessor);
 246     }
 247
 248     for my $method (qw/predicate clearer/) {
 249         my $predicate = "has_$method";
 250         if ($attribute->$predicate) {
 251             my $generator = "generate_$method";
 252             my $coderef = $attribute->$generator;
 253             $class->add_method($attribute->$method => $coderef);
 254         }
 255     }
 256
 257     if ($attribute->has_handles) {
 258         my $method_map = $attribute->generate_handles;
 259         for my $method_name (keys %$method_map) {
 260             $class->add_method($method_name => $method_map->{$method_name});
 261         }
 262     }
 263
 264     return $attribute;
 265 }
 266
 267 sub canonicalize_args {
 268     my $self = shift;
 269     my $name = shift;
 270     my %args = @_;
 271
 272     if ($args{lazy_build}) {
 273         $args{lazy}      = 1;
 274         $args{required}  = 1;
 275         $args{builder}   = "_build_${name}"
 276             if !exists($args{builder});
 277         if ($name =~ /^_/) {
 278             $args{clearer}   = "_clear${name}" if !exists($args{clearer});
 279             $args{predicate} = "_has${name}" if !exists($args{predicate});
 280         }
 281         else {
 282             $args{clearer}   = "clear_${name}" if !exists($args{clearer});
 283             $args{predicate} = "has_${name}" if !exists($args{predicate});
 284         }
 285     }
 286
 287     return %args;
 288 }
 289
 290 sub validate_args {
 291     my $self = shift;
 292     my $name = shift;
 293     my $args = shift;
 294
 295     confess "You can not use lazy_build and default for the same attribute ($name)"
 296         if $args->{lazy_build} && exists $args->{default};
 297
 298     confess "You cannot have lazy attribute ($name) without specifying a default value for it"
 299         if $args->{lazy}
 300         && !exists($args->{default})
 301         && !exists($args->{builder});
 302
 303     confess "References are not allowed as default values, you must wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])"
 304         if ref($args->{default})
 305         && ref($args->{default}) ne 'CODE';
 306
 307     confess "You cannot auto-dereference without specifying a type constraint on attribute ($name)"
 308         if $args->{auto_deref} && !exists($args->{isa});
 309
 310     confess "You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)"
 311         if $args->{auto_deref}
 312         && $args->{isa} ne 'ArrayRef'
 313         && $args->{isa} ne 'HashRef';
 314
 315     if ($args->{trigger}) {
 316         if (ref($args->{trigger}) eq 'HASH') {
 317             Carp::carp "HASH-based form of trigger has been removed. Only the coderef form of triggers are now supported.";
 318         }
 319
 320         confess "Trigger must be a CODE ref on attribute ($name)"
 321             if ref($args->{trigger}) ne 'CODE';
 322     }
 323
 324     return 1;
 325 }
 326
 327 sub verify_type_constraint {
 328     return 1 unless $_[0]->{type_constraint};
 329
 330     local $_ = $_[1];
 331     return 1 if $_[0]->{find_type_constraint}->($_);
 332
 333     my $self = shift;
 334     $self->verify_type_constraint_error($self->name, $_, $self->type_constraint);
 335 }
 336
 337 sub verify_type_constraint_error {
 338     my($self, $name, $value, $type) = @_;
 339     $type = ref($type) eq 'ARRAY' ? join '|', @{ $type } : $type;
 340     my $display = defined($_) ? overload::StrVal($_) : 'undef';
 341     Carp::confess("Attribute ($name) does not pass the type constraint because: Validation failed for \'$type\' failed with value $display");
 342 }
 343
 344 sub coerce_constraint { ## my($self, $value) = @_;
 345     my $type = $_[0]->{type_constraint}
 346         or return $_[1];
 347     return Mouse::TypeRegistry->typecast_constraints($_[0]->associated_class->name, $_[0]->find_type_constraint, $type, $_[1]);
 348 }
 349
 350 sub _canonicalize_handles {
 351     my $self    = shift;
 352     my $handles = shift;
 353
 354     if (ref($handles) eq 'HASH') {
 355         return %$handles;
 356     }
 357     elsif (ref($handles) eq 'ARRAY') {
 358         return map { $_ => $_ } @$handles;
 359     }
 360     else {
 361         confess "Unable to canonicalize the 'handles' option with $handles";
 362     }
 363 }
 364
 365 sub clone_parent {
 366     my $self  = shift;
 367     my $class = shift;
 368     my $name  = shift;
 369     my %args  = ($self->get_parent_args($class, $name), @_);
 370
 371     $self->create($class, $name, %args);
 372 }
 373
 374 sub get_parent_args {
 375     my $self  = shift;
 376     my $class = shift;
 377     my $name  = shift;
 378
 379     for my $super ($class->linearized_isa) {
 380         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 381             or next;
 382         return %{ $super_attr->_create_args };
 383     }
 384
 385     confess "Could not find an attribute by the name of '$name' to inherit from";
 386 }
 387
 388 1;
 389
 390 __END__
 391
 392 =head1 NAME
 393
 394 Mouse::Meta::Attribute - attribute metaclass
 395
 396 =head1 METHODS
 397
 398 =head2 new %args -> Mouse::Meta::Attribute
 399
 400 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 401
 402 =head2 create OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 403
 404 Creates a new attribute in OwnerClass. Accessors and helper methods are
 405 installed. Some error checking is done.
 406
 407 =head2 name -> AttributeName
 408
 409 =head2 associated_class -> OwnerClass
 410
 411 =head2 is_required -> Bool
 412
 413 =head2 default -> Item
 414
 415 =head2 has_default -> Bool
 416
 417 =head2 is_lazy -> Bool
 418
 419 =head2 predicate -> MethodName | Undef
 420
 421 =head2 has_predicate -> Bool
 422
 423 =head2 clearer -> MethodName | Undef
 424
 425 =head2 has_clearer -> Bool
 426
 427 =head2 handles -> { LocalName => RemoteName }
 428
 429 =head2 has_handles -> Bool
 430
 431 =head2 is_weak_ref -> Bool
 432
 433 =head2 init_arg -> Str
 434
 435 =head2 type_constraint -> Str
 436
 437 =head2 has_type_constraint -> Bool
 438
 439 =head2 trigger => CODE | Undef
 440
 441 =head2 has_trigger -> Bool
 442
 443 =head2 builder => MethodName | Undef
 444
 445 =head2 has_builder -> Bool
 446
 447 =head2 is_lazy_build => Bool
 448
 449 =head2 should_auto_deref -> Bool
 450
 451 Informational methods.
 452
 453 =head2 generate_accessor -> CODE
 454
 455 Creates a new code reference for the attribute's accessor.
 456
 457 =head2 generate_predicate -> CODE
 458
 459 Creates a new code reference for the attribute's predicate.
 460
 461 =head2 generate_clearer -> CODE
 462
 463 Creates a new code reference for the attribute's clearer.
 464
 465 =head2 generate_handles -> { MethodName => CODE }
 466
 467 Creates a new code reference for each of the attribute's handles methods.
 468
 469 =head2 find_type_constraint -> CODE
 470
 471 Returns a code reference which can be used to check that a given value passes
 472 this attribute's type constraint;
 473
 474 =head2 verify_type_constraint Item -> 1 | ERROR
 475
 476 Checks that the given value passes this attribute's type constraint. Returns 1
 477 on success, otherwise C<confess>es.
 478
 479 =head2 canonicalize_args Name, %args -> %args
 480
 481 Canonicalizes some arguments to create. In particular, C<lazy_build> is
 482 canonicalized into C<lazy>, C<builder>, etc.
 483
 484 =head2 validate_args Name, \%args -> 1 | ERROR
 485
 486 Checks that the arguments to create the attribute (ie those specified by
 487 C<has>) are valid.
 488
 489 =head2 clone_parent OwnerClass, AttributeName, %args -> Mouse::Meta::Attribute
 490
 491 Creates a new attribute in OwnerClass, inheriting options from parent classes.
 492 Accessors and helper methods are installed. Some error checking is done.
 493
 494 =head2 get_parent_args OwnerClass, AttributeName -> Hash
 495
 496 Returns the options that the parent class of C<OwnerClass> used for attribute
 497 C<AttributeName>.
 498
 499 =cut
 500