lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use Mouse::Util qw(:meta); # enables strict and warnings
   3
   4 use Carp ();
   5
   6 use Mouse::Meta::TypeConstraint;
   7
   8 #use Mouse::Meta::Method::Accessor;
   9 use Mouse::Meta::Method::Delegation;
  10
  11
  12 sub _process_options{
  13     my($class, $name, $args) = @_;
  14
  15
  16     # XXX: for backward compatibility (with method modifiers)
  17     if($class->can('canonicalize_args') != \&canonicalize_args){
  18         %{$args} = $class->canonicalize_args($name, %{$args});
  19     }
  20
  21     # taken from Class::MOP::Attribute::new
  22
  23     defined($name)
  24         or $class->throw_error('You must provide a name for the attribute');
  25
  26     if(!exists $args->{init_arg}){
  27         $args->{init_arg} = $name;
  28     }
  29
  30     # 'required' requires eigher 'init_arg', 'builder', or 'default'
  31     my $can_be_required = defined( $args->{init_arg} );
  32
  33     if(exists $args->{builder}){
  34         # XXX:
  35         # Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
  36         # This feature will be changed in a future. (gfx)
  37         $class->throw_error('builder must be a defined scalar value which is a method name')
  38             #if ref $args->{builder} || !defined $args->{builder};
  39             if !defined $args->{builder};
  40
  41         $can_be_required++;
  42     }
  43     elsif(exists $args->{default}){
  44         if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
  45             $class->throw_error("References are not allowed as default values, you must "
  46                               . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
  47         }
  48         $can_be_required++;
  49     }
  50
  51     if( $args->{required} && !$can_be_required ) {
  52         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
  53     }
  54
  55     # taken from Mouse::Meta::Attribute->new and _process_args->
  56
  57     if(exists $args->{is}){
  58         my $is = $args->{is};
  59
  60         if($is eq 'ro'){
  61             $args->{reader} ||= $name;
  62         }
  63         elsif($is eq 'rw'){
  64             if(exists $args->{writer}){
  65                 $args->{reader} ||= $name;
  66              }
  67              else{
  68                 $args->{accessor} ||= $name;
  69              }
  70         }
  71         elsif($is eq 'bare'){
  72             # do nothing, but don't complain (later) about missing methods
  73         }
  74         else{
  75             $is = 'undef' if !defined $is;
  76             $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
  77         }
  78     }
  79
  80     my $tc;
  81     if(exists $args->{isa}){
  82         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
  83     }
  84     elsif(exists $args->{does}){
  85         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
  86     }
  87     $tc = $args->{type_constraint};
  88
  89     if($args->{coerce}){
  90         defined($tc)
  91             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
  92
  93         $args->{weak_ref}
  94             && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
  95     }
  96
  97     if ($args->{lazy_build}) {
  98         exists($args->{default})
  99             && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
 100
 101         $args->{lazy}      = 1;
 102         $args->{builder} ||= "_build_${name}";
 103         if ($name =~ /^_/) {
 104             $args->{clearer}   ||= "_clear${name}";
 105             $args->{predicate} ||= "_has${name}";
 106         }
 107         else {
 108             $args->{clearer}   ||= "clear_${name}";
 109             $args->{predicate} ||= "has_${name}";
 110         }
 111     }
 112
 113     if ($args->{auto_deref}) {
 114         defined($tc)
 115             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
 116
 117         ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
 118             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
 119     }
 120
 121     if (exists $args->{trigger}) {
 122         ('CODE' eq ref $args->{trigger})
 123             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
 124     }
 125
 126     if ($args->{lazy}) {
 127         (exists $args->{default} || defined $args->{builder})
 128             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
 129     }
 130
 131     return;
 132 }
 133
 134 sub new {
 135     my $class = shift;
 136     my $name  = shift;
 137
 138     my %args  = (@_ == 1) ? %{ $_[0] } : @_;
 139
 140     $class->_process_options($name, \%args);
 141
 142     $args{name} = $name;
 143
 144     my $self = bless \%args, $class;
 145
 146     # extra attributes
 147     if($class ne __PACKAGE__){
 148         $class->meta->_initialize_object($self, \%args);
 149     }
 150
 151 # XXX: there is no fast way to check attribute validity
 152 #    my @bad = ...;
 153 #    if(@bad){
 154 #        @bad = sort @bad;
 155 #        Carp::cluck("Found unknown argument(s) passed to '$name' attribute constructor in '$class': @bad");
 156 #    }
 157
 158     return $self;
 159 }
 160
 161 sub has_read_method      { $_[0]->has_reader || $_[0]->has_accessor }
 162 sub has_write_method     { $_[0]->has_writer || $_[0]->has_accessor }
 163
 164 sub _create_args { # DEPRECATED
 165     $_[0]->{_create_args} = $_[1] if @_ > 1;
 166     $_[0]->{_create_args}
 167 }
 168
 169 sub interpolate_class{
 170     my($class, $args) = @_;
 171
 172     if(my $metaclass = delete $args->{metaclass}){
 173         $class = Mouse::Util::resolve_metaclass_alias( Attribute => $metaclass );
 174     }
 175
 176     my @traits;
 177     if(my $traits_ref = delete $args->{traits}){
 178
 179         for (my $i = 0; $i < @{$traits_ref}; $i++) {
 180             my $trait = Mouse::Util::resolve_metaclass_alias(Attribute => $traits_ref->[$i], trait => 1);
 181
 182             next if $class->does($trait);
 183
 184             push @traits, $trait;
 185
 186             # are there options?
 187             push @traits, $traits_ref->[++$i]
 188                 if ref($traits_ref->[$i+1]);
 189         }
 190
 191         if (@traits) {
 192             $class = Mouse::Meta::Class->create_anon_class(
 193                 superclasses => [ $class ],
 194                 roles        => \@traits,
 195                 cache        => 1,
 196             )->name;
 197         }
 198     }
 199
 200     return( $class, @traits );
 201 }
 202
 203 sub canonicalize_args{ # DEPRECATED
 204     my ($self, $name, %args) = @_;
 205
 206     Carp::cluck("$self->canonicalize_args has been deprecated."
 207         . "Use \$self->_process_options instead.")
 208             if _MOUSE_VERBOSE;
 209
 210     return %args;
 211 }
 212
 213 sub create { # DEPRECATED
 214     my ($self, $class, $name, %args) = @_;
 215
 216     Carp::cluck("$self->create has been deprecated."
 217         . "Use \$meta->add_attribute and \$attr->install_accessors instead.")
 218             if _MOUSE_VERBOSE;
 219
 220     # noop
 221     return $self;
 222 }
 223
 224 sub _coerce_and_verify {
 225     my($self, $value, $instance) = @_;
 226
 227     my $type_constraint = $self->{type_constraint};
 228     return $value if !defined $type_constraint;
 229
 230     if ($self->should_coerce && $type_constraint->has_coercion) {
 231         $value = $type_constraint->coerce($value);
 232     }
 233
 234     $self->verify_against_type_constraint($value);
 235
 236     return $value;
 237 }
 238
 239 sub verify_against_type_constraint {
 240     my ($self, $value) = @_;
 241
 242     my $type_constraint = $self->{type_constraint};
 243     return 1 if !$type_constraint;
 244     return 1 if $type_constraint->check($value);
 245
 246     $self->verify_type_constraint_error($self->name, $value, $type_constraint);
 247 }
 248
 249 sub verify_type_constraint_error {
 250     my($self, $name, $value, $type) = @_;
 251     $self->throw_error("Attribute ($name) does not pass the type constraint because: "
 252         . $type->get_message($value));
 253 }
 254
 255 sub coerce_constraint { # DEPRECATED
 256     my $type = $_[0]->{type_constraint}
 257         or return $_[1];
 258
 259     Carp::cluck("coerce_constraint() has been deprecated, which was an internal utility anyway");
 260
 261     return Mouse::Util::TypeConstraints->typecast_constraints($_[0]->associated_class->name, $type, $_[1]);
 262 }
 263
 264 sub clone_and_inherit_options{
 265     my($self, %args) = @_;
 266
 267     my($attribute_class, @traits) = ref($self)->interpolate_class(\%args);
 268
 269     $args{traits} = \@traits if @traits;
 270     # do not inherit the 'handles' attribute
 271     foreach my $name(keys %{$self}){
 272         if(!exists $args{$name} && $name ne 'handles'){
 273             $args{$name} = $self->{$name};
 274         }
 275     }
 276     return $attribute_class->new($self->name, %args);
 277 }
 278
 279 sub clone_parent { # DEPRECATED
 280     my $self  = shift;
 281     my $class = shift;
 282     my $name  = shift;
 283     my %args  = ($self->get_parent_args($class, $name), @_);
 284
 285     Carp::cluck("$self->clone_parent has been deprecated."
 286         . "Use \$meta->add_attribute and \$attr->install_accessors instead.")
 287         if _MOUSE_VERBOSE;
 288
 289     $self->clone_and_inherited_args($class, $name, %args);
 290 }
 291
 292 sub get_parent_args { # DEPRECATED
 293     my $self  = shift;
 294     my $class = shift;
 295     my $name  = shift;
 296
 297     for my $super ($class->linearized_isa) {
 298         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 299             or next;
 300         return %{ $super_attr->_create_args };
 301     }
 302
 303     $self->throw_error("Could not find an attribute by the name of '$name' to inherit from");
 304 }
 305
 306
 307 sub get_read_method {
 308     $_[0]->reader || $_[0]->accessor
 309 }
 310 sub get_write_method {
 311     $_[0]->writer || $_[0]->accessor
 312 }
 313
 314 sub get_read_method_ref{
 315     my($self) = @_;
 316
 317     $self->{_read_method_ref} ||= do{
 318         my $metaclass = $self->associated_class
 319             or $self->throw_error('No asocciated class for ' . $self->name);
 320
 321         my $reader = $self->{reader} || $self->{accessor};
 322         if($reader){
 323             $metaclass->name->can($reader);
 324         }
 325         else{
 326             $self->accessor_metaclass->_generate_reader($self, $metaclass);
 327         }
 328     };
 329 }
 330
 331 sub get_write_method_ref{
 332     my($self) = @_;
 333
 334     $self->{_write_method_ref} ||= do{
 335         my $metaclass = $self->associated_class
 336             or $self->throw_error('No asocciated class for ' . $self->name);
 337
 338         my $reader = $self->{writer} || $self->{accessor};
 339         if($reader){
 340             $metaclass->name->can($reader);
 341         }
 342         else{
 343             $self->accessor_metaclass->_generate_writer($self, $metaclass);
 344         }
 345     };
 346 }
 347
 348 sub _canonicalize_handles {
 349     my($self, $handles) = @_;
 350
 351     if (ref($handles) eq 'HASH') {
 352         return %$handles;
 353     }
 354     elsif (ref($handles) eq 'ARRAY') {
 355         return map { $_ => $_ } @$handles;
 356     }
 357     elsif (ref($handles) eq 'Regexp') {
 358         my $class_or_role = ($self->{isa} || $self->{does})
 359             || $self->throw_error("Cannot delegate methods based on a Regexp without a type constraint (isa)");
 360
 361         my $meta = Mouse::Meta::Class->initialize("$class_or_role"); # "" for stringify
 362         return map  { $_ => $_ }
 363                grep { $_ ne 'meta' && !Mouse::Object->can($_) && $_ =~ $handles }
 364                    Mouse::Util::TypeConstraints::_is_a_metarole($meta)
 365                         ? $meta->get_method_list
 366                         : $meta->get_all_method_names;
 367     }
 368     else {
 369         $self->throw_error("Unable to canonicalize the 'handles' option with $handles");
 370     }
 371 }
 372
 373 sub associate_method{
 374     my ($attribute, $method) = @_;
 375     $attribute->{associated_methods}++;
 376     return;
 377 }
 378
 379
 380 sub delegation_metaclass() { 'Mouse::Meta::Method::Delegation' }
 381
 382 sub install_accessors{
 383     my($attribute) = @_;
 384
 385     my $metaclass      = $attribute->associated_class;
 386     my $accessor_class = $attribute->accessor_metaclass;
 387
 388     foreach my $type(qw(accessor reader writer predicate clearer)){
 389         if(exists $attribute->{$type}){
 390             my $generator = '_generate_' . $type;
 391             my $code      = $accessor_class->$generator($attribute, $metaclass);
 392             $metaclass->add_method($attribute->{$type} => $code);
 393             $attribute->associate_method($code);
 394         }
 395     }
 396
 397     # install delegation
 398     if(exists $attribute->{handles}){
 399         my $delegation_class = $attribute->delegation_metaclass;
 400         my %handles = $attribute->_canonicalize_handles($attribute->{handles});
 401         my $reader  = $attribute->get_read_method_ref;
 402
 403         while(my($handle_name, $method_to_call) = each %handles){
 404             my $code = $delegation_class->_generate_delegation($attribute, $metaclass,
 405                 $reader, $handle_name, $method_to_call);
 406
 407             $metaclass->add_method($handle_name => $code);
 408             $attribute->associate_method($code);
 409         }
 410     }
 411
 412
 413     if($attribute->can('create') != \&create){
 414         # backword compatibility
 415         $attribute->create($metaclass, $attribute->name, %{$attribute});
 416     }
 417
 418     return;
 419 }
 420
 421 sub throw_error{
 422     my $self = shift;
 423
 424     my $metaclass = (ref $self && $self->associated_class) || 'Mouse::Meta::Class';
 425     $metaclass->throw_error(@_, depth => 1);
 426 }
 427
 428 1;
 429
 430 __END__
 431
 432 =head1 NAME
 433
 434 Mouse::Meta::Attribute - The Mouse attribute metaclass
 435
 436 =head1 VERSION
 437
 438 This document describes Mouse version 0.40_02
 439
 440 =head1 METHODS
 441
 442 =head2 C<< new(%options) -> Mouse::Meta::Attribute >>
 443
 444 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 445
 446 It adds the following options to the constructor:
 447
 448 =over 4
 449
 450 =item C<< is => 'ro', 'rw', 'bare' >>
 451
 452 This provides a shorthand for specifying the C<reader>, C<writer>, or
 453 C<accessor> names. If the attribute is read-only ('ro') then it will
 454 have a C<reader> method with the same attribute as the name.
 455
 456 If it is read-write ('rw') then it will have an C<accessor> method
 457 with the same name. If you provide an explicit C<writer> for a
 458 read-write attribute, then you will have a C<reader> with the same
 459 name as the attribute, and a C<writer> with the name you provided.
 460
 461 Use 'bare' when you are deliberately not installing any methods
 462 (accessor, reader, etc.) associated with this attribute; otherwise,
 463 Moose will issue a deprecation warning when this attribute is added to a
 464 metaclass.
 465
 466 =item C<< isa => Type >>
 467
 468 This option accepts a type. The type can be a string, which should be
 469 a type name. If the type name is unknown, it is assumed to be a class
 470 name.
 471
 472 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 473
 474 If you I<also> provide a C<does> option, then your C<isa> option must
 475 be a class name, and that class must do the role specified with
 476 C<does>.
 477
 478 =item C<< does => Role >>
 479
 480 This is short-hand for saying that the attribute's type must be an
 481 object which does the named role.
 482
 483 B<This option is not yet supported.>
 484
 485 =item C<< coerce => Bool >>
 486
 487 This option is only valid for objects with a type constraint
 488 (C<isa>). If this is true, then coercions will be applied whenever
 489 this attribute is set.
 490
 491 You can make both this and the C<weak_ref> option true.
 492
 493 =item C<< trigger => CodeRef >>
 494
 495 This option accepts a subroutine reference, which will be called after
 496 the attribute is set.
 497
 498 =item C<< required => Bool >>
 499
 500 An attribute which is required must be provided to the constructor. An
 501 attribute which is required can also have a C<default> or C<builder>,
 502 which will satisfy its required-ness.
 503
 504 A required attribute must have a C<default>, C<builder> or a
 505 non-C<undef> C<init_arg>
 506
 507 =item C<< lazy => Bool >>
 508
 509 A lazy attribute must have a C<default> or C<builder>. When an
 510 attribute is lazy, the default value will not be calculated until the
 511 attribute is read.
 512
 513 =item C<< weak_ref => Bool >>
 514
 515 If this is true, the attribute's value will be stored as a weak
 516 reference.
 517
 518 =item C<< auto_deref => Bool >>
 519
 520 If this is true, then the reader will dereference the value when it is
 521 called. The attribute must have a type constraint which defines the
 522 attribute as an array or hash reference.
 523
 524 =item C<< lazy_build => Bool >>
 525
 526 Setting this to true makes the attribute lazy and provides a number of
 527 default methods.
 528
 529   has 'size' => (
 530       is         => 'ro',
 531       lazy_build => 1,
 532   );
 533
 534 is equivalent to this:
 535
 536   has 'size' => (
 537       is        => 'ro',
 538       lazy      => 1,
 539       builder   => '_build_size',
 540       clearer   => 'clear_size',
 541       predicate => 'has_size',
 542   );
 543
 544 =back
 545
 546 =head2 C<< associate_method(Method) >>
 547
 548 Associates a method with the attribute. Typically, this is called internally
 549 when an attribute generates its accessors.
 550
 551 Currently the argument I<Method> is ignored in Mouse.
 552
 553 =head2 C<< verify_against_type_constraint(Item) -> TRUE | ERROR >>
 554
 555 Checks that the given value passes this attribute's type constraint. Returns C<true>
 556 on success, otherwise C<confess>es.
 557
 558 =head2 C<< clone_and_inherit_options(options) -> Mouse::Meta::Attribute >>
 559
 560 Creates a new attribute in the owner class, inheriting options from parent classes.
 561 Accessors and helper methods are installed. Some error checking is done.
 562
 563 =head2 C<< get_read_method_ref >>
 564
 565 =head2 C<< get_write_method_ref >>
 566
 567 Returns the subroutine reference of a method suitable for reading or
 568 writing the attribute's value in the associated class. These methods
 569 always return a subroutine reference, regardless of whether or not the
 570 attribute is read- or write-only.
 571
 572 =head1 SEE ALSO
 573
 574 L<Moose::Meta::Attribute>
 575
 576 L<Class::MOP::Attribute>
 577
 578 =cut
 579