lib/Mouse/Exporter.pm

   1 package Mouse::Exporter;
   2 use strict;
   3 use warnings;
   4
   5 use Carp qw(confess);
   6
   7 my %SPEC;
   8
   9 use constant _strict_bits => strict::bits(qw(subs refs vars));
  10
  11 # it must be "require", because Mouse::Util depends on Mouse::Exporter,
  12 # which depends on Mouse::Util::import()
  13 require Mouse::Util;
  14
  15 sub import{
  16     $^H              |= _strict_bits;         # strict->import;
  17     ${^WARNING_BITS}  = $warnings::Bits{all}; # warnings->import;
  18     return;
  19 }
  20
  21
  22 sub setup_import_methods{
  23     my($class, %args) = @_;
  24
  25     my $exporting_package = $args{exporting_package} ||= caller();
  26
  27     my($import, $unimport) = $class->build_import_methods(%args);
  28
  29     no strict 'refs';
  30
  31     *{$exporting_package . '::import'}    = $import;
  32     *{$exporting_package . '::unimport'}  = $unimport;
  33
  34     # for backward compatibility
  35     *{$exporting_package . '::export_to_level'} = sub{
  36         my($package, $level, undef, @args) = @_; # the third argument is redundant
  37         $package->import({ into_level => $level + 1 }, @args);
  38     };
  39     *{$exporting_package . '::export'} = sub{
  40         my($package, $into, @args) = @_;
  41         $package->import({ into => $into }, @args);
  42     };
  43     return;
  44 }
  45
  46 sub build_import_methods{
  47     my($class, %args) = @_;
  48
  49     my $exporting_package = $args{exporting_package} ||= caller();
  50
  51     $SPEC{$exporting_package} = \%args;
  52
  53     # canonicalize args
  54     my @export_from;
  55     if($args{also}){
  56         my %seen;
  57         my @stack = ($exporting_package);
  58
  59         while(my $current = shift @stack){
  60             push @export_from, $current;
  61
  62             my $also = $SPEC{$current}{also} or next;
  63             push @stack, grep{ !$seen{$_}++ } ref($also) ? @{ $also } : $also;
  64         }
  65     }
  66     else{
  67         @export_from = ($exporting_package);
  68     }
  69
  70     {
  71         my %exports;
  72         my @removables;
  73         my @all;
  74
  75         my @init_meta_methods;
  76
  77         foreach my $package(@export_from){
  78             my $spec = $SPEC{$package} or next;
  79
  80             if(my $as_is = $spec->{as_is}){
  81                 foreach my $thingy (@{$as_is}){
  82                     my($code_package, $code_name, $code);
  83
  84                     if(ref($thingy)){
  85                         $code = $thingy;
  86                         ($code_package, $code_name) = Mouse::Util::get_code_info($code);
  87                     }
  88                     else{
  89                         no strict 'refs';
  90                         $code_package = $package;
  91                         $code_name    = $thingy;
  92                         $code         = \&{ $code_package . '::' . $code_name };
  93                    }
  94
  95                     push @all, $code_name;
  96                     $exports{$code_name} = $code;
  97                     if($code_package eq $package){
  98                         push @removables, $code_name;
  99                     }
 100                 }
 101             }
 102
 103             if(my $init_meta = $package->can('init_meta')){
 104                 if(!grep{ $_ == $init_meta } @init_meta_methods){
 105                     push @init_meta_methods, $init_meta;
 106                 }
 107             }
 108         }
 109         $args{EXPORTS}    = \%exports;
 110         $args{REMOVABLES} = \@removables;
 111
 112         $args{groups}{all}     ||= \@all;
 113
 114         if(my $default_list = $args{groups}{default}){
 115             my %default;
 116             foreach my $keyword(@{$default_list}){
 117                 $default{$keyword} = $exports{$keyword}
 118                     || confess(qq{The $exporting_package package does not export "$keyword"});
 119             }
 120             $args{DEFAULT} = \%default;
 121         }
 122         else{
 123             $args{groups}{default} ||= \@all;
 124             $args{DEFAULT}           = $args{EXPORTS};
 125         }
 126
 127         if(@init_meta_methods){
 128             $args{INIT_META} = \@init_meta_methods;
 129         }
 130     }
 131
 132     return (\&do_import, \&do_unimport);
 133 }
 134
 135
 136 # the entity of general import()
 137 sub do_import {
 138     my($package, @args) = @_;
 139
 140     my $spec = $SPEC{$package}
 141         || confess("The package $package package does not use Mouse::Exporter");
 142
 143     my $into = _get_caller_package(ref($args[0]) ? shift @args : undef);
 144
 145     my @exports;
 146
 147     foreach my $arg(@args){
 148         if($arg =~ s/^-//){
 149             Mouse::Util::not_supported("-$arg");
 150         }
 151         elsif($arg =~ s/^://){
 152             my $group = $spec->{groups}{$arg}
 153                 || confess(qq{The $package package does not export the group "$arg"});
 154             push @exports, @{$group};
 155         }
 156         else{
 157             push @exports, $arg;
 158         }
 159     }
 160
 161     $^H              |= _strict_bits;         # strict->import;
 162     ${^WARNING_BITS}  = $warnings::Bits{all}; # warnings->import;
 163
 164     if($into eq 'main' && !$spec->{_export_to_main}){
 165         warn qq{$package does not export its sugar to the 'main' package.\n};
 166         return;
 167     }
 168
 169     if($spec->{INIT_META}){
 170         foreach my $init_meta(@{$spec->{INIT_META}}){
 171             $into->$init_meta(for_class => $into);
 172         }
 173
 174         # _apply_meta_traits($into); # TODO
 175     }
 176
 177     if(@exports){
 178         foreach my $keyword(@exports){
 179             no strict 'refs';
 180             *{$into.'::'.$keyword} = $spec->{EXPORTS}{$keyword}
 181                 || confess(qq{The $package package does not export "$keyword"});
 182         }
 183     }
 184     else{
 185         my $default = $spec->{DEFAULT};
 186         while(my($keyword, $code) = each %{$default}){
 187             no strict 'refs';
 188             *{$into.'::'.$keyword} = $code;
 189         }
 190     }
 191     return;
 192 }
 193
 194 # the entity of general unimport()
 195 sub do_unimport {
 196     my($package, $arg) = @_;
 197
 198     my $spec = $SPEC{$package}
 199         || confess("The package $package does not use Mouse::Exporter");
 200
 201     my $from = _get_caller_package($arg);
 202
 203     my $stash = do{
 204         no strict 'refs';
 205         \%{$from . '::'}
 206     };
 207
 208     for my $keyword (@{ $spec->{REMOVABLES} }) {
 209         my $gv = \$stash->{$keyword};
 210         if(ref($gv) eq 'GLOB' && *{$gv}{CODE} == $spec->{EXPORTS}{$keyword}){ # make sure it is from us
 211             delete $stash->{$keyword};
 212         }
 213     }
 214     return;
 215 }
 216
 217 # 1 extra level because it's called by import so there's a layer\r
 218 # of indirection\r
 219 sub _LEVEL(){ 1 }
 220
 221 sub _get_caller_package {
 222     my($arg) = @_;
 223
 224     if(ref $arg){
 225         return defined($arg->{into})       ? $arg->{into}
 226              : defined($arg->{into_level}) ? scalar caller(_LEVEL + $arg->{into_level})
 227              :                               scalar caller(_LEVEL);
 228     }
 229     else{
 230         return scalar caller(_LEVEL);
 231     }
 232 }
 233
 234 #sub _spec{ %SPEC }
 235
 236 1;
 237
 238 __END__
 239
 240 =head1 NAME
 241
 242 Mouse::Exporter - make an import() and unimport() just like Mouse.pm
 243
 244 =head1 VERSION
 245
 246 This document describes Mouse version 0.39
 247
 248 =head1 SYNOPSIS
 249
 250     package MyApp::Mouse;\r
 251 \r
 252     use Mouse ();\r
 253     use Mouse::Exporter;\r
 254 \r
 255     Mouse::Exporter->setup_import_methods(\r
 256       as_is     => [ 'has_rw', 'other_sugar', \&Some::Random::thing ],\r
 257       also      => 'Mouse',\r
 258     );\r
 259 \r
 260     sub has_rw {
 261         my $meta = caller->meta;\r
 262         my ( $name, %options ) = @_;\r
 263         $meta->add_attribute(\r
 264           $name,\r
 265           is => 'rw',\r
 266           %options,\r
 267         );\r
 268     }\r
 269 \r
 270     # then later ...\r
 271     package MyApp::User;\r
 272
 273     use MyApp::Mouse;\r
 274 \r
 275     has 'name';\r
 276     has_rw 'size';\r
 277     thing;\r
 278 \r
 279     no MyApp::Mouse;
 280
 281 =head1 DESCRIPTION
 282
 283 This module encapsulates the exporting of sugar functions in a\r
 284 C<Mouse.pm>-like manner. It does this by building custom C<import>,\r
 285 C<unimport> methods for your module, based on a spec you provide.\r
 286
 287 Note that C<Mouse::Exporter> does not provide the C<with_meta> option,
 288 but you can easily get the metaclass by C<< caller->meta >> as L</SYNOPSIS> shows.
 289
 290 =head1 METHODS
 291
 292 =head2 C<< setup_import_methods( ARGS ) >>
 293
 294 =head2 C<< build_import_methods( ARGS ) -> (\&import, \&unimport) >>
 295
 296 =head1 SEE ALSO
 297
 298 L<Moose::Exporter>
 299
 300 =cut
 301