lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use Mouse::Util qw(:meta); # enables strict and warnings
   3
   4 use Carp ();
   5
   6 use Mouse::Meta::TypeConstraint;
   7
   8 my %valid_options = map { $_ => undef } (
   9   'accessor',
  10   'auto_deref',
  11   'builder',
  12   'clearer',
  13   'coerce',
  14   'default',
  15   'documentation',
  16   'does',
  17   'handles',
  18   'init_arg',
  19   'insertion_order',
  20   'is',
  21   'isa',
  22   'lazy',
  23   'lazy_build',
  24   'name',
  25   'predicate',
  26   'reader',
  27   'required',
  28   'traits',
  29   'trigger',
  30   'type_constraint',
  31   'weak_ref',
  32   'writer',
  33
  34   # internally used
  35   'associated_class',
  36   'associated_methods',
  37   '__METACLASS__',
  38
  39   # Moose defines, but Mouse doesn't
  40   #'definition_context',
  41   #'initializer',
  42
  43   # special case for AttributeHelpers
  44   'provides',
  45   'curries',
  46 );
  47
  48 our @CARP_NOT = qw(Mouse::Meta::Class);
  49
  50 sub new {
  51     my $class = shift;
  52     my $name  = shift;
  53
  54     my $args  = $class->Mouse::Object::BUILDARGS(@_);
  55
  56     $class->_process_options($name, $args);
  57
  58     $args->{name} = $name;
  59
  60     # check options
  61     # (1) known by core
  62     my @bad = grep{ !exists $valid_options{$_} } keys %{$args};
  63
  64     # (2) known by subclasses
  65     if(@bad && $class ne __PACKAGE__){
  66         my %valid_attrs = (
  67             map { $_ => undef }
  68             grep { defined }
  69             map { $_->init_arg() }
  70             $class->meta->get_all_attributes()
  71         );
  72         @bad = grep{ !exists $valid_attrs{$_} } @bad;
  73     }
  74
  75     # (3) bad options found
  76     if(@bad){
  77         Carp::carp(
  78             "Found unknown argument(s) passed to '$name' attribute constructor in '$class': "
  79             . Mouse::Util::english_list(@bad));
  80     }
  81
  82     my $self = bless $args, $class;
  83     if($class ne __PACKAGE__){
  84         $class->meta->_initialize_object($self, $args);
  85     }
  86     return $self;
  87 }
  88
  89 sub has_read_method   { $_[0]->has_reader || $_[0]->has_accessor }
  90 sub has_write_method  { $_[0]->has_writer || $_[0]->has_accessor }
  91
  92 sub get_read_method   { $_[0]->reader || $_[0]->accessor }
  93 sub get_write_method  { $_[0]->writer || $_[0]->accessor }
  94
  95 sub get_read_method_ref{
  96     my($self) = @_;
  97     return $self->{_mouse_cache_read_method_ref}
  98         ||= $self->_get_accessor_method_ref('get_read_method', '_generate_reader');
  99 }
 100
 101 sub get_write_method_ref{
 102     my($self) = @_;
 103     return $self->{_mouse_cache_write_method_ref}
 104         ||= $self->_get_accessor_method_ref('get_write_method', '_generate_writer');
 105 }
 106
 107 sub interpolate_class{
 108     my($class, $args) = @_;
 109
 110     if(my $metaclass = delete $args->{metaclass}){
 111         $class = Mouse::Util::resolve_metaclass_alias( Attribute => $metaclass );
 112     }
 113
 114     my @traits;
 115     if(my $traits_ref = delete $args->{traits}){
 116
 117         for (my $i = 0; $i < @{$traits_ref}; $i++) {
 118             my $trait = Mouse::Util::resolve_metaclass_alias(Attribute => $traits_ref->[$i], trait => 1);
 119
 120             next if $class->does($trait);
 121
 122             push @traits, $trait;
 123
 124             # are there options?
 125             push @traits, $traits_ref->[++$i]
 126                 if ref($traits_ref->[$i+1]);
 127         }
 128
 129         if (@traits) {
 130             $class = Mouse::Meta::Class->create_anon_class(
 131                 superclasses => [ $class ],
 132                 roles        => \@traits,
 133                 cache        => 1,
 134             )->name;
 135         }
 136     }
 137
 138     return( $class, @traits );
 139 }
 140
 141 sub verify_against_type_constraint {
 142     my ($self, $value) = @_;
 143
 144     my $type_constraint = $self->{type_constraint};
 145     return 1 if !$type_constraint;
 146     return 1 if $type_constraint->check($value);
 147
 148     $self->_throw_type_constraint_error($value, $type_constraint);
 149 }
 150
 151 sub _throw_type_constraint_error {
 152     my($self, $value, $type) = @_;
 153
 154     $self->throw_error(
 155         sprintf q{Attribute (%s) does not pass the type constraint because: %s},
 156             $self->name,
 157             $type->get_message($value),
 158     );
 159 }
 160
 161 sub illegal_options_for_inheritance {
 162     return qw(reader writer accessor clearer predicate);
 163 }
 164
 165 sub clone_and_inherit_options{
 166     my $self = shift;
 167     my $args = $self->Mouse::Object::BUILDARGS(@_);
 168
 169     foreach my $illegal($self->illegal_options_for_inheritance) {
 170         if(exists $args->{$illegal} and exists $self->{$illegal}) {
 171             $self->throw_error("Illegal inherited option: $illegal");
 172         }
 173     }
 174
 175     foreach my $name(keys %{$self}){
 176         if(!exists $args->{$name}){
 177             $args->{$name} = $self->{$name}; # inherit from self
 178         }
 179     }
 180
 181     my($attribute_class, @traits) = ref($self)->interpolate_class($args);
 182     $args->{traits} = \@traits if @traits;
 183
 184     # remove temporary caches
 185     foreach my $attr(keys %{$args}){
 186         if($attr =~ /\A _mouse_cache_/xms){
 187             delete $args->{$attr};
 188         }
 189     }
 190
 191     # remove default if lazy_build => 1
 192     if($args->{lazy_build}) {
 193         delete $args->{default};
 194     }
 195
 196     return $attribute_class->new($self->name, $args);
 197 }
 198
 199
 200 sub _get_accessor_method_ref {
 201     my($self, $type, $generator) = @_;
 202
 203     my $metaclass = $self->associated_class
 204         || $self->throw_error('No asocciated class for ' . $self->name);
 205
 206     my $accessor = $self->$type();
 207     if($accessor){
 208         return $metaclass->get_method_body($accessor);
 209     }
 210     else{
 211         return $self->accessor_metaclass->$generator($self, $metaclass);
 212     }
 213 }
 214
 215 sub set_value {
 216     my($self, $object, $value) = @_;
 217     return $self->get_write_method_ref()->($object, $value);
 218 }
 219
 220 sub get_value {
 221     my($self, $object) = @_;
 222     return $self->get_read_method_ref()->($object);
 223 }
 224
 225 sub has_value {
 226     my($self, $object) = @_;
 227     my $accessor_ref = $self->{_mouse_cache_predicate_ref}
 228         ||= $self->_get_accessor_method_ref('predicate', '_generate_predicate');
 229
 230     return $accessor_ref->($object);
 231 }
 232
 233 sub clear_value {
 234     my($self, $object) = @_;
 235     my $accessor_ref = $self->{_mouse_cache_crealer_ref}
 236         ||= $self->_get_accessor_method_ref('clearer', '_generate_clearer');
 237
 238     return $accessor_ref->($object);
 239 }
 240
 241 sub associate_method{
 242     #my($attribute, $method_name) = @_;
 243     my($attribute) = @_;
 244     $attribute->{associated_methods}++;
 245     return;
 246 }
 247
 248 sub install_accessors{
 249     my($attribute) = @_;
 250
 251     my $metaclass      = $attribute->associated_class;
 252     my $accessor_class = $attribute->accessor_metaclass;
 253
 254     foreach my $type(qw(accessor reader writer predicate clearer)){
 255         if(exists $attribute->{$type}){
 256             my $generator = '_generate_' . $type;
 257             my $code      = $accessor_class->$generator($attribute, $metaclass);
 258             my $name      = $attribute->{$type};
 259 # TODO: do something for compatibility
 260 #            if( $metaclass->name->can($name) ) {
 261 #                my $t = $metaclass->has_method($name) ? 'method' : 'function';
 262 #                Carp::cluck("You are overwriting a locally defined $t"
 263 #                    . " ($name) with an accessor");
 264 #            }
 265             $metaclass->add_method($name => $code);
 266             $attribute->associate_method($name);
 267         }
 268     }
 269
 270     # install delegation
 271     if(exists $attribute->{handles}){
 272         my %handles = $attribute->_canonicalize_handles();
 273         while(my($handle, $method_to_call) = each %handles){
 274             next if Mouse::Object->can($handle);
 275
 276             if($metaclass->has_method($handle)) {
 277                 $attribute->throw_error("You cannot overwrite a locally defined method ($handle) with a delegation");
 278             }
 279
 280             $metaclass->add_method($handle =>
 281                 $attribute->_make_delegation_method(
 282                     $handle, $method_to_call));
 283
 284             $attribute->associate_method($handle);
 285         }
 286     }
 287
 288     return;
 289 }
 290
 291 sub delegation_metaclass() { ## no critic
 292     'Mouse::Meta::Method::Delegation'
 293 }
 294
 295 sub _canonicalize_handles {
 296     my($self) = @_;
 297     my $handles = $self->{handles};
 298
 299     my $handle_type = ref $handles;
 300     if ($handle_type eq 'HASH') {
 301         return %$handles;
 302     }
 303     elsif ($handle_type eq 'ARRAY') {
 304         return map { $_ => $_ } @$handles;
 305     }
 306     elsif ($handle_type eq 'Regexp') {
 307         my $meta = $self->_find_delegate_metaclass();
 308         return map  { $_ => $_ }
 309                grep { /$handles/ }
 310                    Mouse::Util::is_a_metarole($meta)
 311                         ? $meta->get_method_list
 312                         : $meta->get_all_method_names;
 313     }
 314     elsif ($handle_type eq 'CODE') {
 315         return $handles->( $self, $self->_find_delegate_metaclass() );
 316     }
 317     else {
 318         $self->throw_error("Unable to canonicalize the 'handles' option with $handles");
 319     }
 320 }
 321
 322 sub _find_delegate_metaclass {
 323     my($self) = @_;
 324     my $meta;
 325     if($self->{isa}) {
 326         $meta = Mouse::Meta::Class->initialize("$self->{isa}");
 327     }
 328     elsif($self->{does}) {
 329         $meta = Mouse::Util::get_metaclass_by_name("$self->{does}");
 330     }
 331     defined($meta) or $self->throw_error(
 332         "Cannot find delegate metaclass for attribute " . $self->name);
 333     return $meta;
 334 }
 335
 336
 337 sub _make_delegation_method {
 338     my($self, $handle, $method_to_call) = @_;
 339     return Mouse::Util::load_class($self->delegation_metaclass)
 340         ->_generate_delegation($self, $handle, $method_to_call);
 341 }
 342
 343 1;
 344 __END__
 345
 346 =head1 NAME
 347
 348 Mouse::Meta::Attribute - The Mouse attribute metaclass
 349
 350 =head1 VERSION
 351
 352 This document describes Mouse version 0.95
 353
 354 =head1 DESCRIPTION
 355
 356 This is a meta object protocol for Mouse attributes,
 357 which is a subset of Moose::Meta::Attribute.
 358
 359 =head1 METHODS
 360
 361 =head2 C<< new(%options) -> Mouse::Meta::Attribute >>
 362
 363 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 364
 365 It adds the following options to the constructor:
 366
 367 =over 4
 368
 369 =item C<< is => 'ro', 'rw', 'bare' >>
 370
 371 This provides a shorthand for specifying the C<reader>, C<writer>, or
 372 C<accessor> names. If the attribute is read-only ('ro') then it will
 373 have a C<reader> method with the same attribute as the name.
 374
 375 If it is read-write ('rw') then it will have an C<accessor> method
 376 with the same name. If you provide an explicit C<writer> for a
 377 read-write attribute, then you will have a C<reader> with the same
 378 name as the attribute, and a C<writer> with the name you provided.
 379
 380 Use 'bare' when you are deliberately not installing any methods
 381 (accessor, reader, etc.) associated with this attribute; otherwise,
 382 Moose will issue a deprecation warning when this attribute is added to a
 383 metaclass.
 384
 385 =item C<< isa => Type >>
 386
 387 This option accepts a type. The type can be a string, which should be
 388 a type name. If the type name is unknown, it is assumed to be a class
 389 name.
 390
 391 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 392
 393 If you I<also> provide a C<does> option, then your C<isa> option must
 394 be a class name, and that class must do the role specified with
 395 C<does>.
 396
 397 =item C<< does => Role >>
 398
 399 This is short-hand for saying that the attribute's type must be an
 400 object which does the named role.
 401
 402 B<This option is not yet supported.>
 403
 404 =item C<< coerce => Bool >>
 405
 406 This option is only valid for objects with a type constraint
 407 (C<isa>). If this is true, then coercions will be applied whenever
 408 this attribute is set.
 409
 410 You can make both this and the C<weak_ref> option true.
 411
 412 =item C<< trigger => CodeRef >>
 413
 414 This option accepts a subroutine reference, which will be called after
 415 the attribute is set.
 416
 417 =item C<< required => Bool >>
 418
 419 An attribute which is required must be provided to the constructor. An
 420 attribute which is required can also have a C<default> or C<builder>,
 421 which will satisfy its required-ness.
 422
 423 A required attribute must have a C<default>, C<builder> or a
 424 non-C<undef> C<init_arg>
 425
 426 =item C<< lazy => Bool >>
 427
 428 A lazy attribute must have a C<default> or C<builder>. When an
 429 attribute is lazy, the default value will not be calculated until the
 430 attribute is read.
 431
 432 =item C<< weak_ref => Bool >>
 433
 434 If this is true, the attribute's value will be stored as a weak
 435 reference.
 436
 437 =item C<< auto_deref => Bool >>
 438
 439 If this is true, then the reader will dereference the value when it is
 440 called. The attribute must have a type constraint which defines the
 441 attribute as an array or hash reference.
 442
 443 =item C<< lazy_build => Bool >>
 444
 445 Setting this to true makes the attribute lazy and provides a number of
 446 default methods.
 447
 448   has 'size' => (
 449       is         => 'ro',
 450       lazy_build => 1,
 451   );
 452
 453 is equivalent to this:
 454
 455   has 'size' => (
 456       is        => 'ro',
 457       lazy      => 1,
 458       builder   => '_build_size',
 459       clearer   => 'clear_size',
 460       predicate => 'has_size',
 461   );
 462
 463 =back
 464
 465 =head2 C<< associate_method(MethodName) >>
 466
 467 Associates a method with the attribute. Typically, this is called internally
 468 when an attribute generates its accessors.
 469
 470 Currently the argument I<MethodName> is ignored in Mouse.
 471
 472 =head2 C<< verify_against_type_constraint(Item) -> TRUE | ERROR >>
 473
 474 Checks that the given value passes this attribute's type constraint. Returns C<true>
 475 on success, otherwise C<confess>es.
 476
 477 =head2 C<< clone_and_inherit_options(options) -> Mouse::Meta::Attribute >>
 478
 479 Creates a new attribute in the owner class, inheriting options from parent classes.
 480 Accessors and helper methods are installed. Some error checking is done.
 481
 482 =head2 C<< get_read_method_ref >>
 483
 484 =head2 C<< get_write_method_ref >>
 485
 486 Returns the subroutine reference of a method suitable for reading or
 487 writing the attribute's value in the associated class. These methods
 488 always return a subroutine reference, regardless of whether or not the
 489 attribute is read- or write-only.
 490
 491 =head1 SEE ALSO
 492
 493 L<Moose::Meta::Attribute>
 494
 495 L<Class::MOP::Attribute>
 496
 497 =cut
 498