lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use Mouse::Util qw(:meta); # enables strict and warnings
   3
   4 use Carp ();
   5
   6 use Mouse::Meta::TypeConstraint;
   7 use Mouse::Meta::Method::Accessor;
   8
   9
  10 sub _process_options{
  11     my($class, $name, $args) = @_;
  12
  13
  14     # XXX: for backward compatibility (with method modifiers)
  15     if($class->can('canonicalize_args') != \&canonicalize_args){
  16         %{$args} = $class->canonicalize_args($name, %{$args});
  17     }
  18
  19     # taken from Class::MOP::Attribute::new
  20
  21     defined($name)
  22         or $class->throw_error('You must provide a name for the attribute');
  23
  24     if(!exists $args->{init_arg}){
  25         $args->{init_arg} = $name;
  26     }
  27
  28     # 'required' requires eigher 'init_arg', 'builder', or 'default'
  29     my $can_be_required = defined( $args->{init_arg} );
  30
  31     if(exists $args->{builder}){
  32         # XXX:
  33         # Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
  34         # This feature will be changed in a future. (gfx)
  35         $class->throw_error('builder must be a defined scalar value which is a method name')
  36             #if ref $args->{builder} || !defined $args->{builder};
  37             if !defined $args->{builder};
  38
  39         $can_be_required++;
  40     }
  41     elsif(exists $args->{default}){
  42         if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
  43             $class->throw_error("References are not allowed as default values, you must "
  44                               . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
  45         }
  46         $can_be_required++;
  47     }
  48
  49     if( $args->{required} && !$can_be_required ) {
  50         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
  51     }
  52
  53     # taken from Mouse::Meta::Attribute->new and _process_args->
  54
  55     if(exists $args->{is}){
  56         my $is = $args->{is};
  57
  58         if($is eq 'ro'){
  59             $args->{reader} ||= $name;
  60         }
  61         elsif($is eq 'rw'){
  62             if(exists $args->{writer}){
  63                 $args->{reader} ||= $name;
  64              }
  65              else{
  66                 $args->{accessor} ||= $name;
  67              }
  68         }
  69         elsif($is eq 'bare'){
  70             # do nothing, but don't complain (later) about missing methods
  71         }
  72         else{
  73             $is = 'undef' if !defined $is;
  74             $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
  75         }
  76     }
  77
  78     my $tc;
  79     if(exists $args->{isa}){
  80         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
  81     }
  82     elsif(exists $args->{does}){
  83         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
  84     }
  85     $tc = $args->{type_constraint};
  86
  87     if($args->{coerce}){
  88         defined($tc)
  89             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
  90
  91         $args->{weak_ref}
  92             && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
  93     }
  94
  95     if ($args->{lazy_build}) {
  96         exists($args->{default})
  97             && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
  98
  99         $args->{lazy}      = 1;
 100         $args->{builder} ||= "_build_${name}";
 101         if ($name =~ /^_/) {
 102             $args->{clearer}   ||= "_clear${name}";
 103             $args->{predicate} ||= "_has${name}";
 104         }
 105         else {
 106             $args->{clearer}   ||= "clear_${name}";
 107             $args->{predicate} ||= "has_${name}";
 108         }
 109     }
 110
 111     if ($args->{auto_deref}) {
 112         defined($tc)
 113             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
 114
 115         ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
 116             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
 117     }
 118
 119     if (exists $args->{trigger}) {
 120         ('CODE' eq ref $args->{trigger})
 121             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
 122     }
 123
 124     if ($args->{lazy}) {
 125         (exists $args->{default} || defined $args->{builder})
 126             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
 127     }
 128
 129     return;
 130 }
 131
 132 sub new {
 133     my $class = shift;
 134     my $name  = shift;
 135
 136     my %args  = (@_ == 1) ? %{ $_[0] } : @_;
 137
 138     $class->_process_options($name, \%args);
 139
 140     $args{name} = $name;
 141
 142     my $self = bless \%args, $class;
 143
 144     # extra attributes
 145     if($class ne __PACKAGE__){
 146         $class->meta->_initialize_object($self, \%args);
 147     }
 148
 149 # XXX: there is no fast way to check attribute validity
 150 #    my @bad = ...;
 151 #    if(@bad){
 152 #        @bad = sort @bad;
 153 #        Carp::cluck("Found unknown argument(s) passed to '$name' attribute constructor in '$class': @bad");
 154 #    }
 155
 156     return $self;
 157 }
 158
 159 sub has_read_method      { $_[0]->has_reader || $_[0]->has_accessor }
 160 sub has_write_method     { $_[0]->has_writer || $_[0]->has_accessor }
 161
 162 sub _create_args { # DEPRECATED
 163     $_[0]->{_create_args} = $_[1] if @_ > 1;
 164     $_[0]->{_create_args}
 165 }
 166
 167 sub interpolate_class{
 168     my($class, $args) = @_;
 169
 170     if(my $metaclass = delete $args->{metaclass}){
 171         $class = Mouse::Util::resolve_metaclass_alias( Attribute => $metaclass );
 172     }
 173
 174     my @traits;
 175     if(my $traits_ref = delete $args->{traits}){
 176
 177         for (my $i = 0; $i < @{$traits_ref}; $i++) {
 178             my $trait = Mouse::Util::resolve_metaclass_alias(Attribute => $traits_ref->[$i], trait => 1);
 179
 180             next if $class->does($trait);
 181
 182             push @traits, $trait;
 183
 184             # are there options?
 185             push @traits, $traits_ref->[++$i]
 186                 if ref($traits_ref->[$i+1]);
 187         }
 188
 189         if (@traits) {
 190             $class = Mouse::Meta::Class->create_anon_class(
 191                 superclasses => [ $class ],
 192                 roles        => \@traits,
 193                 cache        => 1,
 194             )->name;
 195         }
 196     }
 197
 198     return( $class, @traits );
 199 }
 200
 201 sub canonicalize_args{ # DEPRECATED
 202     my ($self, $name, %args) = @_;
 203
 204     Carp::cluck("$self->canonicalize_args has been deprecated."
 205         . "Use \$self->_process_options instead.")
 206             if _MOUSE_VERBOSE;
 207
 208     return %args;
 209 }
 210
 211 sub create { # DEPRECATED
 212     my ($self, $class, $name, %args) = @_;
 213
 214     Carp::cluck("$self->create has been deprecated."
 215         . "Use \$meta->add_attribute and \$attr->install_accessors instead.")
 216             if _MOUSE_VERBOSE;
 217
 218     # noop
 219     return $self;
 220 }
 221
 222 sub _coerce_and_verify {
 223     my($self, $value, $instance) = @_;
 224
 225     my $type_constraint = $self->{type_constraint};
 226     return $value if !defined $type_constraint;
 227
 228     if ($self->should_coerce && $type_constraint->has_coercion) {
 229         $value = $type_constraint->coerce($value);
 230     }
 231
 232     $self->verify_against_type_constraint($value);
 233
 234     return $value;
 235 }
 236
 237 sub verify_against_type_constraint {
 238     my ($self, $value) = @_;
 239
 240     my $type_constraint = $self->{type_constraint};
 241     return 1 if !$type_constraint;
 242     return 1 if $type_constraint->check($value);
 243
 244     $self->verify_type_constraint_error($self->name, $value, $type_constraint);
 245 }
 246
 247 sub verify_type_constraint_error {
 248     my($self, $name, $value, $type) = @_;
 249     $self->throw_error("Attribute ($name) does not pass the type constraint because: "
 250         . $type->get_message($value));
 251 }
 252
 253 sub coerce_constraint { # DEPRECATED
 254     my $type = $_[0]->{type_constraint}
 255         or return $_[1];
 256
 257     Carp::cluck("coerce_constraint() has been deprecated, which was an internal utility anyway");
 258
 259     return Mouse::Util::TypeConstraints->typecast_constraints($_[0]->associated_class->name, $type, $_[1]);
 260 }
 261
 262 sub clone_and_inherit_options{
 263     my($self, %args) = @_;
 264
 265     my($attribute_class, @traits) = ref($self)->interpolate_class(\%args);
 266
 267     $args{traits} = \@traits if @traits;
 268     return $attribute_class->new($self->name, %{$self}, %args);
 269 }
 270
 271 sub clone_parent { # DEPRECATED
 272     my $self  = shift;
 273     my $class = shift;
 274     my $name  = shift;
 275     my %args  = ($self->get_parent_args($class, $name), @_);
 276
 277     Carp::cluck("$self->clone_parent has been deprecated."
 278         . "Use \$meta->add_attribute and \$attr->install_accessors instead.")
 279         if _MOUSE_VERBOSE;
 280
 281     $self->clone_and_inherited_args($class, $name, %args);
 282 }
 283
 284 sub get_parent_args { # DEPRECATED
 285     my $self  = shift;
 286     my $class = shift;
 287     my $name  = shift;
 288
 289     for my $super ($class->linearized_isa) {
 290         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 291             or next;
 292         return %{ $super_attr->_create_args };
 293     }
 294
 295     $self->throw_error("Could not find an attribute by the name of '$name' to inherit from");
 296 }
 297
 298
 299 sub get_read_method {
 300     $_[0]->reader || $_[0]->accessor
 301 }
 302 sub get_write_method {
 303     $_[0]->writer || $_[0]->accessor
 304 }
 305
 306 sub get_read_method_ref{
 307     my($self) = @_;
 308
 309     $self->{_read_method_ref} ||= do{
 310         my $metaclass = $self->associated_class
 311             or $self->throw_error('No asocciated class for ' . $self->name);
 312
 313         my $reader = $self->{reader} || $self->{accessor};
 314         if($reader){
 315             $metaclass->name->can($reader);
 316         }
 317         else{
 318             $self->accessor_metaclass->_generate_reader($self, $metaclass);
 319         }
 320     };
 321 }
 322
 323 sub get_write_method_ref{
 324     my($self) = @_;
 325
 326     $self->{_write_method_ref} ||= do{
 327         my $metaclass = $self->associated_class
 328             or $self->throw_error('No asocciated class for ' . $self->name);
 329
 330         my $reader = $self->{writer} || $self->{accessor};
 331         if($reader){
 332             $metaclass->name->can($reader);
 333         }
 334         else{
 335             $self->accessor_metaclass->_generate_writer($self, $metaclass);
 336         }
 337     };
 338 }
 339
 340 sub _canonicalize_handles {
 341     my($self, $handles) = @_;
 342
 343     if (ref($handles) eq 'HASH') {
 344         return %$handles;
 345     }
 346     elsif (ref($handles) eq 'ARRAY') {
 347         return map { $_ => $_ } @$handles;
 348     }
 349     elsif (ref($handles) eq 'Regexp') {
 350         my $class_or_role = ($self->{isa} || $self->{does})
 351             || $self->throw_error("Cannot delegate methods based on a Regexp without a type constraint (isa)");
 352
 353         my $meta = Mouse::Meta::Class->initialize("$class_or_role"); # "" for stringify
 354         return map  { $_ => $_ }
 355                grep { $_ ne 'meta' && !Mouse::Object->can($_) && $_ =~ $handles }
 356                    Mouse::Util::TypeConstraints::_is_a_metarole($meta)
 357                         ? $meta->get_method_list
 358                         : $meta->get_all_method_names;
 359     }
 360     else {
 361         $self->throw_error("Unable to canonicalize the 'handles' option with $handles");
 362     }
 363 }
 364
 365 sub associate_method{
 366     my ($attribute, $method) = @_;
 367     $attribute->{associated_methods}++;
 368     return;
 369 }
 370
 371 sub install_accessors{
 372     my($attribute) = @_;
 373
 374     my $metaclass      = $attribute->associated_class;
 375     my $accessor_class = $attribute->accessor_metaclass;
 376
 377     foreach my $type(qw(accessor reader writer predicate clearer)){
 378         if(exists $attribute->{$type}){
 379             my $generator = '_generate_' . $type;
 380             my $code      = $accessor_class->$generator($attribute, $metaclass);
 381             $metaclass->add_method($attribute->{$type} => $code);
 382             $attribute->associate_method($code);
 383         }
 384     }
 385
 386     # install delegation
 387     if(exists $attribute->{handles}){
 388         my %handles = $attribute->_canonicalize_handles($attribute->{handles});
 389         my $reader  = $attribute->get_read_method_ref;
 390
 391         while(my($handle_name, $method_to_call) = each %handles){
 392             my $code = $accessor_class->_generate_delegation($attribute, $metaclass,
 393                 $reader, $handle_name, $method_to_call);
 394
 395             $metaclass->add_method($handle_name => $code);
 396             $attribute->associate_method($code);
 397         }
 398     }
 399
 400
 401     if($attribute->can('create') != \&create){
 402         # backword compatibility
 403         $attribute->create($metaclass, $attribute->name, %{$attribute});
 404     }
 405
 406     return;
 407 }
 408
 409 sub throw_error{
 410     my $self = shift;
 411
 412     my $metaclass = (ref $self && $self->associated_class) || 'Mouse::Meta::Class';
 413     $metaclass->throw_error(@_, depth => 1);
 414 }
 415
 416 1;
 417
 418 __END__
 419
 420 =head1 NAME
 421
 422 Mouse::Meta::Attribute - The Mouse attribute metaclass
 423
 424 =head1 VERSION
 425
 426 This document describes Mouse version 0.40_01
 427
 428 =head1 METHODS
 429
 430 =head2 C<< new(%options) -> Mouse::Meta::Attribute >>
 431
 432 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 433
 434 It adds the following options to the constructor:
 435
 436 =over 4
 437
 438 =item C<< is => 'ro', 'rw', 'bare' >>
 439
 440 This provides a shorthand for specifying the C<reader>, C<writer>, or
 441 C<accessor> names. If the attribute is read-only ('ro') then it will
 442 have a C<reader> method with the same attribute as the name.
 443
 444 If it is read-write ('rw') then it will have an C<accessor> method
 445 with the same name. If you provide an explicit C<writer> for a
 446 read-write attribute, then you will have a C<reader> with the same
 447 name as the attribute, and a C<writer> with the name you provided.
 448
 449 Use 'bare' when you are deliberately not installing any methods
 450 (accessor, reader, etc.) associated with this attribute; otherwise,
 451 Moose will issue a deprecation warning when this attribute is added to a
 452 metaclass.
 453
 454 =item C<< isa => Type >>
 455
 456 This option accepts a type. The type can be a string, which should be
 457 a type name. If the type name is unknown, it is assumed to be a class
 458 name.
 459
 460 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 461
 462 If you I<also> provide a C<does> option, then your C<isa> option must
 463 be a class name, and that class must do the role specified with
 464 C<does>.
 465
 466 =item C<< does => Role >>
 467
 468 This is short-hand for saying that the attribute's type must be an
 469 object which does the named role.
 470
 471 B<This option is not yet supported.>
 472
 473 =item C<< coerce => Bool >>
 474
 475 This option is only valid for objects with a type constraint
 476 (C<isa>). If this is true, then coercions will be applied whenever
 477 this attribute is set.
 478
 479 You can make both this and the C<weak_ref> option true.
 480
 481 =item C<< trigger => CodeRef >>
 482
 483 This option accepts a subroutine reference, which will be called after
 484 the attribute is set.
 485
 486 =item C<< required => Bool >>
 487
 488 An attribute which is required must be provided to the constructor. An
 489 attribute which is required can also have a C<default> or C<builder>,
 490 which will satisfy its required-ness.
 491
 492 A required attribute must have a C<default>, C<builder> or a
 493 non-C<undef> C<init_arg>
 494
 495 =item C<< lazy => Bool >>
 496
 497 A lazy attribute must have a C<default> or C<builder>. When an
 498 attribute is lazy, the default value will not be calculated until the
 499 attribute is read.
 500
 501 =item C<< weak_ref => Bool >>
 502
 503 If this is true, the attribute's value will be stored as a weak
 504 reference.
 505
 506 =item C<< auto_deref => Bool >>
 507
 508 If this is true, then the reader will dereference the value when it is
 509 called. The attribute must have a type constraint which defines the
 510 attribute as an array or hash reference.
 511
 512 =item C<< lazy_build => Bool >>
 513
 514 Setting this to true makes the attribute lazy and provides a number of
 515 default methods.
 516
 517   has 'size' => (
 518       is         => 'ro',
 519       lazy_build => 1,
 520   );
 521
 522 is equivalent to this:
 523
 524   has 'size' => (
 525       is        => 'ro',
 526       lazy      => 1,
 527       builder   => '_build_size',
 528       clearer   => 'clear_size',
 529       predicate => 'has_size',
 530   );
 531
 532 =back
 533
 534 =head2 C<< associate_method(Method) >>
 535
 536 Associates a method with the attribute. Typically, this is called internally
 537 when an attribute generates its accessors.
 538
 539 Currently the argument I<Method> is ignored in Mouse.
 540
 541 =head2 C<< verify_against_type_constraint(Item) -> TRUE | ERROR >>
 542
 543 Checks that the given value passes this attribute's type constraint. Returns C<true>
 544 on success, otherwise C<confess>es.
 545
 546 =head2 C<< clone_and_inherit_options(options) -> Mouse::Meta::Attribute >>
 547
 548 Creates a new attribute in the owner class, inheriting options from parent classes.
 549 Accessors and helper methods are installed. Some error checking is done.
 550
 551 =head2 C<< get_read_method_ref >>
 552
 553 =head2 C<< get_write_method_ref >>
 554
 555 Returns the subroutine reference of a method suitable for reading or
 556 writing the attribute's value in the associated class. These methods
 557 always return a subroutine reference, regardless of whether or not the
 558 attribute is read- or write-only.
 559
 560 =head1 SEE ALSO
 561
 562 L<Moose::Meta::Attribute>
 563
 564 L<Class::MOP::Attribute>
 565
 566 =cut
 567