lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use Mouse::Util qw(:meta); # enables strict and warnings
   3
   4 use Carp ();
   5
   6 use Mouse::Meta::TypeConstraint;
   7 use Mouse::Meta::Method::Accessor;
   8
   9
  10 sub _process_options{
  11     my($class, $name, $args) = @_;
  12
  13
  14     # XXX: for backward compatibility (with method modifiers)
  15     if($class->can('canonicalize_args') != \&canonicalize_args){
  16         %{$args} = $class->canonicalize_args($name, %{$args});
  17     }
  18
  19     # taken from Class::MOP::Attribute::new
  20
  21     defined($name)
  22         or $class->throw_error('You must provide a name for the attribute');
  23
  24     if(!exists $args->{init_arg}){
  25         $args->{init_arg} = $name;
  26     }
  27
  28     # 'required' requires eigher 'init_arg', 'builder', or 'default'
  29     my $can_be_required = defined( $args->{init_arg} );
  30
  31     if(exists $args->{builder}){
  32         # XXX:
  33         # Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
  34         # This feature will be changed in a future. (gfx)
  35         $class->throw_error('builder must be a defined scalar value which is a method name')
  36             #if ref $args->{builder} || !defined $args->{builder};
  37             if !defined $args->{builder};
  38
  39         $can_be_required++;
  40     }
  41     elsif(exists $args->{default}){
  42         if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
  43             $class->throw_error("References are not allowed as default values, you must "
  44                               . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
  45         }
  46         $can_be_required++;
  47     }
  48
  49     if( $args->{required} && !$can_be_required ) {
  50         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
  51     }
  52
  53     # taken from Mouse::Meta::Attribute->new and _process_args->
  54
  55     if(exists $args->{is}){
  56         my $is = $args->{is};
  57
  58         if($is eq 'ro'){
  59             $args->{reader} ||= $name;
  60         }
  61         elsif($is eq 'rw'){
  62             if(exists $args->{writer}){
  63                 $args->{reader} ||= $name;
  64              }
  65              else{
  66                 $args->{accessor} ||= $name;
  67              }
  68         }
  69         elsif($is eq 'bare'){
  70             # do nothing, but don't complain (later) about missing methods
  71         }
  72         else{
  73             $is = 'undef' if !defined $is;
  74             $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
  75         }
  76     }
  77
  78     my $tc;
  79     if(exists $args->{isa}){
  80         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
  81     }
  82     elsif(exists $args->{does}){
  83         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
  84     }
  85     $tc = $args->{type_constraint};
  86
  87     if($args->{coerce}){
  88         defined($tc)
  89             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
  90
  91         $args->{weak_ref}
  92             && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
  93     }
  94
  95     if ($args->{lazy_build}) {
  96         exists($args->{default})
  97             && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
  98
  99         $args->{lazy}      = 1;
 100         $args->{builder} ||= "_build_${name}";
 101         if ($name =~ /^_/) {
 102             $args->{clearer}   ||= "_clear${name}";
 103             $args->{predicate} ||= "_has${name}";
 104         }
 105         else {
 106             $args->{clearer}   ||= "clear_${name}";
 107             $args->{predicate} ||= "has_${name}";
 108         }
 109     }
 110
 111     if ($args->{auto_deref}) {
 112         defined($tc)
 113             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
 114
 115         ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
 116             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
 117     }
 118
 119     if (exists $args->{trigger}) {
 120         ('CODE' eq ref $args->{trigger})
 121             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
 122     }
 123
 124     if ($args->{lazy}) {
 125         (exists $args->{default} || defined $args->{builder})
 126             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
 127     }
 128
 129     return;
 130 }
 131
 132 sub new {
 133     my $class = shift;
 134     my $name  = shift;
 135
 136     my %args  = (@_ == 1) ? %{ $_[0] } : @_;
 137
 138     $class->_process_options($name, \%args);
 139
 140     $args{name} = $name;
 141
 142     my $self = bless \%args, $class;
 143
 144     # extra attributes
 145     if($class ne __PACKAGE__){
 146         $class->meta->_initialize_object($self, \%args);
 147     }
 148
 149 # XXX: there is no fast way to check attribute validity
 150 #    my @bad = ...;
 151 #    if(@bad){
 152 #        @bad = sort @bad;
 153 #        Carp::cluck("Found unknown argument(s) passed to '$name' attribute constructor in '$class': @bad");
 154 #    }
 155
 156     return $self;
 157 }
 158
 159 # readers
 160
 161 sub name                 { $_[0]->{name}                   }
 162 sub associated_class     { $_[0]->{associated_class}       }
 163
 164 sub accessor             { $_[0]->{accessor}               }
 165 sub reader               { $_[0]->{reader}                 }
 166 sub writer               { $_[0]->{writer}                 }
 167 sub predicate            { $_[0]->{predicate}              }
 168 sub clearer              { $_[0]->{clearer}                }
 169 sub handles              { $_[0]->{handles}                }
 170
 171 sub _is_metadata         { $_[0]->{is}                     }
 172 sub is_required          { $_[0]->{required}               }
 173 sub default              { $_[0]->{default}                }
 174 sub is_lazy              { $_[0]->{lazy}                   }
 175 sub is_lazy_build        { $_[0]->{lazy_build}             }
 176 sub is_weak_ref          { $_[0]->{weak_ref}               }
 177 sub init_arg             { $_[0]->{init_arg}               }
 178 sub type_constraint      { $_[0]->{type_constraint}        }
 179
 180 sub trigger              { $_[0]->{trigger}                }
 181 sub builder              { $_[0]->{builder}                }
 182 sub should_auto_deref    { $_[0]->{auto_deref}             }
 183 sub should_coerce        { $_[0]->{coerce}                 }
 184
 185 # predicates
 186
 187 sub has_accessor         { exists $_[0]->{accessor}        }
 188 sub has_reader           { exists $_[0]->{reader}          }
 189 sub has_writer           { exists $_[0]->{writer}          }
 190 sub has_predicate        { exists $_[0]->{predicate}       }
 191 sub has_clearer          { exists $_[0]->{clearer}         }
 192 sub has_handles          { exists $_[0]->{handles}         }
 193
 194 sub has_default          { exists $_[0]->{default}         }
 195 sub has_type_constraint  { exists $_[0]->{type_constraint} }
 196 sub has_trigger          { exists $_[0]->{trigger}         }
 197 sub has_builder          { exists $_[0]->{builder}         }
 198
 199 sub has_read_method      { exists $_[0]->{reader} || exists $_[0]->{accessor} }
 200 sub has_write_method     { exists $_[0]->{writer} || exists $_[0]->{accessor} }
 201
 202 sub _create_args { # DEPRECATED
 203     $_[0]->{_create_args} = $_[1] if @_ > 1;
 204     $_[0]->{_create_args}
 205 }
 206
 207 sub interpolate_class{
 208     my($class, $args) = @_;
 209
 210     if(my $metaclass = delete $args->{metaclass}){
 211         $class = Mouse::Util::resolve_metaclass_alias( Attribute => $metaclass );
 212     }
 213
 214     my @traits;
 215     if(my $traits_ref = delete $args->{traits}){
 216
 217         for (my $i = 0; $i < @{$traits_ref}; $i++) {
 218             my $trait = Mouse::Util::resolve_metaclass_alias(Attribute => $traits_ref->[$i], trait => 1);
 219
 220             next if $class->does($trait);
 221
 222             push @traits, $trait;
 223
 224             # are there options?
 225             push @traits, $traits_ref->[++$i]
 226                 if ref($traits_ref->[$i+1]);
 227         }
 228
 229         if (@traits) {
 230             $class = Mouse::Meta::Class->create_anon_class(
 231                 superclasses => [ $class ],
 232                 roles        => \@traits,
 233                 cache        => 1,
 234             )->name;
 235         }
 236     }
 237
 238     return( $class, @traits );
 239 }
 240
 241 sub canonicalize_args{ # DEPRECATED
 242     my ($self, $name, %args) = @_;
 243
 244     Carp::cluck("$self->canonicalize_args has been deprecated."
 245         . "Use \$self->_process_options instead.")
 246             if _MOUSE_VERBOSE;
 247
 248     return %args;
 249 }
 250
 251 sub create { # DEPRECATED
 252     my ($self, $class, $name, %args) = @_;
 253
 254     Carp::cluck("$self->create has been deprecated."
 255         . "Use \$meta->add_attribute and \$attr->install_accessors instead.")
 256             if _MOUSE_VERBOSE;
 257
 258     # noop
 259     return $self;
 260 }
 261
 262 sub _coerce_and_verify {
 263     my($self, $value, $instance) = @_;
 264
 265     my $type_constraint = $self->{type_constraint};
 266     return $value if !defined $type_constraint;
 267
 268     if ($self->should_coerce && $type_constraint->has_coercion) {
 269         $value = $type_constraint->coerce($value);
 270     }
 271
 272     $self->verify_against_type_constraint($value);
 273
 274     return $value;
 275 }
 276
 277 sub verify_against_type_constraint {
 278     my ($self, $value) = @_;
 279
 280     my $type_constraint = $self->{type_constraint};
 281     return 1 if !$type_constraint;
 282     return 1 if $type_constraint->check($value);
 283
 284     $self->verify_type_constraint_error($self->name, $value, $type_constraint);
 285 }
 286
 287 sub verify_type_constraint_error {
 288     my($self, $name, $value, $type) = @_;
 289     $self->throw_error("Attribute ($name) does not pass the type constraint because: "
 290         . $type->get_message($value));
 291 }
 292
 293 sub coerce_constraint { # DEPRECATED
 294     my $type = $_[0]->{type_constraint}
 295         or return $_[1];
 296
 297     Carp::cluck("coerce_constraint() has been deprecated, which was an internal utility anyway");
 298
 299     return Mouse::Util::TypeConstraints->typecast_constraints($_[0]->associated_class->name, $type, $_[1]);
 300 }
 301
 302 sub clone_and_inherit_options{
 303     my($self, %args) = @_;
 304
 305     my($attribute_class, @traits) = ref($self)->interpolate_class(\%args);
 306
 307     $args{traits} = \@traits if @traits;
 308     return $attribute_class->new($self->name, %{$self}, %args);
 309 }
 310
 311 sub clone_parent { # DEPRECATED
 312     my $self  = shift;
 313     my $class = shift;
 314     my $name  = shift;
 315     my %args  = ($self->get_parent_args($class, $name), @_);
 316
 317     Carp::cluck("$self->clone_parent has been deprecated."
 318         . "Use \$meta->add_attribute and \$attr->install_accessors instead.")
 319         if _MOUSE_VERBOSE;
 320
 321     $self->clone_and_inherited_args($class, $name, %args);
 322 }
 323
 324 sub get_parent_args { # DEPRECATED
 325     my $self  = shift;
 326     my $class = shift;
 327     my $name  = shift;
 328
 329     for my $super ($class->linearized_isa) {
 330         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 331             or next;
 332         return %{ $super_attr->_create_args };
 333     }
 334
 335     $self->throw_error("Could not find an attribute by the name of '$name' to inherit from");
 336 }
 337
 338
 339 sub get_read_method {
 340     $_[0]->{reader} || $_[0]->{accessor}
 341 }
 342 sub get_write_method {
 343     $_[0]->{writer} || $_[0]->{accessor}
 344 }
 345
 346 sub get_read_method_ref{
 347     my($self) = @_;
 348
 349     $self->{_read_method_ref} ||= do{
 350         my $metaclass = $self->associated_class
 351             or $self->throw_error('No asocciated class for ' . $self->name);
 352
 353         my $reader = $self->{reader} || $self->{accessor};
 354         if($reader){
 355             $metaclass->name->can($reader);
 356         }
 357         else{
 358             $self->accessor_metaclass->_generate_reader($self, $metaclass);
 359         }
 360     };
 361 }
 362
 363 sub get_write_method_ref{
 364     my($self) = @_;
 365
 366     $self->{_write_method_ref} ||= do{
 367         my $metaclass = $self->associated_class
 368             or $self->throw_error('No asocciated class for ' . $self->name);
 369
 370         my $reader = $self->{writer} || $self->{accessor};
 371         if($reader){
 372             $metaclass->name->can($reader);
 373         }
 374         else{
 375             $self->accessor_metaclass->_generate_writer($self, $metaclass);
 376         }
 377     };
 378 }
 379
 380 sub _canonicalize_handles {
 381     my($self, $handles) = @_;
 382
 383     if (ref($handles) eq 'HASH') {
 384         return %$handles;
 385     }
 386     elsif (ref($handles) eq 'ARRAY') {
 387         return map { $_ => $_ } @$handles;
 388     }
 389     elsif (ref($handles) eq 'Regexp') {
 390         my $class_or_role = ($self->{isa} || $self->{does})
 391             || $self->throw_error("Cannot delegate methods based on a Regexp without a type constraint (isa)");
 392
 393         my $meta = Mouse::Meta::Class->initialize("$class_or_role"); # "" for stringify
 394         return map  { $_ => $_ }
 395                grep { $_ ne 'meta' && !Mouse::Object->can($_) && $_ =~ $handles }
 396                    $meta->isa('Mouse::Meta::Class') ? $meta->get_all_method_names : $meta->get_method_list;
 397     }
 398     else {
 399         $self->throw_error("Unable to canonicalize the 'handles' option with $handles");
 400     }
 401 }
 402
 403
 404 sub associate_method{
 405     my ($attribute, $method) = @_;
 406     $attribute->{associated_methods}++;
 407     return;
 408 }
 409
 410 sub accessor_metaclass(){ 'Mouse::Meta::Method::Accessor' }
 411
 412 sub install_accessors{
 413     my($attribute) = @_;
 414
 415     my $metaclass      = $attribute->{associated_class};
 416     my $accessor_class = $attribute->accessor_metaclass;
 417
 418     foreach my $type(qw(accessor reader writer predicate clearer)){
 419         if(exists $attribute->{$type}){
 420             my $generator = '_generate_' . $type;
 421             my $code      = $accessor_class->$generator($attribute, $metaclass);
 422             $metaclass->add_method($attribute->{$type} => $code);
 423             $attribute->associate_method($code);
 424         }
 425     }
 426
 427     # install delegation
 428     if(exists $attribute->{handles}){
 429         my %handles = $attribute->_canonicalize_handles($attribute->{handles});
 430         my $reader  = $attribute->get_read_method_ref;
 431
 432         while(my($handle_name, $method_to_call) = each %handles){
 433             my $code = $accessor_class->_generate_delegation($attribute, $metaclass,
 434                 $reader, $handle_name, $method_to_call);
 435
 436             $metaclass->add_method($handle_name => $code);
 437             $attribute->associate_method($code);
 438         }
 439     }
 440
 441
 442     if($attribute->can('create') != \&create){
 443         # backword compatibility
 444         $attribute->create($metaclass, $attribute->name, %{$attribute});
 445     }
 446
 447     return;
 448 }
 449
 450 sub throw_error{
 451     my $self = shift;
 452
 453     my $metaclass = (ref $self && $self->associated_class) || 'Mouse::Meta::Class';
 454     $metaclass->throw_error(@_, depth => 1);
 455 }
 456
 457 1;
 458
 459 __END__
 460
 461 =head1 NAME
 462
 463 Mouse::Meta::Attribute - The Mouse attribute metaclass
 464
 465 =head1 VERSION
 466
 467 This document describes Mouse version 0.40
 468
 469 =head1 METHODS
 470
 471 =head2 C<< new(%options) -> Mouse::Meta::Attribute >>
 472
 473 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 474
 475 It adds the following options to the constructor:
 476
 477 =over 4
 478
 479 =item C<< is => 'ro', 'rw', 'bare' >>
 480
 481 This provides a shorthand for specifying the C<reader>, C<writer>, or
 482 C<accessor> names. If the attribute is read-only ('ro') then it will
 483 have a C<reader> method with the same attribute as the name.
 484
 485 If it is read-write ('rw') then it will have an C<accessor> method
 486 with the same name. If you provide an explicit C<writer> for a
 487 read-write attribute, then you will have a C<reader> with the same
 488 name as the attribute, and a C<writer> with the name you provided.
 489
 490 Use 'bare' when you are deliberately not installing any methods
 491 (accessor, reader, etc.) associated with this attribute; otherwise,
 492 Moose will issue a deprecation warning when this attribute is added to a
 493 metaclass.
 494
 495 =item C<< isa => Type >>
 496
 497 This option accepts a type. The type can be a string, which should be
 498 a type name. If the type name is unknown, it is assumed to be a class
 499 name.
 500
 501 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 502
 503 If you I<also> provide a C<does> option, then your C<isa> option must
 504 be a class name, and that class must do the role specified with
 505 C<does>.
 506
 507 =item C<< does => Role >>
 508
 509 This is short-hand for saying that the attribute's type must be an
 510 object which does the named role.
 511
 512 B<This option is not yet supported.>
 513
 514 =item C<< coerce => Bool >>
 515
 516 This option is only valid for objects with a type constraint
 517 (C<isa>). If this is true, then coercions will be applied whenever
 518 this attribute is set.
 519
 520 You can make both this and the C<weak_ref> option true.
 521
 522 =item C<< trigger => CodeRef >>
 523
 524 This option accepts a subroutine reference, which will be called after
 525 the attribute is set.
 526
 527 =item C<< required => Bool >>
 528
 529 An attribute which is required must be provided to the constructor. An
 530 attribute which is required can also have a C<default> or C<builder>,
 531 which will satisfy its required-ness.
 532
 533 A required attribute must have a C<default>, C<builder> or a
 534 non-C<undef> C<init_arg>
 535
 536 =item C<< lazy => Bool >>
 537
 538 A lazy attribute must have a C<default> or C<builder>. When an
 539 attribute is lazy, the default value will not be calculated until the
 540 attribute is read.
 541
 542 =item C<< weak_ref => Bool >>
 543
 544 If this is true, the attribute's value will be stored as a weak
 545 reference.
 546
 547 =item C<< auto_deref => Bool >>
 548
 549 If this is true, then the reader will dereference the value when it is
 550 called. The attribute must have a type constraint which defines the
 551 attribute as an array or hash reference.
 552
 553 =item C<< lazy_build => Bool >>
 554
 555 Setting this to true makes the attribute lazy and provides a number of
 556 default methods.
 557
 558   has 'size' => (
 559       is         => 'ro',
 560       lazy_build => 1,
 561   );
 562
 563 is equivalent to this:
 564
 565   has 'size' => (
 566       is        => 'ro',
 567       lazy      => 1,
 568       builder   => '_build_size',
 569       clearer   => 'clear_size',
 570       predicate => 'has_size',
 571   );
 572
 573 =back
 574
 575 =head2 C<< associate_method(Method) >>
 576
 577 Associates a method with the attribute. Typically, this is called internally
 578 when an attribute generates its accessors.
 579
 580 Currently the argument I<Method> is ignored in Mouse.
 581
 582 =head2 C<< verify_against_type_constraint(Item) -> TRUE | ERROR >>
 583
 584 Checks that the given value passes this attribute's type constraint. Returns C<true>
 585 on success, otherwise C<confess>es.
 586
 587 =head2 C<< clone_and_inherit_options(options) -> Mouse::Meta::Attribute >>
 588
 589 Creates a new attribute in the owner class, inheriting options from parent classes.
 590 Accessors and helper methods are installed. Some error checking is done.
 591
 592 =head2 C<< get_read_method_ref >>
 593
 594 =head2 C<< get_write_method_ref >>
 595
 596 Returns the subroutine reference of a method suitable for reading or
 597 writing the attribute's value in the associated class. These methods
 598 always return a subroutine reference, regardless of whether or not the
 599 attribute is read- or write-only.
 600
 601 =head1 SEE ALSO
 602
 603 L<Moose::Meta::Attribute>
 604
 605 L<Class::MOP::Attribute>
 606
 607 =cut
 608