lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use Mouse::Util qw(:meta); # enables strict and warnings
   3
   4 use Carp ();
   5
   6 use Mouse::Meta::TypeConstraint;
   7
   8 sub _process_options{
   9     my($class, $name, $args) = @_;
  10
  11     # XXX: for backward compatibility (with method modifiers)
  12     if($class->can('canonicalize_args') != \&canonicalize_args){
  13         %{$args} = $class->canonicalize_args($name, %{$args});
  14     }
  15
  16     # taken from Class::MOP::Attribute::new
  17
  18     defined($name)
  19         or $class->throw_error('You must provide a name for the attribute');
  20
  21     if(!exists $args->{init_arg}){
  22         $args->{init_arg} = $name;
  23     }
  24
  25     # 'required' requires eigher 'init_arg', 'builder', or 'default'
  26     my $can_be_required = defined( $args->{init_arg} );
  27
  28     if(exists $args->{builder}){
  29         # XXX:
  30         # Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
  31         # This feature will be changed in a future. (gfx)
  32         $class->throw_error('builder must be a defined scalar value which is a method name')
  33             #if ref $args->{builder} || !defined $args->{builder};
  34             if !defined $args->{builder};
  35
  36         $can_be_required++;
  37     }
  38     elsif(exists $args->{default}){
  39         if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
  40             $class->throw_error("References are not allowed as default values, you must "
  41                               . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
  42         }
  43         $can_be_required++;
  44     }
  45
  46     if( $args->{required} && !$can_be_required ) {
  47         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
  48     }
  49
  50     # taken from Mouse::Meta::Attribute->new and _process_args->
  51
  52     if(exists $args->{is}){
  53         my $is = $args->{is};
  54
  55         if($is eq 'ro'){
  56             $args->{reader} ||= $name;
  57         }
  58         elsif($is eq 'rw'){
  59             if(exists $args->{writer}){
  60                 $args->{reader} ||= $name;
  61              }
  62              else{
  63                 $args->{accessor} ||= $name;
  64              }
  65         }
  66         elsif($is eq 'bare'){
  67             # do nothing, but don't complain (later) about missing methods
  68         }
  69         else{
  70             $is = 'undef' if !defined $is;
  71             $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
  72         }
  73     }
  74
  75     my $tc;
  76     if(exists $args->{isa}){
  77         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
  78     }
  79     elsif(exists $args->{does}){
  80         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
  81     }
  82     $tc = $args->{type_constraint};
  83
  84     if($args->{coerce}){
  85         defined($tc)
  86             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
  87
  88         $args->{weak_ref}
  89             && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
  90     }
  91
  92     if ($args->{lazy_build}) {
  93         exists($args->{default})
  94             && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
  95
  96         $args->{lazy}      = 1;
  97         $args->{builder} ||= "_build_${name}";
  98         if ($name =~ /^_/) {
  99             $args->{clearer}   ||= "_clear${name}";
 100             $args->{predicate} ||= "_has${name}";
 101         }
 102         else {
 103             $args->{clearer}   ||= "clear_${name}";
 104             $args->{predicate} ||= "has_${name}";
 105         }
 106     }
 107
 108     if ($args->{auto_deref}) {
 109         defined($tc)
 110             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
 111
 112         ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
 113             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
 114     }
 115
 116     if (exists $args->{trigger}) {
 117         ('CODE' eq ref $args->{trigger})
 118             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
 119     }
 120
 121     if ($args->{lazy}) {
 122         (exists $args->{default} || defined $args->{builder})
 123             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
 124     }
 125
 126     return;
 127 }
 128
 129 sub new {
 130     my $class = shift;
 131     my $name  = shift;
 132
 133     my %args  = (@_ == 1) ? %{ $_[0] } : @_;
 134
 135     $class->_process_options($name, \%args);
 136
 137     $args{name} = $name;
 138
 139     my $self = bless \%args, $class;
 140
 141     # extra attributes
 142     if($class ne __PACKAGE__){
 143         $class->meta->_initialize_object($self, \%args);
 144     }
 145
 146 # XXX: there is no fast way to check attribute validity
 147 #    my @bad = ...;
 148 #    if(@bad){
 149 #        @bad = sort @bad;
 150 #        Carp::cluck("Found unknown argument(s) passed to '$name' attribute constructor in '$class': @bad");
 151 #    }
 152
 153     return $self;
 154 }
 155
 156 sub has_read_method      { $_[0]->has_reader || $_[0]->has_accessor }
 157 sub has_write_method     { $_[0]->has_writer || $_[0]->has_accessor }
 158
 159 sub _create_args { # DEPRECATED
 160     $_[0]->{_create_args} = $_[1] if @_ > 1;
 161     $_[0]->{_create_args}
 162 }
 163
 164 sub interpolate_class{
 165     my($class, $args) = @_;
 166
 167     if(my $metaclass = delete $args->{metaclass}){
 168         $class = Mouse::Util::resolve_metaclass_alias( Attribute => $metaclass );
 169     }
 170
 171     my @traits;
 172     if(my $traits_ref = delete $args->{traits}){
 173
 174         for (my $i = 0; $i < @{$traits_ref}; $i++) {
 175             my $trait = Mouse::Util::resolve_metaclass_alias(Attribute => $traits_ref->[$i], trait => 1);
 176
 177             next if $class->does($trait);
 178
 179             push @traits, $trait;
 180
 181             # are there options?
 182             push @traits, $traits_ref->[++$i]
 183                 if ref($traits_ref->[$i+1]);
 184         }
 185
 186         if (@traits) {
 187             $class = Mouse::Meta::Class->create_anon_class(
 188                 superclasses => [ $class ],
 189                 roles        => \@traits,
 190                 cache        => 1,
 191             )->name;
 192         }
 193     }
 194
 195     return( $class, @traits );
 196 }
 197
 198 sub canonicalize_args{ # DEPRECATED
 199     my ($self, $name, %args) = @_;
 200
 201     Carp::cluck("$self->canonicalize_args has been deprecated."
 202         . "Use \$self->_process_options instead.");
 203
 204     return %args;
 205 }
 206
 207 sub create { # DEPRECATED
 208     my ($self, $class, $name, %args) = @_;
 209
 210     Carp::cluck("$self->create has been deprecated."
 211         . "Use \$meta->add_attribute and \$attr->install_accessors instead.");
 212
 213     # noop
 214     return $self;
 215 }
 216
 217 sub _coerce_and_verify {
 218     my($self, $value, $instance) = @_;
 219
 220     my $type_constraint = $self->{type_constraint};
 221     return $value if !defined $type_constraint;
 222
 223     if ($self->should_coerce && $type_constraint->has_coercion) {
 224         $value = $type_constraint->coerce($value);
 225     }
 226
 227     $self->verify_against_type_constraint($value);
 228
 229     return $value;
 230 }
 231
 232 sub verify_against_type_constraint {
 233     my ($self, $value) = @_;
 234
 235     my $type_constraint = $self->{type_constraint};
 236     return 1 if !$type_constraint;
 237     return 1 if $type_constraint->check($value);
 238
 239     $self->_throw_type_constraint_error($value, $type_constraint);
 240 }
 241
 242 sub _throw_type_constraint_error {
 243     my($self, $value, $type) = @_;
 244
 245     $self->throw_error(
 246         sprintf q{Attribute (%s) does not pass the type constraint because: %s},
 247             $self->name,
 248             $type->get_message($value),
 249     );
 250 }
 251
 252 sub clone_and_inherit_options{
 253     my($self, %args) = @_;
 254
 255     my($attribute_class, @traits) = ref($self)->interpolate_class(\%args);
 256
 257     $args{traits} = \@traits if @traits;
 258     # do not inherit the 'handles' attribute
 259     foreach my $name(keys %{$self}){
 260         if(!exists $args{$name} && $name ne 'handles'){
 261             $args{$name} = $self->{$name};
 262         }
 263     }
 264     return $attribute_class->new($self->name, %args);
 265 }
 266
 267 sub clone_parent { # DEPRECATED
 268     my $self  = shift;
 269     my $class = shift;
 270     my $name  = shift;
 271     my %args  = ($self->get_parent_args($class, $name), @_);
 272
 273     Carp::cluck("$self->clone_parent has been deprecated."
 274         . "Use \$meta->add_attribute and \$attr->install_accessors instead.");
 275
 276     $self->clone_and_inherited_args($class, $name, %args);
 277 }
 278
 279 sub get_parent_args { # DEPRECATED
 280     my $self  = shift;
 281     my $class = shift;
 282     my $name  = shift;
 283
 284     for my $super ($class->linearized_isa) {
 285         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 286             or next;
 287         return %{ $super_attr->_create_args };
 288     }
 289
 290     $self->throw_error("Could not find an attribute by the name of '$name' to inherit from");
 291 }
 292
 293
 294 sub get_read_method {
 295     return $_[0]->reader || $_[0]->accessor
 296 }
 297 sub get_write_method {
 298     return $_[0]->writer || $_[0]->accessor
 299 }
 300
 301 sub _get_accessor_method_ref {
 302     my($self, $type, $generator) = @_;
 303
 304     my $metaclass = $self->associated_class
 305         || $self->throw_error('No asocciated class for ' . $self->name);
 306
 307     my $accessor = $self->$type();
 308     if($accessor){
 309         return $metaclass->get_method_body($accessor);
 310     }
 311     else{
 312         return $self->accessor_metaclass->$generator($self, $metaclass);
 313     }
 314 }
 315
 316 sub get_read_method_ref{
 317     my($self) = @_;
 318     return $self->{_read_method_ref} ||= $self->_get_accessor_method_ref('get_read_method', '_generate_reader');
 319 }
 320
 321 sub get_write_method_ref{
 322     my($self) = @_;
 323     return $self->{_write_method_ref} ||= $self->_get_accessor_method_ref('get_write_method', '_generate_writer');
 324 }
 325
 326 sub set_value {
 327     my($self, $object, $value) = @_;
 328     return $self->get_write_method_ref()->($object, $value);
 329 }
 330
 331 sub get_value {
 332     my($self, $object) = @_;
 333     return $self->get_read_method_ref()->($object);
 334 }
 335
 336 sub has_value {
 337     my($self, $object) = @_;
 338     my $accessor_ref = $self->{_predicate_ref}
 339         ||= $self->_get_accessor_method_ref('predicate', '_generate_predicate');
 340
 341     return $accessor_ref->($object);
 342 }
 343
 344 sub clear_value {
 345     my($self, $object) = @_;
 346     my $accessor_ref = $self->{_crealer_ref}
 347         ||= $self->_get_accessor_method_ref('clearer', '_generate_clearer');
 348
 349     return $accessor_ref->($object);
 350 }
 351
 352
 353 sub associate_method{
 354     my ($attribute, $method_name) = @_;
 355     $attribute->{associated_methods}++;
 356     return;
 357 }
 358
 359 sub install_accessors{
 360     my($attribute) = @_;
 361
 362     my $metaclass      = $attribute->associated_class;
 363     my $accessor_class = $attribute->accessor_metaclass;
 364
 365     foreach my $type(qw(accessor reader writer predicate clearer)){
 366         if(exists $attribute->{$type}){
 367             my $generator = '_generate_' . $type;
 368             my $code      = $accessor_class->$generator($attribute, $metaclass);
 369             $metaclass->add_method($attribute->{$type} => $code);
 370             $attribute->associate_method($attribute->{$type});
 371         }
 372     }
 373
 374     # install delegation
 375     if(exists $attribute->{handles}){
 376         my %handles = $attribute->_canonicalize_handles($attribute->{handles});
 377
 378         while(my($handle, $method_to_call) = each %handles){
 379             $metaclass->add_method($handle =>
 380                 $attribute->_make_delegation_method(
 381                     $handle, $method_to_call));
 382
 383             $attribute->associate_method($handle);
 384         }
 385     }
 386
 387     if($attribute->can('create') != \&create){
 388         # backword compatibility
 389         $attribute->create($metaclass, $attribute->name, %{$attribute});
 390     }
 391
 392     return;
 393 }
 394
 395 sub delegation_metaclass() { 'Mouse::Meta::Method::Delegation' }
 396
 397 sub _canonicalize_handles {
 398     my($self, $handles) = @_;
 399
 400     if (ref($handles) eq 'HASH') {
 401         return %$handles;
 402     }
 403     elsif (ref($handles) eq 'ARRAY') {
 404         return map { $_ => $_ } @$handles;
 405     }
 406     elsif ( ref($handles) eq 'CODE' ) {
 407         my $class_or_role = ( $self->{isa} || $self->{does} )
 408             || $self->throw_error( "Cannot find delegate metaclass for attribute " . $self->name );
 409         return $handles->( $self, Mouse::Meta::Class->initialize("$class_or_role"));
 410     }
 411     elsif (ref($handles) eq 'Regexp') {
 412         my $class_or_role = ($self->{isa} || $self->{does})
 413             || $self->throw_error("Cannot delegate methods based on a Regexp without a type constraint (isa)");
 414
 415         my $meta = Mouse::Meta::Class->initialize("$class_or_role"); # "" for stringify
 416         return map  { $_ => $_ }
 417                grep { !Mouse::Object->can($_) && $_ =~ $handles }
 418                    Mouse::Util::is_a_metarole($meta)
 419                         ? $meta->get_method_list
 420                         : $meta->get_all_method_names;
 421     }
 422     else {
 423         $self->throw_error("Unable to canonicalize the 'handles' option with $handles");
 424     }
 425 }
 426
 427 sub _make_delegation_method {
 428     my($self, $handle, $method_to_call) = @_;
 429     my $delegator = $self->delegation_metaclass;
 430     Mouse::Util::load_class($delegator);
 431
 432     return $delegator->_generate_delegation($self, $handle, $method_to_call);
 433 }
 434
 435 sub throw_error{
 436     my $self = shift;
 437
 438     my $metaclass = (ref $self && $self->associated_class) || 'Mouse::Meta::Class';
 439     $metaclass->throw_error(@_, depth => 1);
 440 }
 441
 442 1;
 443 __END__
 444
 445 =head1 NAME
 446
 447 Mouse::Meta::Attribute - The Mouse attribute metaclass
 448
 449 =head1 VERSION
 450
 451 This document describes Mouse version 0.4501
 452
 453 =head1 METHODS
 454
 455 =head2 C<< new(%options) -> Mouse::Meta::Attribute >>
 456
 457 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 458
 459 It adds the following options to the constructor:
 460
 461 =over 4
 462
 463 =item C<< is => 'ro', 'rw', 'bare' >>
 464
 465 This provides a shorthand for specifying the C<reader>, C<writer>, or
 466 C<accessor> names. If the attribute is read-only ('ro') then it will
 467 have a C<reader> method with the same attribute as the name.
 468
 469 If it is read-write ('rw') then it will have an C<accessor> method
 470 with the same name. If you provide an explicit C<writer> for a
 471 read-write attribute, then you will have a C<reader> with the same
 472 name as the attribute, and a C<writer> with the name you provided.
 473
 474 Use 'bare' when you are deliberately not installing any methods
 475 (accessor, reader, etc.) associated with this attribute; otherwise,
 476 Moose will issue a deprecation warning when this attribute is added to a
 477 metaclass.
 478
 479 =item C<< isa => Type >>
 480
 481 This option accepts a type. The type can be a string, which should be
 482 a type name. If the type name is unknown, it is assumed to be a class
 483 name.
 484
 485 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 486
 487 If you I<also> provide a C<does> option, then your C<isa> option must
 488 be a class name, and that class must do the role specified with
 489 C<does>.
 490
 491 =item C<< does => Role >>
 492
 493 This is short-hand for saying that the attribute's type must be an
 494 object which does the named role.
 495
 496 B<This option is not yet supported.>
 497
 498 =item C<< coerce => Bool >>
 499
 500 This option is only valid for objects with a type constraint
 501 (C<isa>). If this is true, then coercions will be applied whenever
 502 this attribute is set.
 503
 504 You can make both this and the C<weak_ref> option true.
 505
 506 =item C<< trigger => CodeRef >>
 507
 508 This option accepts a subroutine reference, which will be called after
 509 the attribute is set.
 510
 511 =item C<< required => Bool >>
 512
 513 An attribute which is required must be provided to the constructor. An
 514 attribute which is required can also have a C<default> or C<builder>,
 515 which will satisfy its required-ness.
 516
 517 A required attribute must have a C<default>, C<builder> or a
 518 non-C<undef> C<init_arg>
 519
 520 =item C<< lazy => Bool >>
 521
 522 A lazy attribute must have a C<default> or C<builder>. When an
 523 attribute is lazy, the default value will not be calculated until the
 524 attribute is read.
 525
 526 =item C<< weak_ref => Bool >>
 527
 528 If this is true, the attribute's value will be stored as a weak
 529 reference.
 530
 531 =item C<< auto_deref => Bool >>
 532
 533 If this is true, then the reader will dereference the value when it is
 534 called. The attribute must have a type constraint which defines the
 535 attribute as an array or hash reference.
 536
 537 =item C<< lazy_build => Bool >>
 538
 539 Setting this to true makes the attribute lazy and provides a number of
 540 default methods.
 541
 542   has 'size' => (
 543       is         => 'ro',
 544       lazy_build => 1,
 545   );
 546
 547 is equivalent to this:
 548
 549   has 'size' => (
 550       is        => 'ro',
 551       lazy      => 1,
 552       builder   => '_build_size',
 553       clearer   => 'clear_size',
 554       predicate => 'has_size',
 555   );
 556
 557 =back
 558
 559 =head2 C<< associate_method(MethodName) >>
 560
 561 Associates a method with the attribute. Typically, this is called internally
 562 when an attribute generates its accessors.
 563
 564 Currently the argument I<MethodName> is ignored in Mouse.
 565
 566 =head2 C<< verify_against_type_constraint(Item) -> TRUE | ERROR >>
 567
 568 Checks that the given value passes this attribute's type constraint. Returns C<true>
 569 on success, otherwise C<confess>es.
 570
 571 =head2 C<< clone_and_inherit_options(options) -> Mouse::Meta::Attribute >>
 572
 573 Creates a new attribute in the owner class, inheriting options from parent classes.
 574 Accessors and helper methods are installed. Some error checking is done.
 575
 576 =head2 C<< get_read_method_ref >>
 577
 578 =head2 C<< get_write_method_ref >>
 579
 580 Returns the subroutine reference of a method suitable for reading or
 581 writing the attribute's value in the associated class. These methods
 582 always return a subroutine reference, regardless of whether or not the
 583 attribute is read- or write-only.
 584
 585 =head1 SEE ALSO
 586
 587 L<Moose::Meta::Attribute>
 588
 589 L<Class::MOP::Attribute>
 590
 591 =cut
 592