lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use Mouse::Util qw(:meta); # enables strict and warnings
   3
   4 use Carp ();
   5
   6 use Mouse::Meta::TypeConstraint;
   7
   8 my %valid_options = map { $_ => undef } (
   9   'accessor',
  10   'auto_deref',
  11   'builder',
  12   'clearer',
  13   'coerce',
  14   'default',
  15   'documentation',
  16   'does',
  17   'handles',
  18   'init_arg',
  19   'is',
  20   'isa',
  21   'lazy',
  22   'lazy_build',
  23   'name',
  24   'predicate',
  25   'reader',
  26   'required',
  27   'traits',
  28   'trigger',
  29   'type_constraint',
  30   'weak_ref',
  31   'writer',
  32
  33   # internally used
  34   'associated_class',
  35   'associated_methods',
  36
  37   # Moose defines, but Mouse doesn't
  38   #'definition_context',
  39   #'initializer',
  40   #'insertion_order',
  41
  42   # special case for AttributeHelpers
  43   'provides',
  44   'curries',
  45 );
  46
  47 our @CARP_NOT = qw(Mouse::Meta::Class);
  48
  49 sub new {
  50     my $class = shift;
  51     my $name  = shift;
  52
  53     my $args  = $class->Mouse::Object::BUILDARGS(@_);
  54
  55     # XXX: for backward compatibility (with method modifiers)
  56     if($class->can('canonicalize_args') != \&canonicalize_args){
  57         %{$args} = $class->canonicalize_args($name, %{$args});
  58     }
  59
  60     $class->_process_options($name, $args);
  61
  62     $args->{name} = $name;
  63
  64     # check options
  65     # (1) known by core
  66     my @bad = grep{ !exists $valid_options{$_} } keys %{$args};
  67
  68     # (2) known by subclasses
  69     if(@bad && $class ne __PACKAGE__){
  70         my %valid_attrs = (
  71             map { $_ => undef }
  72             grep { defined }
  73             map { $_->init_arg() }
  74             $class->meta->get_all_attributes()
  75         );
  76         @bad = grep{ !exists $valid_attrs{$_} } @bad;
  77     }
  78
  79     # (3) bad options found
  80     if(@bad){
  81         Carp::carp(
  82             "Found unknown argument(s) passed to '$name' attribute constructor in '$class': "
  83             . Mouse::Util::english_list(@bad));
  84     }
  85
  86     my $self = bless $args, $class;
  87
  88     # extra attributes
  89     if($class ne __PACKAGE__){
  90         $class->meta->_initialize_object($self, $args);
  91     }
  92
  93     return $self;
  94 }
  95
  96 sub has_read_method      { $_[0]->has_reader || $_[0]->has_accessor }
  97 sub has_write_method     { $_[0]->has_writer || $_[0]->has_accessor }
  98
  99 sub _create_args { # DEPRECATED
 100     $_[0]->{_create_args} = $_[1] if @_ > 1;
 101     $_[0]->{_create_args}
 102 }
 103
 104 sub interpolate_class{
 105     my($class, $args) = @_;
 106
 107     if(my $metaclass = delete $args->{metaclass}){
 108         $class = Mouse::Util::resolve_metaclass_alias( Attribute => $metaclass );
 109     }
 110
 111     my @traits;
 112     if(my $traits_ref = delete $args->{traits}){
 113
 114         for (my $i = 0; $i < @{$traits_ref}; $i++) {
 115             my $trait = Mouse::Util::resolve_metaclass_alias(Attribute => $traits_ref->[$i], trait => 1);
 116
 117             next if $class->does($trait);
 118
 119             push @traits, $trait;
 120
 121             # are there options?
 122             push @traits, $traits_ref->[++$i]
 123                 if ref($traits_ref->[$i+1]);
 124         }
 125
 126         if (@traits) {
 127             $class = Mouse::Meta::Class->create_anon_class(
 128                 superclasses => [ $class ],
 129                 roles        => \@traits,
 130                 cache        => 1,
 131             )->name;
 132         }
 133     }
 134
 135     return( $class, @traits );
 136 }
 137
 138 sub canonicalize_args{ # DEPRECATED
 139     my ($self, $name, %args) = @_;
 140
 141     Carp::cluck("$self->canonicalize_args has been deprecated."
 142         . "Use \$self->_process_options instead.");
 143
 144     return %args;
 145 }
 146
 147 sub create { # DEPRECATED
 148     my ($self, $class, $name, %args) = @_;
 149
 150     Carp::cluck("$self->create has been deprecated."
 151         . "Use \$meta->add_attribute and \$attr->install_accessors instead.");
 152
 153     # noop
 154     return $self;
 155 }
 156
 157 sub _coerce_and_verify {
 158     my($self, $value, $instance) = @_;
 159
 160     my $type_constraint = $self->{type_constraint};
 161     return $value if !defined $type_constraint;
 162
 163     if ($self->should_coerce && $type_constraint->has_coercion) {
 164         $value = $type_constraint->coerce($value);
 165     }
 166
 167     $self->verify_against_type_constraint($value);
 168
 169     return $value;
 170 }
 171
 172 sub verify_against_type_constraint {
 173     my ($self, $value) = @_;
 174
 175     my $type_constraint = $self->{type_constraint};
 176     return 1 if !$type_constraint;
 177     return 1 if $type_constraint->check($value);
 178
 179     $self->_throw_type_constraint_error($value, $type_constraint);
 180 }
 181
 182 sub _throw_type_constraint_error {
 183     my($self, $value, $type) = @_;
 184
 185     $self->throw_error(
 186         sprintf q{Attribute (%s) does not pass the type constraint because: %s},
 187             $self->name,
 188             $type->get_message($value),
 189     );
 190 }
 191
 192 sub clone_and_inherit_options{
 193     my $self = shift;
 194     my $args = $self->Mouse::Object::BUILDARGS(@_);
 195
 196     my($attribute_class, @traits) = ref($self)->interpolate_class($args);
 197
 198     $args->{traits} = \@traits if @traits;
 199     # do not inherit the 'handles' attribute
 200     foreach my $name(keys %{$self}){
 201         if(!exists $args->{$name} && $name ne 'handles'){
 202             $args->{$name} = $self->{$name};
 203         }
 204     }
 205
 206     # remove temporary caches
 207     foreach my $attr(keys %{$args}){
 208         if($attr =~ /\A _/xms){
 209             delete $args->{$attr};
 210         }
 211     }
 212
 213     return $attribute_class->new($self->name, $args);
 214 }
 215
 216 sub clone_parent { # DEPRECATED
 217     my $self  = shift;
 218     my $class = shift;
 219     my $name  = shift;
 220     my %args  = ($self->get_parent_args($class, $name), @_);
 221
 222     Carp::cluck("$self->clone_parent has been deprecated."
 223         . "Use \$meta->add_attribute and \$attr->install_accessors instead.");
 224
 225     $self->clone_and_inherited_args($class, $name, %args);
 226 }
 227
 228 sub get_parent_args { # DEPRECATED
 229     my $self  = shift;
 230     my $class = shift;
 231     my $name  = shift;
 232
 233     for my $super ($class->linearized_isa) {
 234         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 235             or next;
 236         return %{ $super_attr->_create_args };
 237     }
 238
 239     $self->throw_error("Could not find an attribute by the name of '$name' to inherit from");
 240 }
 241
 242
 243 sub get_read_method {
 244     return $_[0]->reader || $_[0]->accessor
 245 }
 246 sub get_write_method {
 247     return $_[0]->writer || $_[0]->accessor
 248 }
 249
 250 sub _get_accessor_method_ref {
 251     my($self, $type, $generator) = @_;
 252
 253     my $metaclass = $self->associated_class
 254         || $self->throw_error('No asocciated class for ' . $self->name);
 255
 256     my $accessor = $self->$type();
 257     if($accessor){
 258         return $metaclass->get_method_body($accessor);
 259     }
 260     else{
 261         return $self->accessor_metaclass->$generator($self, $metaclass);
 262     }
 263 }
 264
 265 sub get_read_method_ref{
 266     my($self) = @_;
 267     return $self->{_read_method_ref} ||= $self->_get_accessor_method_ref('get_read_method', '_generate_reader');
 268 }
 269
 270 sub get_write_method_ref{
 271     my($self) = @_;
 272     return $self->{_write_method_ref} ||= $self->_get_accessor_method_ref('get_write_method', '_generate_writer');
 273 }
 274
 275 sub set_value {
 276     my($self, $object, $value) = @_;
 277     return $self->get_write_method_ref()->($object, $value);
 278 }
 279
 280 sub get_value {
 281     my($self, $object) = @_;
 282     return $self->get_read_method_ref()->($object);
 283 }
 284
 285 sub has_value {
 286     my($self, $object) = @_;
 287     my $accessor_ref = $self->{_predicate_ref}
 288         ||= $self->_get_accessor_method_ref('predicate', '_generate_predicate');
 289
 290     return $accessor_ref->($object);
 291 }
 292
 293 sub clear_value {
 294     my($self, $object) = @_;
 295     my $accessor_ref = $self->{_crealer_ref}
 296         ||= $self->_get_accessor_method_ref('clearer', '_generate_clearer');
 297
 298     return $accessor_ref->($object);
 299 }
 300
 301
 302 sub associate_method{
 303     my ($attribute, $method_name) = @_;
 304     $attribute->{associated_methods}++;
 305     return;
 306 }
 307
 308 sub install_accessors{
 309     my($attribute) = @_;
 310
 311     my $metaclass      = $attribute->associated_class;
 312     my $accessor_class = $attribute->accessor_metaclass;
 313
 314     foreach my $type(qw(accessor reader writer predicate clearer)){
 315         if(exists $attribute->{$type}){
 316             my $generator = '_generate_' . $type;
 317             my $code      = $accessor_class->$generator($attribute, $metaclass);
 318             $metaclass->add_method($attribute->{$type} => $code);
 319             $attribute->associate_method($attribute->{$type});
 320         }
 321     }
 322
 323     # install delegation
 324     if(exists $attribute->{handles}){
 325         my %handles = $attribute->_canonicalize_handles($attribute->{handles});
 326
 327         while(my($handle, $method_to_call) = each %handles){
 328             $metaclass->add_method($handle =>
 329                 $attribute->_make_delegation_method(
 330                     $handle, $method_to_call));
 331
 332             $attribute->associate_method($handle);
 333         }
 334     }
 335
 336     if($attribute->can('create') != \&create){
 337         # backword compatibility
 338         $attribute->create($metaclass, $attribute->name, %{$attribute});
 339     }
 340
 341     return;
 342 }
 343
 344 sub delegation_metaclass() { 'Mouse::Meta::Method::Delegation' }
 345
 346 sub _canonicalize_handles {
 347     my($self, $handles) = @_;
 348
 349     if (ref($handles) eq 'HASH') {
 350         return %$handles;
 351     }
 352     elsif (ref($handles) eq 'ARRAY') {
 353         return map { $_ => $_ } @$handles;
 354     }
 355     elsif ( ref($handles) eq 'CODE' ) {
 356         my $class_or_role = ( $self->{isa} || $self->{does} )
 357             || $self->throw_error( "Cannot find delegate metaclass for attribute " . $self->name );
 358         return $handles->( $self, Mouse::Meta::Class->initialize("$class_or_role"));
 359     }
 360     elsif (ref($handles) eq 'Regexp') {
 361         my $class_or_role = ($self->{isa} || $self->{does})
 362             || $self->throw_error("Cannot delegate methods based on a Regexp without a type constraint (isa)");
 363
 364         my $meta = Mouse::Meta::Class->initialize("$class_or_role"); # "" for stringify
 365         return map  { $_ => $_ }
 366                grep { !Mouse::Object->can($_) && $_ =~ $handles }
 367                    Mouse::Util::is_a_metarole($meta)
 368                         ? $meta->get_method_list
 369                         : $meta->get_all_method_names;
 370     }
 371     else {
 372         $self->throw_error("Unable to canonicalize the 'handles' option with $handles");
 373     }
 374 }
 375
 376 sub _make_delegation_method {
 377     my($self, $handle, $method_to_call) = @_;
 378     return Mouse::Util::load_class($self->delegation_metaclass)
 379         ->_generate_delegation($self, $handle, $method_to_call);
 380 }
 381
 382 sub throw_error{
 383     my $self = shift;
 384
 385     my $metaclass = (ref $self && $self->associated_class) || 'Mouse::Meta::Class';
 386     $metaclass->throw_error(@_, depth => 1);
 387 }
 388
 389 1;
 390 __END__
 391
 392 =head1 NAME
 393
 394 Mouse::Meta::Attribute - The Mouse attribute metaclass
 395
 396 =head1 VERSION
 397
 398 This document describes Mouse version 0.50_04
 399
 400 =head1 METHODS
 401
 402 =head2 C<< new(%options) -> Mouse::Meta::Attribute >>
 403
 404 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 405
 406 It adds the following options to the constructor:
 407
 408 =over 4
 409
 410 =item C<< is => 'ro', 'rw', 'bare' >>
 411
 412 This provides a shorthand for specifying the C<reader>, C<writer>, or
 413 C<accessor> names. If the attribute is read-only ('ro') then it will
 414 have a C<reader> method with the same attribute as the name.
 415
 416 If it is read-write ('rw') then it will have an C<accessor> method
 417 with the same name. If you provide an explicit C<writer> for a
 418 read-write attribute, then you will have a C<reader> with the same
 419 name as the attribute, and a C<writer> with the name you provided.
 420
 421 Use 'bare' when you are deliberately not installing any methods
 422 (accessor, reader, etc.) associated with this attribute; otherwise,
 423 Moose will issue a deprecation warning when this attribute is added to a
 424 metaclass.
 425
 426 =item C<< isa => Type >>
 427
 428 This option accepts a type. The type can be a string, which should be
 429 a type name. If the type name is unknown, it is assumed to be a class
 430 name.
 431
 432 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 433
 434 If you I<also> provide a C<does> option, then your C<isa> option must
 435 be a class name, and that class must do the role specified with
 436 C<does>.
 437
 438 =item C<< does => Role >>
 439
 440 This is short-hand for saying that the attribute's type must be an
 441 object which does the named role.
 442
 443 B<This option is not yet supported.>
 444
 445 =item C<< coerce => Bool >>
 446
 447 This option is only valid for objects with a type constraint
 448 (C<isa>). If this is true, then coercions will be applied whenever
 449 this attribute is set.
 450
 451 You can make both this and the C<weak_ref> option true.
 452
 453 =item C<< trigger => CodeRef >>
 454
 455 This option accepts a subroutine reference, which will be called after
 456 the attribute is set.
 457
 458 =item C<< required => Bool >>
 459
 460 An attribute which is required must be provided to the constructor. An
 461 attribute which is required can also have a C<default> or C<builder>,
 462 which will satisfy its required-ness.
 463
 464 A required attribute must have a C<default>, C<builder> or a
 465 non-C<undef> C<init_arg>
 466
 467 =item C<< lazy => Bool >>
 468
 469 A lazy attribute must have a C<default> or C<builder>. When an
 470 attribute is lazy, the default value will not be calculated until the
 471 attribute is read.
 472
 473 =item C<< weak_ref => Bool >>
 474
 475 If this is true, the attribute's value will be stored as a weak
 476 reference.
 477
 478 =item C<< auto_deref => Bool >>
 479
 480 If this is true, then the reader will dereference the value when it is
 481 called. The attribute must have a type constraint which defines the
 482 attribute as an array or hash reference.
 483
 484 =item C<< lazy_build => Bool >>
 485
 486 Setting this to true makes the attribute lazy and provides a number of
 487 default methods.
 488
 489   has 'size' => (
 490       is         => 'ro',
 491       lazy_build => 1,
 492   );
 493
 494 is equivalent to this:
 495
 496   has 'size' => (
 497       is        => 'ro',
 498       lazy      => 1,
 499       builder   => '_build_size',
 500       clearer   => 'clear_size',
 501       predicate => 'has_size',
 502   );
 503
 504 =back
 505
 506 =head2 C<< associate_method(MethodName) >>
 507
 508 Associates a method with the attribute. Typically, this is called internally
 509 when an attribute generates its accessors.
 510
 511 Currently the argument I<MethodName> is ignored in Mouse.
 512
 513 =head2 C<< verify_against_type_constraint(Item) -> TRUE | ERROR >>
 514
 515 Checks that the given value passes this attribute's type constraint. Returns C<true>
 516 on success, otherwise C<confess>es.
 517
 518 =head2 C<< clone_and_inherit_options(options) -> Mouse::Meta::Attribute >>
 519
 520 Creates a new attribute in the owner class, inheriting options from parent classes.
 521 Accessors and helper methods are installed. Some error checking is done.
 522
 523 =head2 C<< get_read_method_ref >>
 524
 525 =head2 C<< get_write_method_ref >>
 526
 527 Returns the subroutine reference of a method suitable for reading or
 528 writing the attribute's value in the associated class. These methods
 529 always return a subroutine reference, regardless of whether or not the
 530 attribute is read- or write-only.
 531
 532 =head1 SEE ALSO
 533
 534 L<Moose::Meta::Attribute>
 535
 536 L<Class::MOP::Attribute>
 537
 538 =cut
 539