lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use strict;
   3 use warnings;
   4
   5 use Carp ();
   6
   7 use Mouse::Util qw(:meta);
   8
   9 use Mouse::Meta::TypeConstraint;
  10 use Mouse::Meta::Method::Accessor;
  11
  12 sub _process_options{
  13     my($class, $name, $args) = @_;
  14
  15     # taken from Class::MOP::Attribute::new
  16
  17     defined($name)
  18         or $class->throw_error('You must provide a name for the attribute');
  19
  20     if(!exists $args->{init_arg}){
  21         $args->{init_arg} = $name;
  22     }
  23
  24     # 'required' requires eigher 'init_arg', 'builder', or 'default'
  25     my $can_be_required = defined( $args->{init_arg} );
  26
  27     if(exists $args->{builder}){
  28         $class->throw_error('builder must be a defined scalar value which is a method name')
  29             if ref $args->{builder} || !(defined $args->{builder});
  30
  31         $can_be_required++;
  32     }
  33     elsif(exists $args->{default}){
  34         if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
  35             $class->throw_error("References are not allowed as default values, you must "
  36                               . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
  37         }
  38         $can_be_required++;
  39     }
  40
  41     if( $args->{required} && !$can_be_required ) {
  42         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
  43     }
  44
  45     # taken from Mouse::Meta::Attribute->new and _process_args->
  46
  47     if(exists $args->{is}){
  48         my $is = $args->{is};
  49
  50         if($is eq 'ro'){
  51             $args->{reader} ||= $name;
  52         }
  53         elsif($is eq 'rw'){
  54             if(exists $args->{writer}){
  55                 $args->{reader} ||= $name;
  56              }
  57              else{
  58                 $args->{accessor} ||= $name;
  59              }
  60         }
  61         elsif($is eq 'bare'){
  62             # do nothing, but don't complain (later) about missing methods
  63         }
  64         else{
  65             $is = 'undef' if !defined $is;
  66             $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
  67         }
  68     }
  69
  70     my $tc;
  71     if(exists $args->{isa}){
  72         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
  73     }
  74     elsif(exists $args->{does}){
  75         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
  76     }
  77     $tc = $args->{type_constraint};
  78
  79     if($args->{coerce}){
  80         defined($tc)
  81             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
  82
  83         $args->{weak_ref}
  84             && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
  85     }
  86
  87     if ($args->{lazy_build}) {
  88         exists($args->{default})
  89             && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
  90
  91         $args->{lazy}      = 1;
  92         $args->{builder} ||= "_build_${name}";
  93         if ($name =~ /^_/) {
  94             $args->{clearer}   ||= "_clear${name}";
  95             $args->{predicate} ||= "_has${name}";
  96         }
  97         else {
  98             $args->{clearer}   ||= "clear_${name}";
  99             $args->{predicate} ||= "has_${name}";
 100         }
 101     }
 102
 103     if ($args->{auto_deref}) {
 104         defined($tc)
 105             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
 106
 107         ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
 108             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
 109     }
 110
 111     if (exists $args->{trigger}) {
 112         ('CODE' eq ref $args->{trigger})
 113             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
 114     }
 115
 116     if ($args->{lazy}) {
 117         (exists $args->{default} || defined $args->{builder})
 118             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
 119     }
 120
 121     # XXX: for backward compatibility (with method modifiers)
 122     if($class->can('canonicalize_args') != \&canonicalize_args){
 123         %{$args} = $class->canonicalize_args($name, %{$args});
 124     }
 125     return;
 126 }
 127
 128 sub new {
 129     my $class = shift;
 130     my $name  = shift;
 131
 132     my %args  = (@_ == 1) ? %{ $_[0] } : @_;
 133
 134     $class->_process_options($name, \%args);
 135
 136     $args{name} = $name;
 137
 138     my $instance = bless \%args, $class;
 139
 140     # extra attributes
 141     if($class ne __PACKAGE__){
 142         $class->meta->_initialize_instance($instance,\%args);
 143     }
 144
 145 # XXX: there is no fast way to check attribute validity
 146 #    my @bad = ...;
 147 #    if(@bad){
 148 #        @bad = sort @bad;
 149 #        Carp::cluck("Found unknown argument(s) passed to '$name' attribute constructor in '$class': @bad");
 150 #    }
 151
 152     return $instance
 153 }
 154
 155 # readers
 156
 157 sub name                 { $_[0]->{name}                   }
 158 sub associated_class     { $_[0]->{associated_class}       }
 159
 160 sub accessor             { $_[0]->{accessor}               }
 161 sub reader               { $_[0]->{reader}                 }
 162 sub writer               { $_[0]->{writer}                 }
 163 sub predicate            { $_[0]->{predicate}              }
 164 sub clearer              { $_[0]->{clearer}                }
 165 sub handles              { $_[0]->{handles}                }
 166
 167 sub _is_metadata         { $_[0]->{is}                     }
 168 sub is_required          { $_[0]->{required}               }
 169 sub default              { $_[0]->{default}                }
 170 sub is_lazy              { $_[0]->{lazy}                   }
 171 sub is_lazy_build        { $_[0]->{lazy_build}             }
 172 sub is_weak_ref          { $_[0]->{weak_ref}               }
 173 sub init_arg             { $_[0]->{init_arg}               }
 174 sub type_constraint      { $_[0]->{type_constraint}        }
 175
 176 sub trigger              { $_[0]->{trigger}                }
 177 sub builder              { $_[0]->{builder}                }
 178 sub should_auto_deref    { $_[0]->{auto_deref}             }
 179 sub should_coerce        { $_[0]->{coerce}                 }
 180
 181 sub get_read_method      { $_[0]->{reader} || $_[0]->{accessor} }
 182 sub get_write_method     { $_[0]->{writer} || $_[0]->{accessor} }
 183
 184 # predicates
 185
 186 sub has_accessor         { exists $_[0]->{accessor}        }
 187 sub has_reader           { exists $_[0]->{reader}          }
 188 sub has_writer           { exists $_[0]->{writer}          }
 189 sub has_predicate        { exists $_[0]->{predicate}       }
 190 sub has_clearer          { exists $_[0]->{clearer}         }
 191 sub has_handles          { exists $_[0]->{handles}         }
 192
 193 sub has_default          { exists $_[0]->{default}         }
 194 sub has_type_constraint  { exists $_[0]->{type_constraint} }
 195 sub has_trigger          { exists $_[0]->{trigger}         }
 196 sub has_builder          { exists $_[0]->{builder}         }
 197
 198 sub has_read_method      { exists $_[0]->{reader} || exists $_[0]->{accessor} }
 199 sub has_write_method     { exists $_[0]->{writer} || exists $_[0]->{accessor} }
 200
 201 sub _create_args {
 202     $_[0]->{_create_args} = $_[1] if @_ > 1;
 203     $_[0]->{_create_args}
 204 }
 205
 206 sub interpolate_class{
 207     my($class, $name, $args) = @_;
 208
 209     if(my $metaclass = delete $args->{metaclass}){
 210         $class = Mouse::Util::resolve_metaclass_alias( Attribute => $metaclass );
 211     }
 212
 213     my @traits;
 214     if(my $traits_ref = delete $args->{traits}){
 215
 216         for (my $i = 0; $i < @{$traits_ref}; $i++) {
 217             my $trait = Mouse::Util::resolve_metaclass_alias(Attribute => $traits_ref->[$i], trait => 1);
 218
 219             next if $class->does($trait);
 220
 221             push @traits, $trait;
 222
 223             # are there options?
 224             push @traits, $traits_ref->[++$i]
 225                 if ref($traits_ref->[$i+1]);
 226         }
 227
 228         if (@traits) {
 229             $class = Mouse::Meta::Class->create_anon_class(
 230                 superclasses => [ $class ],
 231                 roles        => \@traits,
 232                 cache        => 1,
 233             )->name;
 234         }
 235     }
 236
 237     return( $class, @traits );
 238 }
 239
 240 sub canonicalize_args{
 241     my ($self, $name, %args) = @_;
 242
 243     Carp::cluck("$self->canonicalize_args has been deprecated."
 244         . "Use \$self->_process_options instead.");
 245
 246     return %args;
 247 }
 248
 249 sub create {
 250     my ($self, $class, $name, %args) = @_;
 251
 252     Carp::cluck("$self->create has been deprecated."
 253         . "Use \$meta->add_attribute and \$attr->install_accessors instead.");
 254
 255     # noop
 256     return $self;
 257 }
 258
 259 sub verify_against_type_constraint {
 260     my ($self, $value) = @_;
 261     my $tc = $self->type_constraint;
 262     return 1 unless $tc;
 263
 264     local $_ = $value;
 265     return 1 if $tc->check($value);
 266
 267     $self->verify_type_constraint_error($self->name, $value, $tc);
 268 }
 269
 270 sub verify_type_constraint_error {
 271     my($self, $name, $value, $type) = @_;
 272     $self->throw_error("Attribute ($name) does not pass the type constraint because: " . $type->get_message($value));
 273 }
 274
 275 sub coerce_constraint { ## my($self, $value) = @_;
 276     my $type = $_[0]->{type_constraint}
 277         or return $_[1];
 278     return Mouse::Util::TypeConstraints->typecast_constraints($_[0]->associated_class->name, $type, $_[1]);
 279 }
 280
 281 sub _canonicalize_handles {
 282     my $self    = shift;
 283     my $handles = shift;
 284
 285     if (ref($handles) eq 'HASH') {
 286         return %$handles;
 287     }
 288     elsif (ref($handles) eq 'ARRAY') {
 289         return map { $_ => $_ } @$handles;
 290     }
 291     else {
 292         $self->throw_error("Unable to canonicalize the 'handles' option with $handles");
 293     }
 294 }
 295
 296 sub clone_and_inherit_options{
 297     my $self = shift;
 298     my $name = shift;
 299
 300     return ref($self)->new($name, %{$self}, (@_ == 1) ? %{$_[0]} : @_);
 301 }
 302
 303 sub clone_parent {
 304     my $self  = shift;
 305     my $class = shift;
 306     my $name  = shift;
 307     my %args  = ($self->get_parent_args($class, $name), @_);
 308
 309     Carp::cluck("$self->clone_parent has been deprecated."
 310         . "Use \$meta->add_attribute and \$attr->install_accessors instead.");
 311
 312
 313     $self->clone_and_inherited_args($class, $name, %args);
 314 }
 315
 316 sub get_parent_args {
 317     my $self  = shift;
 318     my $class = shift;
 319     my $name  = shift;
 320
 321     for my $super ($class->linearized_isa) {
 322         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 323             or next;
 324         return %{ $super_attr->_create_args };
 325     }
 326
 327     $self->throw_error("Could not find an attribute by the name of '$name' to inherit from");
 328 }
 329
 330 sub install_accessors{
 331     my($attribute) = @_;
 332
 333     my $metaclass       = $attribute->{associated_class};
 334
 335     foreach my $type(qw(accessor reader writer predicate clearer handles)){
 336         if(exists $attribute->{$type}){
 337             my $installer    = '_install_' . $type;
 338
 339             Mouse::Meta::Method::Accessor->$installer($attribute, $attribute->{$type}, $metaclass);
 340
 341             $attribute->{associated_methods}++;
 342         }
 343     }
 344
 345     if($attribute->can('create') != \&create){
 346         # backword compatibility
 347         $attribute->create($metaclass, $attribute->name, %{$attribute});
 348     }
 349
 350     return;
 351 }
 352
 353 sub throw_error{
 354     my $self = shift;
 355
 356     my $metaclass = (ref $self && $self->associated_class) || 'Mouse::Meta::Class';
 357     $metaclass->throw_error(@_, depth => 1);
 358 }
 359
 360 1;
 361
 362 __END__
 363
 364 =head1 NAME
 365
 366 Mouse::Meta::Attribute - attribute metaclass
 367
 368 =head1 METHODS
 369
 370 =head2 C<< new(%options) -> Mouse::Meta::Attribute >>
 371
 372 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 373
 374 It adds the following options to the constructor:
 375
 376 =over 4
 377
 378 =item * C<< is => 'ro', 'rw', 'bare' >>
 379
 380 This provides a shorthand for specifying the C<reader>, C<writer>, or
 381 C<accessor> names. If the attribute is read-only ('ro') then it will
 382 have a C<reader> method with the same attribute as the name.
 383
 384 If it is read-write ('rw') then it will have an C<accessor> method
 385 with the same name. If you provide an explicit C<writer> for a
 386 read-write attribute, then you will have a C<reader> with the same
 387 name as the attribute, and a C<writer> with the name you provided.
 388
 389 Use 'bare' when you are deliberately not installing any methods
 390 (accessor, reader, etc.) associated with this attribute; otherwise,
 391 Moose will issue a deprecation warning when this attribute is added to a
 392 metaclass.
 393
 394 =item * C<< isa => Type >>
 395
 396 This option accepts a type. The type can be a string, which should be
 397 a type name. If the type name is unknown, it is assumed to be a class
 398 name.
 399
 400 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 401
 402 If you I<also> provide a C<does> option, then your C<isa> option must
 403 be a class name, and that class must do the role specified with
 404 C<does>.
 405
 406 =item * C<< does => Role >>
 407
 408 This is short-hand for saying that the attribute's type must be an
 409 object which does the named role.
 410
 411 B<This option is not yet supported.>
 412
 413 =item * C<< coerce => Bool >>
 414
 415 This option is only valid for objects with a type constraint
 416 (C<isa>). If this is true, then coercions will be applied whenever
 417 this attribute is set.
 418
 419 You can make both this and the C<weak_ref> option true.
 420
 421 =item * C<< trigger => CodeRef >>
 422
 423 This option accepts a subroutine reference, which will be called after
 424 the attribute is set.
 425
 426 =item * C<< required => Bool >>
 427
 428 An attribute which is required must be provided to the constructor. An
 429 attribute which is required can also have a C<default> or C<builder>,
 430 which will satisfy its required-ness.
 431
 432 A required attribute must have a C<default>, C<builder> or a
 433 non-C<undef> C<init_arg>
 434
 435 =item * C<< lazy => Bool >>
 436
 437 A lazy attribute must have a C<default> or C<builder>. When an
 438 attribute is lazy, the default value will not be calculated until the
 439 attribute is read.
 440
 441 =item * C<< weak_ref => Bool >>
 442
 443 If this is true, the attribute's value will be stored as a weak
 444 reference.
 445
 446 =item * C<< auto_deref => Bool >>
 447
 448 If this is true, then the reader will dereference the value when it is
 449 called. The attribute must have a type constraint which defines the
 450 attribute as an array or hash reference.
 451
 452 =item * C<< lazy_build => Bool >>
 453
 454 Setting this to true makes the attribute lazy and provides a number of
 455 default methods.
 456
 457   has 'size' => (
 458       is         => 'ro',
 459       lazy_build => 1,
 460   );
 461
 462 is equivalent to this:
 463
 464   has 'size' => (
 465       is        => 'ro',
 466       lazy      => 1,
 467       builder   => '_build_size',
 468       clearer   => 'clear_size',
 469       predicate => 'has_size',
 470   );
 471
 472 =back
 473
 474 =head2 C<< verify_against_type_constraint(Item) -> TRUE | ERROR >>
 475
 476 Checks that the given value passes this attribute's type constraint. Returns C<true>
 477 on success, otherwise C<confess>es.
 478
 479 =head2 C<< clone_and_inherit_options(options) -> Mouse::Meta::Attribute >>
 480
 481 Creates a new attribute in OwnerClass, inheriting options from parent classes.
 482 Accessors and helper methods are installed. Some error checking is done.
 483
 484 =head1 SEE ALSO
 485
 486 L<Moose::Meta::Attribute>
 487
 488 =cut
 489