lib/Mouse/Meta/Attribute.pm

   1 package Mouse::Meta::Attribute;
   2 use Mouse::Util qw(:meta); # enables strict and warnings
   3
   4 use Carp ();
   5
   6 use Mouse::Meta::TypeConstraint;
   7
   8 #use Mouse::Meta::Method::Accessor;
   9 use Mouse::Meta::Method::Delegation;
  10
  11 sub _process_options{
  12     my($class, $name, $args) = @_;
  13
  14
  15     # XXX: for backward compatibility (with method modifiers)
  16     if($class->can('canonicalize_args') != \&canonicalize_args){
  17         %{$args} = $class->canonicalize_args($name, %{$args});
  18     }
  19
  20     # taken from Class::MOP::Attribute::new
  21
  22     defined($name)
  23         or $class->throw_error('You must provide a name for the attribute');
  24
  25     if(!exists $args->{init_arg}){
  26         $args->{init_arg} = $name;
  27     }
  28
  29     # 'required' requires eigher 'init_arg', 'builder', or 'default'
  30     my $can_be_required = defined( $args->{init_arg} );
  31
  32     if(exists $args->{builder}){
  33         # XXX:
  34         # Moose refuses a CODE ref builder, but Mouse doesn't for backward compatibility
  35         # This feature will be changed in a future. (gfx)
  36         $class->throw_error('builder must be a defined scalar value which is a method name')
  37             #if ref $args->{builder} || !defined $args->{builder};
  38             if !defined $args->{builder};
  39
  40         $can_be_required++;
  41     }
  42     elsif(exists $args->{default}){
  43         if(ref $args->{default} && ref($args->{default}) ne 'CODE'){
  44             $class->throw_error("References are not allowed as default values, you must "
  45                               . "wrap the default of '$name' in a CODE reference (ex: sub { [] } and not [])");
  46         }
  47         $can_be_required++;
  48     }
  49
  50     if( $args->{required} && !$can_be_required ) {
  51         $class->throw_error("You cannot have a required attribute ($name) without a default, builder, or an init_arg");
  52     }
  53
  54     # taken from Mouse::Meta::Attribute->new and _process_args->
  55
  56     if(exists $args->{is}){
  57         my $is = $args->{is};
  58
  59         if($is eq 'ro'){
  60             $args->{reader} ||= $name;
  61         }
  62         elsif($is eq 'rw'){
  63             if(exists $args->{writer}){
  64                 $args->{reader} ||= $name;
  65              }
  66              else{
  67                 $args->{accessor} ||= $name;
  68              }
  69         }
  70         elsif($is eq 'bare'){
  71             # do nothing, but don't complain (later) about missing methods
  72         }
  73         else{
  74             $is = 'undef' if !defined $is;
  75             $class->throw_error("I do not understand this option (is => $is) on attribute ($name)");
  76         }
  77     }
  78
  79     my $tc;
  80     if(exists $args->{isa}){
  81         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_isa_type_constraint($args->{isa});
  82     }
  83     elsif(exists $args->{does}){
  84         $args->{type_constraint} = Mouse::Util::TypeConstraints::find_or_create_does_type_constraint($args->{does});
  85     }
  86     $tc = $args->{type_constraint};
  87
  88     if($args->{coerce}){
  89         defined($tc)
  90             || $class->throw_error("You cannot have coercion without specifying a type constraint on attribute ($name)");
  91
  92         $args->{weak_ref}
  93             && $class->throw_error("You cannot have a weak reference to a coerced value on attribute ($name)");
  94     }
  95
  96     if ($args->{lazy_build}) {
  97         exists($args->{default})
  98             && $class->throw_error("You can not use lazy_build and default for the same attribute ($name)");
  99
 100         $args->{lazy}      = 1;
 101         $args->{builder} ||= "_build_${name}";
 102         if ($name =~ /^_/) {
 103             $args->{clearer}   ||= "_clear${name}";
 104             $args->{predicate} ||= "_has${name}";
 105         }
 106         else {
 107             $args->{clearer}   ||= "clear_${name}";
 108             $args->{predicate} ||= "has_${name}";
 109         }
 110     }
 111
 112     if ($args->{auto_deref}) {
 113         defined($tc)
 114             || $class->throw_error("You cannot auto-dereference without specifying a type constraint on attribute ($name)");
 115
 116         ( $tc->is_a_type_of('ArrayRef') || $tc->is_a_type_of('HashRef') )
 117             || $class->throw_error("You cannot auto-dereference anything other than a ArrayRef or HashRef on attribute ($name)");
 118     }
 119
 120     if (exists $args->{trigger}) {
 121         ('CODE' eq ref $args->{trigger})
 122             || $class->throw_error("Trigger must be a CODE ref on attribute ($name)");
 123     }
 124
 125     if ($args->{lazy}) {
 126         (exists $args->{default} || defined $args->{builder})
 127             || $class->throw_error("You cannot have lazy attribute ($name) without specifying a default value for it");
 128     }
 129
 130     return;
 131 }
 132
 133 sub new {
 134     my $class = shift;
 135     my $name  = shift;
 136
 137     my %args  = (@_ == 1) ? %{ $_[0] } : @_;
 138
 139     $class->_process_options($name, \%args);
 140
 141     $args{name} = $name;
 142
 143     my $self = bless \%args, $class;
 144
 145     # extra attributes
 146     if($class ne __PACKAGE__){
 147         $class->meta->_initialize_object($self, \%args);
 148     }
 149
 150 # XXX: there is no fast way to check attribute validity
 151 #    my @bad = ...;
 152 #    if(@bad){
 153 #        @bad = sort @bad;
 154 #        Carp::cluck("Found unknown argument(s) passed to '$name' attribute constructor in '$class': @bad");
 155 #    }
 156
 157     return $self;
 158 }
 159
 160 sub has_read_method      { $_[0]->has_reader || $_[0]->has_accessor }
 161 sub has_write_method     { $_[0]->has_writer || $_[0]->has_accessor }
 162
 163 sub _create_args { # DEPRECATED
 164     $_[0]->{_create_args} = $_[1] if @_ > 1;
 165     $_[0]->{_create_args}
 166 }
 167
 168 sub interpolate_class{
 169     my($class, $args) = @_;
 170
 171     if(my $metaclass = delete $args->{metaclass}){
 172         $class = Mouse::Util::resolve_metaclass_alias( Attribute => $metaclass );
 173     }
 174
 175     my @traits;
 176     if(my $traits_ref = delete $args->{traits}){
 177
 178         for (my $i = 0; $i < @{$traits_ref}; $i++) {
 179             my $trait = Mouse::Util::resolve_metaclass_alias(Attribute => $traits_ref->[$i], trait => 1);
 180
 181             next if $class->does($trait);
 182
 183             push @traits, $trait;
 184
 185             # are there options?
 186             push @traits, $traits_ref->[++$i]
 187                 if ref($traits_ref->[$i+1]);
 188         }
 189
 190         if (@traits) {
 191             $class = Mouse::Meta::Class->create_anon_class(
 192                 superclasses => [ $class ],
 193                 roles        => \@traits,
 194                 cache        => 1,
 195             )->name;
 196         }
 197     }
 198
 199     return( $class, @traits );
 200 }
 201
 202 sub canonicalize_args{ # DEPRECATED
 203     my ($self, $name, %args) = @_;
 204
 205     Carp::cluck("$self->canonicalize_args has been deprecated."
 206         . "Use \$self->_process_options instead.")
 207             if Mouse::Util::_MOUSE_VERBOSE;
 208
 209     return %args;
 210 }
 211
 212 sub create { # DEPRECATED
 213     my ($self, $class, $name, %args) = @_;
 214
 215     Carp::cluck("$self->create has been deprecated."
 216         . "Use \$meta->add_attribute and \$attr->install_accessors instead.")
 217             if Mouse::Util::_MOUSE_VERBOSE;
 218
 219     # noop
 220     return $self;
 221 }
 222
 223 sub _coerce_and_verify {
 224     my($self, $value, $instance) = @_;
 225
 226     my $type_constraint = $self->{type_constraint};
 227     return $value if !defined $type_constraint;
 228
 229     if ($self->should_coerce && $type_constraint->has_coercion) {
 230         $value = $type_constraint->coerce($value);
 231     }
 232
 233     $self->verify_against_type_constraint($value);
 234
 235     return $value;
 236 }
 237
 238 sub verify_against_type_constraint {
 239     my ($self, $value) = @_;
 240
 241     my $type_constraint = $self->{type_constraint};
 242     return 1 if !$type_constraint;
 243     return 1 if $type_constraint->check($value);
 244
 245     $self->verify_type_constraint_error($self->name, $value, $type_constraint);
 246 }
 247
 248 sub verify_type_constraint_error {
 249     my($self, $name, $value, $type) = @_;
 250     $self->throw_error("Attribute ($name) does not pass the type constraint because: "
 251         . $type->get_message($value));
 252 }
 253
 254 sub coerce_constraint { # DEPRECATED
 255     my $type = $_[0]->{type_constraint}
 256         or return $_[1];
 257
 258     Carp::cluck("coerce_constraint() has been deprecated, which was an internal utility anyway");
 259
 260     return Mouse::Util::TypeConstraints->typecast_constraints($_[0]->associated_class->name, $type, $_[1]);
 261 }
 262
 263 sub clone_and_inherit_options{
 264     my($self, %args) = @_;
 265
 266     my($attribute_class, @traits) = ref($self)->interpolate_class(\%args);
 267
 268     $args{traits} = \@traits if @traits;
 269     # do not inherit the 'handles' attribute
 270     foreach my $name(keys %{$self}){
 271         if(!exists $args{$name} && $name ne 'handles'){
 272             $args{$name} = $self->{$name};
 273         }
 274     }
 275     return $attribute_class->new($self->name, %args);
 276 }
 277
 278 sub clone_parent { # DEPRECATED
 279     my $self  = shift;
 280     my $class = shift;
 281     my $name  = shift;
 282     my %args  = ($self->get_parent_args($class, $name), @_);
 283
 284     Carp::cluck("$self->clone_parent has been deprecated."
 285         . "Use \$meta->add_attribute and \$attr->install_accessors instead.")
 286         if Mouse::Util::_MOUSE_VERBOSE;
 287
 288     $self->clone_and_inherited_args($class, $name, %args);
 289 }
 290
 291 sub get_parent_args { # DEPRECATED
 292     my $self  = shift;
 293     my $class = shift;
 294     my $name  = shift;
 295
 296     for my $super ($class->linearized_isa) {
 297         my $super_attr = $super->can("meta") && $super->meta->get_attribute($name)
 298             or next;
 299         return %{ $super_attr->_create_args };
 300     }
 301
 302     $self->throw_error("Could not find an attribute by the name of '$name' to inherit from");
 303 }
 304
 305
 306 sub get_read_method {
 307     $_[0]->reader || $_[0]->accessor
 308 }
 309 sub get_write_method {
 310     $_[0]->writer || $_[0]->accessor
 311 }
 312
 313 sub get_read_method_ref{
 314     my($self) = @_;
 315
 316     $self->{_read_method_ref} ||= do{
 317         my $metaclass = $self->associated_class
 318             or $self->throw_error('No asocciated class for ' . $self->name);
 319
 320         my $reader = $self->{reader} || $self->{accessor};
 321         if($reader){
 322             $metaclass->name->can($reader);
 323         }
 324         else{
 325             $self->accessor_metaclass->_generate_reader($self, $metaclass);
 326         }
 327     };
 328 }
 329
 330 sub get_write_method_ref{
 331     my($self) = @_;
 332
 333     $self->{_write_method_ref} ||= do{
 334         my $metaclass = $self->associated_class
 335             or $self->throw_error('No asocciated class for ' . $self->name);
 336
 337         my $reader = $self->{writer} || $self->{accessor};
 338         if($reader){
 339             $metaclass->name->can($reader);
 340         }
 341         else{
 342             $self->accessor_metaclass->_generate_writer($self, $metaclass);
 343         }
 344     };
 345 }
 346
 347 sub _canonicalize_handles {
 348     my($self, $handles) = @_;
 349
 350     if (ref($handles) eq 'HASH') {
 351         return %$handles;
 352     }
 353     elsif (ref($handles) eq 'ARRAY') {
 354         return map { $_ => $_ } @$handles;
 355     }
 356     elsif (ref($handles) eq 'Regexp') {
 357         my $class_or_role = ($self->{isa} || $self->{does})
 358             || $self->throw_error("Cannot delegate methods based on a Regexp without a type constraint (isa)");
 359
 360         my $meta = Mouse::Meta::Class->initialize("$class_or_role"); # "" for stringify
 361         return map  { $_ => $_ }
 362                grep { !Mouse::Object->can($_) && $_ =~ $handles }
 363                    Mouse::Util::is_a_metarole($meta)
 364                         ? $meta->get_method_list
 365                         : $meta->get_all_method_names;
 366     }
 367     else {
 368         $self->throw_error("Unable to canonicalize the 'handles' option with $handles");
 369     }
 370 }
 371
 372 sub associate_method{
 373     my ($attribute, $method_name) = @_;
 374     $attribute->{associated_methods}++;
 375     return;
 376 }
 377
 378 sub delegation_metaclass() { 'Mouse::Meta::Method::Delegation' }
 379
 380 sub install_accessors{
 381     my($attribute) = @_;
 382
 383     my $metaclass      = $attribute->associated_class;
 384     my $accessor_class = $attribute->accessor_metaclass;
 385
 386     foreach my $type(qw(accessor reader writer predicate clearer)){
 387         if(exists $attribute->{$type}){
 388             my $generator = '_generate_' . $type;
 389             my $code      = $accessor_class->$generator($attribute, $metaclass);
 390             $metaclass->add_method($attribute->{$type} => $code);
 391             $attribute->associate_method($attribute->{$type});
 392         }
 393     }
 394
 395     # install delegation
 396     if(exists $attribute->{handles}){
 397         my $delegation_class = $attribute->delegation_metaclass;
 398         my %handles = $attribute->_canonicalize_handles($attribute->{handles});
 399         my $reader  = $attribute->get_read_method_ref;
 400
 401         while(my($handle_name, $method_to_call) = each %handles){
 402             my $code = $delegation_class->_generate_delegation($attribute, $metaclass,
 403                 $reader, $handle_name, $method_to_call);
 404
 405             $metaclass->add_method($handle_name => $code);
 406             $attribute->associate_method($handle_name);
 407         }
 408     }
 409
 410     if($attribute->can('create') != \&create){
 411         # backword compatibility
 412         $attribute->create($metaclass, $attribute->name, %{$attribute});
 413     }
 414
 415     return;
 416 }
 417
 418 sub throw_error{
 419     my $self = shift;
 420
 421     my $metaclass = (ref $self && $self->associated_class) || 'Mouse::Meta::Class';
 422     $metaclass->throw_error(@_, depth => 1);
 423 }
 424
 425 1;
 426 __END__
 427
 428 =head1 NAME
 429
 430 Mouse::Meta::Attribute - The Mouse attribute metaclass
 431
 432 =head1 VERSION
 433
 434 This document describes Mouse version 0.40_09
 435
 436 =head1 METHODS
 437
 438 =head2 C<< new(%options) -> Mouse::Meta::Attribute >>
 439
 440 Instantiates a new Mouse::Meta::Attribute. Does nothing else.
 441
 442 It adds the following options to the constructor:
 443
 444 =over 4
 445
 446 =item C<< is => 'ro', 'rw', 'bare' >>
 447
 448 This provides a shorthand for specifying the C<reader>, C<writer>, or
 449 C<accessor> names. If the attribute is read-only ('ro') then it will
 450 have a C<reader> method with the same attribute as the name.
 451
 452 If it is read-write ('rw') then it will have an C<accessor> method
 453 with the same name. If you provide an explicit C<writer> for a
 454 read-write attribute, then you will have a C<reader> with the same
 455 name as the attribute, and a C<writer> with the name you provided.
 456
 457 Use 'bare' when you are deliberately not installing any methods
 458 (accessor, reader, etc.) associated with this attribute; otherwise,
 459 Moose will issue a deprecation warning when this attribute is added to a
 460 metaclass.
 461
 462 =item C<< isa => Type >>
 463
 464 This option accepts a type. The type can be a string, which should be
 465 a type name. If the type name is unknown, it is assumed to be a class
 466 name.
 467
 468 This option can also accept a L<Moose::Meta::TypeConstraint> object.
 469
 470 If you I<also> provide a C<does> option, then your C<isa> option must
 471 be a class name, and that class must do the role specified with
 472 C<does>.
 473
 474 =item C<< does => Role >>
 475
 476 This is short-hand for saying that the attribute's type must be an
 477 object which does the named role.
 478
 479 B<This option is not yet supported.>
 480
 481 =item C<< coerce => Bool >>
 482
 483 This option is only valid for objects with a type constraint
 484 (C<isa>). If this is true, then coercions will be applied whenever
 485 this attribute is set.
 486
 487 You can make both this and the C<weak_ref> option true.
 488
 489 =item C<< trigger => CodeRef >>
 490
 491 This option accepts a subroutine reference, which will be called after
 492 the attribute is set.
 493
 494 =item C<< required => Bool >>
 495
 496 An attribute which is required must be provided to the constructor. An
 497 attribute which is required can also have a C<default> or C<builder>,
 498 which will satisfy its required-ness.
 499
 500 A required attribute must have a C<default>, C<builder> or a
 501 non-C<undef> C<init_arg>
 502
 503 =item C<< lazy => Bool >>
 504
 505 A lazy attribute must have a C<default> or C<builder>. When an
 506 attribute is lazy, the default value will not be calculated until the
 507 attribute is read.
 508
 509 =item C<< weak_ref => Bool >>
 510
 511 If this is true, the attribute's value will be stored as a weak
 512 reference.
 513
 514 =item C<< auto_deref => Bool >>
 515
 516 If this is true, then the reader will dereference the value when it is
 517 called. The attribute must have a type constraint which defines the
 518 attribute as an array or hash reference.
 519
 520 =item C<< lazy_build => Bool >>
 521
 522 Setting this to true makes the attribute lazy and provides a number of
 523 default methods.
 524
 525   has 'size' => (
 526       is         => 'ro',
 527       lazy_build => 1,
 528   );
 529
 530 is equivalent to this:
 531
 532   has 'size' => (
 533       is        => 'ro',
 534       lazy      => 1,
 535       builder   => '_build_size',
 536       clearer   => 'clear_size',
 537       predicate => 'has_size',
 538   );
 539
 540 =back
 541
 542 =head2 C<< associate_method(MethodName) >>
 543
 544 Associates a method with the attribute. Typically, this is called internally
 545 when an attribute generates its accessors.
 546
 547 Currently the argument I<MethodName> is ignored in Mouse.
 548
 549 =head2 C<< verify_against_type_constraint(Item) -> TRUE | ERROR >>
 550
 551 Checks that the given value passes this attribute's type constraint. Returns C<true>
 552 on success, otherwise C<confess>es.
 553
 554 =head2 C<< clone_and_inherit_options(options) -> Mouse::Meta::Attribute >>
 555
 556 Creates a new attribute in the owner class, inheriting options from parent classes.
 557 Accessors and helper methods are installed. Some error checking is done.
 558
 559 =head2 C<< get_read_method_ref >>
 560
 561 =head2 C<< get_write_method_ref >>
 562
 563 Returns the subroutine reference of a method suitable for reading or
 564 writing the attribute's value in the associated class. These methods
 565 always return a subroutine reference, regardless of whether or not the
 566 attribute is read- or write-only.
 567
 568 =head1 SEE ALSO
 569
 570 L<Moose::Meta::Attribute>
 571
 572 L<Class::MOP::Attribute>
 573
 574 =cut
 575