lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use Mouse::Util qw(:meta); # enables strict and warnings
   3
   4 use Carp ();
   5
   6 use Mouse::Meta::TypeConstraint;
   7
   8 sub _process_options{
   9     my($class, $name, $args) = @_;
  10
  11     # XXX: for backward compatibility (with method modifiers)
  12     if($class->can('canonicalize_args') != \&canonicalize_args){
  13         %{$args} = $class->canonicalize_args($name, %{$args});
  14     }
  15
  16     # taken from Class::MOP::Attribute::new
  17
  18     defined($name)
  19         or $class->throw_error('You must provide a name for the attribute');
  20
  21     if(!exists $args->{init_arg}){
  22         $args->{init_arg} = $name;
  23     }
  24
  25     # 'required' requires eigher 'init_arg', 'builder', or 'default'
  26     my $can_be_required = defined( $args->{init_arg} );
  27
  28     if(exists $args->{builder}){
  29         # XXX:
  30         # Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
  31         # This feature will be changed in a future. (gfx)
  32         $class->throw_error('builder must be a defined scalar value which is a method name')
  33             #if ref $args->{builder} || !defined $args->{builder};
  34             if !defined $args->{builder};
  35
  36         $can_be_required++;
  37     }
  38     elsif(exists $args->{default}){
  39         if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
  40             $class->throw_error("References are not allowed as default values, you must "
  41                               . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
  42         }
  43         $can_be_required++;
  44     }
  45
  46     if( $args->{required} && !$can_be_required ) {
  47         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
  48     }
  49
  50     # taken from Mouse::Meta::Attribute->new and _process_args->
  51
  52     if(exists $args->{is}){
  53         my $is = $args->{is};
  54
  55         if($is eq 'ro'){
  56             $args->{reader} ||= $name;
  57         }
  58         elsif($is eq 'rw'){
  59             if(exists $args->{writer}){
  60                 $args->{reader} ||= $name;
  61              }
  62              else{
  63                 $args->{accessor} ||= $name;
  64              }
  65         }
  66         elsif($is eq 'bare'){
  67             # do nothing, but don't complain (later) about missing methods
  68         }
  69         else{
  70             $is = 'undef' if !defined $is;
  71             $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
  72         }
  73     }
  74
  75     my $tc;
  76     if(exists $args->{isa}){
  77         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
  78     }
  79     elsif(exists $args->{does}){
  80         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
  81     }
  82     $tc = $args->{type_constraint};
  83
  84     if($args->{coerce}){
  85         defined($tc)
  86             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
  87
  88         $args->{weak_ref}
  89             && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
  90     }
  91
  92     if ($args->{lazy_build}) {
  93         exists($args->{default})
  94             && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
  95
  96         $args->{lazy}      = 1;
  97         $args->{builder} ||= "_build_${name}";
  98         if ($name =~ /^_/) {
  99             $args->{clearer}   ||= "_clear${name}";
 100             $args->{predicate} ||= "_has${name}";
 101         }
 102         else {
 103             $args->{clearer}   ||= "clear_${name}";
 104             $args->{predicate} ||= "has_${name}";
 105         }
 106     }
 107
 108     if ($args->{auto_deref}) {
 109         defined($tc)
 110             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
 111
 112         ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
 113             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
 114     }
 115
 116     if (exists $args->{trigger}) {
 117         ('CODE' eq ref $args->{trigger})
 118             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
 119     }
 120
 121     if ($args->{lazy}) {
 122         (exists $args->{default} || defined $args->{builder})
 123             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
 124     }
 125
 126     return;
 127 }
 128
 129 sub new {
 130     my $class = shift;
 131     my $name  = shift;
 132
 133     my %args  = (@_ == 1) ? %{ $_[0] } : @_;
 134
 135     $class->_process_options($name, \%args);
 136
 137     $args{name} = $name;
 138
 139     my $self = bless \%args, $class;
 140
 141     # extra attributes
 142     if($class ne __PACKAGE__){
 143         $class->meta->_initialize_object($self, \%args);
 144     }
 145
 146 # XXX: there is no fast way to check attribute validity
 147 #    my @bad = ...;
 148 #    if(@bad){
 149 #        @bad = sort @bad;
 150 #        Carp::cluck("Found unknown argument(s) passed to '$name' attribute constructor in '$class': @bad");
 151 #    }
 152
 153     return $self;
 154 }
 155
 156 sub has_read_method      { $_[0]->has_reader || $_[0]->has_accessor }
 157 sub has_write_method     { $_[0]->has_writer || $_[0]->has_accessor }
 158
 159 sub _create_args { # DEPRECATED
 160     $_[0]->{_create_args} = $_[1] if @_ > 1;
 161     $_[0]->{_create_args}
 162 }
 163
 164 sub interpolate_class{
 165     my($class, $args) = @_;
 166
 167     if(my $metaclass = delete $args->{metaclass}){
 168         $class = Mouse::Util::resolve_metaclass_alias( Attribute => $metaclass );
 169     }
 170
 171     my @traits;
 172     if(my $traits_ref = delete $args->{traits}){
 173
 174         for (my $i = 0; $i < @{$traits_ref}; $i++) {
 175             my $trait = Mouse::Util::resolve_metaclass_alias(Attribute => $traits_ref->[$i], trait => 1);
 176
 177             next if $class->does($trait);
 178
 179             push @traits, $trait;
 180
 181             # are there options?
 182             push @traits, $traits_ref->[++$i]
 183                 if ref($traits_ref->[$i+1]);
 184         }
 185
 186         if (@traits) {
 187             $class = Mouse::Meta::Class->create_anon_class(
 188                 superclasses => [ $class ],
 189                 roles        => \@traits,
 190                 cache        => 1,
 191             )->name;
 192         }
 193     }
 194
 195     return( $class, @traits );
 196 }
 197
 198 sub canonicalize_args{ # DEPRECATED
 199     my ($self, $name, %args) = @_;
 200
 201     Carp::cluck("$self->canonicalize_args has been deprecated."
 202         . "Use \$self->_process_options instead.")
 203             if Mouse::Util::_MOUSE_VERBOSE;
 204
 205     return %args;
 206 }
 207
 208 sub create { # DEPRECATED
 209     my ($self, $class, $name, %args) = @_;
 210
 211     Carp::cluck("$self->create has been deprecated."
 212         . "Use \$meta->add_attribute and \$attr->install_accessors instead.")
 213             if Mouse::Util::_MOUSE_VERBOSE;
 214
 215     # noop
 216     return $self;
 217 }
 218
 219 sub _coerce_and_verify {
 220     my($self, $value, $instance) = @_;
 221
 222     my $type_constraint = $self->{type_constraint};
 223     return $value if !defined $type_constraint;
 224
 225     if ($self->should_coerce && $type_constraint->has_coercion) {
 226         $value = $type_constraint->coerce($value);
 227     }
 228
 229     $self->verify_against_type_constraint($value);
 230
 231     return $value;
 232 }
 233
 234 sub verify_against_type_constraint {
 235     my ($self, $value) = @_;
 236
 237     my $type_constraint = $self->{type_constraint};
 238     return 1 if !$type_constraint;
 239     return 1 if $type_constraint->check($value);
 240
 241     $self->verify_type_constraint_error($value, $type_constraint);
 242 }
 243
 244 sub verify_type_constraint_error {
 245     my($self, $value, $type) = @_;
 246
 247     $self->throw_error(
 248         sprintf q{Attribute (%s) does not pass the type constraint because: %s},
 249             $self->name,
 250             $type->get_message($value),
 251     );
 252 }
 253
 254 sub coerce_constraint { # DEPRECATED
 255     my $type = $_[0]->{type_constraint}
 256         or return $_[1];
 257
 258     Carp::cluck("coerce_constraint() has been deprecated, which was an internal utility anyway");
 259
 260     return Mouse::Util::TypeConstraints->typecast_constraints($_[0]->associated_class->name, $type, $_[1]);
 261 }
 262
 263 sub clone_and_inherit_options{
 264     my($self, %args) = @_;
 265
 266     my($attribute_class, @traits) = ref($self)->interpolate_class(\%args);
 267
 268     $args{traits} = \@traits if @traits;
 269     # do not inherit the 'handles' attribute
 270     foreach my $name(keys %{$self}){
 271         if(!exists $args{$name} && $name ne 'handles'){
 272             $args{$name} = $self->{$name};
 273         }
 274     }
 275     return $attribute_class->new($self->name, %args);
 276 }
 277
 278 sub clone_parent { # DEPRECATED
 279     my $self  = shift;
 280     my $class = shift;
 281     my $name  = shift;
 282     my %args  = ($self->get_parent_args($class, $name), @_);
 283
 284     Carp::cluck("$self->clone_parent has been deprecated."
 285         . "Use \$meta->add_attribute and \$attr->install_accessors instead.")
 286         if Mouse::Util::_MOUSE_VERBOSE;
 287
 288     $self->clone_and_inherited_args($class, $name, %args);
 289 }
 290
 291 sub get_parent_args { # DEPRECATED
 292     my $self  = shift;
 293     my $class = shift;
 294     my $name  = shift;
 295
 296     for my $super ($class->linearized_isa) {
 297         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 298             or next;
 299         return %{ $super_attr->_create_args };
 300     }
 301
 302     $self->throw_error("Could not find an attribute by the name of '$name' to inherit from");
 303 }
 304
 305
 306 sub get_read_method {
 307     return $_[0]->reader || $_[0]->accessor
 308 }
 309 sub get_write_method {
 310     return $_[0]->writer || $_[0]->accessor
 311 }
 312
 313 sub _get_accessor_method_ref {
 314     my($self, $type, $generator) = @_;
 315
 316     my $metaclass = $self->associated_class
 317         || $self->throw_error('No asocciated class for ' . $self->name);
 318
 319     my $accessor = $self->$type();
 320     if($accessor){
 321         return $metaclass->get_method_body($accessor);
 322     }
 323     else{
 324         return $self->accessor_metaclass->$generator($self, $metaclass);
 325     }
 326 }
 327
 328 sub get_read_method_ref{
 329     my($self) = @_;
 330     return $self->{_read_method_ref} ||= $self->_get_accessor_method_ref('get_read_method', '_generate_reader');
 331 }
 332
 333 sub get_write_method_ref{
 334     my($self) = @_;
 335     return $self->{_write_method_ref} ||= $self->_get_accessor_method_ref('get_write_method', '_generate_writer');
 336 }
 337
 338 sub set_value {
 339     my($self, $object, $value) = @_;
 340     return $self->get_write_method_ref()->($object, $value);
 341 }
 342
 343 sub get_value {
 344     my($self, $object) = @_;
 345     return $self->get_read_method_ref()->($object);
 346 }
 347
 348 sub has_value {
 349     my($self, $object) = @_;
 350     my $accessor_ref = $self->{_predicate_ref}
 351         ||= $self->_get_accessor_method_ref('predicate', '_generate_predicate');
 352
 353     return $accessor_ref->($object);
 354 }
 355
 356 sub clear_value {
 357     my($self, $object) = @_;
 358     my $accessor_ref = $self->{_crealer_ref}
 359         ||= $self->_get_accessor_method_ref('clearer', '_generate_clearer');
 360
 361     return $accessor_ref->($object);
 362 }
 363
 364
 365 sub associate_method{
 366     my ($attribute, $method_name) = @_;
 367     $attribute->{associated_methods}++;
 368     return;
 369 }
 370
 371 sub install_accessors{
 372     my($attribute) = @_;
 373
 374     my $metaclass      = $attribute->associated_class;
 375     my $accessor_class = $attribute->accessor_metaclass;
 376
 377     foreach my $type(qw(accessor reader writer predicate clearer)){
 378         if(exists $attribute->{$type}){
 379             my $generator = '_generate_' . $type;
 380             my $code      = $accessor_class->$generator($attribute, $metaclass);
 381             $metaclass->add_method($attribute->{$type} => $code);
 382             $attribute->associate_method($attribute->{$type});
 383         }
 384     }
 385
 386     # install delegation
 387     if(exists $attribute->{handles}){
 388         my %handles = $attribute->_canonicalize_handles($attribute->{handles});
 389
 390         while(my($handle, $method_to_call) = each %handles){
 391             $metaclass->add_method($handle =>
 392                 $attribute->_make_delegation_method(
 393                     $handle, $method_to_call));
 394
 395             $attribute->associate_method($handle);
 396         }
 397     }
 398
 399     if($attribute->can('create') != \&create){
 400         # backword compatibility
 401         $attribute->create($metaclass, $attribute->name, %{$attribute});
 402     }
 403
 404     return;
 405 }
 406
 407 sub delegation_metaclass() { 'Mouse::Meta::Method::Delegation' }
 408
 409 sub _canonicalize_handles {
 410     my($self, $handles) = @_;
 411
 412     if (ref($handles) eq 'HASH') {
 413         return %$handles;
 414     }
 415     elsif (ref($handles) eq 'ARRAY') {
 416         return map { $_ => $_ } @$handles;
 417     }
 418     elsif (ref($handles) eq 'Regexp') {
 419         my $class_or_role = ($self->{isa} || $self->{does})
 420             || $self->throw_error("Cannot delegate methods based on a Regexp without a type constraint (isa)");
 421
 422         my $meta = Mouse::Meta::Class->initialize("$class_or_role"); # "" for stringify
 423         return map  { $_ => $_ }
 424                grep { !Mouse::Object->can($_) && $_ =~ $handles }
 425                    Mouse::Util::is_a_metarole($meta)
 426                         ? $meta->get_method_list
 427                         : $meta->get_all_method_names;
 428     }
 429     else {
 430         $self->throw_error("Unable to canonicalize the 'handles' option with $handles");
 431     }
 432 }
 433
 434 sub _make_delegation_method {
 435     my($self, $handle, $method_to_call) = @_;
 436     my $delegator = $self->delegation_metaclass;
 437     Mouse::Util::load_class($delegator);
 438
 439     return $delegator->_generate_delegation($self, $handle, $method_to_call);
 440 }
 441
 442 sub throw_error{
 443     my $self = shift;
 444
 445     my $metaclass = (ref $self && $self->associated_class) || 'Mouse::Meta::Class';
 446     $metaclass->throw_error(@_, depth => 1);
 447 }
 448
 449 1;
 450 __END__
 451
 452 =head1 NAME
 453
 454 Mouse::Meta::Attribute - The Mouse attribute metaclass
 455
 456 =head1 VERSION
 457
 458 This document describes Mouse version 0.44
 459
 460 =head1 METHODS
 461
 462 =head2 C<< new(%options) -> Mouse::Meta::Attribute >>
 463
 464 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 465
 466 It adds the following options to the constructor:
 467
 468 =over 4
 469
 470 =item C<< is => 'ro', 'rw', 'bare' >>
 471
 472 This provides a shorthand for specifying the C<reader>, C<writer>, or
 473 C<accessor> names. If the attribute is read-only ('ro') then it will
 474 have a C<reader> method with the same attribute as the name.
 475
 476 If it is read-write ('rw') then it will have an C<accessor> method
 477 with the same name. If you provide an explicit C<writer> for a
 478 read-write attribute, then you will have a C<reader> with the same
 479 name as the attribute, and a C<writer> with the name you provided.
 480
 481 Use 'bare' when you are deliberately not installing any methods
 482 (accessor, reader, etc.) associated with this attribute; otherwise,
 483 Moose will issue a deprecation warning when this attribute is added to a
 484 metaclass.
 485
 486 =item C<< isa => Type >>
 487
 488 This option accepts a type. The type can be a string, which should be
 489 a type name. If the type name is unknown, it is assumed to be a class
 490 name.
 491
 492 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 493
 494 If you I<also> provide a C<does> option, then your C<isa> option must
 495 be a class name, and that class must do the role specified with
 496 C<does>.
 497
 498 =item C<< does => Role >>
 499
 500 This is short-hand for saying that the attribute's type must be an
 501 object which does the named role.
 502
 503 B<This option is not yet supported.>
 504
 505 =item C<< coerce => Bool >>
 506
 507 This option is only valid for objects with a type constraint
 508 (C<isa>). If this is true, then coercions will be applied whenever
 509 this attribute is set.
 510
 511 You can make both this and the C<weak_ref> option true.
 512
 513 =item C<< trigger => CodeRef >>
 514
 515 This option accepts a subroutine reference, which will be called after
 516 the attribute is set.
 517
 518 =item C<< required => Bool >>
 519
 520 An attribute which is required must be provided to the constructor. An
 521 attribute which is required can also have a C<default> or C<builder>,
 522 which will satisfy its required-ness.
 523
 524 A required attribute must have a C<default>, C<builder> or a
 525 non-C<undef> C<init_arg>
 526
 527 =item C<< lazy => Bool >>
 528
 529 A lazy attribute must have a C<default> or C<builder>. When an
 530 attribute is lazy, the default value will not be calculated until the
 531 attribute is read.
 532
 533 =item C<< weak_ref => Bool >>
 534
 535 If this is true, the attribute's value will be stored as a weak
 536 reference.
 537
 538 =item C<< auto_deref => Bool >>
 539
 540 If this is true, then the reader will dereference the value when it is
 541 called. The attribute must have a type constraint which defines the
 542 attribute as an array or hash reference.
 543
 544 =item C<< lazy_build => Bool >>
 545
 546 Setting this to true makes the attribute lazy and provides a number of
 547 default methods.
 548
 549   has 'size' => (
 550       is         => 'ro',
 551       lazy_build => 1,
 552   );
 553
 554 is equivalent to this:
 555
 556   has 'size' => (
 557       is        => 'ro',
 558       lazy      => 1,
 559       builder   => '_build_size',
 560       clearer   => 'clear_size',
 561       predicate => 'has_size',
 562   );
 563
 564 =back
 565
 566 =head2 C<< associate_method(MethodName) >>
 567
 568 Associates a method with the attribute. Typically, this is called internally
 569 when an attribute generates its accessors.
 570
 571 Currently the argument I<MethodName> is ignored in Mouse.
 572
 573 =head2 C<< verify_against_type_constraint(Item) -> TRUE | ERROR >>
 574
 575 Checks that the given value passes this attribute's type constraint. Returns C<true>
 576 on success, otherwise C<confess>es.
 577
 578 =head2 C<< clone_and_inherit_options(options) -> Mouse::Meta::Attribute >>
 579
 580 Creates a new attribute in the owner class, inheriting options from parent classes.
 581 Accessors and helper methods are installed. Some error checking is done.
 582
 583 =head2 C<< get_read_method_ref >>
 584
 585 =head2 C<< get_write_method_ref >>
 586
 587 Returns the subroutine reference of a method suitable for reading or
 588 writing the attribute's value in the associated class. These methods
 589 always return a subroutine reference, regardless of whether or not the
 590 attribute is read- or write-only.
 591
 592 =head1 SEE ALSO
 593
 594 L<Moose::Meta::Attribute>
 595
 596 L<Class::MOP::Attribute>
 597
 598 =cut
 599